config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version $VERSION"
  11 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  12   lyx_devel_version=yes
  13   AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 AC_SUBST(lyx_devel_version)])
  25
  26
  27 dnl Define the option to set a LyX version on installed executables and directories
  28 dnl
  29 dnl
  30 AC_DEFUN([LYX_VERSION_SUFFIX],[
  31 AC_MSG_CHECKING([for install target ... ])
  32 RPM_VERSION_SUFFIX='""'
  33 AC_ARG_WITH(version-suffix,
  34   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  35   [if test "x$withval" = "xyes";
  36    then
  37      withval="-$VERSION"
  38      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  39    fi
  40    lyxname="lyx$withval"
  41    program_suffix=$withval
  42    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"],
  43   [lyxname=lyx])
  44 AC_SUBST(RPM_VERSION_SUFFIX)
  45 AC_MSG_RESULT([$lyxname])
  46 ])
  47
  48
  49 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  50 dnl flag lyx_error to yes.
  51 AC_DEFUN([LYX_ERROR],[
  52 lyx_error_txt="$lyx_error_txt
  53 ** $1
  54 "
  55 lyx_error=yes])
  56
  57
  58 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  59 dnl flag lyx_warning to yes.
  60 AC_DEFUN([LYX_WARNING],[
  61 lyx_warning_txt="$lyx_warning_txt
  62 == $1
  63 "
  64 lyx_warning=yes])
  65
  66
  67 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  68 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  69 AC_DEFUN([LYX_LIB_ERROR],[
  70 LYX_ERROR([Cannot find $1. Please check that the $2 library
  71    is correctly installed on your system.])])
  72
  73
  74 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  75 dnl   has occured previously.
  76 AC_DEFUN([LYX_CHECK_ERRORS],[
  77 if test x$lyx_error = xyes; then
  78 cat <<EOF
  79 **** The following problems have been detected by configure.
  80 **** Please check the messages below before running 'make'.
  81 **** (see the section 'Problems' in the INSTALL file)
  82 $lyx_error_txt
  83 $lyx_warning_txt
  84 EOF
  85 else
  86
  87 if test x$lyx_warning = xyes; then
  88 cat <<EOF
  89 === The following minor problems have been detected by configure.
  90 === Please check the messages below before running 'make'.
  91 === (see the section 'Problems' in the INSTALL file)
  92 $lyx_warning_txt
  93 EOF
  94 fi
  95 cat <<EOF
  96 Configuration of LyX was successful.
  97 Type 'make' to compile the program,
  98 and then 'make install' to install it.
  99 EOF
 100 fi])
 101
 102
 103 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 104 dnl
 105 define(LYX_SEARCH_PROG,[dnl
 106 for ac_prog in $2 ; do
 107 # Extract the first word of "$ac_prog", so it can be a program name with args.
 108   set dummy $ac_prog ; ac_word=$[2]
 109   if test -z "[$]$1"; then
 110     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 111     for ac_dir in $PATH; do
 112       test -z "$ac_dir" && ac_dir=.
 113       if test -f [$ac_dir/$ac_word]; then
 114         $1="$ac_prog"
 115         break
 116       fi
 117     done
 118     IFS="$ac_save_ifs"
 119   fi
 120
 121   if test -n "[$]$1"; then
 122     ac_result=yes
 123   else
 124     ac_result=no
 125   fi
 126   ifelse($3,,,[$3])
 127   test -n "[$]$1" && break
 128 done
 129 ])dnl
 130
 131
 132 AC_DEFUN([LYX_PROG_CXX_WORKS],
 133 [rm -f conftest.C
 134 cat >conftest.C <<EOF
 135 class foo {
 136    // we require the mutable keyword
 137    mutable int bar;
 138  };
 139  // we require namespace support
 140  namespace baz {
 141    int bar;
 142  }
 143  int main() {
 144    return(0);
 145  }
 146 EOF
 147 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 148 rm -f conftest.C conftest.o conftest.obj || true
 149 ])
 150
 151
 152 AC_DEFUN([LYX_PROG_CXX],
 153 [AC_MSG_CHECKING([for a good enough C++ compiler])
 154 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 155
 156 if test -z "$CXX" ; then
 157   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 158 fi
 159 AC_MSG_RESULT($CXX)
 160
 161 AC_PROG_CXX
 162
 163 ### We might want to get or shut warnings.
 164 AC_ARG_ENABLE(warnings,
 165   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 166   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 167         enable_warnings=yes;
 168     else
 169         enable_warnings=no;
 170     fi;])
 171 if test x$enable_warnings = xyes ; then
 172   lyx_flags="warnings $lyx_flags"
 173   AC_DEFINE(WITH_WARNINGS, 1,
 174   [Define this if you want to see the warning directives put here and
 175    there by the developpers to get attention])
 176 fi
 177
 178 ### We might want to disable debug
 179 AC_ARG_ENABLE(debug,
 180   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 181   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 182         enable_debug=yes;
 183     else
 184         enable_debug=no;
 185     fi;])
 186
 187 AC_ARG_ENABLE(stdlib-debug,
 188   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 189   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 190       enable_stdlib_debug=yes;
 191     else
 192       enable_stdlib_debug=no;
 193     fi;])
 194
 195 AC_ARG_ENABLE(concept-checks,
 196   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 197   [ if test $lyx_devel_version = yes -o $lyx-prerelease = yes ; then
 198         enable_concept_checks=yes;
 199     else
 200         enable_concept_checks=no;
 201     fi;])
 202
 203 AC_ARG_ENABLE(profiling,
 204   AC_HELP_STRING([--enable-profiling],[enable profiling]),,
 205   enable_profiling=no;)
 206
 207 ### set up optimization
 208 AC_ARG_ENABLE(optimization,
 209   AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 210         enable_optimization=yes;)
 211 case $enable_optimization in
 212   yes) lyx_opt=-O;;
 213    no) lyx_opt=;;
 214     *) lyx_opt=${enable_optimization};;
 215 esac
 216
 217 AC_ARG_ENABLE(pch,
 218   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 219         enable_pch=yes;)
 220 lyx_pch_comp=no
 221
 222 # set the compiler options correctly.
 223 if test x$GXX = xyes; then
 224   dnl Useful for global version info
 225   gxx_version=`${CXX} -dumpversion`
 226   CXX_VERSION="($gxx_version)"
 227
 228   if test "$ac_test_CXXFLAGS" = set; then
 229     CXXFLAGS="$ac_save_CXXFLAGS"
 230   else
 231       CFLAGS="$lyx_opt"
 232       CXXFLAGS="$lyx_opt"
 233     if test x$enable_debug = xyes ; then
 234         CFLAGS="-g $CFLAGS"
 235         CXXFLAGS="-g $CXXFLAGS"
 236     fi
 237     if test x$enable_profiling = xyes ; then
 238         CFLAGS="-pg $CFLAGS"
 239         CXXFLAGS="-pg $CXXFLAGS"
 240         LDFLAGS="-pg $LDFLAGS"
 241     fi
 242     if test x$enable_warnings = xyes ; then
 243         case $gxx_version in
 244             2.*|3.1*|3.2*|3.3*)
 245                 CPPFLAGS="-W -Wall $CPPFLAGS"
 246                 ;;
 247             *)
 248                 CPPFLAGS="-Wextra -Wall $CPPFLAGS "
 249                 ;;
 250         esac
 251     fi
 252   fi
 253   case $gxx_version in
 254       2.95.1)  AM_CXXFLAGS="-fpermissive -ftemplate-depth-30";;
 255       2.95.*)  AM_CXXFLAGS="-Wno-non-template-friend -ftemplate-depth-30";;
 256       2.96*)  AM_CXXFLAGS="-fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 257       3.1*)    AM_CXXFLAGS="-finline-limit=500 -fno-exceptions";;
 258       3.2*|3.3*)    AM_CXXFLAGS="-fno-exceptions";;
 259       3.4*|4.0*)
 260           AM_CXXFLAGS="-fno-exceptions"
 261           test $enable_pch = yes && lyx_pch_comp=yes
 262           ;;
 263       *)       AM_CXXFLAGS="";;
 264   esac
 265   if test x$enable_stdlib_debug = xyes ; then
 266     case $gxx_version in
 267       3.4*|4.0*)
 268         lyx_flags="stdlib-debug $lyx_flags"
 269         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 270         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 271         ;;
 272     esac
 273   fi
 274   if test x$enable_concept_checks = xyes ; then
 275     case $gxx_version in
 276       3.3*)
 277         lyx_flags="concept-checks $lyx_flags"
 278         AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 279         ;;
 280       3.4*|4.0*)
 281         lyx_flags="concept-checks $lyx_flags"
 282         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 283         ;;
 284     esac
 285   fi
 286 fi
 287 test "$lyx_pch_comp" = yes && lyx_flags="pch $lyx_flags"
 288 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 289 ])dnl
 290
 291
 292 dnl NOT USED CURRENTLY*************************************
 293 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 294 dnl   supports RTTI
 295 AC_DEFUN([LYX_CXX_RTTI],[
 296 ### Check whether the compiler supports runtime type information
 297 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 298  [AC_TRY_RUN([
 299 class rtti {
 300 public:
 301    virtual int tag() { return 0; }
 302 };
 303 class derived1 : public rtti {
 304 public:
 305     int tag() { return 1; }
 306 };
 307 class derived2 : public rtti {
 308 public:
 309     int tag() { return 2; }
 310 };
 311 int main() {
 312     derived1 * foo1 = new derived1();
 313     derived2 * foo2 = new derived2();
 314     rtti * bar = foo1;
 315     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 316     if (bar1 == 0)
 317         exit(1);
 318     bar = foo2;
 319     bar1 = dynamic_cast<derived1 *>(bar);
 320     if (bar1 != 0)
 321         exit(1);
 322     return 0;
 323 }
 324 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 325 ])
 326 if test x$lyx_cv_rtti = xyes ; then
 327   AC_DEFINE(HAVE_RTTI, 1,
 328    [Define to 1 if your compiler supports runtime type information])
 329 fi])
 330
 331
 332 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 333 dnl   understands the "explicit" directive.
 334 AC_DEFUN([LYX_CXX_EXPLICIT],[
 335 ### Check whether the compiler understands the keyword `explicit'
 336 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 337  [AC_TRY_COMPILE([
 338 class Expl {
 339 public:
 340         explicit Expl() {}
 341 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 342 ])
 343 if test $lyx_cv_explicit = no ; then
 344   AC_DEFINE(explicit,[ ],
 345    [Define to nothing if your compiler does not understand the
 346    'explicit' directive])
 347 fi])
 348
 349
 350 dnl NOT USED CURRENTLY*************************************
 351 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 352 dnl   has a working stl stack template
 353 AC_DEFUN([LYX_CXX_STL_STACK],[
 354 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 355  [AC_TRY_COMPILE([
 356 #include <stack>
 357 using std::stack;
 358 ],[
 359     stack<int> stakk;
 360     stakk.push(0);
 361 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 362 ])
 363 if test $lyx_cv_broken_stack = yes ; then
 364   AC_DEFINE(BROKEN_STL_STACK, 1,
 365    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 366    correctly])
 367 fi])
 368
 369
 370 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 371 dnl    count template, if not the old HP version is assumed.
 372 AC_DEFUN([LYX_STD_COUNT],[
 373 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 374  [AC_TRY_COMPILE([
 375 #include <algorithm>
 376 using std::count;
 377 int countChar(char * b, char * e, char const c)
 378 {
 379         return count(b, e, c);
 380 }
 381 ],[
 382     char a[] = "hello";
 383     int i = countChar(a, a + 5, 'l');
 384 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 385 ])
 386 if test $lyx_cv_std_count = yes ; then
 387     AC_DEFINE(HAVE_STD_COUNT, 1,
 388     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 389 fi])
 390
 391
 392 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 393 dnl   supports modern STL streams
 394 AC_DEFUN([LYX_CXX_STL_MODERN_STREAMS],[
 395 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 396  [AC_TRY_COMPILE([
 397 #include <iostream>
 398 ],[
 399  std::streambuf * test = std::cerr.rdbuf();
 400  test->pubsync();
 401 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 402 ])
 403 if test $lyx_cv_modern_streams = yes ; then
 404   AC_DEFINE(MODERN_STL_STREAMS, 1,
 405    [Define if you have modern standard-compliant STL streams])
 406 fi])
 407
 408
 409 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 410 dnl        be used.
 411 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 412         AC_ARG_WITH(included-boost,
 413             [  --with-included-boost  use the boost lib supplied with LyX],
 414             [lyx_cv_with_included_boost=$withval
 415                 AC_MSG_RESULT([$with_included_boost])],
 416             [lyx_cv_with_included_boost=yes])
 417         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 418 ])
 419
 420
 421 dnl NOT USED CURRENTLY*************************************
 422 dnl LYX_CXX_PARTIAL
 423 AC_DEFUN([LYX_CXX_PARTIAL], [
 424     AC_REQUIRE([AC_PROG_CXX])
 425     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 426         [lyx_cv_cxx_partial_specialization],
 427         [AC_TRY_COMPILE(
 428             [
 429             template<class T, class K>
 430             class k {
 431             public:
 432             };
 433             template<class T> class k<void,T> { };
 434             ],[
 435             k<float, float> b;
 436             k<void,void> a;
 437             ],[
 438             lyx_cv_cxx_partial_specialization=yes
 439             ],[
 440             lyx_cv_cxx_partial_specialization=no
 441             ])
 442         ])
 443     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 444         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 445         [Defined if your compiler supports partial specialization.])
 446     fi
 447 ])
 448
 449
 450 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 451 dnl   are already in the global namespace
 452 AC_DEFUN([LYX_CXX_GLOBAL_CSTD],[
 453     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 454     lyx_cv_cxx_global_cstd,
 455     [AC_TRY_COMPILE([
 456     #include <cctype>
 457     using std::tolower;
 458     ],[
 459     return 0;
 460     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 461     if test x$lyx_cv_cxx_global_cstd = xyes; then
 462         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 463         [Define if your C++ compiler puts C library functions in the global namespace])
 464     fi
 465 ])
 466
 467
 468 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 469 dnl                       [default-yes-value])
 470 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 471 dnl  resulting directory name in 'dir-var-name'.
 472 AC_DEFUN([LYX_WITH_DIR],[
 473   AC_ARG_WITH($1,[  --with-$1        specify $2])
 474   AC_MSG_CHECKING([for $2])
 475   if test -z "$with_$3"; then
 476      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 477   else
 478     test "x$with_$3" = xyes && with_$3=$5
 479     lyx_cv_$3="$with_$3"
 480   fi
 481   AC_MSG_RESULT($lyx_cv_$3)])
 482
 483
 484 dnl Usage: LYX_LOOP_DIR(value,action)
 485 dnl Executes action for values of variable `dir' in `values'. `values' can
 486 dnl use ":" as a separator.
 487 AC_DEFUN([LYX_LOOP_DIR],[
 488 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 489 for dir in `eval "echo $1"`; do
 490   if test ! "$dir" = NONE; then
 491     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 492     $2
 493   fi
 494 done
 495 IFS=$ac_save_ifs
 496 ])
 497
 498
 499 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 500 dnl var-name.
 501 AC_DEFUN([LYX_ADD_LIB_DIR],[
 502 $1="${$1} -L$2"
 503 if test "`(uname) 2>/dev/null`" = SunOS &&
 504     uname -r | grep '^5' >/dev/null; then
 505   if test $ac_cv_prog_gxx = yes ; then
 506     $1="${$1} -Wl[,]-R$2"
 507   else
 508     $1="${$1} -R$2"
 509   fi
 510 fi])
 511
 512
 513 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 514 dnl var-name.
 515 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 516
 517 ### Check for a headers existence and location iff it exists
 518 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 519 ## It almost works.  I've tried a few variations but they give errors
 520 ## of one sort or other: bad substitution or file not found etc.  The
 521 ## actual header _is_ found though and the cache variable is set however
 522 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 523 ## reason.
 524 ## Additionally, autoheader can't figure out what to use as the name in
 525 ## the config.h.in file so we need to write our own entries there -- one for
 526 ## each header in the form PATH_HEADER_NAME_H
 527 ##
 528 AC_DEFUN([LYX_PATH_HEADER],
 529 [ AC_CHECK_HEADER($1,[
 530   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 531 ### the only remaining problem is getting the second parameter to this
 532 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 533 ### of $ac_safe being printed.
 534   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 535   [ cat > conftest.$ac_ext <<EOF
 536 #line __oline__ "configure"
 537 #include "confdefs.h"
 538
 539 #include <$1>
 540 EOF
 541 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 542   grep $1  2>/dev/null | \
 543   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 544 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 545 rm -f conftest*])
 546   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 547 ])
 548 ### end of LYX_PATH_HEADER
 549
 550 ### Check which frontends we want to use. The default is XForms only
 551 ###
 552 AC_DEFUN([LYX_USE_FRONTENDS],
 553 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 554 AC_ARG_WITH(frontend,
 555   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 556                             Possible values: xforms, qt, gtk(EXPERIMENTAL)],
 557   [FRONTENDS="$withval"], [FRONTENDS="xforms"])
 558 AC_MSG_RESULT($FRONTENDS)
 559 AC_SUBST(FRONTENDS)
 560 AC_SUBST(FRONTENDS_SUBDIRS)
 561 AC_SUBST(FRONTENDS_PROGS)
 562 ])
 563
 564
 565 ## Check what kind of packaging should be used at install time.
 566 ## The default is autodetected.
 567 AC_DEFUN([LYX_USE_PACKAGING],
 568 [AC_MSG_CHECKING([what packaging should be used])
 569 AC_ARG_WITH(packaging,
 570   [  --with-packaging=THIS   Use THIS packaging for installation:
 571                             Possible values: posix, windows, macosx],
 572   [lyx_use_packaging="$withval"], [
 573   case $host in
 574     *-apple-darwin*) lyx_use_packaging=macosx ;;
 575      *-pc-mingw32*) lyx_use_packaging=windows;;
 576                   *) lyx_use_packaging=posix;;
 577   esac])
 578 AC_MSG_RESULT($lyx_use_packaging)
 579 case $lyx_use_packaging in
 580    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 581            default_prefix="/Applications/LyX.app"
 582            bindir='${prefix}/Contents/MacOS'
 583            libdir='${prefix}/Contents/Resources'
 584            datadir='${prefix}/Contents/Resources'
 585            mandir='${prefix}/Contents/Resources/man' ;;
 586   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 587            default_prefix="C:/Program Files/LyX"
 588            bindir='${prefix}/bin'
 589            libdir='${prefix}/Resources'
 590            datadir='${prefix}/Resources'
 591            mandir='${prefix}/Resources/man' ;;
 592     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 593            default_prefix=$ac_default_prefix ;;
 594     *) LYX_ERROR([Unknown packaging type $lyx_use_packaging]) ;;
 595 esac
 596 ])
 597
 598
 599 ## ------------------------------------------------------------------------
 600 ## Find a file (or one of more files in a list of dirs)
 601 ## ------------------------------------------------------------------------
 602 ##
 603 AC_DEFUN([AC_FIND_FILE],
 604 [
 605 $3=NO
 606 for i in $2;
 607 do
 608   for j in $1;
 609   do
 610     if test -r "$i/$j"; then
 611       $3=$i
 612       break 2
 613     fi
 614   done
 615 done
 616 ])
 617
 618 dnl just a wrapper to clean up configure.in
 619 AC_DEFUN([LYX_PROG_LIBTOOL],
 620 [
 621 AC_REQUIRE([AC_ENABLE_SHARED])
 622 AC_REQUIRE([AC_ENABLE_STATIC])
 623 dnl libtool is only for C, so I must force him
 624 dnl to find the correct flags for C++
 625 ac_save_cc=$CC
 626 ac_save_cflags="$CFLAGS"
 627 CC=$CXX
 628 CFLAGS="$CXXFLAGS"
 629 AM_PROG_LIBTOOL dnl for libraries
 630 CC=$ac_save_cc
 631 CFLAGS="$ac_save_cflags"
 632 ])
 633
 634
 635 ## ------------------------------------------------------------------------
 636 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 637 ## one or two arguments.
 638 ##
 639 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 640 ## ------------------------------------------------------------------------
 641 ##
 642 AC_DEFUN([AC_FUNC_MKDIR],
 643 [AC_CHECK_FUNCS([mkdir _mkdir])
 644 AC_CACHE_CHECK([whether mkdir takes one argument],
 645                [ac_cv_mkdir_takes_one_arg],
 646 [AC_TRY_COMPILE([
 647 #include <sys/stat.h>
 648 #if HAVE_UNISTD_H
 649 #  include <unistd.h>
 650 #endif
 651 ], [mkdir (".");],
 652 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 653 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 654   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 655             [Define if mkdir takes only one argument.])
 656 fi
 657 ])