config/configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AM_MAINTAINER_MODE
  15 AC_CANONICAL_SYSTEM
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57
  58 ### Check for program extensions (.exe or nothing)
  59 AC_EXEEXT
  60
  61 ### check which frontend we want to use
  62 LYX_USE_FRONTEND
  63
  64 ### Check for a C++ compiler
  65 LYX_PROG_CXX
  66 ### Some checks on what the C++ compiler can(not) do
  67 AC_LANG_CPLUSPLUS
  68 dnl we do not need that currently (and probably all our supported
  69 dnl compiler allow that)
  70 dnl LYX_CXX_PARTIAL
  71 LYX_CXX_EXPLICIT
  72 LYX_CXX_STL_STRING
  73 LYX_CXX_GOOD_STD_STRING
  74 LYX_CXX_CHEADERS
  75 LYX_CXX_GLOBAL_CSTD
  76 LYX_STD_COUNT
  77 dnl we disable rtti for now
  78 dnl LYX_CXX_RTTI
  79 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  80 LYX_CXX_STL_MODERN_STREAMS
  81
  82 ### and now some special lyx flags.
  83 AC_ARG_ENABLE(assertions,
  84   [  --enable-assertions     add runtime sanity checks in the program],,
  85   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  86         enable_assertions=yes;
  87     else
  88         enable_assertions=no;
  89     fi;])
  90 if test "x$enable_assertions" = xyes ; then
  91    lyx_flags="$lyx_flags assertions"
  92    AC_DEFINE(ENABLE_ASSERTIONS,1,
  93     [Define if you want assertions to be enabled in the code])
  94 fi
  95
  96 ### Library Files
  97 dnl by testing these we check if it is ok to have
  98 dnl -lc and -lm as args to the compiler
  99 AC_CHECK_LIB(m, sin)
 100 AC_CHECK_LIB(c, fopen)
 101
 102 ### Add extra directories to check for libraries.
 103 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 104 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 105 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 106
 107 ### Add extra directories to check for include files.
 108 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 109 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 110 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 111
 112 ### Add both includes and libraries
 113 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 114 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 115 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 116   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 117
 118 AC_ARG_WITH(aiksaurus,
 119   [  --without-aiksaurus     do not use the Aiksaurus library],
 120   [lyx_use_aiksaurus=$withval])
 121 if test x$lyx_use_aiksaurus != xno; then
 122 AC_CHECK_LIB(Aiksaurus, main,
 123         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 124          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 125         ],,"-lbz2")
 126 fi
 127 AC_SUBST(AIKSAURUS_LIBS)
 128
 129 ### Setup libtool
 130 AC_DISABLE_SHARED
 131 AC_LIBTOOL_WIN32_DLL
 132 #AM_PROG_LIBTOOL
 133 LYX_PROG_LIBTOOL
 134
 135 ### Check if we want spell libraries, prefer new aspell
 136 CHECK_WITH_ASPELL
 137 if test "$USING_ASPELL" != "yes"; then
 138         CHECK_WITH_PSPELL
 139 fi
 140
 141 ### Check for some Cygwin-specific details.
 142 CHECK_WITH_CYGWIN
 143
 144 ### Check for X libraries
 145 AC_PATH_XTRA
 146 case $have_x in
 147   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 148        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 149   no) LYX_ERROR(dnl
 150 [Cannot find X window libraries and/or headers. Check your installation.
 151   If you use a Linux system, check that you have installed
 152   the development tools.]);;
 153   disable) ;;
 154 esac
 155
 156 ### check which frontend we want to use
 157
 158 #LYX_USE_FRONTEND
 159 dnl The code below is not in a macro, because this would cause big
 160 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 161 case "$lyx_use_frontend" in
 162   xforms)
 163         LYX_PATH_XPM
 164         LYX_PATH_XFORMS
 165         LYX_CHECK_XFORMS_IMAGE_LOADER
 166         FRONTEND="xforms"
 167         RPM_FRONTEND="xforms"
 168         RPM_FRONTEND_DEPS='libforms >= 1.0'
 169         FRONTEND_GUILIB="xforms/*.lo xforms/forms/*.lo"
 170         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 171         FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 172         FRONTEND_INFO="    libXpm version:               ${XPM_VERSION}\n\
 173     libforms version:             ${XFORMS_VERSION}\n"
 174         ;;
 175 dnl   gnome)
 176 dnl # Leaving these tests in means that they are performed twice for the
 177 dnl # xforms frontend. No, I don't understand why :-(
 178 dnl # Angus 16 Dec 2002.
 179 dnl #     LYX_PATH_XPM
 180 dnl #     LYX_PATH_XFORMS
 181 dnl #     LYX_CHECK_XFORMS_IMAGE_LOADER
 182 dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 183 dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 184 dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 185
 186 dnl     FRONTEND="xforms gnome"
 187 dnl     FRONTEND_GUILIB="gnome/*.lo"
 188 dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 189 dnl     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 190 dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 191   qt)
 192     QT_DO_IT_ALL
 193     RPM_FRONTEND="qt"
 194     RPM_FRONTEND_DEPS='qt >= 2.2.1'
 195     FRONTEND="qt2"
 196     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 197     FRONTEND_LDFLAGS="\$(QT_LDFLAGS)"
 198     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT_INCLUDES)"
 199     FRONTEND_LIBS="\$(QT_LIB)"
 200     FRONTEND_INFO="    Qt version:                   ${QT_VERSION}\n"
 201     ;;
 202   *)
 203     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 204 esac
 205
 206 ### Setup GNU gettext
 207 dnl GNU gettext is written in C
 208 AC_LANG_C
 209 # Some tests that may be useful for gettext
 210 AC_C_CONST
 211 AC_C_INLINE
 212 # Do the real setup now
 213 AM_GNU_GETTEXT
 214 # a hack for those who try to change LyX, but do not have gettext installed
 215 case  "${XGETTEXT}" in
 216  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 217 esac
 218
 219 AC_SUBST(LINGUAS)
 220
 221 AC_LANG_CPLUSPLUS
 222
 223 # some standard header files
 224 AC_HEADER_DIRENT
 225 AC_HEADER_MAJOR
 226 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 227
 228 # some standard structures
 229 AC_HEADER_STAT
 230 AC_HEADER_TIME
 231
 232 # some standard types
 233 AC_TYPE_MODE_T
 234 AC_TYPE_OFF_T
 235 AC_TYPE_PID_T
 236 AC_TYPE_SIGNAL
 237 AC_TYPE_SIZE_T
 238 AC_TYPE_UID_T
 239
 240 AC_CHECK_FUNCS(snprintf vsnprintf strerror)
 241 LYX_CHECK_DECL(snprintf, stdio.h)
 242 LYX_CHECK_DECL(vsnprintf, stdio.h)
 243 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 244
 245 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 246 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 247 dnl We aim to remove this eventually, since we should test as much as
 248 dnl possible with the compiler which will use the functions (JMarc)
 249 AC_LANG_C
 250 AC_CHECK_FUNCS(memmove memset strchr mkfifo mkstemp mktemp)
 251 AC_LANG_CPLUSPLUS
 252
 253 dnl Until this is fixed in autoconf we provide our own version
 254 LYX_FUNC_SELECT_ARGTYPES
 255
 256 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 257
 258 ### Some information on what just happened
 259 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 260 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 261 VERSION_INFO="Configuration\n\
 262   Host type:                      ${host}\n\
 263   Special build flags:           ${lyx_flags}\n\
 264   C   Compiler:                   ${CC}\n\
 265   C   Compiler flags:             ${CFLAGS}\n\
 266   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 267   C++ Compiler flags:             ${CXXFLAGS}\n\
 268   Linker flags:                   ${LDFLAGS}\n\
 269   Frontend:                       ${lyx_use_frontend}\n\
 270 ${FRONTEND_INFO}\
 271   LyX binary dir:                 ${real_bindir}\n\
 272   LyX files dir:                  ${real_datadir}\n"
 273
 274
 275 AC_SUBST(VERSION_INFO)
 276 AC_SUBST(RPM_FRONTEND)
 277 AC_SUBST(RPM_FRONTEND_DEPS)
 278
 279 ### Finish the work.
 280 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 281 AC_OUTPUT([Makefile \
 282        boost/Makefile \
 283        boost/libs/Makefile \
 284        boost/libs/regex/Makefile \
 285        boost/libs/regex/src/Makefile \
 286        boost/libs/signals/Makefile \
 287        boost/libs/signals/src/Makefile \
 288        config/Makefile \
 289        development/Makefile \
 290        development/lyx.spec \
 291        lib/Makefile \
 292        intl/Makefile \
 293        po/Makefile.in \
 294        sourcedoc/Doxyfile \
 295        sourcedoc/Makefile \
 296        src/Makefile \
 297        src/version.C \
 298        src/tex2lyx/Makefile \
 299        src/mathed/Makefile \
 300        src/graphics/Makefile \
 301        src/insets/Makefile \
 302        src/support/Makefile \
 303        src/frontends/Makefile \
 304        src/frontends/controllers/Makefile \
 305        src/frontends/xforms/Makefile \
 306        src/frontends/xforms/lyx_forms.h \
 307        src/frontends/xforms/lyx_xpm.h \
 308        src/frontends/xforms/forms/Makefile \
 309        src/frontends/qt2/Makefile \
 310        src/frontends/qt2/moc/Makefile \
 311        src/frontends/qt2/ui/Makefile \
 312        src/frontends/qt2/ui/moc/Makefile \
 313        src/frontends/gnome/Makefile \
 314 ])
 315
 316 # show version information
 317 echo
 318 printf "$VERSION_INFO"
 319 echo
 320
 321 # Display a final warning if there has been a LYX_ERROR
 322 LYX_CHECK_ERRORS