config/configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.3.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.3.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_TARGET
  15
  16 LYX_VERSION_SUFFIX
  17
  18 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  19
  20 # The list of languages known to LyX
  21 # This is needed by GNU gettext
  22 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  23
  24 # fix the value of the prefixes.
  25 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  26 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  27
  28 ### Set the execute permissions of the various scripts correctly
  29 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  30   chmod 755 ${srcdir}/${file}
  31 done
  32
  33 ### Check for programs
  34 AC_PROG_MAKE_SET
  35 AC_PROG_INSTALL
  36 #AC_PROG_RANLIB
  37 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  38 if test "x$KPSEWHICH" = xkpsewhich ; then
  39     AC_DEFINE(HAVE_KPSEWHICH, 1,
  40     [Define this if you have the kpsewhich program working on your system.])
  41 fi
  42 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  43
  44 # Work around a problem in automake 1.4: when invoking install-strip,
  45 # INSTALL_PROGRAM is changed to 'install -s', and since
  46 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  47 # which returns an error condition when stripping fails.
  48 INSTALL_SCRIPT='${INSTALL}'
  49
  50 ### we will also need a C compiler to compile GNU gettext
  51 AC_PROG_CC
  52
  53 ### check for special systems
  54 AC_ISC_POSIX
  55 AC_AIX
  56
  57 ### check which frontend we want to use
  58 LYX_USE_FRONTEND
  59
  60 #old gnome stuff removed by Michael Koziarski 25-05-2002
  61
  62 ### Check for a C++ compiler
  63 LYX_PROG_CXX
  64 ### Some checks on what the C++ compiler can(not) do
  65 AC_LANG(C++)
  66 dnl we do not need that currently (and probably all our supported
  67 dnl compiler allow that)
  68 dnl LYX_CXX_PARTIAL
  69 LYX_CXX_EXPLICIT
  70 LYX_CXX_STL_STRING
  71 LYX_CXX_GOOD_STD_STRING
  72 LYX_CXX_CHEADERS
  73 LYX_CXX_GLOBAL_CSTD
  74 LYX_STD_COUNT
  75 dnl we disable rtti for now
  76 dnl LYX_CXX_RTTI
  77 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  78 LYX_CXX_STL_MODERN_STREAMS
  79
  80 ### and now some special lyx flags.
  81 AC_ARG_ENABLE(assertions,
  82   [  --enable-assertions     add runtime sanity checks in the program],,
  83   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  84         enable_assertions=yes;
  85     else
  86         enable_assertions=no;
  87     fi;])
  88 if test "x$enable_assertions" = xyes ; then
  89    lyx_flags="$lyx_flags assertions"
  90    AC_DEFINE(ENABLE_ASSERTIONS,1,
  91     [Define if you want assertions to be enabled in the code])
  92 fi
  93
  94 ### Library Files
  95 dnl by testing these we check if it is ok to have
  96 dnl -lc and -lm as args to the compiler
  97 AC_CHECK_LIB(m, sin)
  98 AC_CHECK_LIB(c, fopen)
  99
 100 ### Add extra directories to check for libraries.
 101 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 102 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 103 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 104
 105 ### Add extra directories to check for include files.
 106 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 107 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 108 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 109
 110 ### Add both includes and libraries
 111 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 112 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 113 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 114   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 115
 116 AC_ARG_WITH(aiksaurus,
 117   [  --without-aiksaurus     do not use the Aiksaurus library],
 118   [lyx_use_aiksaurus=$withval])
 119 if test x$lyx_use_aiksaurus != xno; then
 120 AC_CHECK_LIB(Aiksaurus, main,
 121         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 122          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 123         ],,"-lbz2")
 124 fi
 125 AC_SUBST(AIKSAURUS_LIBS)
 126
 127 ### Setup libtool
 128 AC_DISABLE_SHARED
 129 AC_LIBTOOL_WIN32_DLL
 130 #AM_PROG_LIBTOOL
 131 LYX_PROG_LIBTOOL
 132
 133 ### Check if we want pspell libraries
 134 CHECK_WITH_PSPELL
 135
 136 ### Check for X libraries
 137 # The real thing.
 138 AC_PATH_XTRA
 139 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 140 # Since solaris X headers use int as implicit return type and modern
 141 # gcc's do not like that, let's use -isystem instead of -I.
 142 # We should test for gcc version and see whether it supports -isystem,
 143 # but since at least gcc 2.6.x supports it and it is still too old for
 144 # us, it seems we are safe.
 145 if test -n "$GXX" ; then
 146   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 147 fi
 148 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 149
 150 ### check which frontend we want to use
 151
 152 #LYX_USE_FRONTEND
 153 dnl The code below is not in a macro, because this would cause big
 154 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 155 case "$lyx_use_frontend" in
 156   xforms)
 157         LYX_PATH_XPM
 158         LYX_PATH_XFORMS
 159         LYX_CHECK_XFORMS_IMAGE_LOADER
 160         FRONTEND="xforms"
 161         FRONTEND_GUILIB="xforms/*.lo xforms/forms/*.lo"
 162         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 163         case "$host" in
 164           *cygwin)
 165             FRONTEND_LIBS="@XFORMS_LIB@ @XFORMS_IMAGE_LIB@ @XPM_LIB@"
 166             ;;
 167           *)
 168             FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 169             ;;
 170         esac
 171         FRONTEND_INFO="    libXpm version:               ${XPM_VERSION}\n\
 172     libforms version:             ${XFORMS_VERSION}\n"
 173         ;;
 174   gnome)
 175     LYX_PATH_XPM
 176     LYX_PATH_XFORMS
 177     LYX_CHECK_XFORMS_IMAGE_LOADER
 178     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 179     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 180     AC_SUBST(GNOME_FRONTEND_LIBS)
 181
 182     FRONTEND="xforms gnome"
 183     FRONTEND_GUILIB="gnome/*.lo"
 184     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 185     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 186     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 187         ;;
 188   qt)
 189     QT_DO_IT_ALL
 190     FRONTEND="qt2"
 191     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 192     FRONTEND_LDFLAGS="\$(QT_LDFLAGS)"
 193     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT_INCLUDES)"
 194     FRONTEND_LIBS="\$(QT_LIB)"
 195     FRONTEND_INFO="    Qt version:                   ${QT_VERSION}\n"
 196     ;;
 197   *)
 198     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 199 esac
 200
 201 ### Check for xforms and xpm (only if X has been found).
 202 if test "$have_x" = no ; then
 203 LYX_ERROR(dnl
 204 [Cannot find X window libraries and/or headers. Check your installation.
 205    If you use a Linux system, check that you have installed
 206    the development tools.])
 207 fi
 208
 209 ### Setup GNU gettext
 210 dnl GNU gettext is written in C
 211 AC_LANG_PUSH(C)
 212 # Some tests that may be useful for gettext
 213 AC_C_CONST
 214 AC_C_INLINE
 215 # Do the real setup now
 216 AM_GNU_GETTEXT
 217 # a hack for those who try to change LyX, but do not have gettext installed
 218 case  "${XGETTEXT}" in
 219  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 220 esac
 221
 222 AC_SUBST(LINGUAS)
 223
 224 AC_LANG_POP(C)
 225
 226 # some standard header files
 227 AC_HEADER_DIRENT
 228 AC_HEADER_MAJOR
 229 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 230
 231 # some standard structures
 232 AC_HEADER_STAT
 233 AC_HEADER_TIME
 234
 235 # some standard types
 236 AC_TYPE_MODE_T
 237 AC_TYPE_OFF_T
 238 AC_TYPE_PID_T
 239 AC_TYPE_SIGNAL
 240 AC_TYPE_SIZE_T
 241 AC_TYPE_UID_T
 242
 243 AC_CHECK_FUNCS(snprintf vsnprintf)
 244 LYX_CHECK_DECL(snprintf, stdio.h)
 245 LYX_CHECK_DECL(vsnprintf, stdio.h)
 246 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 247 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 248
 249 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 250 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 251 dnl We aim to remove this eventually, since we should test as much as
 252 dnl possible with the compiler which will use the functions (JMarc)
 253 AC_LANG_PUSH(C)
 254 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo mkstemp mktemp)
 255 AC_LANG_POP(C)
 256
 257 dnl Until this is fixed in autoconf we provide our own version
 258 AC_FUNC_SELECT_ARGTYPES
 259
 260 dnl check whether we have to work around solaris broken putenv()
 261 LYX_FUNC_PUTENV_ARGTYPE
 262
 263
 264 ### Some information on what just happened
 265 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 266 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 267 VERSION_INFO="Configuration\n\
 268   Host type:                      ${host}\n\
 269   Special build flags:           ${lyx_flags}\n\
 270   C   Compiler:                   ${CC}\n\
 271   C   Compiler flags:             ${CFLAGS}\n\
 272   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 273   C++ Compiler flags:             ${CXXFLAGS}\n\
 274   Linker flags:                   ${LDFLAGS}\n\
 275   Frontend:                       ${lyx_use_frontend}\n\
 276 ${FRONTEND_INFO}\
 277   LyX binary dir:                 ${real_bindir}\n\
 278   LyX files dir:                  ${real_datadir}\n"
 279
 280
 281 AC_SUBST(VERSION_INFO)
 282
 283 ## Some config.h stuff
 284
 285 AH_TOP([
 286 /* -*- C++ -*- */
 287 /* This is the compilation configuration file for LyX. It was generated by
 288    autoconfs configure. You might want to change some of the defaults if
 289    something goes wrong during the compilation
 290
 291    * This file is part of
 292    * ======================================================
 293    *
 294    *           LyX, the High Level Word Processor
 295    *
 296    *           Copyright 1995 Matthias Ettrich
 297    *           Copyright 1995-2001 The LyX Team.
 298    *
 299    *======================================================*/
 300
 301 #ifndef _CONFIG_H
 302 #define _CONFIG_H
 303 ])
 304
 305 AH_BOTTOM([
 306 /************************************************************
 307  ** You should not need to change anything beyond this point */
 308
 309 #ifndef HAVE_STRCHR
 310 # define strchr(a,b)    index(a,b)
 311 #endif
 312
 313 #ifndef HAVE_MEMMOVE
 314 # define memmove(a,b,c) bcopy(b,a,c)
 315 #endif
 316
 317 #ifndef HAVE_STRERROR
 318 #if defined(__cplusplus)
 319 extern "C"
 320 #endif
 321 char * strerror(int n);
 322 #endif
 323
 324 #ifdef BROKEN_HEADERS
 325 #include "broken_headers.h"
 326 #endif
 327
 328 #ifdef HAVE_MKSTEMP
 329 #ifndef HAVE_DECL_MKSTEMP
 330 #if defined(__cplusplus)
 331 extern "C"
 332 #endif
 333 int mkstemp(char*);
 334 #endif
 335 #endif
 336
 337 #ifdef __EMX__
 338 #include "support/os2_defines.h"
 339 #endif
 340
 341 #if defined(__CYGWIN__) || defined(__CYGWIN32__)
 342 #include "support/nt_defines.h"
 343 #endif
 344
 345 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 346 #define USE_BOOST_FORMAT 1
 347 #else
 348 #define USE_BOOST_FORMAT 0
 349 #endif
 350
 351 #endif
 352 ])
 353
 354 ### Finish the work.
 355 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 356 AC_CONFIG_FILES([Makefile \
 357        boost/Makefile \
 358        boost/libs/Makefile \
 359        boost/libs/regex/Makefile \
 360        boost/libs/regex/src/Makefile \
 361        boost/libs/signals/Makefile \
 362        boost/libs/signals/src/Makefile \
 363        config/Makefile \
 364        development/Makefile \
 365        development/lyx.spec \
 366        lib/Makefile \
 367        intl/Makefile \
 368        po/Makefile.in \
 369        sourcedoc/Doxyfile \
 370        src/Makefile \
 371        src/version.C \
 372        src/mathed/Makefile \
 373        src/graphics/Makefile \
 374        src/insets/Makefile \
 375        src/support/Makefile \
 376        src/frontends/Makefile \
 377        src/frontends/controllers/Makefile \
 378        src/frontends/xforms/Makefile \
 379        src/frontends/xforms/forms/Makefile \
 380        src/frontends/qt2/Makefile \
 381        src/frontends/qt2/moc/Makefile \
 382        src/frontends/qt2/ui/Makefile \
 383        src/frontends/qt2/ui/moc/Makefile \
 384        src/frontends/gnome/Makefile \
 385 ])
 386 AC_OUTPUT
 387 # show version information
 388 echo
 389 printf "$VERSION_INFO"
 390 echo
 391
 392 # Display a final warning if there has been a LYX_ERROR
 393 LYX_CHECK_ERRORS