config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6 dnl Compute the default build type from AC_PACKAGE_VERSION at autoconf time.
   7 m4_define([LYX_BUILD_TYPE], [m4_bmatch(AC_PACKAGE_VERSION,
   8     [dev], [development],
   9     [pre\|alpha\|beta\|rc], [prerelease],
  10     [release])])
  11
  12
  13 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
  14 dnl sets variable "build_type"
  15 AC_DEFUN([LYX_CHECK_VERSION],[
  16 echo "configuring LyX version" AC_PACKAGE_VERSION
  17
  18 AC_MSG_CHECKING([for build type])
  19 lyx_devel_version=no
  20 lyx_prerelease=no
  21 AC_ARG_ENABLE(build-type,
  22   AS_HELP_STRING([--enable-build-type=STR],[set build type to rel(ease), pre(release), dev(elopment), prof(iling), or gprof (default: LYX_BUILD_TYPE)]),
  23   [case $enableval in
  24     dev*) build_type=development;;
  25     pre*) build_type=prerelease;;
  26     prof*)  build_type=profiling;;
  27     gprof*) build_type=gprof;;
  28     rel*) build_type=release;;
  29     *) AC_MSG_ERROR([bad build type specification '$enableval'. Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  30    esac],
  31   [build_type=LYX_BUILD_TYPE])
  32 AC_MSG_RESULT([$build_type])
  33 lyx_flags="$lyx_flags build=$build_type"
  34 case $build_type in
  35     development) lyx_devel_version=yes
  36                  LYX_DATE="not released yet" ;;
  37     prerelease) lyx_prerelease=yes ;;
  38 esac
  39
  40 AC_SUBST(lyx_devel_version)
  41 ])
  42
  43
  44 dnl Define the option to set a LyX version on installed executables and directories
  45 dnl
  46 dnl
  47 AC_DEFUN([LYX_VERSION_SUFFIX],[
  48 AC_MSG_CHECKING([for version suffix])
  49 dnl We need the literal double quotes in the rpm spec file
  50 RPM_VERSION_SUFFIX='""'
  51 AC_ARG_WITH(version-suffix,
  52   [AS_HELP_STRING([--with-version-suffix@<:@=STR@:>@], install lyx files as lyxSTR (default STR: -AC_PACKAGE_VERSION))],
  53   [if test "x$withval" = "xyes";
  54    then
  55      withval="-"AC_PACKAGE_VERSION
  56      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  57    fi
  58    AC_SUBST(version_suffix,$withval)
  59    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  60 AC_SUBST(RPM_VERSION_SUFFIX)
  61 AC_SUBST(program_base_name,"lyx")
  62 AC_MSG_RESULT([$withval])
  63 ])
  64
  65
  66 dnl Check whether to configure for Qt4 or Qt5. Default is Qt5.
  67 dnl
  68 AC_DEFUN([LYX_CHECK_QT5],[
  69 AC_MSG_CHECKING([whether Qt5 is disabled])
  70 AC_ARG_ENABLE([qt5],
  71   [AS_HELP_STRING([--disable-qt5],[do not use Qt5 for building])],
  72   USE_QT5=$enableval, USE_QT5=yes)
  73 if test x$USE_QT5 != xno ; then
  74   AC_MSG_RESULT([no])
  75 else
  76   AC_MSG_RESULT([yes])
  77 fi
  78 AC_SUBST([USE_QT5])
  79 ])
  80
  81
  82 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  83 dnl flag lyx_warning to yes.
  84 AC_DEFUN([LYX_WARNING],[
  85 lyx_warning_txt="$lyx_warning_txt
  86 == $1
  87 "
  88 lyx_warning=yes])
  89
  90
  91 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  92 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  93 AC_DEFUN([LYX_LIB_ERROR],[
  94 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  95    is correctly installed on your system.])])
  96
  97
  98 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  99 dnl   has occurred previously.
 100 AC_DEFUN([LYX_CHECK_WARNINGS],[
 101 if test x$lyx_warning = xyes; then
 102 cat <<EOF
 103 === The following minor problems have been detected by configure.
 104 === Please check the messages below before running 'make'.
 105 === (see the section 'Problems' in the INSTALL file)
 106 $lyx_warning_txt
 107
 108 EOF
 109 fi])
 110
 111
 112 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 113 dnl
 114 define(LYX_SEARCH_PROG,[dnl
 115 for ac_prog in $2 ; do
 116 # Extract the first word of "$ac_prog", so it can be a program name with args.
 117   set dummy $ac_prog ; ac_word=$[2]
 118   if test -z "[$]$1"; then
 119     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 120     for ac_dir in $PATH; do
 121       test -z "$ac_dir" && ac_dir=.
 122       if test -f [$ac_dir/$ac_word]; then
 123         $1="$ac_prog"
 124         break
 125       fi
 126     done
 127     IFS="$ac_save_ifs"
 128   fi
 129
 130   if test -n "[$]$1"; then
 131     ac_result=yes
 132   else
 133     ac_result=no
 134   fi
 135   ifelse($3,,,[$3])
 136   test -n "[$]$1" && break
 137 done
 138 ])dnl
 139
 140
 141 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 142 AC_DEFUN([LYX_PROG_CLANG],
 143 [AC_CACHE_CHECK([whether the compiler is clang],
 144                [lyx_cv_prog_clang],
 145 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 146 #ifndef __clang__
 147             this is not clang
 148 #endif
 149 ]])],[lyx_cv_prog_clang=yes ; CLANG=yes],[lyx_cv_prog_clang=no ; CLANG=no])])
 150 if test $CLANG = yes ; then
 151   AC_CACHE_CHECK([for clang version],
 152     [lyx_cv_clang_version],
 153     [clang_noversion=no
 154      AC_COMPUTE_INT(clang_major,__clang_major__,,[clang_noversion_=yes])
 155      AC_COMPUTE_INT(clang_minor,__clang_minor__,,[clang_noversion_=yes])
 156      AC_COMPUTE_INT(clang_patchlevel,__clang_patchlevel__,,[clang_noversion_=yes])
 157      if test $clang_noversion = yes ; then
 158        clang_version=unknown
 159      else
 160        clang_version=$clang_major.$clang_minor.$clang_patchlevel
 161      fi
 162      lyx_cv_clang_version=$clang_version])
 163 fi
 164 ])
 165
 166
 167 dnl Usage: LYX_CXX_CXX11_FLAGS: add to AM_CXXFLAGS the best flag that
 168 selects C++11 mode; gives an error when C++11 mode is not found.
 169 AC_DEFUN([LYX_CXX_CXX11_FLAGS],
 170 [AC_CACHE_CHECK([for at least C++11 mode], [lyx_cv_cxx11_flags],
 171  [lyx_cv_cxx11_flags=none
 172   for flag in -std=c++14 -std=c++11 "" -std=gnu++14 -std=gnu++11 ; do
 173     save_CPPFLAGS=$CPPFLAGS
 174     CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 175     save_CXXFLAGS=$CXXFLAGS
 176     CXXFLAGS="$flag $AM_CXXFLAGS $CXXFLAGS"
 177     dnl sample openmp source code to test
 178     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 179        template <typename T>
 180        struct check
 181        {
 182            static_assert(sizeof(int) <= sizeof(T), "not big enough");
 183        };
 184
 185        typedef check<check<bool>> right_angle_brackets;
 186
 187        class TestDeleted
 188        {
 189        public:
 190            TestDeleted() = delete;
 191        };
 192
 193
 194        int a;
 195        decltype(a) b;
 196
 197        typedef check<int> check_type;
 198        check_type c;
 199        check_type&& cr = static_cast<check_type&&>(c);
 200
 201        auto d = a;]], [[]])],[lyx_cv_cxx11_flags=$flag; break],[])
 202    CXXFLAGS=$save_CXXFLAGS
 203    CPPFLAGS=$save_CPPFLAGS
 204   done])
 205   if test $lyx_cv_cxx11_flags = none ; then
 206     AC_MSG_ERROR([Cannot find suitable C++11 mode for compiler $CXX])
 207   fi
 208   AM_CXXFLAGS="$lyx_cv_cxx11_flags $AM_CXXFLAGS"
 209 ])
 210
 211
 212 dnl Usage: LYX_CXX_USE_REGEX
 213 dnl decide whether we want to use std::regex and set the
 214 dnl LYX_USE_STD_REGEX macro and conditional accordingly.
 215 AC_DEFUN([LYX_CXX_USE_REGEX],
 216 [AC_ARG_ENABLE(std-regex,
 217   AS_HELP_STRING([--enable-std-regex],[use std::regex instead of boost::regex (default is autodetected)]),
 218   [lyx_std_regex=$enableval],
 219   [AC_MSG_CHECKING([for correct regex implementation])
 220    save_CPPFLAGS=$CPPFLAGS
 221    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 222    save_CXXFLAGS=$CXXFLAGS
 223    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 224    # The following code snippet has been taken taken from example in
 225    #   http://stackoverflow.com/questions/8561850/compile-stdregex-iterator-with-gcc
 226    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 227         #include <regex>
 228         #include <iostream>
 229
 230         #include <string.h>
 231
 232         typedef std::regex_iterator<const char *> Myiter;
 233      ]], [[
 234         const char *pat = "axayaz";
 235         Myiter::regex_type rx("a");
 236         Myiter next(pat, pat + strlen(pat), rx);
 237         Myiter end;
 238    ]])],[lyx_std_regex=yes],[lyx_std_regex=no])
 239    CXXFLAGS=$save_CXXFLAGS
 240    CPPFLAGS=$save_CPPFLAGS
 241    AC_MSG_RESULT([$lyx_std_regex])
 242  ])
 243
 244  if test $lyx_std_regex = yes ; then
 245   lyx_flags="$lyx_flags std-regex"
 246   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 247  fi
 248  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 249 ])
 250
 251
 252 dnl Usage: LYX_CXX_USE_CALL_ONCE
 253 dnl check whether we can use std::call_once and set the
 254 dnl LYX_USE_STD_CALL_ONCE macro and conditional accordingly.
 255 AC_DEFUN([LYX_CXX_USE_CALL_ONCE],
 256 [AC_MSG_CHECKING([for std::call_once availability])
 257    save_CPPFLAGS=$CPPFLAGS
 258    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 259    save_CXXFLAGS=$CXXFLAGS
 260    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 261    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 262         #include <mutex>
 263         static std::once_flag flag;
 264      ]], [[
 265         std::call_once(flag, [](){ return; });
 266    ]])],[lyx_std_call_once=yes],[lyx_std_call_once=no])
 267    CXXFLAGS=$save_CXXFLAGS
 268    CPPFLAGS=$save_CPPFLAGS
 269    AC_MSG_RESULT([$lyx_std_call_once])
 270
 271  if test $lyx_std_call_once = yes ; then
 272   AC_DEFINE([LYX_USE_STD_CALL_ONCE], 1, [define to 1 if std::call_once is supported by the compiler])
 273  fi
 274  AM_CONDITIONAL([LYX_USE_STD_CALL_ONCE], test $lyx_std_call_once = yes)
 275 ])
 276
 277
 278 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 279 AC_DEFUN([LYX_LIB_STDCXX],
 280 [AC_CACHE_CHECK([whether STL is libstdc++],
 281                [lyx_cv_lib_stdcxx],
 282 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 283 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 284             this is not libstdc++
 285 #endif
 286 ]])],[lyx_cv_lib_stdcxx=yes],[lyx_cv_lib_stdcxx=no])])
 287 ])
 288
 289
 290 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 291 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 292 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 293 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 294                [lyx_cv_lib_stdcxx_cxx11_abi],
 295 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 296 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 297             this is not libstdc++ using the C++11 ABI
 298 #endif
 299 ]])],[lyx_cv_lib_stdcxx_cxx11_abi=yes],[lyx_cv_lib_stdcxx_cxx11_abi=no])])
 300 ])
 301
 302
 303 AC_DEFUN([LYX_PROG_CXX],
 304 [AC_REQUIRE([AC_PROG_CXX])
 305 AC_REQUIRE([AC_PROG_CXXCPP])
 306
 307 AC_LANG_PUSH(C++)
 308 LYX_PROG_CLANG
 309 LYX_CXX_CXX11_FLAGS
 310 LYX_LIB_STDCXX
 311 LYX_LIB_STDCXX_CXX11_ABI
 312 LYX_CXX_USE_REGEX
 313 LYX_CXX_USE_CALL_ONCE
 314 AC_LANG_POP(C++)
 315
 316 if test $lyx_cv_lib_stdcxx = "yes" ; then
 317   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 318     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 319   else
 320     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 321   fi
 322 else
 323   if test $lyx_cv_prog_clang = "yes" ; then
 324     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 325   fi
 326 fi
 327
 328 ### We might want to get or shut warnings.
 329 AC_ARG_ENABLE(warnings,
 330   AS_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 331   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $GXX = yes ; then
 332         enable_warnings=yes;
 333     else
 334         enable_warnings=no;
 335     fi;])
 336 if test x$enable_warnings = xyes ; then
 337   lyx_flags="$lyx_flags warnings"
 338 fi
 339
 340 ### We might want to disable debug
 341 AC_ARG_ENABLE(debug,
 342   AS_HELP_STRING([--enable-debug],[enable debug information]),,
 343   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 344 )
 345
 346 AC_ARG_ENABLE(stdlib-debug,
 347   AS_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 348   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 349           [enable_stdlib_debug=no])]
 350 )
 351
 352 ### set up optimization
 353 AC_ARG_ENABLE(optimization,
 354     AS_HELP_STRING([--enable-optimization@<:@=ARG@:>@],[enable compiler optimisation]),,
 355     enable_optimization=yes;)
 356 case $enable_optimization in
 357     yes)
 358         if test $lyx_devel_version = yes ; then
 359             lyx_optim=-O
 360         else
 361             lyx_optim=-O2
 362         fi;;
 363     no) lyx_optim=;;
 364     *) lyx_optim=${enable_optimization};;
 365 esac
 366
 367 AC_ARG_ENABLE(assertions,
 368   AS_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 369   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 370           [enable_assertions=no])]
 371 )
 372 if test "x$enable_assertions" = xyes ; then
 373    lyx_flags="$lyx_flags assertions"
 374    AC_DEFINE(ENABLE_ASSERTIONS,1,
 375     [Define if you want assertions to be enabled in the code])
 376 fi
 377
 378 # set the compiler options correctly.
 379 if test x$GXX = xyes; then
 380   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 381   if test x$CLANG = xno; then
 382     dnl Useful for global version info
 383     gxx_version=`${CXX} -dumpversion`
 384     case $gxx_version in
 385         *.*) ;;
 386         *) gxx_version=`${CXX} -dumpfullversion` ;;
 387     esac
 388     CXX_VERSION="($gxx_version)"
 389   else
 390     gxx_version=clang-$clang_version
 391     CXX_VERSION="($clang_version)"
 392   fi
 393
 394   AM_CXXFLAGS="$lyx_optim $AM_CXXFLAGS"
 395   if test x$enable_debug = xyes ; then
 396       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 397   fi
 398   if test $build_type = gprof ; then
 399     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 400     AM_LDFLAGS="$AM_LDFLAGS -pg"
 401   fi
 402   if test $build_type = profiling ; then
 403     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 404   fi
 405
 406   if test x$USE_QT5 = xyes ; then
 407       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 408   fi
 409   dnl Warnings are for preprocessor too
 410   if test x$enable_warnings = xyes ; then
 411       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 412       dnl Shut off warning -Wdeprecated-copy, which triggers too much
 413       dnl note that g++ always accepts -Wno-xxx, even when -Wxxx is an error.
 414       AC_LANG_PUSH(C++)
 415       AX_CHECK_COMPILE_FLAG([-Wno-deprecated-copy],
 416         [AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-copy"], [], [-Werror])
 417       AC_LANG_POP(C++)
 418     fi
 419   case $gxx_version in
 420       2.*|3.*|4.@<:@0-6@:>@) AC_MSG_ERROR([gcc >= 4.7 is required]);;
 421   esac
 422   if test x$enable_stdlib_debug = xyes ; then
 423     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 424     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 425     if test x$lyx_cv_lib_stdcxx = xyes ; then
 426         lyx_flags="$lyx_flags stdlib-debug"
 427         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 428         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 429         AC_SUBST(STDLIB_DEBUG, "-D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 430     else
 431         enable_stdlib_debug=no
 432     fi
 433   fi
 434 fi
 435
 436 # Some additional flags may be needed
 437 if test x$GXX = xyes; then
 438     case $gxx_version in
 439       clang-3.0*|clang-3.1*|clang-3.2*|clang-3.3*)
 440         dnl boost contains pragmas that are annoying on older clang versions
 441         AM_CPPFLAGS="-Wno-unknown-pragmas $AM_CPPFLAGS";;
 442       clang*)
 443         dnl the more recent versions support the deprecated-register warning,
 444         dnl which  is very annoying with Qt4.x right now.
 445         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 446     esac
 447 fi
 448 ])
 449
 450 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 451 dnl        be used.
 452 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 453         AC_MSG_CHECKING([whether to use included boost library])
 454         AC_ARG_WITH(included-boost,
 455             [AS_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 456             [lyx_cv_with_included_boost=$withval],
 457             [lyx_cv_with_included_boost=yes])
 458         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 459         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 460         if test x$lyx_cv_with_included_boost = xyes ; then
 461             lyx_included_libs="$lyx_included_libs boost"
 462             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 463             if test $lyx_std_regex = yes ; then
 464               BOOST_LIBS=""
 465             else
 466               BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 467             fi
 468         else
 469             BOOST_INCLUDES=
 470             if test $lyx_std_regex = yes ; then
 471               BOOST_LIBS=""
 472             else
 473               AC_LANG_PUSH(C++)
 474               save_LIBS=$LIBS
 475
 476               AC_MSG_CHECKING([for multithreaded boost libraries])
 477               LIBS="$save_LIBS -lboost_regex-mt $LIBTHREAD"
 478               AC_LINK_IFELSE(
 479                 [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 480                         [boost::regex reg;])],
 481                 [AC_MSG_RESULT([yes])
 482                  BOOST_MT="-mt"],
 483                 [AC_MSG_RESULT([no])
 484                  AC_MSG_CHECKING([for plain boost libraries])
 485                  LIBS="$save_LIBS -lboost_regex"
 486                  AC_LINK_IFELSE(
 487                      [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 488                              [boost::regex reg;])],
 489                      [AC_MSG_RESULT([yes])
 490                       BOOST_MT=""],
 491                      [AC_MSG_RESULT([no])
 492                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 493                  ])
 494               ])
 495               LIBS=$save_LIBS
 496               AC_LANG_POP(C++)
 497
 498               dnl In general, system boost libraries are incompatible with
 499               dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 500               dnl details.
 501               if test $enable_stdlib_debug = "yes" ; then
 502                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 503    crashes. Consider using --disable-stdlib-debug or removing
 504    --without-included-boost.])
 505               fi
 506
 507               BOOST_LIBS="-lboost_regex${BOOST_MT}"
 508             fi
 509         fi
 510         AC_SUBST(BOOST_INCLUDES)
 511         AC_SUBST(BOOST_LIBS)
 512 ])
 513
 514
 515 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 516 dnl        be used.
 517 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 518   AC_MSG_CHECKING([whether to use included iconv library])
 519   AC_ARG_WITH(included-iconv,
 520     [AS_HELP_STRING([--with-included-iconv], [use the iconv lib supplied with LyX instead of the system one])],
 521     [lyx_cv_with_included_iconv=$withval],
 522     [lyx_cv_with_included_iconv=no])
 523   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 524   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 525   if test x$lyx_cv_with_included_iconv = xyes ; then
 526   lyx_included_libs="$lyx_included_libs iconv"
 527
 528 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 529     AC_EILSEQ
 530     AC_TYPE_MBSTATE_T
 531     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 532 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.14/lib/loop_wchar.h.
 533     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 534       USE_MBSTATE_T=1
 535     else
 536       USE_MBSTATE_T=0
 537     fi
 538     AC_SUBST([USE_MBSTATE_T])
 539     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 540       [gl_cv_header_wchar_h_standalone],
 541       [AC_COMPILE_IFELSE(
 542         [AC_LANG_PROGRAM(
 543           [[#include <wchar.h>
 544             wchar_t w;]],
 545           [[]])],
 546         [gl_cv_header_wchar_h_standalone=yes],
 547         [gl_cv_header_wchar_h_standalone=no])])
 548     if test $gl_cv_header_wchar_h_standalone = yes; then
 549       BROKEN_WCHAR_H=0
 550     else
 551       BROKEN_WCHAR_H=1
 552     fi
 553     AC_SUBST([BROKEN_WCHAR_H])
 554 dnl we want const correctness
 555     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 556       [Define as const if the declaration of iconv() needs const.])
 557     ICONV_CONST=const
 558     AC_SUBST([ICONV_CONST])
 559 dnl we build a static lib
 560     DLL_VARIABLE=
 561     AC_SUBST([DLL_VARIABLE])
 562     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.14 -I$(top_builddir)/3rdparty/libiconv'
 563     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 564     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.14/include/iconv.h.in
 565   else
 566     ICONV_INCLUDES=
 567     AM_ICONV
 568     if test "$am_cv_func_iconv" = no; then
 569       AC_MSG_ERROR([cannot find required library iconv.])
 570     else
 571       ICONV_LIBS="$LIBICONV"
 572     fi
 573     ICONV_ICONV_H_IN=
 574   fi
 575   AC_SUBST(ICONV_INCLUDES)
 576   AC_SUBST(ICONV_LIBS)
 577   AC_SUBST(ICONV_ICONV_H_IN)
 578 ])
 579
 580
 581 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 582 dnl        be used.
 583 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 584   AC_MSG_CHECKING([whether to use included zlib library])
 585   AC_ARG_WITH(included-zlib,
 586     [AS_HELP_STRING([--with-included-zlib], [use the zlib lib supplied with LyX instead of the system one])],
 587     [lyx_cv_with_included_zlib=$withval],
 588     [lyx_cv_with_included_zlib=no])
 589   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 590   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 591   if test x$lyx_cv_with_included_zlib = xyes ; then
 592     lyx_included_libs="$lyx_included_libs zlib"
 593     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 594     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 595     mkdir -p 3rdparty/zlib
 596 dnl include standard config.h for HAVE_UNISTD_H
 597     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 598 dnl prevent clash with system zlib that might be dragged in by other libs
 599     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 600     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 601   else
 602     ZLIB_INCLUDES=
 603     AC_CHECK_HEADERS(zlib.h,
 604       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 605       [LYX_LIB_ERROR(zlib.h,zlib)])
 606   fi
 607   AC_SUBST(ZLIB_INCLUDES)
 608   AC_SUBST(ZLIB_LIBS)
 609 ])
 610
 611
 612 dnl Usage: LYX_BUILD_INCLUDED_DTL : select if the included dtl should
 613 dnl        be built and installed.
 614 AC_DEFUN([LYX_BUILD_INCLUDED_DTL],[
 615         AC_MSG_CHECKING([whether to build dv2dt and dt2dv])
 616         AC_ARG_WITH(included-dtl,
 617             [AS_HELP_STRING([--with-included-dtl], [build and install the dv2dt and dt2dv programs supplied with LyX])],
 618             [lyx_cv_with_included_dtl=$withval],
 619             [lyx_cv_with_included_dtl=no])
 620         AM_CONDITIONAL(BUILD_INCLUDED_DTL, test x$lyx_cv_with_included_dtl = xyes)
 621         AC_MSG_RESULT([$lyx_cv_with_included_dtl])
 622         if test x$lyx_cv_with_included_dtl = xyes ; then
 623             lyx_flags="$lyx_flags build-dtl"
 624         fi])
 625
 626
 627 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 628 dnl        necessary APIs are available to print callstacks.
 629 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 630 [AC_ARG_ENABLE([callstack-printing],
 631                [AS_HELP_STRING([--disable-callstack-printing],[do not print a callstack when crashing])],
 632                lyx_cv_callstack_printing=$enableval, lyx_cv_callstack_printing=yes)
 633
 634 if test x"$lyx_cv_callstack_printing" = xyes; then
 635   AC_CACHE_CHECK([whether printing callstack is possible],
 636                  [lyx_cv_callstack_printing],
 637   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 638   #include <execinfo.h>
 639   #include <cxxabi.h>
 640   ]], [[
 641           void* array[200];
 642           size_t size = backtrace(array, 200);
 643           backtrace_symbols(array, size);
 644           int status = 0;
 645           abi::__cxa_demangle("abcd", 0, 0, &status);
 646   ]])],[],[lyx_cv_callstack_printing=no])])
 647 fi
 648 if test x"$lyx_cv_callstack_printing" = xyes; then
 649   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 650             [Define if callstack can be printed])
 651   lyx_flags="$lyx_flags callback-printing"
 652   AM_LDFLAGS="${AM_LDFLAGS} -rdynamic"
 653 fi
 654 ])
 655
 656
 657 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 658 dnl        be used.
 659 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 660   AC_ARG_WITH(included-mythes,
 661     [AS_HELP_STRING([--with-included-mythes], [force to use the MyThes lib supplied with LyX])],
 662     [use_included_mythes=$withval],
 663     [use_included_mythes=no])
 664   if test x$use_included_mythes != xyes ; then
 665     AC_LANG_PUSH(C++)
 666     use_included_mythes=yes
 667     AC_CHECK_HEADERS([mythes.hxx mythes/mythes.hxx],
 668       [mythes_h_location="<$ac_header>"
 669        save_LIBS=$LIBS
 670        AC_MSG_CHECKING([checking for MyThes library])
 671        for ac_lib in mythes mythes-1.2 ; do
 672          LIBS="-l$ac_lib $save_LIBS"
 673          AC_LINK_IFELSE(
 674            [AC_LANG_PROGRAM([#include <cstdio>]
 675               [#include $mythes_h_location], [MyThes dummy("idx","dat")])],
 676            [MYTHES_LIBS=-l$ac_lib
 677             AC_MSG_RESULT([$MYTHES_LIBS])
 678             use_included_mythes=no])
 679        done
 680        if test $use_included_mythes != no ; then
 681          AC_MSG_RESULT([not found])
 682        fi
 683        break])
 684     AC_LANG_POP(C++)
 685   fi
 686   if test $use_included_mythes = yes ; then
 687     mythes_h_location="<mythes.hxx>"
 688     MYTHES_INCLUDES='-I$(top_srcdir)/3rdparty/mythes/1.2.5/'
 689     MYTHES_LIBS='$(top_builddir)/3rdparty/mythes/liblyxmythes.a'
 690     lyx_included_libs="$lyx_included_libs mythes"
 691   fi
 692   AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$use_included_mythes = xyes)
 693   AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$mythes_h_location,[Location of mythes.hxx])
 694   AC_SUBST(MYTHES_INCLUDES)
 695   AC_SUBST(MYTHES_LIBS)
 696   AC_MSG_CHECKING([whether to use included MyThes library])
 697   AC_MSG_RESULT([$use_included_mythes])
 698 ])
 699
 700
 701 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 702 dnl                       [default-yes-value])
 703 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 704 dnl  resulting directory name in 'dir-var-name'.
 705 AC_DEFUN([LYX_WITH_DIR],[
 706   AC_ARG_WITH($1,[AS_HELP_STRING([--with-$1],[specify $2])])
 707   AC_MSG_CHECKING([for $2])
 708   if test -z "$with_$3"; then
 709      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 710   else
 711     test "x$with_$3" = xyes && with_$3=$5
 712     lyx_cv_$3="$with_$3"
 713   fi
 714   AC_MSG_RESULT($lyx_cv_$3)
 715 ])
 716
 717
 718 dnl Usage: LYX_LOOP_DIR(value,action)
 719 dnl Executes action for values of variable `dir' in `values'. `values' can
 720 dnl use ":" as a separator.
 721 AC_DEFUN([LYX_LOOP_DIR],[
 722 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 723 for dir in `eval "echo $1"`; do
 724   if test ! "$dir" = NONE; then
 725     test ! -d "$dir" && AC_MSG_ERROR(['$dir' is not a directory])
 726     $2
 727   fi
 728 done
 729 IFS=$ac_save_ifs
 730 ])
 731
 732
 733 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 734 dnl var-name.
 735 AC_DEFUN([LYX_ADD_LIB_DIR],[
 736 $1="${$1} -L$2"
 737 if test "`(uname) 2>/dev/null`" = SunOS &&
 738     uname -r | grep '^5' >/dev/null; then
 739   if test $GXX = yes ; then
 740     $1="${$1} -Wl[,]-R$2"
 741   else
 742     $1="${$1} -R$2"
 743   fi
 744 fi])
 745
 746
 747 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 748 dnl var-name.
 749 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 750
 751 ### Check for a headers existence and location iff it exists
 752 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 753 ## It almost works.  I've tried a few variations but they give errors
 754 ## of one sort or other: bad substitution or file not found etc.  The
 755 ## actual header _is_ found though and the cache variable is set however
 756 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 757 ## reason.
 758 ## Additionally, autoheader can't figure out what to use as the name in
 759 ## the config.h.in file so we need to write our own entries there -- one for
 760 ## each header in the form PATH_HEADER_NAME_H
 761 ##
 762 AC_DEFUN([LYX_PATH_HEADER],
 763 [ AC_CHECK_HEADER($1,[
 764   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 765 ### the only remaining problem is getting the second parameter to this
 766 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 767 ### of $ac_safe being printed.
 768   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 769   [ cat > conftest.$ac_ext <<EOF
 770 #line __oline__ "configure"
 771 #include "confdefs.h"
 772
 773 #include <$1>
 774 EOF
 775 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 776   grep $1  2>/dev/null | \
 777   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 778 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 779 rm -f conftest*])
 780   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 781 ])
 782 ### end of LYX_PATH_HEADER
 783
 784 ## Check what kind of packaging should be used at install time.
 785 ## The default is autodetected.
 786 AC_DEFUN([LYX_USE_PACKAGING],
 787 [AC_MSG_CHECKING([what packaging should be used])
 788 AC_ARG_WITH(packaging,
 789   [AS_HELP_STRING([--with-packaging=STR], [set packaging for installation among:
 790                             posix, windows, macosx, haiku (default is autodetected)])],
 791   [lyx_use_packaging="$withval"], [
 792   case $host in
 793     *-apple-darwin*) lyx_use_packaging=macosx ;;
 794     *-pc-mingw*) lyx_use_packaging=windows ;;
 795     *-mingw32*) lyx_use_packaging=windows ;;
 796     *haiku*) lyx_use_packaging=haiku ;;
 797     *) lyx_use_packaging=posix ;;
 798   esac])
 799 AC_MSG_RESULT($lyx_use_packaging)
 800 lyx_install_posix=false
 801 lyx_install_macosx=false
 802 lyx_install_cygwin=false
 803 lyx_install_windows=false
 804 case $lyx_use_packaging in
 805    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 806            PACKAGE=LyX${version_suffix}
 807            default_prefix="/Applications/${PACKAGE}.app"
 808            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 809            bindir='${prefix}/Contents/MacOS'
 810            libdir='${prefix}/Contents/Resources'
 811            datarootdir='${prefix}/Contents/Resources'
 812            pkgdatadir='${datadir}'
 813            mandir='${datadir}/man'
 814            lyx_install_macosx=true ;;
 815   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 816            PACKAGE=LyX${version_suffix}
 817            default_prefix="C:/Program Files/${PACKAGE}"
 818            bindir='${prefix}/bin'
 819            libdir='${prefix}/Resources'
 820            datarootdir='${prefix}/Resources'
 821            pkgdatadir='${datadir}'
 822            mandir='${prefix}/Resources/man'
 823            lyx_install_windows=true ;;
 824     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 825            PACKAGE=lyx${version_suffix}
 826            program_suffix=$version_suffix
 827            pkgdatadir='${datadir}/${PACKAGE}'
 828            default_prefix=$ac_default_prefix
 829            case ${host} in
 830              *cygwin*) lyx_install_cygwin=true ;;
 831              *apple-darwin*) lyx_install_macosx=true ;;
 832            esac
 833            lyx_install_posix=true ;;
 834         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 835            PACKAGE=lyx${version_suffix}
 836            program_suffix=$version_suffix
 837            pkgdatadir='${datadir}/${PACKAGE}'
 838            default_prefix=$ac_default_prefix
 839            lyx_install_posix=true ;;
 840     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 841 esac
 842 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 843 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 844 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 845 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 846 AC_SUBST(pkgdatadir)
 847 AC_SUBST(program_suffix)
 848 ])
 849
 850
 851 ## ------------------------------------------------------------------------
 852 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 853 ## one or two arguments.
 854 ##
 855 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 856 ## ------------------------------------------------------------------------
 857 ##
 858 AC_DEFUN([AC_FUNC_MKDIR],
 859 [AC_CHECK_FUNCS([mkdir _mkdir])
 860 AC_CACHE_CHECK([whether mkdir takes one argument],
 861                [ac_cv_mkdir_takes_one_arg],
 862 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 863 #include <sys/stat.h>
 864 #if HAVE_UNISTD_H
 865 #  include <unistd.h>
 866 #endif
 867 ]], [[mkdir (".");]])],[ac_cv_mkdir_takes_one_arg=yes],[ac_cv_mkdir_takes_one_arg=no])])
 868 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 869   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 870             [Define if mkdir takes only one argument.])
 871 fi
 872 ])
 873
 874
 875 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 876 dnl (which may be a relative path, and need not refer to any existing
 877 dnl entity).
 878
 879 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 880 dnl native Win32 path name, (but with slashes, not backslashes).
 881
 882 dnl On any other system, it is simply the result which would be obtained
 883 dnl if PATHNAME represented an existing directory, and the pwd command was
 884 dnl executed in that directory.
 885 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 886 [ac_dir="$2"
 887  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 888     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 889  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 890  do
 891    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 892  done
 893  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 894  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 895  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 896    s?/*$[]??'`
 897 ])
 898
 899 dnl this is used by the macro blow to general a proper config.h.in entry
 900 m4_define([LYX_AH_CHECK_DECL],
 901 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 902   [Define if you have the prototype for function `$1'])])dnl`
 903
 904 dnl Check things are declared in headers to avoid errors or warnings.
 905 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 906 dnl Defines HAVE_DECL_{FUNCTION}
 907 AC_DEFUN([LYX_CHECK_DECL],
 908 [LYX_AH_CHECK_DECL($1)
 909 for ac_header in $2
 910 do
 911   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 912   AC_EGREP_HEADER($1, $ac_header,
 913       [AC_MSG_RESULT(yes)
 914        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 915        break],
 916       [AC_MSG_RESULT(no)])
 917 done])
 918
 919 dnl this is used by the macro below to generate a proper config.h.in entry
 920 m4_define([LYX_AH_CHECK_DEF],
 921 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 922   [Define to 1 if `$1' is defined in `$2'])])dnl'
 923
 924 dnl Check whether name is defined in header by using it in codesnippet.
 925 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 926 dnl Defines HAVE_DEF_{NAME}
 927 AC_DEFUN([LYX_CHECK_DEF],
 928 [LYX_AH_CHECK_DEF($1, $2)
 929  AC_MSG_CHECKING([whether $1 is defined by header $2])
 930  save_CPPFLAGS=$CPPFLAGS
 931  CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 932  save_CXXFLAGS=$CXXFLAGS
 933  CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 934  AC_LANG_PUSH(C++)
 935  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <$2>]], [[$3]])],[lyx_have_def_name=yes],[lyx_have_def_name=no])
 936  AC_LANG_POP(C++)
 937  CXXFLAGS=$save_CXXFLAGS
 938  CPPFLAGS=$save_CPPFLAGS
 939  AC_MSG_RESULT($lyx_have_def_name)
 940  if test "x$lyx_have_def_name" = xyes; then
 941    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 942  fi
 943 ])
 944
 945 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 946 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 947 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 948 AC_DEFUN([LYX_SET_VERSION_INFO],
 949 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 950  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 951  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 952  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 953  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 954  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 955  test "x$lyx_patch" = "x" && lyx_patch=0
 956  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 957  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 958  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 959  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 960  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 961  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 962  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 963  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 964 ])
 965