config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CPPFLAGS=$CPPFLAGS
 155   CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 156   save_CXXFLAGS=$CXXFLAGS
 157   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 158   AC_LANG_PUSH(C++)
 159   AC_TRY_COMPILE([], [
 160 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 161             this is a c++11 compiler
 162 #endif
 163   ],
 164   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 165  AC_LANG_POP(C++)
 166  CXXFLAGS=$save_CXXFLAGS
 167  CPPFLAGS=$save_CPPFLAGS])
 168  lyx_use_cxx11=$lyx_cv_cxx_cxx11
 169 ])
 170
 171
 172 dnl Usage: LYX_CXX_USE_REGEX(cxx11_flags)
 173 dnl decide whether we want to use std::regex and set the
 174 dnl LYX_USE_STD_REGEX accordingly.
 175 dnl the extra cxx11 flags have to be passed to the preprocessor. They are
 176 dnl not plainly added to AM_CPPFLAGS because then the objc compiler (mac)
 177 dnl would fail.
 178 AC_DEFUN([LYX_CXX_USE_REGEX],
 179 [AC_ARG_ENABLE(std-regex,
 180   AC_HELP_STRING([--enable-std-regex],[use std::regex instead of boost::regex (default is autodetected)]),
 181   [lyx_std_regex=$enableval],
 182   [save_CPPFLAGS=$CPPFLAGS
 183    # we want to pass -std=c++11 to clang/cpp if necessary
 184    CPPFLAGS="$AM_CPPFLAGS $1 $CPPFLAGS"
 185    save_CXXFLAGS=$CXXFLAGS
 186    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 187    AC_LANG_PUSH(C++)
 188    AC_CHECK_HEADER([regex], [lyx_std_regex=yes], [lyx_std_regex=no])
 189    AC_LANG_POP(C++)
 190    CXXFLAGS=$save_CXXFLAGS
 191    CPPFLAGS=$save_CPPFLAGS
 192    if test x$GXX = xyes && test $lyx_std_regex = yes ; then
 193      AC_MSG_CHECKING([for correct regex implementation])
 194      if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 195        dnl <regex> in gcc is unusable in versions less than 4.9.0
 196        dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 197        case $gxx_version in
 198          4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) lyx_std_regex=no ;;
 199          *) ;;
 200        esac
 201      fi
 202      AC_MSG_RESULT([$lyx_std_regex])
 203    fi])
 204
 205  if test $lyx_std_regex = yes ; then
 206   lyx_flags="$lyx_flags std-regex"
 207   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 208  fi
 209  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 210 ])
 211
 212
 213 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 214 AC_DEFUN([LYX_LIB_STDCXX],
 215 [AC_CACHE_CHECK([whether STL is libstdc++],
 216                [lyx_cv_lib_stdcxx],
 217 [AC_TRY_COMPILE([#include<vector>], [
 218 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 219             this is not libstdc++
 220 #endif
 221 ],
 222 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 223 ])
 224
 225
 226 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 227 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 228 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 229 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 230                [lyx_cv_lib_stdcxx_cxx11_abi],
 231 [AC_TRY_COMPILE([#include<vector>], [
 232 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 233             this is not libstdc++ using the C++11 ABI
 234 #endif
 235 ],
 236 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 237 ])
 238
 239
 240 AC_DEFUN([LYX_PROG_CXX],
 241 [AC_REQUIRE([AC_PROG_CXX])
 242 AC_REQUIRE([AC_PROG_CXXCPP])
 243
 244 AC_LANG_PUSH(C++)
 245 LYX_PROG_CLANG
 246 LYX_LIB_STDCXX
 247 LYX_LIB_STDCXX_CXX11_ABI
 248 AC_LANG_POP(C++)
 249
 250 if test $lyx_cv_lib_stdcxx = "yes" ; then
 251   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 252     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 253   else
 254     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 255   fi
 256 else
 257   if test $lyx_cv_prog_clang = "yes" ; then
 258     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 259   fi
 260 fi
 261
 262 ### We might want to get or shut warnings.
 263 AC_ARG_ENABLE(warnings,
 264   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 265   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 266         enable_warnings=yes;
 267     else
 268         enable_warnings=no;
 269     fi;])
 270 if test x$enable_warnings = xyes ; then
 271   lyx_flags="$lyx_flags warnings"
 272 fi
 273
 274 ### We might want to disable debug
 275 AC_ARG_ENABLE(debug,
 276   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 277   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 278 )
 279
 280 AC_ARG_ENABLE(stdlib-debug,
 281   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 282   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 283           [enable_stdlib_debug=no])]
 284 )
 285
 286 ### set up optimization
 287 AC_ARG_ENABLE(optimization,
 288     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 289     enable_optimization=yes;)
 290 case $enable_optimization in
 291     yes)
 292         if test $lyx_devel_version = yes ; then
 293             lyx_optim=-O
 294         else
 295             lyx_optim=-O2
 296         fi;;
 297     no) lyx_optim=;;
 298     *) lyx_optim=${enable_optimization};;
 299 esac
 300
 301 AC_ARG_ENABLE(assertions,
 302   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 303   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 304           [enable_assertions=no])]
 305 )
 306 if test "x$enable_assertions" = xyes ; then
 307    lyx_flags="$lyx_flags assertions"
 308    AC_DEFINE(ENABLE_ASSERTIONS,1,
 309     [Define if you want assertions to be enabled in the code])
 310 fi
 311
 312 # set the compiler options correctly.
 313 if test x$GXX = xyes; then
 314   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 315   if test x$CLANG = xno; then
 316     dnl Useful for global version info
 317     gxx_version=`${CXX} -dumpversion`
 318     CXX_VERSION="($gxx_version)"
 319   else
 320     gxx_version=clang
 321   fi
 322
 323   AM_CXXFLAGS="$lyx_optim"
 324   if test x$enable_debug = xyes ; then
 325       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 326   fi
 327   if test $build_type = gprof ; then
 328     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 329     AM_LDFLAGS="$AM_LDFLAGS -pg"
 330   fi
 331   if test $build_type = profiling ; then
 332     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 333   fi
 334
 335   if test x$USE_QT5 = xyes ; then
 336       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 337   fi
 338   dnl Warnings are for preprocessor too
 339   if test x$enable_warnings = xyes ; then
 340       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 341   fi
 342   case $gxx_version in
 343       2.*|3.*) AC_ERROR([gcc >= 4.3 is required]);;
 344       4.0*|4.1*|4.2*) AC_ERROR([gcc >= 4.3 is required]);;
 345   esac
 346   if test x$enable_stdlib_debug = xyes ; then
 347     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 348     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 349     case $gxx_version in
 350       *)
 351         lyx_flags="$lyx_flags stdlib-debug"
 352         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 353         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 354         ;;
 355     esac
 356   fi
 357     case $gxx_version in
 358       4.3*|4.4*|4.5*|4.6*)
 359         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 360         dnl The source code relies on that.
 361         cxx11_flags="-std=c++0x";;
 362       clang)
 363         dnl presumably all clang versions support c++11.
 364         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 365         cxx11_flags="-std=c++11"
 366         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 367       *)
 368         AS_CASE([$host], [*cygwin*],
 369                 [cxx11_flags="-std=gnu++11"],
 370                 [cxx11_flags="-std=c++11"]);;
 371     esac
 372     # cxx11_flags is useful when running preprocessor alone
 373     # (see detection of regex).
 374     AM_CXXFLAGS="$cxx11_flags $AM_CXXFLAGS"
 375 fi
 376
 377 LYX_CXX_CXX11
 378 if test $lyx_use_cxx11 = no; then
 379   AC_ERROR([A C++11 compatible compiler is required])
 380 fi
 381 LYX_CXX_USE_REGEX([$cxx11_flags])
 382 ])
 383
 384 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 385 dnl        be used.
 386 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 387         AC_MSG_CHECKING([whether to use included boost library])
 388         AC_ARG_WITH(included-boost,
 389             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 390             [lyx_cv_with_included_boost=$withval],
 391             [lyx_cv_with_included_boost=yes])
 392         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 393         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 394         if test x$lyx_cv_with_included_boost = xyes ; then
 395             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 396             BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 397         else
 398             AC_LANG_PUSH(C++)
 399             save_LIBS=$LIBS
 400
 401             AC_MSG_CHECKING([for multithreaded boost libraries])
 402             LIBS="$save_LIBS -lboost_regex-mt $LIBTHREAD"
 403             AC_LINK_IFELSE(
 404                 [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 405                         [boost::regex reg;])],
 406                 [AC_MSG_RESULT([yes])
 407                  BOOST_MT="-mt"],
 408                 [AC_MSG_RESULT([no])
 409                  AC_MSG_CHECKING([for plain boost libraries])
 410                  LIBS="$save_LIBS -lboost_regex"
 411                  AC_LINK_IFELSE(
 412                      [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 413                              [boost::regex reg;])],
 414                      [AC_MSG_RESULT([yes])
 415                       BOOST_MT=""],
 416                      [AC_MSG_RESULT([no])
 417                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 418                  ])
 419             ])
 420             LIBS=$save_LIBS
 421             AC_LANG_POP(C++)
 422             BOOST_INCLUDES=
 423             if test $lyx_std_regex = yes ; then
 424               BOOST_LIBS=""
 425             else
 426               BOOST_LIBS="-lboost_regex${BOOST_MT}"
 427             fi
 428
 429             dnl In general, system boost libraries are incompatible with
 430             dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 431             dnl details.
 432             if test $enable_stdlib_debug = "yes" ; then
 433                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 434    crashes. Consider using --disable-stdlib-debug or removing
 435    --without-included-boost.])
 436             fi
 437         fi
 438         AC_SUBST(BOOST_INCLUDES)
 439         AC_SUBST(BOOST_LIBS)
 440 ])
 441
 442
 443 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 444 dnl        be used.
 445 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 446   AC_MSG_CHECKING([whether to use included iconv library])
 447   AC_ARG_WITH(included-iconv,
 448     [AC_HELP_STRING([--without-included-iconv], [do not use the iconv lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 449     [lyx_cv_with_included_iconv=$withval],
 450     [lyx_cv_with_included_iconv=no])
 451   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 452   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 453   if test x$lyx_cv_with_included_iconv = xyes ; then
 454 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 455     AC_EILSEQ
 456     AC_TYPE_MBSTATE_T
 457     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 458 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.14/lib/loop_wchar.h.
 459     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 460       USE_MBSTATE_T=1
 461     else
 462       USE_MBSTATE_T=0
 463     fi
 464     AC_SUBST([USE_MBSTATE_T])
 465     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 466       [gl_cv_header_wchar_h_standalone],
 467       [AC_COMPILE_IFELSE(
 468         [AC_LANG_PROGRAM(
 469           [[#include <wchar.h>
 470             wchar_t w;]],
 471           [[]])],
 472         [gl_cv_header_wchar_h_standalone=yes],
 473         [gl_cv_header_wchar_h_standalone=no])])
 474     if test $gl_cv_header_wchar_h_standalone = yes; then
 475       BROKEN_WCHAR_H=0
 476     else
 477       BROKEN_WCHAR_H=1
 478     fi
 479     AC_SUBST([BROKEN_WCHAR_H])
 480 dnl we want const correctness
 481     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 482       [Define as const if the declaration of iconv() needs const.])
 483     ICONV_CONST=const
 484     AC_SUBST([ICONV_CONST])
 485 dnl we build a static lib
 486     DLL_VARIABLE=
 487     AC_SUBST([DLL_VARIABLE])
 488     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.14 -I$(top_builddir)/3rdparty/libiconv'
 489     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 490     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.14/include/iconv.h.in
 491   else
 492     ICONV_INCLUDES=
 493     AM_ICONV
 494     if test "$am_cv_func_iconv" = no; then
 495       AC_MSG_ERROR([cannot find required library iconv.])
 496     else
 497       ICONV_LIBS="$LIBICONV"
 498     fi
 499     ICONV_ICONV_H_IN=
 500   fi
 501   AC_SUBST(ICONV_INCLUDES)
 502   AC_SUBST(ICONV_LIBS)
 503   AC_SUBST(ICONV_ICONV_H_IN)
 504 ])
 505
 506
 507 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 508 dnl        be used.
 509 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 510   AC_MSG_CHECKING([whether to use included zlib library])
 511   AC_ARG_WITH(included-zlib,
 512     [AC_HELP_STRING([--without-included-zlib], [do not use the zlib lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 513     [lyx_cv_with_included_zlib=$withval],
 514     [lyx_cv_with_included_zlib=no])
 515   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 516   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 517   if test x$lyx_cv_with_included_zlib = xyes ; then
 518     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 519     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 520     mkdir -p 3rdparty/zlib
 521 dnl include standard config.h for HAVE_UNISTD_H
 522     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 523 dnl prevent clash with system zlib that might be dragged in by other libs
 524     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 525     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 526   else
 527     ZLIB_INCLUDES=
 528     AC_CHECK_HEADERS(zlib.h,
 529       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 530       [LYX_LIB_ERROR(zlib.h,zlib)])
 531   fi
 532   AC_SUBST(ZLIB_INCLUDES)
 533   AC_SUBST(ZLIB_LIBS)
 534 ])
 535
 536
 537 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 538 dnl        necessary APIs are available to print callstacks.
 539 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 540 [AC_CACHE_CHECK([whether printing callstack is possible],
 541                [lyx_cv_callstack_printing],
 542 [AC_TRY_COMPILE([
 543 #include <execinfo.h>
 544 #include <cxxabi.h>
 545 ], [
 546         void* array[200];
 547         size_t size = backtrace(array, 200);
 548         backtrace_symbols(array, size);
 549         int status = 0;
 550         abi::__cxa_demangle("abcd", 0, 0, &status);
 551 ],
 552 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 553 if test x"$lyx_cv_callstack_printing" = xyes; then
 554   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 555             [Define if callstack can be printed])
 556 fi
 557 ])
 558
 559
 560 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 561 dnl        be used.
 562 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 563         AC_MSG_CHECKING([whether to use included MyThes library])
 564         AC_ARG_WITH(included-mythes,
 565             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 566             [lyx_cv_with_included_mythes=$withval],
 567             [lyx_cv_with_included_mythes=yes])
 568         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 569         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 570         if test x$lyx_cv_with_included_mythes != xyes ; then
 571                 AC_LANG_PUSH(C++)
 572                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 573                 if test x$ac_cv_header_mythes_h != xyes; then
 574                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 575                 fi
 576                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 577                 if test x$lyx_mythes != xyes; then
 578                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 579                 fi
 580                 AC_LANG_POP(C++)
 581                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 582                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 583                 fi
 584                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 585                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 586                 AC_SUBST(MYTHES_LIBS)
 587         fi
 588 ])
 589
 590
 591 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 592 dnl                       [default-yes-value])
 593 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 594 dnl  resulting directory name in 'dir-var-name'.
 595 AC_DEFUN([LYX_WITH_DIR],[
 596   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 597   AC_MSG_CHECKING([for $2])
 598   if test -z "$with_$3"; then
 599      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 600   else
 601     test "x$with_$3" = xyes && with_$3=$5
 602     lyx_cv_$3="$with_$3"
 603   fi
 604   AC_MSG_RESULT($lyx_cv_$3)])
 605
 606
 607 dnl Usage: LYX_LOOP_DIR(value,action)
 608 dnl Executes action for values of variable `dir' in `values'. `values' can
 609 dnl use ":" as a separator.
 610 AC_DEFUN([LYX_LOOP_DIR],[
 611 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 612 for dir in `eval "echo $1"`; do
 613   if test ! "$dir" = NONE; then
 614     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 615     $2
 616   fi
 617 done
 618 IFS=$ac_save_ifs
 619 ])
 620
 621
 622 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 623 dnl var-name.
 624 AC_DEFUN([LYX_ADD_LIB_DIR],[
 625 $1="${$1} -L$2"
 626 if test "`(uname) 2>/dev/null`" = SunOS &&
 627     uname -r | grep '^5' >/dev/null; then
 628   if test $ac_cv_prog_gxx = yes ; then
 629     $1="${$1} -Wl[,]-R$2"
 630   else
 631     $1="${$1} -R$2"
 632   fi
 633 fi])
 634
 635
 636 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 637 dnl var-name.
 638 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 639
 640 ### Check for a headers existence and location iff it exists
 641 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 642 ## It almost works.  I've tried a few variations but they give errors
 643 ## of one sort or other: bad substitution or file not found etc.  The
 644 ## actual header _is_ found though and the cache variable is set however
 645 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 646 ## reason.
 647 ## Additionally, autoheader can't figure out what to use as the name in
 648 ## the config.h.in file so we need to write our own entries there -- one for
 649 ## each header in the form PATH_HEADER_NAME_H
 650 ##
 651 AC_DEFUN([LYX_PATH_HEADER],
 652 [ AC_CHECK_HEADER($1,[
 653   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 654 ### the only remaining problem is getting the second parameter to this
 655 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 656 ### of $ac_safe being printed.
 657   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 658   [ cat > conftest.$ac_ext <<EOF
 659 #line __oline__ "configure"
 660 #include "confdefs.h"
 661
 662 #include <$1>
 663 EOF
 664 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 665   grep $1  2>/dev/null | \
 666   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 667 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 668 rm -f conftest*])
 669   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 670 ])
 671 ### end of LYX_PATH_HEADER
 672
 673 ## Check what kind of packaging should be used at install time.
 674 ## The default is autodetected.
 675 AC_DEFUN([LYX_USE_PACKAGING],
 676 [AC_MSG_CHECKING([what packaging should be used])
 677 AC_ARG_WITH(packaging,
 678   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 679                             Possible values: posix, windows, macosx, haiku])],
 680   [lyx_use_packaging="$withval"], [
 681   case $host in
 682     *-apple-darwin*) lyx_use_packaging=macosx ;;
 683     *-pc-mingw*) lyx_use_packaging=windows ;;
 684     *-mingw32*) lyx_use_packaging=windows ;;
 685     *haiku*) lyx_use_packaging=haiku ;;
 686     *) lyx_use_packaging=posix ;;
 687   esac])
 688 AC_MSG_RESULT($lyx_use_packaging)
 689 lyx_install_posix=false
 690 lyx_install_macosx=false
 691 lyx_install_cygwin=false
 692 lyx_install_windows=false
 693 case $lyx_use_packaging in
 694    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 695            PACKAGE=LyX${version_suffix}
 696            default_prefix="/Applications/${PACKAGE}.app"
 697            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 698            bindir='${prefix}/Contents/MacOS'
 699            libdir='${prefix}/Contents/Resources'
 700            datarootdir='${prefix}/Contents/Resources'
 701            pkgdatadir='${datadir}'
 702            mandir='${datadir}/man'
 703            lyx_install_macosx=true ;;
 704   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 705            PACKAGE=LyX${version_suffix}
 706            default_prefix="C:/Program Files/${PACKAGE}"
 707            bindir='${prefix}/bin'
 708            libdir='${prefix}/Resources'
 709            datarootdir='${prefix}/Resources'
 710            pkgdatadir='${datadir}'
 711            mandir='${prefix}/Resources/man'
 712            lyx_install_windows=true ;;
 713     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 714            PACKAGE=lyx${version_suffix}
 715            program_suffix=$version_suffix
 716            pkgdatadir='${datadir}/${PACKAGE}'
 717            default_prefix=$ac_default_prefix
 718            case ${host} in
 719              *cygwin*) lyx_install_cygwin=true ;;
 720              *apple-darwin*) lyx_install_macosx=true ;;
 721            esac
 722            lyx_install_posix=true ;;
 723         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 724            PACKAGE=lyx${version_suffix}
 725            program_suffix=$version_suffix
 726            pkgdatadir='${datadir}/${PACKAGE}'
 727            default_prefix=$ac_default_prefix
 728            lyx_install_posix=true ;;
 729     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 730 esac
 731 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 732 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 733 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 734 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 735 AC_SUBST(pkgdatadir)
 736 AC_SUBST(program_suffix)
 737 ])
 738
 739
 740 ## ------------------------------------------------------------------------
 741 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 742 ## one or two arguments.
 743 ##
 744 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 745 ## ------------------------------------------------------------------------
 746 ##
 747 AC_DEFUN([AC_FUNC_MKDIR],
 748 [AC_CHECK_FUNCS([mkdir _mkdir])
 749 AC_CACHE_CHECK([whether mkdir takes one argument],
 750                [ac_cv_mkdir_takes_one_arg],
 751 [AC_TRY_COMPILE([
 752 #include <sys/stat.h>
 753 #if HAVE_UNISTD_H
 754 #  include <unistd.h>
 755 #endif
 756 ], [mkdir (".");],
 757 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 758 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 759   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 760             [Define if mkdir takes only one argument.])
 761 fi
 762 ])
 763
 764
 765 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 766 dnl (which may be a relative path, and need not refer to any existing
 767 dnl entity).
 768
 769 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 770 dnl native Win32 path name, (but with slashes, not backslashes).
 771
 772 dnl On any other system, it is simply the result which would be obtained
 773 dnl if PATHNAME represented an existing directory, and the pwd command was
 774 dnl executed in that directory.
 775 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 776 [ac_dir="$2"
 777  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 778     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 779  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 780  do
 781    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 782  done
 783  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 784  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 785  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 786    s?/*$[]??'`
 787 ])
 788
 789 dnl this is used by the macro blow to general a proper config.h.in entry
 790 m4_define([LYX_AH_CHECK_DECL],
 791 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 792   [Define if you have the prototype for function `$1'])])
 793
 794 dnl Check things are declared in headers to avoid errors or warnings.
 795 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 796 dnl Defines HAVE_DECL_{FUNCTION}
 797 AC_DEFUN([LYX_CHECK_DECL],
 798 [LYX_AH_CHECK_DECL($1)
 799 for ac_header in $2
 800 do
 801   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 802   AC_EGREP_HEADER($1, $ac_header,
 803       [AC_MSG_RESULT(yes)
 804        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 805        break],
 806       [AC_MSG_RESULT(no)])
 807 done])
 808
 809 dnl this is used by the macro below to generate a proper config.h.in entry
 810 m4_define([LYX_AH_CHECK_DEF],
 811 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 812   [Define to 1 if `$1' is defined in `$2'])])
 813
 814 dnl Check whether name is defined in header by using it in codesnippet.
 815 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 816 dnl Defines HAVE_DEF_{NAME}
 817 AC_DEFUN([LYX_CHECK_DEF],
 818 [LYX_AH_CHECK_DEF($1, $2)
 819  AC_MSG_CHECKING([whether $1 is defined by header $2])
 820  AC_TRY_COMPILE([#include <$2>], [$3],
 821      lyx_have_def_name=yes,
 822      lyx_have_def_name=no)
 823  AC_MSG_RESULT($lyx_have_def_name)
 824  if test "x$lyx_have_def_name" = xyes; then
 825    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 826  fi
 827 ])
 828
 829 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 830 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 831 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 832 AC_DEFUN([LYX_SET_VERSION_INFO],
 833 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 834  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 835  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 836  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 837  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 838  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 839  test "x$lyx_patch" = "x" && lyx_patch=0
 840  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 841  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 842  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 843  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 844  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 845  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 846  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 847  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 848 ])
 849
 850 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 851 # ---------------------------------------------------------------------------
 852 # Copied from autoconf 2.68, added a check that python version is < 3.0
 853 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 854 # Run ACTION-IF-FALSE otherwise.
 855 # This test uses sys.hexversion instead of the string equivalent (first
 856 # word of sys.version), in order to cope with versions such as 2.2c1.
 857 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 858 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 859  [prog="import sys
 860 # split strings by '.' and convert to numeric.  Append some zeros
 861 # because we need at least 4 digits for the hex conversion.
 862 # map returns an iterator in Python 3.0 and a list in 2.x
 863 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 864 minverhex = 0
 865 maxverhex = 50331648 # = 3.0.0.0
 866 # xrange is not present in Python 3.0 and range returns an iterator
 867 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 868 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 869   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])