config/configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15
  16 LYX_VERSION_SUFFIX
  17
  18 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  19
  20 # The list of languages known to LyX
  21 # This is needed by GNU gettext
  22 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  23
  24 # fix the value of the prefixes.
  25 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  26 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  27
  28 ### Set the execute permissions of the various scripts correctly
  29 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  30   chmod 755 ${srcdir}/${file}
  31 done
  32
  33 ### Check for programs
  34 AC_PROG_MAKE_SET
  35 AC_PROG_INSTALL
  36 #AC_PROG_RANLIB
  37 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  38 if test "x$KPSEWHICH" = xkpsewhich ; then
  39     AC_DEFINE(HAVE_KPSEWHICH, 1,
  40     [Define this if you have the kpsewhich program working on your system.])
  41 fi
  42 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  43
  44 # Work around a problem in automake 1.4: when invoking install-strip,
  45 # INSTALL_PROGRAM is changed to 'install -s', and since
  46 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  47 # which returns an error condition when stripping fails.
  48 INSTALL_SCRIPT='${INSTALL}'
  49
  50 ### we will also need a C compiler to compile GNU gettext
  51 AC_PROG_CC
  52
  53 ### check for special systems
  54 AC_ISC_POSIX
  55 AC_AIX
  56
  57 ### Check for program extensions (.exe or nothing)
  58 AC_EXEEXT
  59
  60 ### check which frontend we want to use
  61 LYX_USE_FRONTEND
  62
  63 ### Check for a C++ compiler
  64 LYX_PROG_CXX
  65 ### Some checks on what the C++ compiler can(not) do
  66 AC_LANG_CPLUSPLUS
  67 dnl we do not need that currently (and probably all our supported
  68 dnl compiler allow that)
  69 dnl LYX_CXX_PARTIAL
  70 LYX_CXX_EXPLICIT
  71 LYX_CXX_STL_STRING
  72 LYX_CXX_GOOD_STD_STRING
  73 LYX_CXX_CHEADERS
  74 LYX_CXX_GLOBAL_CSTD
  75 LYX_STD_COUNT
  76 dnl we disable rtti for now
  77 dnl LYX_CXX_RTTI
  78 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  79 LYX_CXX_STL_MODERN_STREAMS
  80
  81 ### and now some special lyx flags.
  82 AC_ARG_ENABLE(assertions,
  83   [  --enable-assertions     add runtime sanity checks in the program],,
  84   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  85         enable_assertions=yes;
  86     else
  87         enable_assertions=no;
  88     fi;])
  89 if test "x$enable_assertions" = xyes ; then
  90    lyx_flags="$lyx_flags assertions"
  91    AC_DEFINE(ENABLE_ASSERTIONS,1,
  92     [Define if you want assertions to be enabled in the code])
  93 fi
  94
  95 ### Library Files
  96 dnl by testing these we check if it is ok to have
  97 dnl -lc and -lm as args to the compiler
  98 AC_CHECK_LIB(m, sin)
  99 AC_CHECK_LIB(c, fopen)
 100
 101 ### Add extra directories to check for libraries.
 102 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 103 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 104 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 105
 106 ### Add extra directories to check for include files.
 107 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 108 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 109 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 110
 111 ### Add both includes and libraries
 112 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 113 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 114 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 115   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 116
 117 AC_ARG_WITH(aiksaurus,
 118   [  --without-aiksaurus     do not use the Aiksaurus library],
 119   [lyx_use_aiksaurus=$withval])
 120 if test x$lyx_use_aiksaurus != xno; then
 121 AC_CHECK_LIB(Aiksaurus, main,
 122         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 123          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 124         ],,"-lbz2")
 125 fi
 126 AC_SUBST(AIKSAURUS_LIBS)
 127
 128 ### Setup libtool
 129 AC_DISABLE_SHARED
 130 AC_LIBTOOL_WIN32_DLL
 131 #AM_PROG_LIBTOOL
 132 LYX_PROG_LIBTOOL
 133
 134 ### Check if we want pspell libraries
 135 CHECK_WITH_PSPELL
 136
 137 ### Check for X libraries
 138 # The real thing.
 139 AC_PATH_XTRA
 140 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 141 # Since solaris X headers use int as implicit return type and modern
 142 # gcc's do not like that, let's use -isystem instead of -I.
 143 # We should test for gcc version and see whether it supports -isystem,
 144 # but since at least gcc 2.6.x supports it and it is still too old for
 145 # us, it seems we are safe.
 146 if test -n "$GXX" ; then
 147   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 148 fi
 149 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 150
 151 ### check which frontend we want to use
 152
 153 #LYX_USE_FRONTEND
 154 dnl The code below is not in a macro, because this would cause big
 155 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 156 case "$lyx_use_frontend" in
 157   xforms)
 158         LYX_PATH_XPM
 159         LYX_PATH_XFORMS
 160         LYX_CHECK_XFORMS_IMAGE_LOADER
 161         FRONTEND="xforms"
 162         FRONTEND_GUILIB="xforms/*.lo xforms/forms/*.lo"
 163         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 164         case "$host" in
 165           *cygwin)
 166             FRONTEND_LIBS="@XFORMS_LIB@ @XFORMS_IMAGE_LIB@ @XPM_LIB@"
 167             ;;
 168           *)
 169             FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 170             ;;
 171         esac
 172         FRONTEND_INFO="    libXpm version:               ${XPM_VERSION}\n\
 173     libforms version:             ${XFORMS_VERSION}\n"
 174         ;;
 175 dnl   gnome)
 176 dnl # Leaving these tests in means that they are performed twice for the
 177 dnl # xforms frontend. No, I don't understand why :-(
 178 dnl # Angus 16 Dec 2002.
 179 dnl #     LYX_PATH_XPM
 180 dnl #     LYX_PATH_XFORMS
 181 dnl #     LYX_CHECK_XFORMS_IMAGE_LOADER
 182 dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 183 dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 184 dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 185
 186 dnl     FRONTEND="xforms gnome"
 187 dnl     FRONTEND_GUILIB="gnome/*.lo"
 188 dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 189 dnl     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 190 dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 191   qt)
 192     QT_DO_IT_ALL
 193     FRONTEND="qt2"
 194     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 195     FRONTEND_LDFLAGS="\$(QT_LDFLAGS)"
 196     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT_INCLUDES)"
 197     FRONTEND_LIBS="\$(QT_LIB)"
 198     FRONTEND_INFO="    Qt version:                   ${QT_VERSION}\n"
 199     ;;
 200   *)
 201     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 202 esac
 203
 204 ### Check for xforms and xpm (only if X has been found).
 205 if test "$have_x" = no ; then
 206 LYX_ERROR(dnl
 207 [Cannot find X window libraries and/or headers. Check your installation.
 208    If you use a Linux system, check that you have installed
 209    the development tools.])
 210 fi
 211
 212 ### Setup GNU gettext
 213 dnl GNU gettext is written in C
 214 AC_LANG_C
 215 # Some tests that may be useful for gettext
 216 AC_C_CONST
 217 AC_C_INLINE
 218 # Do the real setup now
 219 AM_GNU_GETTEXT
 220 # a hack for those who try to change LyX, but do not have gettext installed
 221 case  "${XGETTEXT}" in
 222  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 223 esac
 224
 225 AC_SUBST(LINGUAS)
 226
 227 AC_LANG_CPLUSPLUS
 228
 229 # some standard header files
 230 AC_HEADER_DIRENT
 231 AC_HEADER_MAJOR
 232 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 233
 234 # some standard structures
 235 AC_HEADER_STAT
 236 AC_HEADER_TIME
 237
 238 # some standard types
 239 AC_TYPE_MODE_T
 240 AC_TYPE_OFF_T
 241 AC_TYPE_PID_T
 242 AC_TYPE_SIGNAL
 243 AC_TYPE_SIZE_T
 244 AC_TYPE_UID_T
 245
 246 AC_CHECK_FUNCS(snprintf vsnprintf strerror)
 247 LYX_CHECK_DECL(snprintf, stdio.h)
 248 LYX_CHECK_DECL(vsnprintf, stdio.h)
 249 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 250
 251 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 252 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 253 dnl We aim to remove this eventually, since we should test as much as
 254 dnl possible with the compiler which will use the functions (JMarc)
 255 AC_LANG_C
 256 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo mkstemp mktemp)
 257 AC_LANG_CPLUSPLUS
 258
 259 dnl Until this is fixed in autoconf we provide our own version
 260 LYX_FUNC_SELECT_ARGTYPES
 261
 262 dnl check whether we have to work around solaris broken putenv()
 263 LYX_FUNC_PUTENV_ARGTYPE
 264
 265
 266 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 267
 268 ### Some information on what just happened
 269 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 270 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 271 VERSION_INFO="Configuration\n\
 272   Host type:                      ${host}\n\
 273   Special build flags:           ${lyx_flags}\n\
 274   C   Compiler:                   ${CC}\n\
 275   C   Compiler flags:             ${CFLAGS}\n\
 276   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 277   C++ Compiler flags:             ${CXXFLAGS}\n\
 278   Linker flags:                   ${LDFLAGS}\n\
 279   Frontend:                       ${lyx_use_frontend}\n\
 280 ${FRONTEND_INFO}\
 281   LyX binary dir:                 ${real_bindir}\n\
 282   LyX files dir:                  ${real_datadir}\n"
 283
 284
 285 AC_SUBST(VERSION_INFO)
 286
 287 ### Finish the work.
 288 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 289 AC_OUTPUT([Makefile \
 290        boost/Makefile \
 291        boost/libs/Makefile \
 292        boost/libs/regex/Makefile \
 293        boost/libs/regex/src/Makefile \
 294        boost/libs/signals/Makefile \
 295        boost/libs/signals/src/Makefile \
 296        config/Makefile \
 297        development/Makefile \
 298        development/lyx.spec \
 299        lib/Makefile \
 300        intl/Makefile \
 301        po/Makefile.in \
 302        sourcedoc/Doxyfile \
 303        sourcedoc/Makefile \
 304        src/Makefile \
 305        src/version.C \
 306        src/mathed/Makefile \
 307        src/graphics/Makefile \
 308        src/insets/Makefile \
 309        src/support/Makefile \
 310        src/frontends/Makefile \
 311        src/frontends/controllers/Makefile \
 312        src/frontends/xforms/Makefile \
 313        src/frontends/xforms/forms/Makefile \
 314        src/frontends/qt2/Makefile \
 315        src/frontends/qt2/moc/Makefile \
 316        src/frontends/qt2/ui/Makefile \
 317        src/frontends/qt2/ui/moc/Makefile \
 318        src/frontends/gnome/Makefile \
 319 ])
 320
 321 # show version information
 322 echo
 323 printf "$VERSION_INFO"
 324 echo
 325
 326 # Display a final warning if there has been a LYX_ERROR
 327 LYX_CHECK_ERRORS