config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6 dnl Compute the default build type from AC_PACKAGE_VERSION at autoconf time.
   7 m4_define([LYX_BUILD_TYPE], [m4_bmatch(AC_PACKAGE_VERSION,
   8     [dev], [development],
   9     [pre\|alpha\|beta\|rc], [prerelease],
  10     [release])])
  11
  12
  13 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
  14 dnl sets variable "build_type"
  15 AC_DEFUN([LYX_CHECK_VERSION],[
  16 echo "configuring LyX version" AC_PACKAGE_VERSION
  17
  18 AC_MSG_CHECKING([for build type])
  19 lyx_devel_version=no
  20 lyx_prerelease=no
  21 AC_ARG_ENABLE(build-type,
  22   AS_HELP_STRING([--enable-build-type=STR],[set build type to rel(ease), pre(release), dev(elopment), prof(iling), or gprof (default: LYX_BUILD_TYPE)]),
  23   [case $enableval in
  24     dev*) build_type=development;;
  25     pre*) build_type=prerelease;;
  26     prof*)  build_type=profiling;;
  27     gprof*) build_type=gprof;;
  28     rel*) build_type=release;;
  29     *) AC_MSG_ERROR([bad build type specification '$enableval'. Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  30    esac],
  31   [build_type=LYX_BUILD_TYPE])
  32 AC_MSG_RESULT([$build_type])
  33 lyx_flags="$lyx_flags build=$build_type"
  34 case $build_type in
  35     development) lyx_devel_version=yes
  36                  LYX_DATE="not released yet" ;;
  37     prerelease) lyx_prerelease=yes ;;
  38 esac
  39
  40 AC_SUBST(lyx_devel_version)
  41 ])
  42
  43
  44 dnl Define the option to set a LyX version on installed executables and directories
  45 dnl
  46 dnl
  47 AC_DEFUN([LYX_VERSION_SUFFIX],[
  48 AC_MSG_CHECKING([for version suffix])
  49 dnl We need the literal double quotes in the rpm spec file
  50 RPM_VERSION_SUFFIX='""'
  51 AC_ARG_WITH(version-suffix,
  52   [AS_HELP_STRING([--with-version-suffix@<:@=STR@:>@], install lyx files as lyxSTR (default STR: -AC_PACKAGE_VERSION))],
  53   [if test "x$withval" = "xyes";
  54    then
  55      withval="-"AC_PACKAGE_VERSION
  56      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  57    fi
  58    AC_SUBST(version_suffix,$withval)
  59    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  60 AC_SUBST(RPM_VERSION_SUFFIX)
  61 AC_SUBST(program_base_name,"lyx")
  62 AC_MSG_RESULT([$withval])
  63 ])
  64
  65
  66 dnl Check whether to configure for Qt4 or Qt5. Default is Qt5.
  67 dnl
  68 AC_DEFUN([LYX_CHECK_QT5],[
  69 AC_MSG_CHECKING([whether Qt5 is disabled])
  70 AC_ARG_ENABLE([qt5],
  71   [AS_HELP_STRING([--disable-qt5],[do not use Qt5 for building])],
  72   USE_QT5=$enableval, USE_QT5=yes)
  73 if test x$USE_QT5 != xno ; then
  74   AC_MSG_RESULT([no])
  75 else
  76   AC_MSG_RESULT([yes])
  77 fi
  78 AC_SUBST([USE_QT5])
  79 ])
  80
  81
  82 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  83 dnl flag lyx_warning to yes.
  84 AC_DEFUN([LYX_WARNING],[
  85 lyx_warning_txt="$lyx_warning_txt
  86 == $1
  87 "
  88 lyx_warning=yes])
  89
  90
  91 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  92 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  93 AC_DEFUN([LYX_LIB_ERROR],[
  94 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  95    is correctly installed on your system.])])
  96
  97
  98 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  99 dnl   has occurred previously.
 100 AC_DEFUN([LYX_CHECK_WARNINGS],[
 101 if test x$lyx_warning = xyes; then
 102 cat <<EOF
 103 === The following minor problems have been detected by configure.
 104 === Please check the messages below before running 'make'.
 105 === (see the section 'Problems' in the INSTALL file)
 106 $lyx_warning_txt
 107
 108 EOF
 109 fi])
 110
 111
 112 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 113 dnl
 114 define(LYX_SEARCH_PROG,[dnl
 115 for ac_prog in $2 ; do
 116 # Extract the first word of "$ac_prog", so it can be a program name with args.
 117   set dummy $ac_prog ; ac_word=$[2]
 118   if test -z "[$]$1"; then
 119     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 120     for ac_dir in $PATH; do
 121       test -z "$ac_dir" && ac_dir=.
 122       if test -f [$ac_dir/$ac_word]; then
 123         $1="$ac_prog"
 124         break
 125       fi
 126     done
 127     IFS="$ac_save_ifs"
 128   fi
 129
 130   if test -n "[$]$1"; then
 131     ac_result=yes
 132   else
 133     ac_result=no
 134   fi
 135   ifelse($3,,,[$3])
 136   test -n "[$]$1" && break
 137 done
 138 ])dnl
 139
 140
 141 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 142 AC_DEFUN([LYX_PROG_CLANG],
 143 [AC_CACHE_CHECK([whether the compiler is clang],
 144                [lyx_cv_prog_clang],
 145 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 146 #ifndef __clang__
 147             this is not clang
 148 #endif
 149 ]])],[lyx_cv_prog_clang=yes ; CLANG=yes],[lyx_cv_prog_clang=no ; CLANG=no])])
 150 if test $CLANG = yes ; then
 151   AC_CACHE_CHECK([for clang version],
 152     [lyx_cv_clang_version],
 153     [clang_noversion=no
 154      AC_COMPUTE_INT(clang_major,__clang_major__,,[clang_noversion_=yes])
 155      AC_COMPUTE_INT(clang_minor,__clang_minor__,,[clang_noversion_=yes])
 156      AC_COMPUTE_INT(clang_patchlevel,__clang_patchlevel__,,[clang_noversion_=yes])
 157      if test $clang_noversion = yes ; then
 158        clang_version=unknown
 159      else
 160        clang_version=$clang_major.$clang_minor.$clang_patchlevel
 161      fi
 162      lyx_cv_clang_version=$clang_version])
 163 fi
 164 ])
 165
 166
 167 dnl Usage: LYX_CXX_CXX11_FLAGS(VERSION): add to AM_CXXFLAGS the best flag that
 168 dnl selects C++11 mode; gives an error when C++11 mode is not found.
 169 dnl VERSION is a list of years to try (e.g. 11 or {14,11}).
 170 AC_DEFUN([LYX_CXX_CXX11_FLAGS],
 171 [AC_CACHE_CHECK([for a good C++ mode], [lyx_cv_cxx11_flags],
 172  [lyx_cv_cxx11_flags=none
 173   for flag in `eval echo -std=c++$1 default -std=gnu++$1` ; do
 174     if test $flag = default ; then
 175       flag=
 176     fi
 177     save_CPPFLAGS=$CPPFLAGS
 178     CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 179     save_CXXFLAGS=$CXXFLAGS
 180     CXXFLAGS="$flag $AM_CXXFLAGS $CXXFLAGS"
 181     dnl sample openmp source code to test
 182     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 183        template <typename T>
 184        struct check
 185        {
 186            static_assert(sizeof(int) <= sizeof(T), "not big enough");
 187        };
 188
 189        typedef check<check<bool>> right_angle_brackets;
 190
 191        class TestDeleted
 192        {
 193        public:
 194            TestDeleted() = delete;
 195        };
 196
 197
 198        int a;
 199        decltype(a) b;
 200
 201        typedef check<int> check_type;
 202        check_type c;
 203        check_type&& cr = static_cast<check_type&&>(c);
 204
 205        auto d = a;]], [[]])],[lyx_cv_cxx11_flags=$flag; break],[])
 206    CXXFLAGS=$save_CXXFLAGS
 207    CPPFLAGS=$save_CPPFLAGS
 208   done])
 209   if test x$lyx_cv_cxx11_flags = xnone ; then
 210     AC_MSG_ERROR([Cannot find suitable mode for compiler $CXX])
 211   fi
 212   AM_CXXFLAGS="$lyx_cv_cxx11_flags $AM_CXXFLAGS"
 213 ])
 214
 215
 216 dnl Usage: LYX_CXX_USE_CALL_ONCE
 217 dnl check whether we can use std::call_once and set the
 218 dnl LYX_USE_STD_CALL_ONCE macro and conditional accordingly.
 219 AC_DEFUN([LYX_CXX_USE_CALL_ONCE],
 220 [AC_MSG_CHECKING([for std::call_once availability])
 221    save_CPPFLAGS=$CPPFLAGS
 222    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 223    save_CXXFLAGS=$CXXFLAGS
 224    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 225    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 226         #include <mutex>
 227         static std::once_flag flag;
 228      ]], [[
 229         std::call_once(flag, [](){ return; });
 230    ]])],[lyx_std_call_once=yes],[lyx_std_call_once=no])
 231    CXXFLAGS=$save_CXXFLAGS
 232    CPPFLAGS=$save_CPPFLAGS
 233    AC_MSG_RESULT([$lyx_std_call_once])
 234
 235  if test $lyx_std_call_once = yes ; then
 236   AC_DEFINE([LYX_USE_STD_CALL_ONCE], 1, [define to 1 if std::call_once is supported by the compiler])
 237  fi
 238  AM_CONDITIONAL([LYX_USE_STD_CALL_ONCE], test $lyx_std_call_once = yes)
 239 ])
 240
 241
 242 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 243 AC_DEFUN([LYX_LIB_STDCXX],
 244 [AC_CACHE_CHECK([whether STL is libstdc++],
 245                [lyx_cv_lib_stdcxx],
 246 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 247 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 248             this is not libstdc++
 249 #endif
 250 ]])],[lyx_cv_lib_stdcxx=yes],[lyx_cv_lib_stdcxx=no])])
 251 ])
 252
 253
 254 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 255 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 256 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 257 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 258                [lyx_cv_lib_stdcxx_cxx11_abi],
 259 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 260 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 261             this is not libstdc++ using the C++11 ABI
 262 #endif
 263 ]])],[lyx_cv_lib_stdcxx_cxx11_abi=yes],[lyx_cv_lib_stdcxx_cxx11_abi=no])])
 264 ])
 265
 266
 267 AC_DEFUN([LYX_PROG_CXX],
 268 [AC_REQUIRE([AC_PROG_CXX])
 269 AC_REQUIRE([AC_PROG_CXXCPP])
 270
 271 ### We might want to force the C++ standard.
 272 AC_ARG_ENABLE(cxx-mode,
 273   AS_HELP_STRING([--enable-cxx-mode],[choose C++ standard (default: 17, 14, then 11)]),,
 274   [enable_cxx_mode={17,14,11}]
 275 )
 276
 277 AC_LANG_PUSH(C++)
 278 LYX_PROG_CLANG
 279 LYX_CXX_CXX11_FLAGS($enable_cxx_mode)
 280 LYX_LIB_STDCXX
 281 LYX_LIB_STDCXX_CXX11_ABI
 282 LYX_CXX_USE_CALL_ONCE
 283 AC_LANG_POP(C++)
 284
 285 if test $lyx_cv_lib_stdcxx = "yes" ; then
 286   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 287     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 288   else
 289     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 290   fi
 291 else
 292   if test $lyx_cv_prog_clang = "yes" ; then
 293     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 294   fi
 295 fi
 296
 297 ### We might want to get or shut warnings.
 298 AC_ARG_ENABLE(warnings,
 299   AS_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 300   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $GXX = yes ; then
 301         enable_warnings=yes;
 302     else
 303         enable_warnings=no;
 304     fi;])
 305 if test x$enable_warnings = xyes ; then
 306   lyx_flags="$lyx_flags warnings"
 307 fi
 308
 309 ### We might want to disable debug
 310 AC_ARG_ENABLE(debug,
 311   AS_HELP_STRING([--enable-debug],[enable debug information]),,
 312   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 313 )
 314
 315 AC_ARG_ENABLE(stdlib-debug,
 316   AS_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 317   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 318           [enable_stdlib_debug=no])]
 319 )
 320
 321 ### set up optimization
 322 AC_ARG_ENABLE(optimization,
 323     AS_HELP_STRING([--enable-optimization@<:@=ARG@:>@],[enable compiler optimisation]),,
 324     enable_optimization=yes;)
 325 case $enable_optimization in
 326     yes)
 327         if test $lyx_devel_version = yes ; then
 328             lyx_optim=-O
 329         else
 330             lyx_optim=-O2
 331         fi;;
 332     no) lyx_optim=;;
 333     *) lyx_optim=${enable_optimization};;
 334 esac
 335
 336 AC_ARG_ENABLE(assertions,
 337   AS_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 338   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 339           [enable_assertions=no])]
 340 )
 341 if test "x$enable_assertions" = xyes ; then
 342    lyx_flags="$lyx_flags assertions"
 343    AC_DEFINE(ENABLE_ASSERTIONS,1,
 344     [Define if you want assertions to be enabled in the code])
 345 fi
 346
 347 # set the compiler options correctly.
 348 if test x$GXX = xyes; then
 349   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 350   if test x$CLANG = xno; then
 351     dnl Useful for global version info
 352     gxx_version=`${CXX} -dumpversion`
 353     case $gxx_version in
 354         *.*) ;;
 355         *) gxx_version=`${CXX} -dumpfullversion` ;;
 356     esac
 357     CXX_VERSION="($gxx_version)"
 358   else
 359     gxx_version=clang-$clang_version
 360     CXX_VERSION="($clang_version)"
 361   fi
 362
 363   AM_CXXFLAGS="$lyx_optim $AM_CXXFLAGS"
 364   if test x$enable_debug = xyes ; then
 365       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 366   fi
 367   if test $build_type = gprof ; then
 368     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 369     AM_LDFLAGS="$AM_LDFLAGS -pg"
 370   fi
 371   if test $build_type = profiling ; then
 372     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 373   fi
 374
 375   if test x$USE_QT5 = xyes ; then
 376       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 377   fi
 378   dnl Warnings are for preprocessor too
 379   if test x$enable_warnings = xyes ; then
 380       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 381       dnl Shut off warning -Wdeprecated-copy, which triggers too much
 382       dnl note that g++ always accepts -Wno-xxx, even when -Wxxx is an error.
 383       AC_LANG_PUSH(C++)
 384       AX_CHECK_COMPILE_FLAG([-Wno-deprecated-copy],
 385         [AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-copy"], [], [-Werror])
 386       AC_LANG_POP(C++)
 387     fi
 388   case $gxx_version in
 389       2.*|3.*|4.@<:@0-8@:>@) AC_MSG_ERROR([gcc >= 4.9 is required]);;
 390   esac
 391   if test x$enable_stdlib_debug = xyes ; then
 392     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 393     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 394     if test x$lyx_cv_lib_stdcxx = xyes ; then
 395         lyx_flags="$lyx_flags stdlib-debug"
 396         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 397         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 398         AC_SUBST(STDLIB_DEBUG, "-D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 399     else
 400         enable_stdlib_debug=no
 401     fi
 402   fi
 403 fi
 404
 405 # Some additional flags may be needed
 406 if test x$GXX = xyes; then
 407     case $gxx_version in
 408       clang-3.0*|clang-3.1*|clang-3.2*|clang-3.3*)
 409         dnl boost contains pragmas that are annoying on older clang versions
 410         AM_CPPFLAGS="-Wno-unknown-pragmas $AM_CPPFLAGS";;
 411       clang*)
 412         dnl the more recent versions support the deprecated-register warning,
 413         dnl which  is very annoying with Qt4.x right now.
 414         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 415     esac
 416 fi
 417 ])
 418
 419 dnl Usage: LYX_USE_INCLUDED_NOD : select if the included nod should be used.
 420 AC_DEFUN([LYX_USE_INCLUDED_NOD],[
 421         AC_MSG_CHECKING([whether to use included nod library])
 422         AC_ARG_WITH(included-nod,
 423             [AS_HELP_STRING([--without-included-nod], [do not use the nod lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 424             [lyx_cv_with_included_nod=$withval],
 425             [lyx_cv_with_included_nod=yes])
 426         AM_CONDITIONAL(USE_INCLUDED_NOD, test x$lyx_cv_with_included_nod = xyes)
 427         AC_MSG_RESULT([$lyx_cv_with_included_nod])
 428         if test x$lyx_cv_with_included_nod = xyes ; then
 429             lyx_included_libs="$lyx_included_libs nod"
 430             NOD_INCLUDES='-I$(top_srcdir)/3rdparty/nod'
 431         else
 432             NOD_INCLUDES=
 433             AC_LANG_PUSH(C++)
 434             AC_MSG_CHECKING([for nod library])
 435             AC_LINK_IFELSE(
 436                 [AC_LANG_PROGRAM([#include <nod.hpp>],
 437                     [nod::scoped_connection conn;])],
 438                 [AC_MSG_RESULT([yes])],
 439                 [AC_MSG_RESULT([no])
 440                 AC_MSG_ERROR([cannot find suitable nod library (do not use --without-included-nod)])
 441             ])
 442             AC_LANG_POP(C++)
 443         fi
 444         AC_SUBST(NOD_INCLUDES)
 445 ])
 446
 447 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 448 dnl        be used.
 449 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 450         AC_MSG_CHECKING([whether to use included boost library])
 451         AC_ARG_WITH(included-boost,
 452             [AS_HELP_STRING([--with-included-boost], [use the boost lib supplied with LyX])],
 453             [lyx_cv_with_included_boost=$withval],
 454             [lyx_cv_with_included_boost=no])
 455         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 456         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 457         if test x$lyx_cv_with_included_boost = xyes ; then
 458             lyx_included_libs="$lyx_included_libs boost"
 459             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 460         else
 461             BOOST_INCLUDES=
 462         fi
 463         AC_SUBST(BOOST_INCLUDES)
 464 ])
 465
 466
 467 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 468 dnl        be used.
 469 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 470   AC_MSG_CHECKING([whether to use included iconv library])
 471   AC_ARG_WITH(included-iconv,
 472     [AS_HELP_STRING([--with-included-iconv], [use the iconv lib supplied with LyX instead of the system one])],
 473     [lyx_cv_with_included_iconv=$withval],
 474     [lyx_cv_with_included_iconv=no])
 475   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 476   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 477   if test x$lyx_cv_with_included_iconv = xyes ; then
 478   lyx_included_libs="$lyx_included_libs iconv"
 479
 480 dnl This is hardcoded to make it compile
 481     AC_DEFINE([HAVE_WORKING_O_NOFOLLOW], 0, [Define to 1 if O_NOFOLLOW works.])
 482
 483 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 484     AC_EILSEQ
 485     AC_TYPE_MBSTATE_T
 486     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 487 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.15/lib/loop_wchar.h.
 488     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 489       USE_MBSTATE_T=1
 490     else
 491       USE_MBSTATE_T=0
 492     fi
 493     AC_SUBST([USE_MBSTATE_T])
 494     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 495       [gl_cv_header_wchar_h_standalone],
 496       [AC_COMPILE_IFELSE(
 497         [AC_LANG_PROGRAM(
 498           [[#include <wchar.h>
 499             wchar_t w;]],
 500           [[]])],
 501         [gl_cv_header_wchar_h_standalone=yes],
 502         [gl_cv_header_wchar_h_standalone=no])])
 503     if test $gl_cv_header_wchar_h_standalone = yes; then
 504       BROKEN_WCHAR_H=0
 505     else
 506       BROKEN_WCHAR_H=1
 507     fi
 508     AC_SUBST([BROKEN_WCHAR_H])
 509 dnl we want const correctness
 510     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 511       [Define as const if the declaration of iconv() needs const.])
 512     ICONV_CONST=const
 513     AC_SUBST([ICONV_CONST])
 514 dnl we build a static lib
 515     DLL_VARIABLE=
 516     AC_SUBST([DLL_VARIABLE])
 517     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.15 -I$(top_builddir)/3rdparty/libiconv'
 518     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 519     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.15/include/iconv.h.in
 520   else
 521     ICONV_INCLUDES=
 522     AM_ICONV
 523     if test "$am_cv_func_iconv" = no; then
 524       AC_MSG_ERROR([cannot find required library iconv.])
 525     else
 526       ICONV_LIBS="$LIBICONV"
 527     fi
 528     ICONV_ICONV_H_IN=
 529   fi
 530   AC_SUBST(ICONV_INCLUDES)
 531   AC_SUBST(ICONV_LIBS)
 532   AC_SUBST(ICONV_ICONV_H_IN)
 533 ])
 534
 535
 536 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 537 dnl        be used.
 538 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 539   AC_MSG_CHECKING([whether to use included zlib library])
 540   AC_ARG_WITH(included-zlib,
 541     [AS_HELP_STRING([--with-included-zlib], [use the zlib lib supplied with LyX instead of the system one])],
 542     [lyx_cv_with_included_zlib=$withval],
 543     [lyx_cv_with_included_zlib=no])
 544   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 545   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 546   if test x$lyx_cv_with_included_zlib = xyes ; then
 547     lyx_included_libs="$lyx_included_libs zlib"
 548     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 549     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 550     mkdir -p 3rdparty/zlib
 551 dnl include standard config.h for HAVE_UNISTD_H
 552     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 553 dnl prevent clash with system zlib that might be dragged in by other libs
 554     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 555     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 556   else
 557     ZLIB_INCLUDES=
 558     AC_CHECK_HEADERS(zlib.h,
 559       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 560       [LYX_LIB_ERROR(zlib.h,zlib)])
 561   fi
 562   AC_SUBST(ZLIB_INCLUDES)
 563   AC_SUBST(ZLIB_LIBS)
 564 ])
 565
 566
 567 dnl Usage: LYX_BUILD_INCLUDED_DTL : select if the included dtl should
 568 dnl        be built and installed.
 569 AC_DEFUN([LYX_BUILD_INCLUDED_DTL],[
 570         AC_MSG_CHECKING([whether to build dv2dt and dt2dv])
 571         AC_ARG_WITH(included-dtl,
 572             [AS_HELP_STRING([--with-included-dtl], [build and install the dv2dt and dt2dv programs supplied with LyX])],
 573             [lyx_cv_with_included_dtl=$withval],
 574             [lyx_cv_with_included_dtl=no])
 575         AM_CONDITIONAL(BUILD_INCLUDED_DTL, test x$lyx_cv_with_included_dtl = xyes)
 576         AC_MSG_RESULT([$lyx_cv_with_included_dtl])
 577         if test x$lyx_cv_with_included_dtl = xyes ; then
 578             lyx_flags="$lyx_flags build-dtl"
 579         fi])
 580
 581
 582 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 583 dnl        necessary APIs are available to print callstacks.
 584 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 585 [AC_ARG_ENABLE([callstack-printing],
 586                [AS_HELP_STRING([--disable-callstack-printing],[do not print a callstack when crashing])],
 587                lyx_cv_callstack_printing=$enableval, lyx_cv_callstack_printing=yes)
 588
 589 if test x"$lyx_cv_callstack_printing" = xyes; then
 590   AC_CACHE_CHECK([whether printing callstack is possible],
 591                  [lyx_cv_callstack_printing],
 592   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 593   #include <execinfo.h>
 594   #include <cxxabi.h>
 595   ]], [[
 596           void* array[200];
 597           size_t size = backtrace(array, 200);
 598           backtrace_symbols(array, size);
 599           int status = 0;
 600           abi::__cxa_demangle("abcd", 0, 0, &status);
 601   ]])],[],[lyx_cv_callstack_printing=no])])
 602 fi
 603 if test x"$lyx_cv_callstack_printing" = xyes; then
 604   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 605             [Define if callstack can be printed])
 606   lyx_flags="$lyx_flags callback-printing"
 607   AM_LDFLAGS="${AM_LDFLAGS} -rdynamic"
 608 fi
 609 ])
 610
 611
 612 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 613 dnl        be used.
 614 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 615   AC_ARG_WITH(included-mythes,
 616     [AS_HELP_STRING([--with-included-mythes], [force to use the MyThes lib supplied with LyX])],
 617     [use_included_mythes=$withval],
 618     [use_included_mythes=no])
 619   if test x$use_included_mythes != xyes ; then
 620     AC_LANG_PUSH(C++)
 621     use_included_mythes=yes
 622     AC_CHECK_HEADERS([mythes.hxx mythes/mythes.hxx],
 623       [mythes_h_location="<$ac_header>"
 624        save_LIBS=$LIBS
 625        AC_MSG_CHECKING([checking for MyThes library])
 626        for ac_lib in mythes mythes-1.2 ; do
 627          LIBS="-l$ac_lib $save_LIBS"
 628          AC_LINK_IFELSE(
 629            [AC_LANG_PROGRAM([#include <cstdio>]
 630               [#include $mythes_h_location], [MyThes dummy("idx","dat")])],
 631            [MYTHES_LIBS=-l$ac_lib
 632             AC_MSG_RESULT([$MYTHES_LIBS])
 633             use_included_mythes=no])
 634        done
 635        if test $use_included_mythes != no ; then
 636          AC_MSG_RESULT([not found])
 637        fi
 638        break])
 639     AC_LANG_POP(C++)
 640   fi
 641   if test $use_included_mythes = yes ; then
 642     mythes_h_location="<mythes.hxx>"
 643     MYTHES_INCLUDES='-I$(top_srcdir)/3rdparty/mythes/1.2.5/'
 644     MYTHES_LIBS='$(top_builddir)/3rdparty/mythes/liblyxmythes.a'
 645     lyx_included_libs="$lyx_included_libs mythes"
 646   fi
 647   AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$use_included_mythes = xyes)
 648   AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$mythes_h_location,[Location of mythes.hxx])
 649   AC_SUBST(MYTHES_INCLUDES)
 650   AC_SUBST(MYTHES_LIBS)
 651   AC_MSG_CHECKING([whether to use included MyThes library])
 652   AC_MSG_RESULT([$use_included_mythes])
 653 ])
 654
 655
 656 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 657 dnl                       [default-yes-value])
 658 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 659 dnl  resulting directory name in 'dir-var-name'.
 660 AC_DEFUN([LYX_WITH_DIR],[
 661   AC_ARG_WITH($1,[AS_HELP_STRING([--with-$1],[specify $2])])
 662   AC_MSG_CHECKING([for $2])
 663   if test -z "$with_$3"; then
 664      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 665   else
 666     test "x$with_$3" = xyes && with_$3=$5
 667     lyx_cv_$3="$with_$3"
 668   fi
 669   AC_MSG_RESULT($lyx_cv_$3)
 670 ])
 671
 672
 673 dnl Usage: LYX_LOOP_DIR(value,action)
 674 dnl Executes action for values of variable `dir' in `values'. `values' can
 675 dnl use ":" as a separator.
 676 AC_DEFUN([LYX_LOOP_DIR],[
 677 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 678 for dir in `eval "echo $1"`; do
 679   if test ! "$dir" = NONE; then
 680     test ! -d "$dir" && AC_MSG_ERROR(['$dir' is not a directory])
 681     $2
 682   fi
 683 done
 684 IFS=$ac_save_ifs
 685 ])
 686
 687
 688 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 689 dnl var-name.
 690 AC_DEFUN([LYX_ADD_LIB_DIR],[
 691 $1="${$1} -L$2"
 692 if test "`(uname) 2>/dev/null`" = SunOS &&
 693     uname -r | grep '^5' >/dev/null; then
 694   if test $GXX = yes ; then
 695     $1="${$1} -Wl[,]-R$2"
 696   else
 697     $1="${$1} -R$2"
 698   fi
 699 fi])
 700
 701
 702 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 703 dnl var-name.
 704 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 705
 706 ### Check for a headers existence and location iff it exists
 707 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 708 ## It almost works.  I've tried a few variations but they give errors
 709 ## of one sort or other: bad substitution or file not found etc.  The
 710 ## actual header _is_ found though and the cache variable is set however
 711 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 712 ## reason.
 713 ## Additionally, autoheader can't figure out what to use as the name in
 714 ## the config.h.in file so we need to write our own entries there -- one for
 715 ## each header in the form PATH_HEADER_NAME_H
 716 ##
 717 AC_DEFUN([LYX_PATH_HEADER],
 718 [ AC_CHECK_HEADER($1,[
 719   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 720 ### the only remaining problem is getting the second parameter to this
 721 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 722 ### of $ac_safe being printed.
 723   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 724   [ cat > conftest.$ac_ext <<EOF
 725 #line __oline__ "configure"
 726 #include "confdefs.h"
 727
 728 #include <$1>
 729 EOF
 730 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 731   grep $1  2>/dev/null | \
 732   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 733 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 734 rm -f conftest*])
 735   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 736 ])
 737 ### end of LYX_PATH_HEADER
 738
 739 ## Check what kind of packaging should be used at install time.
 740 ## The default is autodetected.
 741 AC_DEFUN([LYX_USE_PACKAGING],
 742 [AC_MSG_CHECKING([what packaging should be used])
 743 AC_ARG_WITH(packaging,
 744   [AS_HELP_STRING([--with-packaging=STR], [set packaging for installation among:
 745                             posix, windows, macosx, haiku (default is autodetected)])],
 746   [lyx_use_packaging="$withval"], [
 747   case $host in
 748     *-apple-darwin*) lyx_use_packaging=macosx ;;
 749     *-pc-mingw*) lyx_use_packaging=windows ;;
 750     *-mingw32*) lyx_use_packaging=windows ;;
 751     *haiku*) lyx_use_packaging=haiku ;;
 752     *) lyx_use_packaging=posix ;;
 753   esac])
 754 AC_MSG_RESULT($lyx_use_packaging)
 755 lyx_install_posix=false
 756 lyx_install_macosx=false
 757 lyx_install_cygwin=false
 758 lyx_install_windows=false
 759 case $lyx_use_packaging in
 760    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 761            PACKAGE=LyX${version_suffix}
 762            default_prefix="/Applications/${PACKAGE}.app"
 763            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 764            bindir='${prefix}/Contents/MacOS'
 765            libdir='${prefix}/Contents/Resources'
 766            datarootdir='${prefix}/Contents/Resources'
 767            pkgdatadir='${datadir}'
 768            mandir='${datadir}/man'
 769            lyx_install_macosx=true ;;
 770   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 771            PACKAGE=LyX${version_suffix}
 772            default_prefix="C:/Program Files/${PACKAGE}"
 773            bindir='${prefix}/bin'
 774            libdir='${prefix}/Resources'
 775            datarootdir='${prefix}/Resources'
 776            pkgdatadir='${datadir}'
 777            mandir='${prefix}/Resources/man'
 778            lyx_install_windows=true ;;
 779     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 780            PACKAGE=lyx${version_suffix}
 781            program_suffix=$version_suffix
 782            pkgdatadir='${datadir}/${PACKAGE}'
 783            default_prefix=$ac_default_prefix
 784            case ${host} in
 785              *cygwin*) lyx_install_cygwin=true ;;
 786              *apple-darwin*) lyx_install_macosx=true ;;
 787            esac
 788            lyx_install_posix=true ;;
 789         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 790            PACKAGE=lyx${version_suffix}
 791            program_suffix=$version_suffix
 792            pkgdatadir='${datadir}/${PACKAGE}'
 793            default_prefix=$ac_default_prefix
 794            lyx_install_posix=true ;;
 795     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 796 esac
 797 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 798 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 799 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 800 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 801 AC_SUBST(pkgdatadir)
 802 AC_SUBST(program_suffix)
 803 ])
 804
 805
 806 ## ------------------------------------------------------------------------
 807 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 808 ## one or two arguments.
 809 ##
 810 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 811 ## ------------------------------------------------------------------------
 812 ##
 813 AC_DEFUN([AC_FUNC_MKDIR],
 814 [AC_CHECK_FUNCS([mkdir _mkdir])
 815 AC_CACHE_CHECK([whether mkdir takes one argument],
 816                [ac_cv_mkdir_takes_one_arg],
 817 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 818 #include <sys/stat.h>
 819 #if HAVE_UNISTD_H
 820 #  include <unistd.h>
 821 #endif
 822 ]], [[mkdir (".");]])],[ac_cv_mkdir_takes_one_arg=yes],[ac_cv_mkdir_takes_one_arg=no])])
 823 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 824   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 825             [Define if mkdir takes only one argument.])
 826 fi
 827 ])
 828
 829
 830 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 831 dnl (which may be a relative path, and need not refer to any existing
 832 dnl entity).
 833
 834 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 835 dnl native Win32 path name, (but with slashes, not backslashes).
 836
 837 dnl On any other system, it is simply the result which would be obtained
 838 dnl if PATHNAME represented an existing directory, and the pwd command was
 839 dnl executed in that directory.
 840 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 841 [ac_dir="$2"
 842  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 843     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 844  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 845  do
 846    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 847  done
 848  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 849  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 850  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 851    s?/*$[]??'`
 852 ])
 853
 854 dnl this is used by the macro blow to general a proper config.h.in entry
 855 m4_define([LYX_AH_CHECK_DECL],
 856 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 857   [Define if you have the prototype for function `$1'])])dnl`
 858
 859 dnl Check things are declared in headers to avoid errors or warnings.
 860 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 861 dnl Defines HAVE_DECL_{FUNCTION}
 862 AC_DEFUN([LYX_CHECK_DECL],
 863 [LYX_AH_CHECK_DECL($1)
 864 for ac_header in $2
 865 do
 866   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 867   AC_EGREP_HEADER($1, $ac_header,
 868       [AC_MSG_RESULT(yes)
 869        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 870        break],
 871       [AC_MSG_RESULT(no)])
 872 done])
 873
 874 dnl this is used by the macro below to generate a proper config.h.in entry
 875 m4_define([LYX_AH_CHECK_DEF],
 876 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 877   [Define to 1 if `$1' is defined in `$2'])])dnl'
 878
 879 dnl Check whether name is defined in header by using it in codesnippet.
 880 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 881 dnl Defines HAVE_DEF_{NAME}
 882 AC_DEFUN([LYX_CHECK_DEF],
 883 [LYX_AH_CHECK_DEF($1, $2)
 884  AC_MSG_CHECKING([whether $1 is defined by header $2])
 885  save_CPPFLAGS=$CPPFLAGS
 886  CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 887  save_CXXFLAGS=$CXXFLAGS
 888  CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 889  AC_LANG_PUSH(C++)
 890  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <$2>]], [[$3]])],[lyx_have_def_name=yes],[lyx_have_def_name=no])
 891  AC_LANG_POP(C++)
 892  CXXFLAGS=$save_CXXFLAGS
 893  CPPFLAGS=$save_CPPFLAGS
 894  AC_MSG_RESULT($lyx_have_def_name)
 895  if test "x$lyx_have_def_name" = xyes; then
 896    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 897  fi
 898 ])
 899
 900 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 901 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 902 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 903 AC_DEFUN([LYX_SET_VERSION_INFO],
 904 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 905  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 906  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 907  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 908  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 909  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 910  test "x$lyx_patch" = "x" && lyx_patch=0
 911  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 912  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 913  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 914  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 915  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 916  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 917  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 918  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 919 ])
 920