config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CPPFLAGS=$CPPFLAGS
 155   CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 156   save_CXXFLAGS=$CXXFLAGS
 157   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 158   AC_LANG_PUSH(C++)
 159   AC_TRY_COMPILE([], [
 160 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 161             this is a c++11 compiler
 162 #endif
 163   ],
 164   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 165  AC_LANG_POP(C++)
 166  CXXFLAGS=$save_CXXFLAGS
 167  CPPFLAGS=$save_CPPFLAGS])
 168  lyx_use_cxx11=$lyx_cv_cxx_cxx11
 169 ])
 170
 171
 172 dnl Usage: LYX_CXX_USE_REGEX(cxx11_flags)
 173 dnl decide whether we want to use std::regex and set the
 174 dnl LYX_USE_STD_REGEX accordingly.
 175 dnl the extra cxx11 flags have to be passed to the preprocessor. They are
 176 dnl not plainly added to AM_CPPFLAGS because then the objc compiler (mac)
 177 dnl would fail.
 178 AC_DEFUN([LYX_CXX_USE_REGEX],
 179 [AC_ARG_ENABLE(std-regex,
 180   AC_HELP_STRING([--enable-std-regex],[use std::regex instead of boost::regex (default is autodetected)]),
 181   [lyx_std_regex=$enableval],
 182   [save_CPPFLAGS=$CPPFLAGS
 183    # we want to pass -std=c++11 to clang/cpp if necessary
 184    CPPFLAGS="$AM_CPPFLAGS $1 $CPPFLAGS"
 185    save_CXXFLAGS=$CXXFLAGS
 186    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 187    AC_LANG_PUSH(C++)
 188    AC_CHECK_HEADER([regex], [lyx_std_regex=yes], [lyx_std_regex=no])
 189    AC_LANG_POP(C++)
 190    CXXFLAGS=$save_CXXFLAGS
 191    CPPFLAGS=$save_CPPFLAGS
 192    if test x$GXX = xyes && test $lyx_std_regex = yes ; then
 193      AC_MSG_CHECKING([for correct regex implementation])
 194      if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 195        dnl <regex> in gcc is unusable in versions less than 4.9.0
 196        dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 197        case $gxx_version in
 198          4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) lyx_std_regex=no ;;
 199          *) ;;
 200        esac
 201      fi
 202      AC_MSG_RESULT([$lyx_std_regex])
 203    fi])
 204
 205  if test $lyx_std_regex = yes ; then
 206   lyx_flags="$lyx_flags std-regex"
 207   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 208  fi
 209  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 210 ])
 211
 212
 213 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 214 AC_DEFUN([LYX_LIB_STDCXX],
 215 [AC_CACHE_CHECK([whether STL is libstdc++],
 216                [lyx_cv_lib_stdcxx],
 217 [AC_TRY_COMPILE([#include<vector>], [
 218 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 219             this is not libstdc++
 220 #endif
 221 ],
 222 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 223 ])
 224
 225
 226 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 227 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 228 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 229 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 230                [lyx_cv_lib_stdcxx_cxx11_abi],
 231 [AC_TRY_COMPILE([#include<vector>], [
 232 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 233             this is not libstdc++ using the C++11 ABI
 234 #endif
 235 ],
 236 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 237 ])
 238
 239
 240 AC_DEFUN([LYX_PROG_CXX],
 241 [AC_REQUIRE([AC_PROG_CXX])
 242 AC_REQUIRE([AC_PROG_CXXCPP])
 243
 244 AC_LANG_PUSH(C++)
 245 LYX_PROG_CLANG
 246 LYX_LIB_STDCXX
 247 LYX_LIB_STDCXX_CXX11_ABI
 248 AC_LANG_POP(C++)
 249
 250 if test $lyx_cv_lib_stdcxx = "yes" ; then
 251   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 252     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 253   else
 254     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 255   fi
 256 else
 257   if test $lyx_cv_prog_clang = "yes" ; then
 258     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 259   fi
 260 fi
 261
 262 ### We might want to get or shut warnings.
 263 AC_ARG_ENABLE(warnings,
 264   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 265   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 266         enable_warnings=yes;
 267     else
 268         enable_warnings=no;
 269     fi;])
 270 if test x$enable_warnings = xyes ; then
 271   lyx_flags="$lyx_flags warnings"
 272 fi
 273
 274 ### We might want to disable debug
 275 AC_ARG_ENABLE(debug,
 276   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 277   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 278 )
 279
 280 AC_ARG_ENABLE(stdlib-debug,
 281   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 282   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 283           [enable_stdlib_debug=no])]
 284 )
 285
 286 ### set up optimization
 287 AC_ARG_ENABLE(optimization,
 288     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 289     enable_optimization=yes;)
 290 case $enable_optimization in
 291     yes)
 292         if test $lyx_devel_version = yes ; then
 293             lyx_optim=-O
 294         else
 295             lyx_optim=-O2
 296         fi;;
 297     no) lyx_optim=;;
 298     *) lyx_optim=${enable_optimization};;
 299 esac
 300
 301 AC_ARG_ENABLE(assertions,
 302   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 303   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 304           [enable_assertions=no])]
 305 )
 306 if test "x$enable_assertions" = xyes ; then
 307    lyx_flags="$lyx_flags assertions"
 308    AC_DEFINE(ENABLE_ASSERTIONS,1,
 309     [Define if you want assertions to be enabled in the code])
 310 fi
 311
 312 # set the compiler options correctly.
 313 if test x$GXX = xyes; then
 314   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 315   if test x$CLANG = xno; then
 316     dnl Useful for global version info
 317     gxx_version=`${CXX} -dumpversion`
 318     CXX_VERSION="($gxx_version)"
 319   else
 320     gxx_version=clang
 321   fi
 322
 323   AM_CXXFLAGS="$lyx_optim"
 324   if test x$enable_debug = xyes ; then
 325       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 326   fi
 327   if test $build_type = gprof ; then
 328     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 329     AM_LDFLAGS="$AM_LDFLAGS -pg"
 330   fi
 331   if test $build_type = profiling ; then
 332     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 333   fi
 334
 335   if test x$USE_QT5 = xyes ; then
 336       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 337   fi
 338   dnl Warnings are for preprocessor too
 339   if test x$enable_warnings = xyes ; then
 340       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 341   fi
 342   case $gxx_version in
 343       2.*|3.*) AC_ERROR([gcc >= 4.3 is required]);;
 344       4.0*|4.1*|4.2*) AC_ERROR([gcc >= 4.3 is required]);;
 345   esac
 346   if test x$enable_stdlib_debug = xyes ; then
 347     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 348     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 349     case $gxx_version in
 350       *)
 351         lyx_flags="$lyx_flags stdlib-debug"
 352         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 353         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 354         ;;
 355     esac
 356   fi
 357     case $gxx_version in
 358       4.3*|4.4*|4.5*|4.6*)
 359         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 360         dnl The source code relies on that.
 361         cxx11_flags="-std=c++0x";;
 362       clang)
 363         dnl presumably all clang versions support c++11.
 364         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 365         cxx11_flags="-std=c++11"
 366         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 367       *)
 368         AS_CASE([$host], [*cygwin*],
 369                 [cxx11_flags="-std=gnu++11"],
 370                 [cxx11_flags="-std=c++11"]);;
 371     esac
 372     # cxx11_flags is useful when running preprocessor alone
 373     # (see detection of regex).
 374     AM_CXXFLAGS="$cxx11_flags $AM_CXXFLAGS"
 375 fi
 376
 377 LYX_CXX_CXX11
 378 if test $lyx_use_cxx11 = no; then
 379   AC_ERROR([A C++11 compatible compiler is required])
 380 fi
 381 LYX_CXX_USE_REGEX([$cxx11_flags])
 382 ])
 383
 384 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 385 dnl        be used.
 386 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 387         AC_MSG_CHECKING([whether to use included boost library])
 388         AC_ARG_WITH(included-boost,
 389             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 390             [lyx_cv_with_included_boost=$withval],
 391             [lyx_cv_with_included_boost=yes])
 392         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 393         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 394         if test x$lyx_cv_with_included_boost = xyes ; then
 395             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 396             BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 397         else
 398             AC_LANG_PUSH(C++)
 399             save_LIBS=$LIBS
 400
 401             dnl FIXME: Rewrite test to use regex, we do not use signals anymore.
 402             AC_MSG_CHECKING([for multithreaded boost libraries])
 403             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 404             AC_LINK_IFELSE(
 405                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 406                         [boost::signal<void ()> s;])],
 407                 [AC_MSG_RESULT([yes])
 408                  BOOST_MT="-mt"],
 409                 [AC_MSG_RESULT([no])
 410                  AC_MSG_CHECKING([for plain boost libraries])
 411                  LIBS="$save_LIBS -lboost_signals"
 412                  AC_LINK_IFELSE(
 413                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 414                              [boost::signal<void ()> s;])],
 415                      [AC_MSG_RESULT([yes])
 416                       BOOST_MT=""],
 417                      [AC_MSG_RESULT([no])
 418                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 419                  ])
 420             ])
 421             LIBS=$save_LIBS
 422             AC_LANG_POP(C++)
 423             BOOST_INCLUDES=
 424             if test $lyx_std_regex = yes ; then
 425               BOOST_LIBS=""
 426             else
 427               BOOST_LIBS="-lboost_regex${BOOST_MT}"
 428             fi
 429
 430             dnl In general, system boost libraries are incompatible with
 431             dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 432             dnl details.
 433             if test $enable_stdlib_debug = "yes" ; then
 434                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 435    crashes. Consider using --disable-stdlib-debug or removing
 436    --without-included-boost.])
 437             fi
 438         fi
 439         AC_SUBST(BOOST_INCLUDES)
 440         AC_SUBST(BOOST_LIBS)
 441 ])
 442
 443
 444 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 445 dnl        be used.
 446 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 447   AC_MSG_CHECKING([whether to use included iconv library])
 448   AC_ARG_WITH(included-iconv,
 449     [AC_HELP_STRING([--without-included-iconv], [do not use the iconv lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 450     [lyx_cv_with_included_iconv=$withval],
 451     [lyx_cv_with_included_iconv=no])
 452   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 453   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 454   if test x$lyx_cv_with_included_iconv = xyes ; then
 455 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 456     AC_EILSEQ
 457     AC_TYPE_MBSTATE_T
 458     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 459 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.14/lib/loop_wchar.h.
 460     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 461       USE_MBSTATE_T=1
 462     else
 463       USE_MBSTATE_T=0
 464     fi
 465     AC_SUBST([USE_MBSTATE_T])
 466     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 467       [gl_cv_header_wchar_h_standalone],
 468       [AC_COMPILE_IFELSE(
 469         [AC_LANG_PROGRAM(
 470           [[#include <wchar.h>
 471             wchar_t w;]],
 472           [[]])],
 473         [gl_cv_header_wchar_h_standalone=yes],
 474         [gl_cv_header_wchar_h_standalone=no])])
 475     if test $gl_cv_header_wchar_h_standalone = yes; then
 476       BROKEN_WCHAR_H=0
 477     else
 478       BROKEN_WCHAR_H=1
 479     fi
 480     AC_SUBST([BROKEN_WCHAR_H])
 481 dnl we want const correctness
 482     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 483       [Define as const if the declaration of iconv() needs const.])
 484     ICONV_CONST=const
 485     AC_SUBST([ICONV_CONST])
 486 dnl we build a static lib
 487     DLL_VARIABLE=
 488     AC_SUBST([DLL_VARIABLE])
 489     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.14 -I$(top_builddir)/3rdparty/libiconv'
 490     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 491     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.14/include/iconv.h.in
 492   else
 493     ICONV_INCLUDES=
 494     AM_ICONV
 495     if test "$am_cv_func_iconv" = no; then
 496       AC_MSG_ERROR([cannot find required library iconv.])
 497     else
 498       ICONV_LIBS="$LIBICONV"
 499     fi
 500     ICONV_ICONV_H_IN=
 501   fi
 502   AC_SUBST(ICONV_INCLUDES)
 503   AC_SUBST(ICONV_LIBS)
 504   AC_SUBST(ICONV_ICONV_H_IN)
 505 ])
 506
 507
 508 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 509 dnl        be used.
 510 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 511   AC_MSG_CHECKING([whether to use included zlib library])
 512   AC_ARG_WITH(included-zlib,
 513     [AC_HELP_STRING([--without-included-zlib], [do not use the zlib lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 514     [lyx_cv_with_included_zlib=$withval],
 515     [lyx_cv_with_included_zlib=no])
 516   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 517   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 518   if test x$lyx_cv_with_included_zlib = xyes ; then
 519     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 520     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 521     mkdir -p 3rdparty/zlib
 522 dnl include standard config.h for HAVE_UNISTD_H
 523     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 524 dnl prevent clash with system zlib that might be dragged in by other libs
 525     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 526     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 527   else
 528     ZLIB_INCLUDES=
 529     AC_CHECK_HEADERS(zlib.h,
 530       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 531       [LYX_LIB_ERROR(zlib.h,zlib)])
 532   fi
 533   AC_SUBST(ZLIB_INCLUDES)
 534   AC_SUBST(ZLIB_LIBS)
 535 ])
 536
 537
 538 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 539 dnl        necessary APIs are available to print callstacks.
 540 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 541 [AC_CACHE_CHECK([whether printing callstack is possible],
 542                [lyx_cv_callstack_printing],
 543 [AC_TRY_COMPILE([
 544 #include <execinfo.h>
 545 #include <cxxabi.h>
 546 ], [
 547         void* array[200];
 548         size_t size = backtrace(array, 200);
 549         backtrace_symbols(array, size);
 550         int status = 0;
 551         abi::__cxa_demangle("abcd", 0, 0, &status);
 552 ],
 553 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 554 if test x"$lyx_cv_callstack_printing" = xyes; then
 555   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 556             [Define if callstack can be printed])
 557 fi
 558 ])
 559
 560
 561 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 562 dnl        be used.
 563 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 564         AC_MSG_CHECKING([whether to use included MyThes library])
 565         AC_ARG_WITH(included-mythes,
 566             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 567             [lyx_cv_with_included_mythes=$withval],
 568             [lyx_cv_with_included_mythes=yes])
 569         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 570         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 571         if test x$lyx_cv_with_included_mythes != xyes ; then
 572                 AC_LANG_PUSH(C++)
 573                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 574                 if test x$ac_cv_header_mythes_h != xyes; then
 575                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 576                 fi
 577                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 578                 if test x$lyx_mythes != xyes; then
 579                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 580                 fi
 581                 AC_LANG_POP(C++)
 582                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 583                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 584                 fi
 585                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 586                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 587                 AC_SUBST(MYTHES_LIBS)
 588         fi
 589 ])
 590
 591
 592 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 593 dnl                       [default-yes-value])
 594 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 595 dnl  resulting directory name in 'dir-var-name'.
 596 AC_DEFUN([LYX_WITH_DIR],[
 597   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 598   AC_MSG_CHECKING([for $2])
 599   if test -z "$with_$3"; then
 600      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 601   else
 602     test "x$with_$3" = xyes && with_$3=$5
 603     lyx_cv_$3="$with_$3"
 604   fi
 605   AC_MSG_RESULT($lyx_cv_$3)])
 606
 607
 608 dnl Usage: LYX_LOOP_DIR(value,action)
 609 dnl Executes action for values of variable `dir' in `values'. `values' can
 610 dnl use ":" as a separator.
 611 AC_DEFUN([LYX_LOOP_DIR],[
 612 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 613 for dir in `eval "echo $1"`; do
 614   if test ! "$dir" = NONE; then
 615     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 616     $2
 617   fi
 618 done
 619 IFS=$ac_save_ifs
 620 ])
 621
 622
 623 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 624 dnl var-name.
 625 AC_DEFUN([LYX_ADD_LIB_DIR],[
 626 $1="${$1} -L$2"
 627 if test "`(uname) 2>/dev/null`" = SunOS &&
 628     uname -r | grep '^5' >/dev/null; then
 629   if test $ac_cv_prog_gxx = yes ; then
 630     $1="${$1} -Wl[,]-R$2"
 631   else
 632     $1="${$1} -R$2"
 633   fi
 634 fi])
 635
 636
 637 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 638 dnl var-name.
 639 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 640
 641 ### Check for a headers existence and location iff it exists
 642 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 643 ## It almost works.  I've tried a few variations but they give errors
 644 ## of one sort or other: bad substitution or file not found etc.  The
 645 ## actual header _is_ found though and the cache variable is set however
 646 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 647 ## reason.
 648 ## Additionally, autoheader can't figure out what to use as the name in
 649 ## the config.h.in file so we need to write our own entries there -- one for
 650 ## each header in the form PATH_HEADER_NAME_H
 651 ##
 652 AC_DEFUN([LYX_PATH_HEADER],
 653 [ AC_CHECK_HEADER($1,[
 654   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 655 ### the only remaining problem is getting the second parameter to this
 656 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 657 ### of $ac_safe being printed.
 658   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 659   [ cat > conftest.$ac_ext <<EOF
 660 #line __oline__ "configure"
 661 #include "confdefs.h"
 662
 663 #include <$1>
 664 EOF
 665 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 666   grep $1  2>/dev/null | \
 667   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 668 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 669 rm -f conftest*])
 670   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 671 ])
 672 ### end of LYX_PATH_HEADER
 673
 674 ## Check what kind of packaging should be used at install time.
 675 ## The default is autodetected.
 676 AC_DEFUN([LYX_USE_PACKAGING],
 677 [AC_MSG_CHECKING([what packaging should be used])
 678 AC_ARG_WITH(packaging,
 679   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 680                             Possible values: posix, windows, macosx, haiku])],
 681   [lyx_use_packaging="$withval"], [
 682   case $host in
 683     *-apple-darwin*) lyx_use_packaging=macosx ;;
 684     *-pc-mingw*) lyx_use_packaging=windows ;;
 685     *-mingw32*) lyx_use_packaging=windows ;;
 686     *haiku*) lyx_use_packaging=haiku ;;
 687     *) lyx_use_packaging=posix ;;
 688   esac])
 689 AC_MSG_RESULT($lyx_use_packaging)
 690 lyx_install_posix=false
 691 lyx_install_macosx=false
 692 lyx_install_cygwin=false
 693 lyx_install_windows=false
 694 case $lyx_use_packaging in
 695    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 696            PACKAGE=LyX${version_suffix}
 697            default_prefix="/Applications/${PACKAGE}.app"
 698            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 699            bindir='${prefix}/Contents/MacOS'
 700            libdir='${prefix}/Contents/Resources'
 701            datarootdir='${prefix}/Contents/Resources'
 702            pkgdatadir='${datadir}'
 703            mandir='${datadir}/man'
 704            lyx_install_macosx=true ;;
 705   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 706            PACKAGE=LyX${version_suffix}
 707            default_prefix="C:/Program Files/${PACKAGE}"
 708            bindir='${prefix}/bin'
 709            libdir='${prefix}/Resources'
 710            datarootdir='${prefix}/Resources'
 711            pkgdatadir='${datadir}'
 712            mandir='${prefix}/Resources/man'
 713            lyx_install_windows=true ;;
 714     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 715            PACKAGE=lyx${version_suffix}
 716            program_suffix=$version_suffix
 717            pkgdatadir='${datadir}/${PACKAGE}'
 718            default_prefix=$ac_default_prefix
 719            case ${host} in
 720              *cygwin*) lyx_install_cygwin=true ;;
 721              *apple-darwin*) lyx_install_macosx=true ;;
 722            esac
 723            lyx_install_posix=true ;;
 724         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 725            PACKAGE=lyx${version_suffix}
 726            program_suffix=$version_suffix
 727            pkgdatadir='${datadir}/${PACKAGE}'
 728            default_prefix=$ac_default_prefix
 729            lyx_install_posix=true ;;
 730     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 731 esac
 732 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 733 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 734 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 735 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 736 AC_SUBST(pkgdatadir)
 737 AC_SUBST(program_suffix)
 738 ])
 739
 740
 741 ## ------------------------------------------------------------------------
 742 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 743 ## one or two arguments.
 744 ##
 745 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 746 ## ------------------------------------------------------------------------
 747 ##
 748 AC_DEFUN([AC_FUNC_MKDIR],
 749 [AC_CHECK_FUNCS([mkdir _mkdir])
 750 AC_CACHE_CHECK([whether mkdir takes one argument],
 751                [ac_cv_mkdir_takes_one_arg],
 752 [AC_TRY_COMPILE([
 753 #include <sys/stat.h>
 754 #if HAVE_UNISTD_H
 755 #  include <unistd.h>
 756 #endif
 757 ], [mkdir (".");],
 758 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 759 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 760   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 761             [Define if mkdir takes only one argument.])
 762 fi
 763 ])
 764
 765
 766 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 767 dnl (which may be a relative path, and need not refer to any existing
 768 dnl entity).
 769
 770 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 771 dnl native Win32 path name, (but with slashes, not backslashes).
 772
 773 dnl On any other system, it is simply the result which would be obtained
 774 dnl if PATHNAME represented an existing directory, and the pwd command was
 775 dnl executed in that directory.
 776 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 777 [ac_dir="$2"
 778  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 779     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 780  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 781  do
 782    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 783  done
 784  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 785  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 786  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 787    s?/*$[]??'`
 788 ])
 789
 790 dnl this is used by the macro blow to general a proper config.h.in entry
 791 m4_define([LYX_AH_CHECK_DECL],
 792 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 793   [Define if you have the prototype for function `$1'])])
 794
 795 dnl Check things are declared in headers to avoid errors or warnings.
 796 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 797 dnl Defines HAVE_DECL_{FUNCTION}
 798 AC_DEFUN([LYX_CHECK_DECL],
 799 [LYX_AH_CHECK_DECL($1)
 800 for ac_header in $2
 801 do
 802   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 803   AC_EGREP_HEADER($1, $ac_header,
 804       [AC_MSG_RESULT(yes)
 805        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 806        break],
 807       [AC_MSG_RESULT(no)])
 808 done])
 809
 810 dnl this is used by the macro below to generate a proper config.h.in entry
 811 m4_define([LYX_AH_CHECK_DEF],
 812 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 813   [Define to 1 if `$1' is defined in `$2'])])
 814
 815 dnl Check whether name is defined in header by using it in codesnippet.
 816 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 817 dnl Defines HAVE_DEF_{NAME}
 818 AC_DEFUN([LYX_CHECK_DEF],
 819 [LYX_AH_CHECK_DEF($1, $2)
 820  AC_MSG_CHECKING([whether $1 is defined by header $2])
 821  AC_TRY_COMPILE([#include <$2>], [$3],
 822      lyx_have_def_name=yes,
 823      lyx_have_def_name=no)
 824  AC_MSG_RESULT($lyx_have_def_name)
 825  if test "x$lyx_have_def_name" = xyes; then
 826    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 827  fi
 828 ])
 829
 830 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 831 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 832 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 833 AC_DEFUN([LYX_SET_VERSION_INFO],
 834 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 835  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 836  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 837  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 838  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 839  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 840  test "x$lyx_patch" = "x" && lyx_patch=0
 841  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 842  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 843  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 844  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 845  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 846  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 847  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 848  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 849 ])
 850
 851 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 852 # ---------------------------------------------------------------------------
 853 # Copied from autoconf 2.68, added a check that python version is < 3.0
 854 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 855 # Run ACTION-IF-FALSE otherwise.
 856 # This test uses sys.hexversion instead of the string equivalent (first
 857 # word of sys.version), in order to cope with versions such as 2.2c1.
 858 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 859 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 860  [prog="import sys
 861 # split strings by '.' and convert to numeric.  Append some zeros
 862 # because we need at least 4 digits for the hex conversion.
 863 # map returns an iterator in Python 3.0 and a list in 2.x
 864 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 865 minverhex = 0
 866 maxverhex = 50331648 # = 3.0.0.0
 867 # xrange is not present in Python 3.0 and range returns an iterator
 868 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 869 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 870   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])