config/configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AM_MAINTAINER_MODE
  15 AC_CANONICAL_SYSTEM
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57
  58 ### Check for program extensions (.exe or nothing)
  59 AC_EXEEXT
  60
  61 ### check which frontend we want to use
  62 LYX_USE_FRONTEND
  63
  64 ### Check for a C++ compiler
  65 LYX_PROG_CXX
  66 ### Some checks on what the C++ compiler can(not) do
  67 AC_LANG_CPLUSPLUS
  68 dnl we do not need that currently (and probably all our supported
  69 dnl compiler allow that)
  70 dnl LYX_CXX_PARTIAL
  71 LYX_CXX_EXPLICIT
  72 LYX_CXX_STL_STRING
  73 LYX_CXX_GOOD_STD_STRING
  74 LYX_CXX_CHEADERS
  75 LYX_CXX_GLOBAL_CSTD
  76 LYX_STD_COUNT
  77 dnl we disable rtti for now
  78 dnl LYX_CXX_RTTI
  79 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  80 LYX_CXX_STL_MODERN_STREAMS
  81
  82 ### and now some special lyx flags.
  83 AC_ARG_ENABLE(assertions,
  84   [  --enable-assertions     add runtime sanity checks in the program],,
  85   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  86         enable_assertions=yes;
  87     else
  88         enable_assertions=no;
  89     fi;])
  90 if test "x$enable_assertions" = xyes ; then
  91    lyx_flags="$lyx_flags assertions"
  92    AC_DEFINE(ENABLE_ASSERTIONS,1,
  93     [Define if you want assertions to be enabled in the code])
  94 fi
  95
  96 ### Library Files
  97 dnl by testing these we check if it is ok to have
  98 dnl -lc and -lm as args to the compiler
  99 AC_CHECK_LIB(m, sin)
 100 AC_CHECK_LIB(c, fopen)
 101
 102 ### Add extra directories to check for libraries.
 103 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 104 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 105 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 106
 107 ### Add extra directories to check for include files.
 108 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 109 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 110 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 111
 112 ### Add both includes and libraries
 113 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 114 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 115 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 116   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 117
 118 AC_ARG_WITH(aiksaurus,
 119   [  --without-aiksaurus     do not use the Aiksaurus library],
 120   [lyx_use_aiksaurus=$withval])
 121 if test x$lyx_use_aiksaurus != xno; then
 122 AC_CHECK_LIB(Aiksaurus, main,
 123         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 124          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 125         ],,"-lbz2")
 126 fi
 127 AC_SUBST(AIKSAURUS_LIBS)
 128
 129 ### Setup libtool
 130 AC_DISABLE_SHARED
 131 AC_LIBTOOL_WIN32_DLL
 132 #AM_PROG_LIBTOOL
 133 LYX_PROG_LIBTOOL
 134
 135 ### Check if we want spell libraries, prefer new aspell
 136 CHECK_WITH_ASPELL
 137 if test "$USING_ASPELL" != "yes"; then
 138         CHECK_WITH_PSPELL
 139 fi
 140
 141 ### Check for some Cygwin-specific details.
 142 CHECK_WITH_CYGWIN
 143
 144 ### Check for X libraries
 145 # The real thing.
 146 AC_PATH_XTRA
 147 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 148 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 149
 150 ### check which frontend we want to use
 151
 152 #LYX_USE_FRONTEND
 153 dnl The code below is not in a macro, because this would cause big
 154 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 155 case "$lyx_use_frontend" in
 156   xforms)
 157         LYX_PATH_XPM
 158         LYX_PATH_XFORMS
 159         LYX_CHECK_XFORMS_IMAGE_LOADER
 160         FRONTEND="xforms"
 161         RPM_FRONTEND="xforms"
 162         RPM_FRONTEND_DEPS='libforms >= 1.0'
 163         FRONTEND_GUILIB="xforms/*.lo xforms/forms/*.lo"
 164         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 165         FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 166         FRONTEND_INFO="    libXpm version:               ${XPM_VERSION}\n\
 167     libforms version:             ${XFORMS_VERSION}\n"
 168         ;;
 169 dnl   gnome)
 170 dnl # Leaving these tests in means that they are performed twice for the
 171 dnl # xforms frontend. No, I don't understand why :-(
 172 dnl # Angus 16 Dec 2002.
 173 dnl #     LYX_PATH_XPM
 174 dnl #     LYX_PATH_XFORMS
 175 dnl #     LYX_CHECK_XFORMS_IMAGE_LOADER
 176 dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 177 dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 178 dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 179
 180 dnl     FRONTEND="xforms gnome"
 181 dnl     FRONTEND_GUILIB="gnome/*.lo"
 182 dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 183 dnl     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 184 dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 185   qt)
 186     QT_DO_IT_ALL
 187     RPM_FRONTEND="qt"
 188     RPM_FRONTEND_DEPS='qt >= 2.2.1'
 189     FRONTEND="qt2"
 190     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 191     FRONTEND_LDFLAGS="\$(QT_LDFLAGS)"
 192     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT_INCLUDES)"
 193     FRONTEND_LIBS="\$(QT_LIB)"
 194     FRONTEND_INFO="    Qt version:                   ${QT_VERSION}\n"
 195     ;;
 196   *)
 197     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 198 esac
 199
 200 ### Check for xforms and xpm (only if X has been found).
 201 if test "$have_x" = no ; then
 202 LYX_ERROR(dnl
 203 [Cannot find X window libraries and/or headers. Check your installation.
 204    If you use a Linux system, check that you have installed
 205    the development tools.])
 206 fi
 207
 208 ### Setup GNU gettext
 209 dnl GNU gettext is written in C
 210 AC_LANG_C
 211 # Some tests that may be useful for gettext
 212 AC_C_CONST
 213 AC_C_INLINE
 214 # Do the real setup now
 215 AM_GNU_GETTEXT
 216 # a hack for those who try to change LyX, but do not have gettext installed
 217 case  "${XGETTEXT}" in
 218  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 219 esac
 220
 221 AC_SUBST(LINGUAS)
 222
 223 AC_LANG_CPLUSPLUS
 224
 225 # some standard header files
 226 AC_HEADER_DIRENT
 227 AC_HEADER_MAJOR
 228 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 229
 230 # some standard structures
 231 AC_HEADER_STAT
 232 AC_HEADER_TIME
 233
 234 # some standard types
 235 AC_TYPE_MODE_T
 236 AC_TYPE_OFF_T
 237 AC_TYPE_PID_T
 238 AC_TYPE_SIGNAL
 239 AC_TYPE_SIZE_T
 240 AC_TYPE_UID_T
 241
 242 AC_CHECK_FUNCS(snprintf vsnprintf strerror)
 243 LYX_CHECK_DECL(snprintf, stdio.h)
 244 LYX_CHECK_DECL(vsnprintf, stdio.h)
 245 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 246
 247 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 248 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 249 dnl We aim to remove this eventually, since we should test as much as
 250 dnl possible with the compiler which will use the functions (JMarc)
 251 AC_LANG_C
 252 AC_CHECK_FUNCS(memmove memset strchr mkfifo mkstemp mktemp)
 253 AC_LANG_CPLUSPLUS
 254
 255 dnl Until this is fixed in autoconf we provide our own version
 256 LYX_FUNC_SELECT_ARGTYPES
 257
 258 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 259
 260 ### Some information on what just happened
 261 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 262 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 263 VERSION_INFO="Configuration\n\
 264   Host type:                      ${host}\n\
 265   Special build flags:           ${lyx_flags}\n\
 266   C   Compiler:                   ${CC}\n\
 267   C   Compiler flags:             ${CFLAGS}\n\
 268   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 269   C++ Compiler flags:             ${CXXFLAGS}\n\
 270   Linker flags:                   ${LDFLAGS}\n\
 271   Frontend:                       ${lyx_use_frontend}\n\
 272 ${FRONTEND_INFO}\
 273   LyX binary dir:                 ${real_bindir}\n\
 274   LyX files dir:                  ${real_datadir}\n"
 275
 276
 277 AC_SUBST(VERSION_INFO)
 278 AC_SUBST(RPM_FRONTEND)
 279 AC_SUBST(RPM_FRONTEND_DEPS)
 280
 281 ### Finish the work.
 282 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 283 AC_OUTPUT([Makefile \
 284        boost/Makefile \
 285        boost/libs/Makefile \
 286        boost/libs/regex/Makefile \
 287        boost/libs/regex/src/Makefile \
 288        boost/libs/signals/Makefile \
 289        boost/libs/signals/src/Makefile \
 290        config/Makefile \
 291        development/Makefile \
 292        development/lyx.spec \
 293        lib/Makefile \
 294        intl/Makefile \
 295        po/Makefile.in \
 296        sourcedoc/Doxyfile \
 297        sourcedoc/Makefile \
 298        src/Makefile \
 299        src/version.C \
 300        src/tex2lyx/Makefile \
 301        src/mathed/Makefile \
 302        src/graphics/Makefile \
 303        src/insets/Makefile \
 304        src/support/Makefile \
 305        src/frontends/Makefile \
 306        src/frontends/controllers/Makefile \
 307        src/frontends/xforms/Makefile \
 308        src/frontends/xforms/lyx_forms.h \
 309        src/frontends/xforms/lyx_xpm.h \
 310        src/frontends/xforms/forms/Makefile \
 311        src/frontends/qt2/Makefile \
 312        src/frontends/qt2/moc/Makefile \
 313        src/frontends/qt2/ui/Makefile \
 314        src/frontends/qt2/ui/moc/Makefile \
 315        src/frontends/gnome/Makefile \
 316 ])
 317
 318 # show version information
 319 echo
 320 printf "$VERSION_INFO"
 321 echo
 322
 323 # Display a final warning if there has been a LYX_ERROR
 324 LYX_CHECK_ERRORS