config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version $VERSION"
  11 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  12   lyx_devel_version=yes
  13   AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 AC_SUBST(lyx_devel_version)])
  25
  26
  27 dnl Define the option to set a LyX version on installed executables and directories
  28 dnl
  29 dnl
  30 AC_DEFUN([LYX_VERSION_SUFFIX],[
  31 AC_MSG_CHECKING([for install target ... ])
  32 RPM_VERSION_SUFFIX='""'
  33 AC_ARG_WITH(version-suffix,
  34   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  35   [if test "x$withval" = "xyes";
  36    then
  37      withval="-$VERSION"
  38      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  39    fi
  40    lyxname="lyx$withval"
  41    program_suffix=$withval
  42    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"],
  43   [lyxname=lyx])
  44 AC_SUBST(RPM_VERSION_SUFFIX)
  45 AC_MSG_RESULT([$lyxname])
  46 ])
  47
  48
  49 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  50 dnl flag lyx_error to yes.
  51 AC_DEFUN([LYX_ERROR],[
  52 lyx_error_txt="$lyx_error_txt
  53 ** $1
  54 "
  55 lyx_error=yes])
  56
  57
  58 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  59 dnl flag lyx_warning to yes.
  60 AC_DEFUN([LYX_WARNING],[
  61 lyx_warning_txt="$lyx_warning_txt
  62 == $1
  63 "
  64 lyx_warning=yes])
  65
  66
  67 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  68 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  69 AC_DEFUN([LYX_LIB_ERROR],[
  70 LYX_ERROR([Cannot find $1. Please check that the $2 library
  71    is correctly installed on your system.])])
  72
  73
  74 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  75 dnl   has occured previously.
  76 AC_DEFUN([LYX_CHECK_ERRORS],[
  77 if test x$lyx_error = xyes; then
  78 cat <<EOF
  79 **** The following problems have been detected by configure.
  80 **** Please check the messages below before running 'make'.
  81 **** (see the section 'Problems' in the INSTALL file)
  82 $lyx_error_txt
  83 $lyx_warning_txt
  84 EOF
  85 else
  86
  87 if test x$lyx_warning = xyes; then
  88 cat <<EOF
  89 === The following minor problems have been detected by configure.
  90 === Please check the messages below before running 'make'.
  91 === (see the section 'Problems' in the INSTALL file)
  92 $lyx_warning_txt
  93 EOF
  94 fi
  95 cat <<EOF
  96 Configuration of LyX was successful.
  97 Type 'make' to compile the program,
  98 and then 'make install' to install it.
  99 EOF
 100 fi])
 101
 102
 103 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 104 dnl
 105 define(LYX_SEARCH_PROG,[dnl
 106 for ac_prog in $2 ; do
 107 # Extract the first word of "$ac_prog", so it can be a program name with args.
 108   set dummy $ac_prog ; ac_word=$[2]
 109   if test -z "[$]$1"; then
 110     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 111     for ac_dir in $PATH; do
 112       test -z "$ac_dir" && ac_dir=.
 113       if test -f [$ac_dir/$ac_word]; then
 114         $1="$ac_prog"
 115         break
 116       fi
 117     done
 118     IFS="$ac_save_ifs"
 119   fi
 120
 121   if test -n "[$]$1"; then
 122     ac_result=yes
 123   else
 124     ac_result=no
 125   fi
 126   ifelse($3,,,[$3])
 127   test -n "[$]$1" && break
 128 done
 129 ])dnl
 130
 131
 132 AC_DEFUN([LYX_PROG_CXX_WORKS],
 133 [rm -f conftest.C
 134 cat >conftest.C <<EOF
 135 class foo {
 136    // we require the mutable keyword
 137    mutable int bar;
 138  };
 139  // we require namespace support
 140  namespace baz {
 141    int bar;
 142  }
 143  int main() {
 144    return(0);
 145  }
 146 EOF
 147 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 148 rm -f conftest.C conftest.o conftest.obj || true
 149 ])
 150
 151
 152 AC_DEFUN([LYX_PROG_CXX],
 153 [AC_MSG_CHECKING([for a good enough C++ compiler])
 154 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 155
 156 if test -z "$CXX" ; then
 157   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 158 fi
 159 AC_MSG_RESULT($CXX)
 160
 161 AC_PROG_CXX
 162
 163 ### We might want to get or shut warnings.
 164 AC_ARG_ENABLE(warnings,
 165   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 166   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 167         enable_warnings=yes;
 168     else
 169         enable_warnings=no;
 170     fi;])
 171 if test x$enable_warnings = xyes ; then
 172   lyx_flags="$lyx_flags warnings"
 173   AC_DEFINE(WITH_WARNINGS, 1,
 174   [Define this if you want to see the warning directives put here and
 175    there by the developpers to get attention])
 176 fi
 177
 178 ### We might want to disable debug
 179 AC_ARG_ENABLE(debug,
 180   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 181   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 182         enable_debug=yes;
 183     else
 184         enable_debug=no;
 185     fi;])
 186
 187 AC_ARG_ENABLE(stdlib-debug,
 188   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 189   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 190       enable_stdlib_debug=yes;
 191     else
 192       enable_stdlib_debug=no;
 193     fi;])
 194
 195 AC_ARG_ENABLE(concept-checks,
 196   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 197   [ if test $lyx_devel_version = yes -o $lyx-prerelease = yes ; then
 198         enable_concept_checks=yes;
 199     else
 200         enable_concept_checks=no;
 201     fi;])
 202
 203 ### set up optimization
 204 AC_ARG_ENABLE(optimization,
 205   AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 206         enable_optimization=yes;)
 207 case $enable_optimization in
 208   yes) lyx_opt=-O;;
 209    no) lyx_opt=;;
 210     *) lyx_opt=${enable_optimization};;
 211 esac
 212
 213 AC_ARG_ENABLE(pch,
 214   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 215         enable_pch=yes;)
 216 lyx_pch_comp=no
 217
 218 # set the compiler options correctly.
 219 if test x$GXX = xyes; then
 220   dnl Useful for global version info
 221   gxx_version=`${CXX} -dumpversion`
 222   CXX_VERSION="($gxx_version)"
 223
 224   if test "$ac_test_CXXFLAGS" = set; then
 225     CXXFLAGS="$ac_save_CXXFLAGS"
 226   else
 227     case $gxx_version in
 228       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive -ftemplate-depth-30";;
 229       2.95.*)  CXXFLAGS="$lyx_opt -Wno-non-template-friend -ftemplate-depth-30";;
 230       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 231       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 232       3.2*|3.3*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 233       3.4*|4.0*)
 234             CXXFLAGS="$lyx_opt -fno-exceptions"
 235             test $enable_pch = yes && lyx_pch_comp=yes
 236             ;;
 237       *)       CXXFLAGS="$lyx_opt";;
 238     esac
 239     if test x$enable_debug = xyes ; then
 240         CXXFLAGS="-g $CXXFLAGS"
 241     fi
 242   fi
 243   if test x$enable_stdlib_debug = xyes ; then
 244     case $gxx_version in
 245       3.4*|4.0*)
 246         lyx_flags="$lyx_flags stdlib-debug"
 247         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 248         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 249         ;;
 250     esac
 251   fi
 252   if test x$enable_concept_checks = xyes ; then
 253     case $gxx_version in
 254       3.3*)
 255         lyx_flags="$lyx_flags concept-checks"
 256         AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 257         ;;
 258       3.4*|4.0*)
 259         lyx_flags="$lyx_flags concept-checks"
 260         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 261         ;;
 262     esac
 263   fi
 264   if test x$enable_warnings = xyes ; then
 265     case $gxx_version in
 266       2.*|3.1*|3.2*|3.3*)
 267         CPPFLAGS="$CPPFLAGS -W -Wall"
 268         ;;
 269       *)
 270         CPPFLAGS="$CPPFLAGS -Wextra -Wall"
 271         ;;
 272     esac
 273   fi
 274 fi
 275 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 276 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 277 ])dnl
 278
 279
 280 dnl NOT USED CURRENTLY*************************************
 281 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 282 dnl   supports RTTI
 283 AC_DEFUN([LYX_CXX_RTTI],[
 284 ### Check whether the compiler supports runtime type information
 285 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 286  [AC_TRY_RUN([
 287 class rtti {
 288 public:
 289    virtual int tag() { return 0; }
 290 };
 291 class derived1 : public rtti {
 292 public:
 293     int tag() { return 1; }
 294 };
 295 class derived2 : public rtti {
 296 public:
 297     int tag() { return 2; }
 298 };
 299 int main() {
 300     derived1 * foo1 = new derived1();
 301     derived2 * foo2 = new derived2();
 302     rtti * bar = foo1;
 303     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 304     if (bar1 == 0)
 305         exit(1);
 306     bar = foo2;
 307     bar1 = dynamic_cast<derived1 *>(bar);
 308     if (bar1 != 0)
 309         exit(1);
 310     return 0;
 311 }
 312 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 313 ])
 314 if test x$lyx_cv_rtti = xyes ; then
 315   AC_DEFINE(HAVE_RTTI, 1,
 316    [Define to 1 if your compiler supports runtime type information])
 317 fi])
 318
 319
 320 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 321 dnl   understands the "explicit" directive.
 322 AC_DEFUN([LYX_CXX_EXPLICIT],[
 323 ### Check whether the compiler understands the keyword `explicit'
 324 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 325  [AC_TRY_COMPILE([
 326 class Expl {
 327 public:
 328         explicit Expl() {}
 329 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 330 ])
 331 if test $lyx_cv_explicit = no ; then
 332   AC_DEFINE(explicit,[ ],
 333    [Define to nothing if your compiler does not understand the
 334    'explicit' directive])
 335 fi])
 336
 337
 338 dnl NOT USED CURRENTLY*************************************
 339 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 340 dnl   has a working stl stack template
 341 AC_DEFUN([LYX_CXX_STL_STACK],[
 342 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 343  [AC_TRY_COMPILE([
 344 #include <stack>
 345 using std::stack;
 346 ],[
 347     stack<int> stakk;
 348     stakk.push(0);
 349 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 350 ])
 351 if test $lyx_cv_broken_stack = yes ; then
 352   AC_DEFINE(BROKEN_STL_STACK, 1,
 353    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 354    correctly])
 355 fi])
 356
 357
 358 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 359 dnl    count template, if not the old HP version is assumed.
 360 AC_DEFUN([LYX_STD_COUNT],[
 361 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 362  [AC_TRY_COMPILE([
 363 #include <algorithm>
 364 using std::count;
 365 int countChar(char * b, char * e, char const c)
 366 {
 367         return count(b, e, c);
 368 }
 369 ],[
 370     char a[] = "hello";
 371     int i = countChar(a, a + 5, 'l');
 372 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 373 ])
 374 if test $lyx_cv_std_count = yes ; then
 375     AC_DEFINE(HAVE_STD_COUNT, 1,
 376     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 377 fi])
 378
 379
 380 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 381 dnl   supports modern STL streams
 382 AC_DEFUN([LYX_CXX_STL_MODERN_STREAMS],[
 383 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 384  [AC_TRY_COMPILE([
 385 #include <iostream>
 386 ],[
 387  std::streambuf * test = std::cerr.rdbuf();
 388  test->pubsync();
 389 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 390 ])
 391 if test $lyx_cv_modern_streams = yes ; then
 392   AC_DEFINE(MODERN_STL_STREAMS, 1,
 393    [Define if you have modern standard-compliant STL streams])
 394 fi])
 395
 396
 397 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 398 dnl        be used.
 399 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 400         AC_ARG_WITH(included-boost,
 401             [  --with-included-boost  use the boost lib supplied with LyX],
 402             [lyx_cv_with_included_boost=$withval
 403                 AC_MSG_RESULT([$with_included_boost])],
 404             [lyx_cv_with_included_boost=yes])
 405         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 406 ])
 407
 408
 409 dnl NOT USED CURRENTLY*************************************
 410 dnl LYX_CXX_PARTIAL
 411 AC_DEFUN([LYX_CXX_PARTIAL], [
 412     AC_REQUIRE([AC_PROG_CXX])
 413     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 414         [lyx_cv_cxx_partial_specialization],
 415         [AC_TRY_COMPILE(
 416             [
 417             template<class T, class K>
 418             class k {
 419             public:
 420             };
 421             template<class T> class k<void,T> { };
 422             ],[
 423             k<float, float> b;
 424             k<void,void> a;
 425             ],[
 426             lyx_cv_cxx_partial_specialization=yes
 427             ],[
 428             lyx_cv_cxx_partial_specialization=no
 429             ])
 430         ])
 431     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 432         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 433         [Defined if your compiler supports partial specialization.])
 434     fi
 435 ])
 436
 437
 438 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 439 dnl   are already in the global namespace
 440 AC_DEFUN([LYX_CXX_GLOBAL_CSTD],[
 441     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 442     lyx_cv_cxx_global_cstd,
 443     [AC_TRY_COMPILE([
 444     #include <cctype>
 445     using std::tolower;
 446     ],[
 447     return 0;
 448     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 449     if test x$lyx_cv_cxx_global_cstd = xyes; then
 450         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 451         [Define if your C++ compiler puts C library functions in the global namespace])
 452     fi
 453 ])
 454
 455
 456 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 457 dnl                       [default-yes-value])
 458 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 459 dnl  resulting directory name in 'dir-var-name'.
 460 AC_DEFUN([LYX_WITH_DIR],[
 461   AC_ARG_WITH($1,[  --with-$1        specify $2])
 462   AC_MSG_CHECKING([for $2])
 463   if test -z "$with_$3"; then
 464      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 465   else
 466     test "x$with_$3" = xyes && with_$3=$5
 467     lyx_cv_$3="$with_$3"
 468   fi
 469   AC_MSG_RESULT($lyx_cv_$3)])
 470
 471
 472 dnl Usage: LYX_LOOP_DIR(value,action)
 473 dnl Executes action for values of variable `dir' in `values'. `values' can
 474 dnl use ":" as a separator.
 475 AC_DEFUN([LYX_LOOP_DIR],[
 476 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 477 for dir in `eval "echo $1"`; do
 478   if test ! "$dir" = NONE; then
 479     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 480     $2
 481   fi
 482 done
 483 IFS=$ac_save_ifs
 484 ])
 485
 486
 487 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 488 dnl var-name.
 489 AC_DEFUN([LYX_ADD_LIB_DIR],[
 490 $1="${$1} -L$2"
 491 if test "`(uname) 2>/dev/null`" = SunOS &&
 492     uname -r | grep '^5' >/dev/null; then
 493   if test $ac_cv_prog_gxx = yes ; then
 494     $1="${$1} -Wl[,]-R$2"
 495   else
 496     $1="${$1} -R$2"
 497   fi
 498 fi])
 499
 500
 501 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 502 dnl var-name.
 503 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 504
 505 ### Check for a headers existence and location iff it exists
 506 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 507 ## It almost works.  I've tried a few variations but they give errors
 508 ## of one sort or other: bad substitution or file not found etc.  The
 509 ## actual header _is_ found though and the cache variable is set however
 510 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 511 ## reason.
 512 ## Additionally, autoheader can't figure out what to use as the name in
 513 ## the config.h.in file so we need to write our own entries there -- one for
 514 ## each header in the form PATH_HEADER_NAME_H
 515 ##
 516 AC_DEFUN([LYX_PATH_HEADER],
 517 [ AC_CHECK_HEADER($1,[
 518   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 519 ### the only remaining problem is getting the second parameter to this
 520 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 521 ### of $ac_safe being printed.
 522   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 523   [ cat > conftest.$ac_ext <<EOF
 524 #line __oline__ "configure"
 525 #include "confdefs.h"
 526
 527 #include <$1>
 528 EOF
 529 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 530   grep $1  2>/dev/null | \
 531   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 532 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 533 rm -f conftest*])
 534   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 535 ])
 536 ### end of LYX_PATH_HEADER
 537
 538 ### Check which frontends we want to use. The default is XForms only
 539 ###
 540 AC_DEFUN([LYX_USE_FRONTENDS],
 541 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 542 AC_ARG_WITH(frontend,
 543   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 544                             Possible values: xforms, qt, gtk(EXPERIMENTAL)],
 545   [FRONTENDS="$withval"], [FRONTENDS="xforms"])
 546 AC_MSG_RESULT($FRONTENDS)
 547 AC_SUBST(FRONTENDS)
 548 AC_SUBST(FRONTENDS_SUBDIRS)
 549 AC_SUBST(FRONTENDS_PROGS)
 550 ])
 551
 552
 553 ## Check what kind of packaging should be used at install time.
 554 ## The default is autodetected.
 555 AC_DEFUN([LYX_USE_PACKAGING],
 556 [AC_MSG_CHECKING([what packaging should be used])
 557 AC_ARG_WITH(packaging,
 558   [  --with-packaging=THIS   Use THIS packaging for installation:
 559                             Possible values: posix, windows, macosx],
 560   [lyx_use_packaging="$withval"], [
 561   case $host in
 562     *-apple-darwin*) lyx_use_packaging=macosx ;;
 563      *-pc-mingw32*) lyx_use_packaging=windows;;
 564                   *) lyx_use_packaging=posix;;
 565   esac])
 566 AC_MSG_RESULT($lyx_use_packaging)
 567 case $lyx_use_packaging in
 568    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 569            default_prefix="/Applications/LyX.app"
 570            bindir='${prefix}/Contents/MacOS'
 571            libdir='${prefix}/Contents/Resources'
 572            datadir='${prefix}/Contents/Resources'
 573            mandir='${prefix}/Contents/Resources/man' ;;
 574   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 575            default_prefix="C:/Program Files/LyX"
 576            bindir='${prefix}/bin'
 577            libdir='${prefix}/Resources'
 578            datadir='${prefix}/Resources'
 579            mandir='${prefix}/Resources/man' ;;
 580     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 581            default_prefix=$ac_default_prefix ;;
 582     *) LYX_ERROR([Unknown packaging type $lyx_use_packaging]) ;;
 583 esac
 584 ])
 585
 586
 587 ## ------------------------------------------------------------------------
 588 ## Find a file (or one of more files in a list of dirs)
 589 ## ------------------------------------------------------------------------
 590 ##
 591 AC_DEFUN([AC_FIND_FILE],
 592 [
 593 $3=NO
 594 for i in $2;
 595 do
 596   for j in $1;
 597   do
 598     if test -r "$i/$j"; then
 599       $3=$i
 600       break 2
 601     fi
 602   done
 603 done
 604 ])
 605
 606 dnl just a wrapper to clean up configure.in
 607 AC_DEFUN([LYX_PROG_LIBTOOL],
 608 [
 609 AC_REQUIRE([AC_ENABLE_SHARED])
 610 AC_REQUIRE([AC_ENABLE_STATIC])
 611 dnl libtool is only for C, so I must force him
 612 dnl to find the correct flags for C++
 613 ac_save_cc=$CC
 614 ac_save_cflags="$CFLAGS"
 615 CC=$CXX
 616 CFLAGS="$CXXFLAGS"
 617 AM_PROG_LIBTOOL dnl for libraries
 618 CC=$ac_save_cc
 619 CFLAGS="$ac_save_cflags"
 620 ])
 621
 622
 623 ## ------------------------------------------------------------------------
 624 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 625 ## one or two arguments.
 626 ##
 627 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 628 ## ------------------------------------------------------------------------
 629 ##
 630 AC_DEFUN([AC_FUNC_MKDIR],
 631 [AC_CHECK_FUNCS([mkdir _mkdir])
 632 AC_CACHE_CHECK([whether mkdir takes one argument],
 633                [ac_cv_mkdir_takes_one_arg],
 634 [AC_TRY_COMPILE([
 635 #include <sys/stat.h>
 636 #if HAVE_UNISTD_H
 637 #  include <unistd.h>
 638 #endif
 639 ], [mkdir (".");],
 640 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 641 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 642   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 643             [Define if mkdir takes only one argument.])
 644 fi
 645 ])