config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN(LYX_CHECK_VERSION,[
  10 changequote(, ) dnl
  11 echo "configuring LyX version $VERSION"
  12 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  13   lyx_devel_version=yes
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 changequote([, ]) dnl
  25 AC_SUBST(lyx_devel_version)
  26 if test $lyx_devel_version = yes ; then
  27   AC_DEFINE(DEVEL_VERSION, 1, Define if you are building a development version of LyX)
  28 fi])
  29
  30
  31 dnl Define the option to set a LyX version on installed executables and directories
  32 dnl
  33 dnl
  34 AC_DEFUN(LYX_VERSION_SUFFIX,[
  35 AC_MSG_CHECKING([for install target ... ])
  36 AC_ARG_WITH(version-suffix,
  37   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  38   [if test "x$withval" = "xyes";
  39    then
  40      withval="-$VERSION"
  41      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  42    fi
  43    lyxname="lyx$withval"
  44    program_suffix=$withval],
  45   [lyxname=lyx])
  46 AC_MSG_RESULT([$lyxname])
  47 ])
  48
  49
  50 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  51 dnl flag lyx_error to yes.
  52 AC_DEFUN(LYX_ERROR,[
  53 lyx_error_txt="$lyx_error_txt
  54 ** $1
  55 "
  56 lyx_error=yes])
  57
  58
  59 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  60 dnl flag lyx_warning to yes.
  61 AC_DEFUN(LYX_WARNING,[
  62 lyx_warning_txt="$lyx_warning_txt
  63 == $1
  64 "
  65 lyx_warning=yes])
  66
  67
  68 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  69 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  70 AC_DEFUN(LYX_LIB_ERROR,[
  71 LYX_ERROR([Cannot find $1. Please check that the $2 library
  72    is correctly installed on your system.])])
  73
  74
  75 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  76 dnl   has occured previously.
  77 AC_DEFUN(LYX_CHECK_ERRORS,[
  78 if test x$lyx_error = xyes; then
  79 cat <<EOF
  80 **** The following problems have been detected by configure.
  81 **** Please check the messages below before running 'make'.
  82 **** (see the section 'Problems' in the INSTALL file)
  83 $lyx_error_txt
  84 $lyx_warning_txt
  85 EOF
  86 else
  87
  88 if test x$lyx_warning = xyes; then
  89 cat <<EOF
  90 === The following minor problems have been detected by configure.
  91 === Please check the messages below before running 'make'.
  92 === (see the section 'Problems' in the INSTALL file)
  93 $lyx_warning_txt
  94 EOF
  95 fi
  96 cat <<EOF
  97 Configuration of LyX was successful.
  98 Type 'make' to compile the program,
  99 and then 'make install' to install it.
 100 EOF
 101 fi])
 102
 103
 104 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 105 dnl
 106 define(LYX_SEARCH_PROG,[dnl
 107 for ac_prog in $2 ; do
 108 # Extract the first word of "$ac_prog", so it can be a program name with args.
 109   set dummy $ac_prog ; ac_word=$[2]
 110   if test -z "[$]$1"; then
 111     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 112     for ac_dir in $PATH; do
 113       test -z "$ac_dir" && ac_dir=.
 114       if test -f [$ac_dir/$ac_word]; then
 115         $1="$ac_prog"
 116         break
 117       fi
 118     done
 119     IFS="$ac_save_ifs"
 120   fi
 121
 122   if test -n "[$]$1"; then
 123     ac_result=yes
 124   else
 125     ac_result=no
 126   fi
 127   ifelse($3,,,[$3])
 128   test -n "[$]$1" && break
 129 done
 130 ])dnl
 131
 132
 133 AC_DEFUN([LYX_PROG_CXX_WORKS],
 134 [rm -f conftest.C
 135 cat >conftest.C <<EOF
 136 class foo {
 137    // we require the mutable keyword
 138    mutable int bar;
 139  };
 140  // we require namespace support
 141  namespace baz {
 142    int bar;
 143  }
 144  int main() {
 145    return(0);
 146  }
 147 EOF
 148 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 149 rm -f conftest.C conftest.o conftest.obj || true
 150 ])
 151
 152
 153 AC_DEFUN(LYX_PROG_CXX,
 154 [AC_MSG_CHECKING([for a good enough C++ compiler])
 155 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 156
 157 if test -z "$CXX" ; then
 158   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 159 fi
 160 AC_MSG_RESULT($CXX)
 161
 162 AC_PROG_CXX
 163
 164 ### We might want to get or shut warnings.
 165 AC_ARG_ENABLE(warnings,
 166   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 167   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 168         enable_warnings=yes;
 169     else
 170         enable_warnings=no;
 171     fi;])
 172 if test x$enable_warnings = xyes ; then
 173   lyx_flags="$lyx_flags warnings"
 174   AC_DEFINE(WITH_WARNINGS, 1,
 175   [Define this if you want to see the warning directives put here and
 176    there by the developpers to get attention])
 177 fi
 178
 179 ### We might want to disable debug
 180 AC_ARG_ENABLE(debug,
 181   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 182   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 183         enable_debug=yes;
 184     else
 185         enable_debug=no;
 186     fi;])
 187
 188 ### set up optimization
 189 AC_ARG_ENABLE(optimization,
 190   AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 191         enable_optimization=yes;)
 192 case $enable_optimization in
 193   yes) lyx_opt=-O;;
 194    no) lyx_opt=;;
 195     *) lyx_opt=${enable_optimization};;
 196 esac
 197
 198 # set the debug flags correctly.
 199 if test x$GXX = xyes; then
 200   dnl Useful for global version info
 201   gxx_version=`${CXX} -dumpversion`
 202   CXX_VERSION="($gxx_version)"
 203
 204   if test "$ac_test_CXXFLAGS" = set; then
 205     CXXFLAGS="$ac_save_CXXFLAGS"
 206   else
 207     case $gxx_version in
 208       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive -ftemplate-depth-30";;
 209       2.95.*)  CXXFLAGS="$lyx_opt -Wno-non-template-friend -ftemplate-depth-30";;
 210       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 211       3.0*)    CXXFLAGS="$lyx_opt";;
 212       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 213       3.2*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 214       3.3*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 215       3.4*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 216       *)       CXXFLAGS="$lyx_opt";;
 217     esac
 218     if test x$enable_debug = xyes ; then
 219         CXXFLAGS="-g $CXXFLAGS"
 220     fi
 221   fi
 222   if test x$enable_warnings = xyes ; then
 223     case $gxx_version in
 224         2.95.*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 225         2.96*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 226         3.1*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 227         *)      CXXFLAGS="$CXXFLAGS -W -Wall";;
 228     esac
 229   fi
 230 fi])dnl
 231
 232
 233 dnl NOT USED CURRENTLY*************************************
 234 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 235 dnl   supports RTTI
 236 AC_DEFUN(LYX_CXX_RTTI,[
 237 ### Check whether the compiler supports runtime type information
 238 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 239  [AC_TRY_RUN([
 240 class rtti {
 241 public:
 242    virtual int tag() { return 0; }
 243 };
 244 class derived1 : public rtti {
 245 public:
 246     int tag() { return 1; }
 247 };
 248 class derived2 : public rtti {
 249 public:
 250     int tag() { return 2; }
 251 };
 252 int main() {
 253     derived1 * foo1 = new derived1();
 254     derived2 * foo2 = new derived2();
 255     rtti * bar = foo1;
 256     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 257     if (bar1 == 0)
 258         exit(1);
 259     bar = foo2;
 260     bar1 = dynamic_cast<derived1 *>(bar);
 261     if (bar1 != 0)
 262         exit(1);
 263     return 0;
 264 }
 265 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 266 ])
 267 if test x$lyx_cv_rtti = xyes ; then
 268   AC_DEFINE(HAVE_RTTI, 1,
 269    [Define to 1 if your compiler supports runtime type information])
 270 fi])
 271
 272
 273 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 274 dnl   understands the "explicit" directive.
 275 AC_DEFUN(LYX_CXX_EXPLICIT,[
 276 ### Check whether the compiler understands the keyword `explicit'
 277 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 278  [AC_TRY_COMPILE([
 279 class Expl {
 280 public:
 281         explicit Expl() {}
 282 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 283 ])
 284 if test $lyx_cv_explicit = no ; then
 285   AC_DEFINE(explicit,[ ],
 286    [Define to nothing if your compiler does not understand the
 287    'explicit' directive])
 288 fi])
 289
 290
 291 dnl NOT USED CURRENTLY*************************************
 292 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 293 dnl   has a working stl stack template
 294 AC_DEFUN(LYX_CXX_STL_STACK,[
 295 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 296  [AC_TRY_COMPILE([
 297 #include <stack>
 298 using std::stack;
 299 ],[
 300     stack<int> stakk;
 301     stakk.push(0);
 302 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 303 ])
 304 if test $lyx_cv_broken_stack = yes ; then
 305   AC_DEFINE(BROKEN_STL_STACK, 1,
 306    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 307    correctly])
 308 fi])
 309
 310
 311 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 312 dnl    count template, if not the old HP version is assumed.
 313 AC_DEFUN(LYX_STD_COUNT,[
 314 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 315  [AC_TRY_COMPILE([
 316 #include <algorithm>
 317 using std::count;
 318 int countChar(char * b, char * e, char const c)
 319 {
 320         return count(b, e, c);
 321 }
 322 ],[
 323     char a[] = "hello";
 324     int i = countChar(a, a + 5, 'l');
 325 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 326 ])
 327 if test $lyx_cv_std_count = yes ; then
 328     AC_DEFINE(HAVE_STD_COUNT, 1,
 329     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 330 fi])
 331
 332
 333 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 334 dnl   supports modern STL streams
 335 AC_DEFUN(LYX_CXX_STL_MODERN_STREAMS,[
 336 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 337  [AC_TRY_COMPILE([
 338 #include <iostream>
 339 ],[
 340  std::streambuf * test = std::cerr.rdbuf();
 341  test->pubsync();
 342 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 343 ])
 344 if test $lyx_cv_modern_streams = yes ; then
 345   AC_DEFINE(MODERN_STL_STREAMS, 1,
 346    [Define if you have modern standard-compliant STL streams])
 347 fi])
 348
 349
 350 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 351 dnl        be used.
 352 AC_DEFUN(LYX_USE_INCLUDED_BOOST,[
 353         AC_ARG_WITH(included-boost,
 354             [  --with-included-boost  use the boost lib supplied with LyX],
 355             [lyx_cv_with_included_boost=$withval
 356                 AC_MSG_RESULT([$with_included_boost])],
 357             [lyx_cv_with_included_boost=yes])
 358         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 359 ])
 360
 361
 362 dnl NOT USED CURRENTLY*************************************
 363 dnl LYX_CXX_PARTIAL
 364 AC_DEFUN(LYX_CXX_PARTIAL, [
 365     AC_REQUIRE([AC_PROG_CXX])
 366     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 367         [lyx_cv_cxx_partial_specialization],
 368         [AC_TRY_COMPILE(
 369             [
 370             template<class T, class K>
 371             class k {
 372             public:
 373             };
 374             template<class T> class k<void,T> { };
 375             ],[
 376             k<float, float> b;
 377             k<void,void> a;
 378             ],[
 379             lyx_cv_cxx_partial_specialization=yes
 380             ],[
 381             lyx_cv_cxx_partial_specialization=no
 382             ])
 383         ])
 384     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 385         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 386         [Defined if your compiler supports partial specialization.])
 387     fi
 388 ])
 389
 390
 391 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 392 dnl   provides wrappers for C headers and use our alternate version otherwise.
 393 AC_DEFUN(LYX_CXX_CHEADERS,[
 394 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 395  [AC_TRY_CPP([
 396 #include <clocale>
 397 #include <cctype>
 398 #include <cerrno>
 399 #include <cmath>
 400 #include <csignal>
 401 #include <cstdio>
 402 #include <cstdlib>
 403 #include <cstring>
 404 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 405 if test $lyx_cv_cxx_cheaders = no ; then
 406   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 407 fi])
 408
 409
 410 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 411 dnl   are already in the global namespace
 412 AC_DEFUN(LYX_CXX_GLOBAL_CSTD,[
 413     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 414     lyx_cv_cxx_global_cstd,
 415     [AC_TRY_COMPILE([
 416     #include <cctype>
 417     using std::tolower;
 418     ],[
 419     return 0;
 420     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 421     if test x$lyx_cv_cxx_global_cstd = xyes; then
 422         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 423         [Define if your C++ compiler puts C library functions in the global namespace])
 424     fi
 425 ])
 426
 427
 428 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 429 dnl                       [default-yes-value])
 430 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 431 dnl  resulting directory name in 'dir-var-name'.
 432 AC_DEFUN(LYX_WITH_DIR,[
 433   AC_ARG_WITH($1,[  --with-$1        specify $2])
 434   AC_MSG_CHECKING([for $2])
 435   if test -z "$with_$3"; then
 436      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 437   else
 438     test "x$with_$3" = xyes && with_$3=$5
 439     lyx_cv_$3="$with_$3"
 440   fi
 441   AC_MSG_RESULT($lyx_cv_$3)])
 442
 443
 444 dnl Usage: LYX_LOOP_DIR(value,action)
 445 dnl Executes action for values of variable `dir' in `values'. `values' can
 446 dnl use ":" as a separator.
 447 AC_DEFUN(LYX_LOOP_DIR,[
 448 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 449 for dir in `eval "echo $1"`; do
 450   if test ! "$dir" = NONE; then
 451     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 452     $2
 453   fi
 454 done
 455 IFS=$ac_save_ifs
 456 ])
 457
 458
 459 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 460 dnl var-name.
 461 AC_DEFUN(LYX_ADD_LIB_DIR,[
 462 $1="${$1} -L$2"
 463 if test "`(uname) 2>/dev/null`" = SunOS &&
 464     uname -r | grep '^5' >/dev/null; then
 465   if test $ac_cv_prog_gxx = yes ; then
 466     $1="${$1} -Wl[,]-R$2"
 467   else
 468     $1="${$1} -R$2"
 469   fi
 470 fi])
 471
 472
 473 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 474 dnl var-name.
 475 AC_DEFUN(LYX_ADD_INC_DIR,[$1="${$1} -I$2 "])
 476
 477 ### Check for a headers existence and location iff it exists
 478 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 479 ## It almost works.  I've tried a few variations but they give errors
 480 ## of one sort or other: bad substitution or file not found etc.  The
 481 ## actual header _is_ found though and the cache variable is set however
 482 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 483 ## reason.
 484 ## Additionally, autoheader can't figure out what to use as the name in
 485 ## the config.h.in file so we need to write our own entries there -- one for
 486 ## each header in the form PATH_HEADER_NAME_H
 487 ##
 488 AC_DEFUN(LYX_PATH_HEADER,
 489 [ AC_CHECK_HEADER($1,[
 490   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 491 ### the only remaining problem is getting the second parameter to this
 492 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 493 ### of $ac_safe being printed.
 494   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 495   [ cat > conftest.$ac_ext <<EOF
 496 #line __oline__ "configure"
 497 #include "confdefs.h"
 498
 499 #include <$1>
 500 EOF
 501 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 502   grep $1  2>/dev/null | \
 503   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 504 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 505 rm -f conftest*])
 506   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 507 ])
 508 ### end of LYX_PATH_HEADER
 509
 510 ### Check which frontends we want to use. The default is XForms only
 511 ###
 512 AC_DEFUN(LYX_USE_FRONTENDS,
 513 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 514 AC_ARG_WITH(frontend,
 515   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 516                             Possible values: xforms, qt],
 517   [FRONTENDS="$withval"], [FRONTENDS="xforms"])
 518 AC_MSG_RESULT($FRONTENDS)
 519 AC_SUBST(FRONTENDS)
 520 AC_SUBST(FRONTENDS_SUBDIRS)
 521 AC_SUBST(FRONTENDS_PROGS)
 522 ])
 523
 524
 525
 526 ## ------------------------------------------------------------------------
 527 ## Find a file (or one of more files in a list of dirs)
 528 ## ------------------------------------------------------------------------
 529 ##
 530 AC_DEFUN(AC_FIND_FILE,
 531 [
 532 $3=NO
 533 for i in $2;
 534 do
 535   for j in $1;
 536   do
 537     if test -r "$i/$j"; then
 538       $3=$i
 539       break 2
 540     fi
 541   done
 542 done
 543 ])
 544
 545 dnl just a wrapper to clean up configure.in
 546 AC_DEFUN(LYX_PROG_LIBTOOL,
 547 [
 548 AC_REQUIRE([AC_ENABLE_SHARED])
 549 AC_REQUIRE([AC_ENABLE_STATIC])
 550 dnl libtool is only for C, so I must force him
 551 dnl to find the correct flags for C++
 552 ac_save_cc=$CC
 553 ac_save_cflags="$CFLAGS"
 554 CC=$CXX
 555 CFLAGS="$CXXFLAGS"
 556 AM_PROG_LIBTOOL dnl for libraries
 557 CC=$ac_save_cc
 558 CFLAGS="$ac_save_cflags"
 559 ])