config/configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AM_MAINTAINER_MODE
  15 AC_CANONICAL_SYSTEM
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57
  58 ### Check for program extensions (.exe or nothing)
  59 AC_EXEEXT
  60
  61 ### check which frontend we want to use
  62 LYX_USE_FRONTEND
  63
  64 ### Check for a C++ compiler
  65 LYX_PROG_CXX
  66 ### Some checks on what the C++ compiler can(not) do
  67 AC_LANG_CPLUSPLUS
  68 dnl we do not need that currently (and probably all our supported
  69 dnl compiler allow that)
  70 dnl LYX_CXX_PARTIAL
  71 LYX_CXX_EXPLICIT
  72 LYX_CXX_STL_STRING
  73 LYX_CXX_GOOD_STD_STRING
  74 LYX_CXX_CHEADERS
  75 LYX_CXX_GLOBAL_CSTD
  76 LYX_STD_COUNT
  77 dnl we disable rtti for now
  78 dnl LYX_CXX_RTTI
  79 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  80 LYX_CXX_STL_MODERN_STREAMS
  81
  82 ### and now some special lyx flags.
  83 AC_ARG_ENABLE(assertions,
  84   [  --enable-assertions     add runtime sanity checks in the program],,
  85   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  86         enable_assertions=yes;
  87     else
  88         enable_assertions=no;
  89     fi;])
  90 if test "x$enable_assertions" = xyes ; then
  91    lyx_flags="$lyx_flags assertions"
  92    AC_DEFINE(ENABLE_ASSERTIONS,1,
  93     [Define if you want assertions to be enabled in the code])
  94 fi
  95
  96 ### Library Files
  97 dnl by testing these we check if it is ok to have
  98 dnl -lc and -lm as args to the compiler
  99 AC_CHECK_LIB(m, sin)
 100 AC_CHECK_LIB(c, fopen)
 101
 102 ### Add extra directories to check for libraries.
 103 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 104 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 105 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 106
 107 ### Add extra directories to check for include files.
 108 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 109 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 110 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 111
 112 ### Add both includes and libraries
 113 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 114 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 115 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 116   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 117
 118 AC_ARG_WITH(aiksaurus,
 119   [  --without-aiksaurus     do not use the Aiksaurus library],
 120   [lyx_use_aiksaurus=$withval])
 121 if test x$lyx_use_aiksaurus != xno; then
 122 AC_CHECK_LIB(Aiksaurus, main,
 123         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 124          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 125         ],,"-lbz2")
 126 AC_CHECK_HEADER(Aiksaurus.h,[
 127   ac_cv_header_aiksaurus_h=yes
 128   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 129 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 130   ac_cv_header_aiksaurus_h=yes
 131   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 132 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 133 fi
 134 AC_SUBST(AIKSAURUS_LIBS)
 135
 136 ### Setup libtool
 137 AC_DISABLE_SHARED
 138 AC_LIBTOOL_WIN32_DLL
 139 #AM_PROG_LIBTOOL
 140 LYX_PROG_LIBTOOL
 141
 142 ### Check if we want spell libraries, prefer new aspell
 143 CHECK_WITH_ASPELL
 144 if test "$USING_ASPELL" != "yes"; then
 145         CHECK_WITH_PSPELL
 146 fi
 147
 148 ### Check for some Cygwin-specific details.
 149 CHECK_WITH_CYGWIN
 150
 151 ### Check for X libraries
 152 AC_PATH_XTRA
 153 case $have_x in
 154   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 155        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 156   no) LYX_ERROR(dnl
 157 [Cannot find X window libraries and/or headers. Check your installation.
 158   If you use a Linux system, check that you have installed
 159   the development tools.]);;
 160   disable) ;;
 161 esac
 162
 163 ### check which frontend we want to use
 164
 165 #LYX_USE_FRONTEND
 166 dnl The code below is not in a macro, because this would cause big
 167 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 168 case "$lyx_use_frontend" in
 169   xforms)
 170         LYX_PATH_XPM
 171         LYX_PATH_XFORMS
 172         LYX_CHECK_XFORMS_IMAGE_LOADER
 173         FRONTEND="xforms"
 174         RPM_FRONTEND="xforms"
 175         RPM_FRONTEND_DEPS='libforms >= 1.0'
 176         FRONTEND_GUILIB="xforms/*.lo xforms/forms/*.lo"
 177         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 178         FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 179         FRONTEND_INFO="    libXpm version:               ${XPM_VERSION}\n\
 180     libforms version:             ${XFORMS_VERSION}\n"
 181         ;;
 182 dnl   gnome)
 183 dnl # Leaving these tests in means that they are performed twice for the
 184 dnl # xforms frontend. No, I don't understand why :-(
 185 dnl # Angus 16 Dec 2002.
 186 dnl #     LYX_PATH_XPM
 187 dnl #     LYX_PATH_XFORMS
 188 dnl #     LYX_CHECK_XFORMS_IMAGE_LOADER
 189 dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 190 dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 191 dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 192
 193 dnl     FRONTEND="xforms gnome"
 194 dnl     FRONTEND_GUILIB="gnome/*.lo"
 195 dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 196 dnl     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 197 dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 198   qt)
 199     QT_DO_IT_ALL
 200     RPM_FRONTEND="qt"
 201     RPM_FRONTEND_DEPS='qt >= 2.2.1'
 202     FRONTEND="qt2"
 203     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 204     FRONTEND_LDFLAGS="\$(QT_LDFLAGS)"
 205     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT_INCLUDES)"
 206     FRONTEND_LIBS="\$(QT_LIB)"
 207     FRONTEND_INFO="    Qt version:                   ${QT_VERSION}\n"
 208     ;;
 209   *)
 210     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 211 esac
 212
 213 ### Setup GNU gettext
 214 dnl GNU gettext is written in C
 215 AC_LANG_C
 216 # Some tests that may be useful for gettext
 217 AC_C_CONST
 218 AC_C_INLINE
 219 # Do the real setup now
 220 AM_GNU_GETTEXT
 221 # a hack for those who try to change LyX, but do not have gettext installed
 222 case  "${XGETTEXT}" in
 223  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 224 esac
 225
 226 AC_SUBST(LINGUAS)
 227
 228 AC_LANG_CPLUSPLUS
 229
 230 # some standard header files
 231 AC_HEADER_DIRENT
 232 AC_HEADER_MAJOR
 233 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 234
 235 # some standard structures
 236 AC_HEADER_STAT
 237 AC_HEADER_TIME
 238
 239 # some standard types
 240 AC_TYPE_MODE_T
 241 AC_TYPE_OFF_T
 242 AC_TYPE_PID_T
 243 AC_TYPE_SIGNAL
 244 AC_TYPE_SIZE_T
 245 AC_TYPE_UID_T
 246
 247 AC_CHECK_FUNCS(snprintf vsnprintf strerror)
 248 LYX_CHECK_DECL(snprintf, stdio.h)
 249 LYX_CHECK_DECL(vsnprintf, stdio.h)
 250 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 251
 252 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 253 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 254 dnl We aim to remove this eventually, since we should test as much as
 255 dnl possible with the compiler which will use the functions (JMarc)
 256 AC_LANG_C
 257 AC_CHECK_FUNCS(memmove memset strchr mkfifo mkstemp mktemp)
 258 AC_LANG_CPLUSPLUS
 259
 260 dnl Until this is fixed in autoconf we provide our own version
 261 LYX_FUNC_SELECT_ARGTYPES
 262
 263 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 264
 265 ### Some information on what just happened
 266 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 267 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 268 VERSION_INFO="Configuration\n\
 269   Host type:                      ${host}\n\
 270   Special build flags:           ${lyx_flags}\n\
 271   C   Compiler:                   ${CC}\n\
 272   C   Compiler flags:             ${CFLAGS}\n\
 273   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 274   C++ Compiler flags:             ${CXXFLAGS}\n\
 275   Linker flags:                   ${LDFLAGS}\n\
 276   Frontend:                       ${lyx_use_frontend}\n\
 277 ${FRONTEND_INFO}\
 278   LyX binary dir:                 ${real_bindir}\n\
 279   LyX files dir:                  ${real_datadir}\n"
 280
 281
 282 AC_SUBST(VERSION_INFO)
 283 AC_SUBST(RPM_FRONTEND)
 284 AC_SUBST(RPM_FRONTEND_DEPS)
 285
 286 ### Finish the work.
 287 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 288 AC_OUTPUT([Makefile \
 289        boost/Makefile \
 290        boost/libs/Makefile \
 291        boost/libs/regex/Makefile \
 292        boost/libs/regex/src/Makefile \
 293        boost/libs/signals/Makefile \
 294        boost/libs/signals/src/Makefile \
 295        config/Makefile \
 296        development/Makefile \
 297        development/lyx.spec \
 298        lib/Makefile \
 299        intl/Makefile \
 300        po/Makefile.in \
 301        sourcedoc/Doxyfile \
 302        sourcedoc/Makefile \
 303        src/Makefile \
 304        src/version.C \
 305        src/tex2lyx/Makefile \
 306        src/mathed/Makefile \
 307        src/graphics/Makefile \
 308        src/insets/Makefile \
 309        src/support/Makefile \
 310        src/frontends/Makefile \
 311        src/frontends/controllers/Makefile \
 312        src/frontends/xforms/Makefile \
 313        src/frontends/xforms/lyx_forms.h \
 314        src/frontends/xforms/lyx_xpm.h \
 315        src/frontends/xforms/forms/Makefile \
 316        src/frontends/qt2/Makefile \
 317        src/frontends/qt2/moc/Makefile \
 318        src/frontends/qt2/ui/Makefile \
 319        src/frontends/qt2/ui/moc/Makefile \
 320        src/frontends/gnome/Makefile \
 321 ])
 322
 323 # show version information
 324 echo
 325 printf "$VERSION_INFO"
 326 echo
 327
 328 # Display a final warning if there has been a LYX_ERROR
 329 LYX_CHECK_ERRORS