config/configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_TARGET
  15
  16 LYX_VERSION_SUFFIX
  17
  18 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  19
  20 # The list of languages known to LyX
  21 # This is needed by GNU gettext
  22 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  23
  24 # fix the value of the prefixes.
  25 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  26 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  27
  28 ### Set the execute permissions of the various scripts correctly
  29 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  30   chmod 755 ${srcdir}/${file}
  31 done
  32
  33 ### Check for programs
  34 AC_PROG_MAKE_SET
  35 AC_PROG_INSTALL
  36 #AC_PROG_RANLIB
  37 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  38 if test "x$KPSEWHICH" = xkpsewhich ; then
  39     AC_DEFINE(HAVE_KPSEWHICH, 1,
  40     [Define this if you have the kpsewhich program working on your system.])
  41 fi
  42 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  43
  44 # Work around a problem in automake 1.4: when invoking install-strip,
  45 # INSTALL_PROGRAM is changed to 'install -s', and since
  46 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  47 # which returns an error condition when stripping fails.
  48 INSTALL_SCRIPT='${INSTALL}'
  49
  50 ### we will also need a C compiler to compile GNU gettext
  51 AC_PROG_CC
  52
  53 ### check for special systems
  54 AC_ISC_POSIX
  55 AC_AIX
  56
  57 ### check which frontend we want to use
  58 LYX_USE_FRONTEND
  59
  60 ### Check for a C++ compiler
  61 LYX_PROG_CXX
  62 ### Some checks on what the C++ compiler can(not) do
  63 AC_LANG(C++)
  64 dnl we do not need that currently (and probably all our supported
  65 dnl compiler allow that)
  66 dnl LYX_CXX_PARTIAL
  67 LYX_CXX_EXPLICIT
  68 LYX_CXX_STL_STRING
  69 LYX_CXX_GOOD_STD_STRING
  70 LYX_CXX_CHEADERS
  71 LYX_CXX_GLOBAL_CSTD
  72 LYX_STD_COUNT
  73 dnl we disable rtti for now
  74 dnl LYX_CXX_RTTI
  75 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  76 LYX_CXX_STL_MODERN_STREAMS
  77
  78 ### and now some special lyx flags.
  79 AC_ARG_ENABLE(assertions,
  80   [  --enable-assertions     add runtime sanity checks in the program],,
  81   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  82         enable_assertions=yes;
  83     else
  84         enable_assertions=no;
  85     fi;])
  86 if test "x$enable_assertions" = xyes ; then
  87    lyx_flags="$lyx_flags assertions"
  88    AC_DEFINE(ENABLE_ASSERTIONS,1,
  89     [Define if you want assertions to be enabled in the code])
  90 fi
  91
  92 ### Library Files
  93 dnl by testing these we check if it is ok to have
  94 dnl -lc and -lm as args to the compiler
  95 AC_CHECK_LIB(m, sin)
  96 AC_CHECK_LIB(c, fopen)
  97
  98 ### Add extra directories to check for libraries.
  99 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 100 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 101 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 102
 103 ### Add extra directories to check for include files.
 104 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 105 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 106 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 107
 108 ### Add both includes and libraries
 109 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 110 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 111 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 112   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 113
 114 AC_ARG_WITH(aiksaurus,
 115   [  --without-aiksaurus     do not use the Aiksaurus library],
 116   [lyx_use_aiksaurus=$withval])
 117 if test x$lyx_use_aiksaurus != xno; then
 118 AC_CHECK_LIB(Aiksaurus, main,
 119         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 120          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 121         ],,"-lbz2")
 122 fi
 123 AC_SUBST(AIKSAURUS_LIBS)
 124
 125 ### Setup libtool
 126 AC_DISABLE_SHARED
 127 AC_LIBTOOL_WIN32_DLL
 128 #AM_PROG_LIBTOOL
 129 LYX_PROG_LIBTOOL
 130
 131 ### Check if we want pspell libraries
 132 CHECK_WITH_PSPELL
 133
 134 ### Check for X libraries
 135 # The real thing.
 136 AC_PATH_XTRA
 137 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 138 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 139
 140 ### check which frontend we want to use
 141
 142 #LYX_USE_FRONTEND
 143 dnl The code below is not in a macro, because this would cause big
 144 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 145 case "$lyx_use_frontend" in
 146   xforms)
 147         LYX_PATH_XPM
 148         LYX_PATH_XFORMS
 149         LYX_CHECK_XFORMS_IMAGE_LOADER
 150         FRONTEND="xforms"
 151         RPM_FRONTEND="xforms"
 152         RPM_FRONTEND_DEPS='libforms >= 1.0'
 153         FRONTEND_GUILIB="xforms/*.lo xforms/forms/*.lo"
 154         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 155         case "$host" in
 156           *cygwin)
 157             FRONTEND_LIBS="@XFORMS_LIB@ @XFORMS_IMAGE_LIB@ @XPM_LIB@"
 158             ;;
 159           *)
 160             FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 161             ;;
 162         esac
 163         FRONTEND_INFO="    libXpm version:               ${XPM_VERSION}\n\
 164     libforms version:             ${XFORMS_VERSION}\n"
 165         ;;
 166 dnl   gnome)
 167 dnl     LYX_PATH_XPM
 168 dnl     LYX_PATH_XFORMS
 169 dnl     LYX_CHECK_XFORMS_IMAGE_LOADER
 170 dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 171 dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 172 dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 173
 174 dnl     FRONTEND="xforms gnome"
 175 dnl     FRONTEND_GUILIB="gnome/*.lo"
 176 dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 177 dnl     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 178 dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 179 dnl     ;;
 180   qt)
 181     QT_DO_IT_ALL
 182     RPM_FRONTEND="qt"
 183     RPM_FRONTEND_DEPS='qt >= 2.2.1'
 184     FRONTEND="qt2"
 185     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 186     FRONTEND_LDFLAGS="\$(QT_LDFLAGS)"
 187     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT_INCLUDES)"
 188     FRONTEND_LIBS="\$(QT_LIB)"
 189     FRONTEND_INFO="    Qt version:                   ${QT_VERSION}\n"
 190     ;;
 191   *)
 192     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 193 esac
 194
 195 ### Check for xforms and xpm (only if X has been found).
 196 if test "$have_x" = no ; then
 197 LYX_ERROR(dnl
 198 [Cannot find X window libraries and/or headers. Check your installation.
 199    If you use a Linux system, check that you have installed
 200    the development tools.])
 201 fi
 202
 203 ### Setup GNU gettext
 204 dnl GNU gettext is written in C
 205 AC_LANG_PUSH(C)
 206 # Some tests that may be useful for gettext
 207 AC_C_CONST
 208 AC_C_INLINE
 209 # Do the real setup now
 210 AM_GNU_GETTEXT
 211 # a hack for those who try to change LyX, but do not have gettext installed
 212 case  "${XGETTEXT}" in
 213  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 214 esac
 215
 216 AC_SUBST(LINGUAS)
 217
 218 AC_LANG_POP(C)
 219
 220 # some standard header files
 221 AC_HEADER_DIRENT
 222 AC_HEADER_MAJOR
 223 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 224
 225 # some standard structures
 226 AC_HEADER_STAT
 227 AC_HEADER_TIME
 228
 229 # some standard types
 230 AC_TYPE_MODE_T
 231 AC_TYPE_OFF_T
 232 AC_TYPE_PID_T
 233 AC_TYPE_SIGNAL
 234 AC_TYPE_SIZE_T
 235 AC_TYPE_UID_T
 236
 237 AC_CHECK_FUNCS(snprintf vsnprintf strerror)
 238 LYX_CHECK_DECL(snprintf, stdio.h)
 239 LYX_CHECK_DECL(vsnprintf, stdio.h)
 240 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 241 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 242
 243 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 244 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 245 dnl We aim to remove this eventually, since we should test as much as
 246 dnl possible with the compiler which will use the functions (JMarc)
 247 AC_LANG_PUSH(C)
 248 AC_CHECK_FUNCS(memmove memset strchr mkfifo mkstemp mktemp)
 249 AC_LANG_POP(C)
 250
 251 dnl Until this is fixed in autoconf we provide our own version
 252 AC_FUNC_SELECT_ARGTYPES
 253
 254 dnl check whether we have to work around solaris broken putenv()
 255 LYX_FUNC_PUTENV_ARGTYPE
 256
 257
 258 ### Some information on what just happened
 259 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 260 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 261 VERSION_INFO="Configuration\n\
 262   Host type:                      ${host}\n\
 263   Special build flags:           ${lyx_flags}\n\
 264   C   Compiler:                   ${CC}\n\
 265   C   Compiler flags:             ${CFLAGS}\n\
 266   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 267   C++ Compiler flags:             ${CXXFLAGS}\n\
 268   Linker flags:                   ${LDFLAGS}\n\
 269   Frontend:                       ${lyx_use_frontend}\n\
 270 ${FRONTEND_INFO}\
 271   LyX binary dir:                 ${real_bindir}\n\
 272   LyX files dir:                  ${real_datadir}\n"
 273
 274
 275 AC_SUBST(VERSION_INFO)
 276
 277 ## Some config.h stuff
 278
 279 AH_TOP([
 280 /* -*- C++ -*- */
 281 /* This is the compilation configuration file for LyX. It was generated by
 282    autoconfs configure. You might want to change some of the defaults if
 283    something goes wrong during the compilation
 284
 285    * This file is part of
 286    * ======================================================
 287    *
 288    *           LyX, the High Level Word Processor
 289    *
 290    *           Copyright 1995 Matthias Ettrich
 291    *           Copyright 1995-2001 The LyX Team.
 292    *
 293    *======================================================*/
 294
 295 #ifndef _CONFIG_H
 296 #define _CONFIG_H
 297 ])
 298
 299 AH_BOTTOM([
 300 /************************************************************
 301  ** You should not need to change anything beyond this point */
 302
 303 #ifndef HAVE_STRCHR
 304 # define strchr(a,b)    index(a,b)
 305 #endif
 306
 307 #ifndef HAVE_MEMMOVE
 308 # define memmove(a,b,c) bcopy(b,a,c)
 309 #endif
 310
 311 #ifndef HAVE_STRERROR
 312 #if defined(__cplusplus)
 313 extern "C"
 314 #endif
 315 char * strerror(int n);
 316 #endif
 317
 318 #ifdef BROKEN_HEADERS
 319 #include "broken_headers.h"
 320 #endif
 321
 322 #ifdef HAVE_MKSTEMP
 323 #ifndef HAVE_DECL_MKSTEMP
 324 #if defined(__cplusplus)
 325 extern "C"
 326 #endif
 327 int mkstemp(char*);
 328 #endif
 329 #endif
 330
 331 #ifdef __EMX__
 332 #include "support/os2_defines.h"
 333 #endif
 334
 335 #if defined(__CYGWIN__) || defined(__CYGWIN32__)
 336 #include "support/nt_defines.h"
 337 #endif
 338
 339 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 340 #define USE_BOOST_FORMAT 1
 341 #else
 342 #define USE_BOOST_FORMAT 0
 343 #endif
 344
 345 #endif
 346 ])
 347
 348 ### Finish the work.
 349 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 350 AC_CONFIG_FILES([Makefile \
 351        boost/Makefile \
 352        boost/libs/Makefile \
 353        boost/libs/regex/Makefile \
 354        boost/libs/regex/src/Makefile \
 355        boost/libs/signals/Makefile \
 356        boost/libs/signals/src/Makefile \
 357        config/Makefile \
 358        development/Makefile \
 359        development/lyx.spec \
 360        lib/Makefile \
 361        intl/Makefile \
 362        po/Makefile.in \
 363        sourcedoc/Doxyfile \
 364        sourcedoc/Makefile \
 365        src/Makefile \
 366        src/version.C \
 367        src/tex2lyx/Makefile \
 368        src/mathed/Makefile \
 369        src/graphics/Makefile \
 370        src/insets/Makefile \
 371        src/support/Makefile \
 372        src/frontends/Makefile \
 373        src/frontends/controllers/Makefile \
 374        src/frontends/xforms/Makefile \
 375        src/frontends/xforms/forms/Makefile \
 376        src/frontends/qt2/Makefile \
 377        src/frontends/qt2/moc/Makefile \
 378        src/frontends/qt2/ui/Makefile \
 379        src/frontends/qt2/ui/moc/Makefile \
 380        src/frontends/gnome/Makefile \
 381 ])
 382
 383 AC_SUBST(RPM_FRONTEND, 'xforms')
 384 AC_SUBST(RPM_FRONTEND_DEPS, 'libforms >= 1.0')
 385
 386 AC_OUTPUT
 387 # show version information
 388 echo
 389 printf "$VERSION_INFO"
 390 echo
 391
 392 # Display a final warning if there has been a LYX_ERROR
 393 LYX_CHECK_ERRORS