acinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4
   5
   6 dnl Usage LYX_GET_VERSION   Sets "lyx_version" to the version of LyX being
   7 dnl   built, displays it and sets variable "lyx_devel" to yes or no depending
   8 dnl   whether the version is a development release or not.
   9 AC_DEFUN(LYX_GET_VERSION,[
  10 changequote(, ) dnl
  11 VERSION=`grep '#define *LYX_VERSION' $1 |
  12               sed -e 's/^.*"\(.*\)"$/\1/' 2>/dev/null`
  13 echo "configuring LyX version $VERSION"
  14 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  15   lyx_devel_version=yes
  16   echo "WARNING: This is a development version. Expect bugs."
  17 else
  18   lyx_devel_version=no
  19 fi
  20 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  21     lyx_prerelease=yes
  22     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  23 else
  24     lyx_prerelease=no
  25 fi
  26 changequote([, ]) dnl
  27 PACKAGE=lyx${program_suffix}
  28 AC_SUBST(lyx_devel_version)
  29 if test $lyx_devel_version = yes ; then
  30   AC_DEFINE(DEVEL_VERSION, 1, Define if you are building a development version of LyX)
  31 fi])
  32
  33 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  34 dnl flag lyx_error to yes.
  35 AC_DEFUN(LYX_ERROR,[
  36 lyx_error_txt="$lyx_error_txt
  37 ** $1
  38 "
  39 lyx_error=yes])
  40
  41
  42 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  43 dnl flag lyx_warning to yes.
  44 AC_DEFUN(LYX_WARNING,[
  45 lyx_warning_txt="$lyx_warning_txt
  46 == $1
  47 "
  48 lyx_warning=yes])
  49
  50
  51 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  52 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  53 AC_DEFUN(LYX_LIB_ERROR,[
  54 LYX_ERROR([Cannot find $1. Please check that the $2 library
  55    is correctly installed on your system.])])
  56
  57
  58 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  59 dnl   has occured previously.
  60 AC_DEFUN(LYX_CHECK_ERRORS,[
  61 if test x$lyx_error = xyes; then
  62 cat <<EOF
  63 **** The following problems have been detected by configure.
  64 **** Please check the messages below before running 'make'.
  65 **** (see the section 'Problems' in the INSTALL file)
  66 $lyx_error_txt
  67 $lyx_warning_txt
  68 deleting cache $cache_file
  69 EOF
  70   rm -f $cache_file
  71 else
  72
  73 if test x$lyx_warning = xyes; then
  74 cat <<EOF
  75 === The following minor problems have been detected by configure.
  76 === Please check the messages below before running 'make'.
  77 === (see the section 'Problems' in the INSTALL file)
  78 $lyx_warning_txt
  79 EOF
  80 fi
  81 cat <<EOF
  82 Configuration of LyX was successful.
  83 Type 'make' to compile the program,
  84 and then 'make install' to install it.
  85 EOF
  86 fi])
  87
  88
  89 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
  90 dnl
  91 define(LYX_SEARCH_PROG,[dnl
  92 for ac_prog in $2 ; do
  93 # Extract the first word of "$ac_prog", so it can be a program name with args.
  94   set dummy $ac_prog ; ac_word=$[2]
  95   if test -z "[$]$1"; then
  96     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
  97     for ac_dir in $PATH; do
  98       test -z "$ac_dir" && ac_dir=.
  99       if test -f [$ac_dir/$ac_word]; then
 100         $1="$ac_prog"
 101         break
 102       fi
 103     done
 104     IFS="$ac_save_ifs"
 105   fi
 106
 107   if test -n "[$]$1"; then
 108     ac_result=yes
 109   else
 110     ac_result=no
 111   fi
 112   ifelse($3,,,[$3])
 113   test -n "[$]$1" && break
 114 done
 115 ])dnl
 116
 117
 118 AC_DEFUN(LYX_PROG_CXX_WORKS,
 119 [AC_LANG_SAVE
 120 AC_LANG_CPLUSPLUS
 121 AC_TRY_COMPILER([class foo { int bar; }; int main(){return(0);}], ac_cv_prog_cxx_works, ac_cv_prog_cxx_cross)
 122 AC_LANG_RESTORE
 123 if test $ac_cv_prog_cxx_works = no; then
 124   CXX=
 125 fi
 126 cross_compiling=$ac_cv_prog_cxx_cross
 127 ])
 128
 129
 130 AC_DEFUN(LYX_PROG_CXX,
 131 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 132 AC_MSG_CHECKING([for a working C++ compiler])
 133 LYX_SEARCH_PROG(CXX, $CCC g++ gcc c++ CC cxx xlC cc++, LYX_PROG_CXX_WORKS)
 134
 135 if test -z "$CXX" ; then
 136   AC_ERROR([Unable to find a working C++ compiler])
 137 fi
 138
 139 AC_SUBST(CXX)
 140 AC_MSG_RESULT($CXX)
 141
 142 AC_MSG_CHECKING([whether the C++ compiler ($CXX $CXXFLAGS $LDFLAGS) is a cross-compiler])
 143 AC_MSG_RESULT($cross_compiling)
 144
 145 AC_PROG_CXX_GNU
 146
 147 dnl We might want to get or shut warnings.
 148 AC_ARG_WITH(warnings,
 149   [  --with-warnings         tell GNU C++ to display more warnings],,
 150   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 151         with_warnings=yes;
 152     else
 153         with_warnings=no;
 154     fi;])
 155 if test x$with_warnings = xyes ; then
 156   lyx_flags="$lyx_flags warnings"
 157   AC_DEFINE(WITH_WARNINGS, 1,
 158   [Define this if you want to see the warning directives put here and
 159    there by the developpers to get attention])
 160 fi
 161
 162 # optimize less for development versions
 163 if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 164   lyx_opt="-O"
 165 else
 166   lyx_opt="-O2"
 167 fi
 168
 169 # set the debug flags correctly.
 170 if test $ac_cv_prog_gxx = yes; then
 171   GXX=yes
 172 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 173 dnl plays around with CXXFLAGS (such as to build both debugging and
 174 dnl normal versions of a library), tasteless as that idea is.
 175   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 176   ac_save_CXXFLAGS="$CXXFLAGS"
 177   CXXFLAGS=
 178 dnl Check the version of g++
 179   gxx_version=`g++ --version`
 180
 181   AC_PROG_CXX_G
 182   if test "$ac_test_CXXFLAGS" = set; then
 183     CXXFLAGS="$ac_save_CXXFLAGS"
 184   elif test $ac_cv_prog_cxx_g = yes; then
 185     case $gxx_version in
 186       2.7*) CXXFLAGS="$lyx_opt";;
 187       2.95.*) CXXFLAGS="-g $lyx_opt -fno-exceptions -fno-rtti -fpermissive";;
 188       *)    CXXFLAGS="-g $lyx_opt -fno-exceptions -fno-rtti";;
 189     esac
 190   else
 191     CXXFLAGS="$lyx_opt"
 192   fi
 193   if test x$with_warnings = xyes ; then
 194     CXXFLAGS="$CXXFLAGS -ansi -Wall"
 195     if test $lyx_devel_version = yes ; then
 196         CXXFLAGS="$CXXFLAGS -pedantic"
 197     fi
 198   fi
 199 else
 200   GXX=
 201   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 202 fi
 203 ])dnl
 204
 205
 206 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 207 dnl   supports RTTI
 208 AC_DEFUN(LYX_CXX_RTTI,[
 209 ### Check whether the compiler supports runtime type information
 210 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 211  [AC_TRY_RUN([
 212 class rtti {
 213 public:
 214    virtual int tag() { return 0; }
 215 };
 216 class derived1 : public rtti {
 217 public:
 218     int tag() { return 1; }
 219 };
 220 class derived2 : public rtti {
 221 public:
 222     int tag() { return 2; }
 223 };
 224 int main() {
 225     derived1 * foo1 = new derived1();
 226     derived2 * foo2 = new derived2();
 227     rtti * bar = foo1;
 228     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 229     if (bar1 == 0)
 230         exit(1);
 231     bar = foo2;
 232     bar1 = dynamic_cast<derived1 *>(bar);
 233     if (bar1 != 0)
 234         exit(1);
 235     return 0;
 236 }
 237 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 238 ])
 239 if test x$lyx_cv_rtti = xyes ; then
 240   AC_DEFINE(HAVE_RTTI, 1,
 241    [Define to 1 if your compiler supports runtime type information])
 242 fi])
 243
 244
 245 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 246 dnl   understands the "explicit" directive.
 247 AC_DEFUN(LYX_CXX_EXPLICIT,[
 248 ### Check whether the compiler understands the keyword `explicit'
 249 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 250  [AC_TRY_COMPILE([
 251 class Expl {
 252 public:
 253         explicit Expl() {};
 254 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 255 ])
 256 if test $lyx_cv_explicit = no ; then
 257   AC_DEFINE(explicit,[ ],
 258    [Define to nothing if your compiler does not understand the
 259    'explicit' directive])
 260 fi])
 261
 262
 263 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 264 dnl   has a working stl stack template
 265 AC_DEFUN(LYX_CXX_STL_STACK,[
 266 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 267  [AC_TRY_COMPILE([
 268 #include <stack>
 269 using std::stack;
 270 ],[
 271     stack<int> stakk;
 272     stakk.push(0);
 273 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 274 ])
 275 if test $lyx_cv_broken_stack = yes ; then
 276   AC_DEFINE(BROKEN_STL_STACK, 1,
 277    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 278    correctly])
 279 fi])
 280
 281
 282 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 283 dnl   supports modern STL streams
 284 AC_DEFUN(LYX_CXX_STL_MODERN_STREAMS,[
 285 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 286  [AC_TRY_COMPILE([
 287 #include <fstream>
 288 ],[
 289  std::streambuf * test = std::cerr.rdbuf();
 290  test->pubsync();
 291 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 292 ])
 293 if test $lyx_cv_modern_streams = yes ; then
 294   AC_DEFINE(MODERN_STL_STREAMS, 1,
 295    [Define if you have modern standard-compliant STL streams])
 296 fi])
 297
 298
 299 dnl Usage: LYX_CXX_STL_STRING : checks whether the C++ compiler
 300 dnl   has a working stl string container, the check is really stupid
 301 dnl   and could need some improvement.
 302 AC_DEFUN(LYX_CXX_STL_STRING,[
 303     AC_REQUIRE([LYX_PROG_CXX])
 304     AC_MSG_CHECKING(whether the included std::string should be used)
 305     AC_ARG_WITH(included-string,[
 306         --with-included-string  use LyX string class instead of STL string
 307     ],[
 308         with_included_string=$withval
 309     ],[
 310         AC_TRY_COMPILE([
 311             #include <string>
 312             using std::string;
 313         ],[
 314             string a("hello there");
 315             a.clear();
 316             a = "hey";
 317             a.erase();
 318         ],[
 319             with_included_string=no
 320         ],[
 321             with_included_string=yes
 322
 323         ])
 324     ])
 325     if test x$with_included_string = xyes ; then
 326         AC_DEFINE(USE_INCLUDED_STRING, 1,
 327             [Define to use the lyxstring class bundled with LyX.])
 328             lyx_flags="$lyx_flags included-string"
 329     fi
 330     AM_CONDITIONAL(USE_LYXSTRING, test x$with_included_string = xyes)
 331     AC_MSG_RESULT([$with_included_string])
 332 ])
 333
 334
 335 dnl LYX_CXX_MUTABLE
 336 AC_DEFUN(LYX_CXX_MUTABLE, [
 337 AC_REQUIRE([LYX_PROG_CXX])
 338 AC_MSG_CHECKING(if C++ compiler supports mutable)
 339 AC_TRY_COMPILE(
 340 [
 341 class k {
 342         mutable char *c;
 343 public:
 344    void foo() const { c=0; }
 345 };
 346 ],[
 347 ],[
 348   ac_mutable=yes
 349   AC_DEFINE(HAVE_MUTABLE, 1,
 350    [Defined if you compiler supports 'mutable'.])
 351 ],[
 352   ac_mutable=no
 353 ])
 354 AC_MSG_RESULT([$ac_mutable])
 355 ])
 356
 357
 358 dnl LYX_CXX_PARTIAL
 359 AC_DEFUN(LYX_CXX_PARTIAL, [
 360 AC_REQUIRE([LYX_PROG_CXX])
 361 AC_MSG_CHECKING(if C++ compiler supports partial specialization)
 362 AC_TRY_COMPILE(
 363 [
 364 template<class T, class K>
 365 class k {
 366 public:
 367 };
 368 template<class T> class k<void,T> { };
 369 ],[
 370   k<float, float> b;
 371   k<void,void> a;
 372 ],[
 373   ac_partial_specialization=yes
 374   AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 375    [Defined if your compiler supports partial specialization.])
 376 ],[
 377   ac_partial_specialization=no
 378 ])
 379 AC_MSG_RESULT([$ac_partial_specialization])
 380 ])
 381
 382
 383 dnl Usage: LYX_CXX_NAMESPACES : checks whether the C++ compiler
 384 dnl   has a correct namespace handling and define CXX_WORKING_NAMESPACES
 385 dnl   if true. This macro does not do a thourough test, but it should be
 386 dnl   good enough to suit our needs.
 387 AC_DEFUN(LYX_CXX_NAMESPACES,[
 388 AC_CACHE_CHECK(for correct namespaces support,lyx_cv_cxx_namespace,
 389  [AC_TRY_COMPILE([
 390   #include <vector>
 391   using std::vector;
 392 ],[
 393         vector<int> test;
 394         return 0;
 395 ],lyx_cv_cxx_namespace=yes,lyx_cv_cxx_namespace=no)
 396 ])
 397 if test $lyx_cv_cxx_namespace = yes ; then
 398   AC_DEFINE(CXX_WORKING_NAMESPACES, 1,
 399    [Define if your C++ compiler has correct support for namespaces])
 400 fi])
 401
 402
 403 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 404 dnl   provides wrappers for C headers and use our alternate version otherwise.
 405 AC_DEFUN(LYX_CXX_CHEADERS,[
 406 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 407  [AC_TRY_CPP([
 408 #include <clocale>
 409 #include <cctype>
 410 #include <cerrno>
 411 #include <cmath>
 412 #include <csignal>
 413 #include <cstdio>
 414 #include <cstdlib>
 415 #include <cstring>
 416 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 417 if test $lyx_cv_cxx_cheaders = no ; then
 418   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 419 fi])
 420
 421
 422 dnl Usage LYX_PATH_XPM: Checks for xpm library and header
 423 AC_DEFUN(LYX_PATH_XPM,[
 424 ### Check for Xpm library
 425 AC_CHECK_LIB(Xpm, XpmCreateBufferFromImage,LYX_LIBS="-lXpm $LYX_LIBS",
 426         [LYX_LIB_ERROR(libXpm,Xpm)], $LYX_LIBS)
 427
 428 ### Check for Xpm headers
 429 lyx_cv_xpm_h_location="<xpm.h>"
 430 AC_CHECK_HEADER(X11/xpm.h,[
 431   ac_cv_header_xpm_h=yes
 432   lyx_cv_xpm_h_location="<X11/xpm.h>"],[
 433 AC_CHECK_HEADER(xpm.h,[],[
 434 LYX_LIB_ERROR(xpm.h,Xpm)])])
 435 AC_DEFINE_UNQUOTED(XPM_H_LOCATION,$lyx_cv_xpm_h_location)
 436
 437 ### Test for the header version
 438 if test $ac_cv_header_xpm_h = yes; then
 439   AC_CACHE_CHECK([xpm header version],lyx_cv_xpmversion,
 440   [ cat > conftest.$ac_ext <<EOF
 441 #line __oline__ "configure"
 442 #include "confdefs.h"
 443
 444 #include XPM_H_LOCATION
 445 "%%%"lyx_cv_xpmv=XpmVersion;lyx_cv_xpmr=XpmRevision"%%%"
 446 EOF
 447     eval `(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 448       grep '^"%%%"'  2>/dev/null | \
 449       sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 450     case "$lyx_cv_xpmr" in
 451 changequote(,)
 452      [0-9]) lyxxpmr_alpha=`echo $lyx_cv_xpmr |tr 123456789 abcdefghi`
 453             lyxxpmv_alpha=" (aka 3.$lyx_cv_xpmv$lyxxpmr_alpha)";;
 454 changequote([,])
 455          *) ;;
 456     esac
 457     lyx_cv_xpmversion="$lyx_cv_xpmv.$lyx_cv_xpmr$lyxxpmv_alpha"
 458     rm -f conftest*])
 459   case "$lyx_cv_xpmr" in
 460 changequote(,)
 461         [789]|[0-9][0-9]*) ;;
 462 changequote([,])
 463         *) LYX_WARNING([Version $lyx_cv_xpmversion of the Xpm library is a bit old.
 464    If you experience strange crashes with LyX, try to upgrade
 465    to at least version 4.7 (aka 3.4g).
 466    If you have installed a newer version of the library, check whether you
 467    have an old xpm.h header file in your include path.]);;
 468   esac
 469 fi])
 470
 471
 472 dnl Usage LYX_PATH_XFORMS: Checks for xforms library and flags
 473 AC_DEFUN(LYX_PATH_XFORMS,[
 474 ### Check for xforms library
 475 AC_CHECK_LIB(forms, fl_initialize, LYX_LIBS="-lforms $LYX_LIBS",
 476   [AC_CHECK_LIB(xforms, fl_initialize, LYX_LIBS="-lxforms $LYX_LIBS",
 477     [LYX_LIB_ERROR(libforms or libxforms,xforms)], $LYX_LIBS)], $LYX_LIBS)
 478
 479 ### Check for xforms headers
 480 lyx_cv_forms_h_location="<forms.h>"
 481 AC_CHECK_HEADER(X11/forms.h,[
 482   ac_cv_header_forms_h=yes
 483   lyx_cv_forms_h_location="<X11/forms.h>"],[
 484 AC_CHECK_HEADER(forms.h,[],[
 485 LYX_LIB_ERROR(forms.h,forms)])])
 486 AC_DEFINE_UNQUOTED(FORMS_H_LOCATION,$lyx_cv_forms_h_location)
 487 if test $ac_cv_header_forms_h = yes; then
 488   AC_CACHE_CHECK([xforms header version],lyx_cv_xfversion,
 489   [ cat > conftest.$ac_ext <<EOF
 490 #line __oline__ "configure"
 491 #include "confdefs.h"
 492
 493 #include FORMS_H_LOCATION
 494 #if ! defined(FL_INCLUDE_VERSION)
 495 "%%%"(unknown)"%%%"
 496 #else
 497 "%%%"FL_VERSION.FL_REVISION"%%%"
 498 #endif
 499 EOF
 500 lyx_cv_xfversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 501   grep '^"%%%"'  2>/dev/null | \
 502   sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 503 rm -f conftest*])
 504 case "$lyx_cv_xfversion" in
 505   "(unknown)"|0.82|0.83|0.84|0.85)
 506      LYX_ERROR(dnl
 507 Version $lyx_cv_xfversion of xforms is not compatible with LyX.
 508    This version of LyX works best with version 0.88[,] although it
 509    supports also versions 0.81[,] 0.86 and 0.87.) ;;
 510   0.81|0.86|0.87)
 511      LYX_WARNING(dnl
 512 While LyX is compatible with version $lyx_cv_xfversion of xforms[,]
 513    it is recommended that you upgrade to version 0.88.) ;;
 514      0.88) ;;
 515      0.89) LYX_WARNING(dnl
 516 LyX should work ok with version $lyx_cv_xfversion of xforms[,] but
 517 it is an unproven version and might still have some bugs. If you
 518 have problems[,] please use version 0.88 instead.) ;;
 519           *) LYX_WARNING(dnl
 520 Version $lyx_cv_xfversion of xforms might not be compatible with LyX[,]
 521    since it is newer than 0.88. You might have slight problems with it.);;
 522 esac
 523 fi])
 524
 525
 526 dnl Usage: LYX_HPUX  Checks for HP-UX and update CXXFLAGS accordingly
 527 AC_DEFUN(LYX_HPUX,
 528 [#It seems that HPUX requires using -fpcc-struct-return with gcc.
 529 AC_CACHE_CHECK(for HP-UX,ac_cv_hpux,[
 530 os=`uname -s | tr '[A-Z]' '[a-z]'`
 531 ac_cv_hpux=no
 532 test "$os" = hp-ux && ac_cv_hpux=yes])
 533 if test "$ac_cv_hpux" = yes; then
 534  test "x$GXX" = xyes && CXXFLAGS="$CXXFLAGS -fpcc-struct-return"
 535 fi])
 536
 537
 538 dnl Usage: LYX_SUNOS4 Checks for SunOS 4.x and sets the flag lyx_broken_headers
 539 dnl   if necessary
 540 AC_DEFUN(LYX_SUNOS4,
 541 [#The headers are not correct under SunOS4
 542 AC_CACHE_CHECK(for SunOS 4.x,ac_cv_sunos4,[
 543 changequote(, ) dnl
 544 os=`uname -a | sed -e 's/^\([^ ]*\) [^ ]* \([0-9]\)\..*/\1\2/'`
 545 changequote([, ]) dnl
 546 ac_cv_sunos4=no
 547 test "$os" = SunOS4 && ac_cv_sunos4=yes])
 548 if test "$ac_cv_sunos4" = yes; then
 549  test "x$GXX" = xyes && lyx_broken_headers=yes
 550 fi])
 551
 552
 553 dnl Usage: LYX_SCO Checks for SCO and sets the flag lyx_broken_headers
 554 dnl   if necessary
 555 AC_DEFUN(LYX_SCO,
 556 [AC_CACHE_CHECK(for SCO 3.2v4,ac_cv_sco,[
 557 ac_cv_sco=no
 558 if test `uname -s` != "SCO_SV"; then
 559   lyx_machine_rel=`uname -m`:`uname -r`
 560   if test $lyx_machine_rel = i386:3.2 || test $lyx_machine_rel = i486:3.2;
 561   then
 562     if test -f /usr/options/cb.name; then
 563       ac_cv_sco=no
 564     elif /bin/uname -X 2>/dev/null >/dev/null ; then
 565       ac_cv_sco=yes
 566     fi
 567   fi
 568 fi])
 569 if test "$ac_cv_sco" = yes; then
 570  test "x$GXX" = xyes && lyx_broken_headers=yes
 571 fi])
 572
 573
 574 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 575 dnl                       [default-yes-value])
 576 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 577 dnl  resulting directory name in 'dir-var-name'.
 578 AC_DEFUN(LYX_WITH_DIR,[
 579   AC_ARG_WITH($1,[  --with-$1     specify $2])
 580   AC_MSG_CHECKING([for $2])
 581   if test -z "$with_$3"; then
 582      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 583   else
 584     test "x$with_$3" = xyes && with_$3=$5
 585     lyx_cv_$3="$with_$3"
 586   fi
 587   AC_MSG_RESULT($lyx_cv_$3)])
 588
 589
 590 dnl Usage: LYX_LOOP_DIR(value,action)
 591 dnl Executes action for values of variable `dir' in `values'. `values' can
 592 dnl use ":" as a separator.
 593 AC_DEFUN(LYX_LOOP_DIR,[
 594 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 595 for dir in `eval "echo $1"`; do
 596   if test ! "$dir" = NONE; then
 597     test ! -d "$dir" && AC_ERROR([\"$dir\" is not a directory])
 598     $2
 599   fi
 600 done
 601 IFS=$ac_save_ifs
 602 ])
 603
 604
 605 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 606 dnl var-name.
 607 AC_DEFUN(LYX_ADD_LIB_DIR,[
 608 $1="${$1} -L$2"
 609 if test "`(uname) 2>/dev/null`" = SunOS &&
 610     uname -r | grep '^5' >/dev/null; then
 611   if test $ac_cv_prog_gxx = yes ; then
 612     $1="${$1} -Wl[,]-R$2"
 613   else
 614     $1="${$1} -R$2"
 615   fi
 616 fi])
 617
 618
 619 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 620 dnl var-name.
 621 AC_DEFUN(LYX_ADD_INC_DIR,[$1="${$1} -I$2 "])
 622
 623
 624 dnl AC_VALIDATE_CACHE_SYSTEM_TYPE[(cmd)]
 625 dnl if the cache file is inconsistent with the current host,
 626 dnl target and build system types, execute CMD or print a default
 627 dnl error message.
 628 AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE, [
 629     AC_REQUIRE([AC_CANONICAL_SYSTEM])
 630     AC_MSG_CHECKING([config.cache system type])
 631     if { test x"${ac_cv_host_system_type+set}" = x"set" &&
 632          test x"$ac_cv_host_system_type" != x"$host"; } ||
 633        { test x"${ac_cv_build_system_type+set}" = x"set" &&
 634          test x"$ac_cv_build_system_type" != x"$build"; } ||
 635        { test x"${ac_cv_target_system_type+set}" = x"set" &&
 636          test x"$ac_cv_target_system_type" != x"$target"; }; then
 637         AC_MSG_RESULT([different])
 638         ifelse($#, 1, [$1],
 639                 [AC_MSG_ERROR(["you must remove config.cache and restart configure"])])
 640     else
 641         AC_MSG_RESULT([same])
 642     fi
 643     ac_cv_host_system_type="$host"
 644     ac_cv_build_system_type="$build"
 645     ac_cv_target_system_type="$target"
 646 ])
 647
 648
 649 dnl We use this until autoconf fixes its version.
 650 AC_DEFUN(LYX_FUNC_SELECT_ARGTYPES,
 651 [AC_MSG_CHECKING([types of arguments for select()])
 652  AC_CACHE_VAL(ac_cv_func_select_arg234,dnl
 653  [AC_CACHE_VAL(ac_cv_func_select_arg1,dnl
 654   [AC_CACHE_VAL(ac_cv_func_select_arg5,dnl
 655    [for ac_cv_func_select_arg234 in 'fd_set *' 'int *' 'void *'; do
 656      for ac_cv_func_select_arg1 in 'int' 'size_t' 'unsigned long' 'unsigned'; do      for ac_cv_func_select_arg5 in 'struct timeval *' 'const struct timeval *'; do
 657        AC_TRY_COMPILE(dnl
 658 [#ifdef HAVE_SYS_TYPES_H
 659 #include <sys/types.h>
 660 #endif
 661 #ifdef HAVE_SYS_TIME_H
 662 #include <sys/time.h>
 663 #endif
 664 #ifdef HAVE_SYS_SELECT_H
 665 #include <sys/select.h>
 666 #endif
 667 #ifdef HAVE_SYS_SOCKET_H
 668 #include <sys/socket.h>
 669 #endif
 670 extern int select ($ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5);],,dnl
 671         [ac_not_found=no ; break 3],ac_not_found=yes)
 672       done
 673      done
 674     done
 675    ])dnl AC_CACHE_VAL
 676   ])dnl AC_CACHE_VAL
 677  ])dnl AC_CACHE_VAL
 678  if test "$ac_not_found" = yes; then
 679   ac_cv_func_select_arg1=int
 680   ac_cv_func_select_arg234='int *'
 681   ac_cv_func_select_arg5='struct timeval *'
 682  fi
 683  AC_MSG_RESULT([$ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5])
 684  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG1,$ac_cv_func_select_arg1)
 685  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG234,($ac_cv_func_select_arg234))
 686  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG5,($ac_cv_func_select_arg5))
 687 ])
 688
 689 dnl This is taken from gettext.m4, but a bug has been fixed
 690 # Macro to add for using GNU gettext.
 691 # Ulrich Drepper <drepper@cygnus.com>, 1995.
 692 #
 693 # This file can be copied and used freely without restrictions.  It can
 694 # be used in projects which are not available under the GNU Public License
 695 # but which still want to provide support for the GNU gettext functionality.
 696 # Please note that the actual code is *not* freely available.
 697
 698 # serial 5
 699
 700 AC_DEFUN(LYX_GNU_GETTEXT,
 701   [AC_REQUIRE([AC_PROG_MAKE_SET])dnl
 702    AC_REQUIRE([AC_PROG_CC])dnl
 703    AC_REQUIRE([AC_PROG_RANLIB])dnl
 704    AC_REQUIRE([AC_ISC_POSIX])dnl
 705    AC_REQUIRE([AC_HEADER_STDC])dnl
 706    AC_REQUIRE([AC_C_CONST])dnl
 707    AC_REQUIRE([AC_C_INLINE])dnl
 708    AC_REQUIRE([AC_TYPE_OFF_T])dnl
 709    AC_REQUIRE([AC_TYPE_SIZE_T])dnl
 710    AC_REQUIRE([AC_FUNC_ALLOCA])dnl
 711    AC_REQUIRE([AC_FUNC_MMAP])dnl
 712
 713    AC_CHECK_HEADERS([argz.h limits.h locale.h nl_types.h malloc.h string.h \
 714 unistd.h sys/param.h])
 715    AC_CHECK_FUNCS([getcwd munmap putenv setenv setlocale strchr strcasecmp \
 716 strdup __argz_count __argz_stringify __argz_next])
 717
 718    if test "${ac_cv_func_stpcpy+set}" != "set"; then
 719      AC_CHECK_FUNCS(stpcpy)
 720    fi
 721    if test "${ac_cv_func_stpcpy}" = "yes"; then
 722      AC_DEFINE(HAVE_STPCPY)
 723    fi
 724
 725    AM_LC_MESSAGES
 726    AM_WITH_NLS
 727
 728    if test "x$CATOBJEXT" != "x"; then
 729      if test "x$ALL_LINGUAS" = "x"; then
 730        LINGUAS=
 731      else
 732        AC_MSG_CHECKING(for catalogs to be installed)
 733        NEW_LINGUAS=
 734 dnl =============Fix is here !===============================
 735 dnl Some sh do not like substituation in bounds of for loops
 736 dnl       for lang in ${LINGUAS=$ALL_LINGUAS}; do
 737        tmplinguas=${LINGUAS=$ALL_LINGUAS}
 738        for lang in ${tmplinguas}; do
 739 dnl =========================================================
 740          case "$ALL_LINGUAS" in
 741           *$lang*) NEW_LINGUAS="$NEW_LINGUAS $lang" ;;
 742          esac
 743        done
 744        LINGUAS=$NEW_LINGUAS
 745        AC_MSG_RESULT($LINGUAS)
 746      fi
 747
 748      dnl Construct list of names of catalog files to be constructed.
 749      if test -n "$LINGUAS"; then
 750        for lang in $LINGUAS; do CATALOGS="$CATALOGS $lang$CATOBJEXT"; done
 751      fi
 752    fi
 753
 754    dnl The reference to <locale.h> in the installed <libintl.h> file
 755    dnl must be resolved because we cannot expect the users of this
 756    dnl to define HAVE_LOCALE_H.
 757    if test $ac_cv_header_locale_h = yes; then
 758      INCLUDE_LOCALE_H="#include <locale.h>"
 759    else
 760      INCLUDE_LOCALE_H="\
 761 /* The system does not provide the header <locale.h>.  Take care yourself.  */"
 762    fi
 763    AC_SUBST(INCLUDE_LOCALE_H)
 764
 765    dnl Determine which catalog format we have (if any is needed)
 766    dnl For now we know about two different formats:
 767    dnl   Linux libc-5 and the normal X/Open format
 768    test -d intl || mkdir intl
 769    if test "$CATOBJEXT" = ".cat"; then
 770      AC_CHECK_HEADER(linux/version.h, msgformat=linux, msgformat=xopen)
 771
 772      dnl Transform the SED scripts while copying because some dumb SEDs
 773      dnl cannot handle comments.
 774      sed -e '/^#/d' $srcdir/intl/$msgformat-msg.sed > intl/po2msg.sed
 775    fi
 776    dnl po2tbl.sed is always needed.
 777    sed -e '/^#.*[^\\]$/d' -e '/^#$/d' \
 778      $srcdir/intl/po2tbl.sed.in > intl/po2tbl.sed
 779
 780    dnl In the intl/Makefile.in we have a special dependency which makes
 781    dnl only sense for gettext.  We comment this out for non-gettext
 782    dnl packages.
 783    if test "$PACKAGE" = "gettext"; then
 784      GT_NO="#NO#"
 785      GT_YES=
 786    else
 787      GT_NO=
 788      GT_YES="#YES#"
 789    fi
 790    AC_SUBST(GT_NO)
 791    AC_SUBST(GT_YES)
 792
 793    dnl If the AC_CONFIG_AUX_DIR macro for autoconf is used we possibly
 794    dnl find the mkinstalldirs script in another subdir but ($top_srcdir).
 795    dnl Try to locate is.
 796    MKINSTALLDIRS=
 797    if test -n "$ac_aux_dir"; then
 798      MKINSTALLDIRS="$ac_aux_dir/mkinstalldirs"
 799    fi
 800    if test -z "$MKINSTALLDIRS"; then
 801      MKINSTALLDIRS="\$(top_srcdir)/mkinstalldirs"
 802    fi
 803    AC_SUBST(MKINSTALLDIRS)
 804
 805    dnl *** For now the libtool support in intl/Makefile is not for real.
 806    l=
 807    AC_SUBST(l)
 808
 809    dnl Generate list of files to be processed by xgettext which will
 810    dnl be included in po/Makefile.
 811    test -d po || mkdir po
 812    if test "x$srcdir" != "x."; then
 813      if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 814        posrcprefix="$srcdir/"
 815      else
 816        posrcprefix="../$srcdir/"
 817      fi
 818    else
 819      posrcprefix="../"
 820    fi
 821    rm -f po/POTFILES
 822    sed -e "/^#/d" -e "/^\$/d" -e "s,.*, $posrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 823         < $srcdir/po/POTFILES.in > po/POTFILES
 824   ])
 825
 826 ## libtool.m4 - Configure libtool for the target system. -*-Shell-script-*-
 827 ## Copyright (C) 1996-1999 Free Software Foundation, Inc.
 828 ## Originally by Gordon Matzigkeit <gord@gnu.ai.mit.edu>, 1996
 829 ##
 830 ## This program is free software; you can redistribute it and/or modify
 831 ## it under the terms of the GNU General Public License as published by
 832 ## the Free Software Foundation; either version 2 of the License, or
 833 ## (at your option) any later version.
 834 ##
 835 ## This program is distributed in the hope that it will be useful, but
 836 ## WITHOUT ANY WARRANTY; without even the implied warranty of
 837 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 838 ## General Public License for more details.
 839 ##
 840 ## You should have received a copy of the GNU General Public License
 841 ## along with this program; if not, write to the Free Software
 842 ## Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
 843 ##
 844 ## As a special exception to the GNU General Public License, if you
 845 ## distribute this file as part of a program that contains a
 846 ## configuration script generated by Autoconf, you may include it under
 847 ## the same distribution terms that you use for the rest of that program.
 848
 849 # serial 40 AC_PROG_LIBTOOL
 850 AC_DEFUN(AC_PROG_LIBTOOL,
 851 [AC_REQUIRE([AC_LIBTOOL_SETUP])dnl
 852
 853 # Save cache, so that ltconfig can load it
 854 AC_CACHE_SAVE
 855
 856 # Actually configure libtool.  ac_aux_dir is where install-sh is found.
 857 CC="$CC" CFLAGS="$CFLAGS" CPPFLAGS="$CPPFLAGS" \
 858 LD="$LD" LDFLAGS="$LDFLAGS" LIBS="$LIBS" \
 859 LN_S="$LN_S" NM="$NM" RANLIB="$RANLIB" \
 860 DLLTOOL="$DLLTOOL" AS="$AS" OBJDUMP="$OBJDUMP" \
 861 ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/ltconfig --no-reexec \
 862 $libtool_flags --no-verify $ac_aux_dir/ltmain.sh $host \
 863 || AC_MSG_ERROR([libtool configure failed])
 864
 865 # Reload cache, that may have been modified by ltconfig
 866 AC_CACHE_LOAD
 867
 868 # This can be used to rebuild libtool when needed
 869 LIBTOOL_DEPS="$ac_aux_dir/ltconfig $ac_aux_dir/ltmain.sh"
 870
 871 # Always use our own libtool.
 872 LIBTOOL='$(SHELL) $(top_builddir)/libtool'
 873 AC_SUBST(LIBTOOL)dnl
 874
 875 # Redirect the config.log output again, so that the ltconfig log is not
 876 # clobbered by the next message.
 877 exec 5>>./config.log
 878 ])
 879
 880 AC_DEFUN(AC_LIBTOOL_SETUP,
 881 [AC_PREREQ(2.13)dnl
 882 AC_REQUIRE([AC_ENABLE_SHARED])dnl
 883 AC_REQUIRE([AC_ENABLE_STATIC])dnl
 884 AC_REQUIRE([AC_ENABLE_FAST_INSTALL])dnl
 885 AC_REQUIRE([AC_CANONICAL_HOST])dnl
 886 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
 887 AC_REQUIRE([AC_PROG_RANLIB])dnl
 888 AC_REQUIRE([AC_PROG_CC])dnl
 889 AC_REQUIRE([AC_PROG_LD])dnl
 890 AC_REQUIRE([AC_PROG_NM])dnl
 891 AC_REQUIRE([AC_PROG_LN_S])dnl
 892 dnl
 893
 894 # Check for any special flags to pass to ltconfig.
 895 #
 896 # the following will cause an existing older ltconfig to fail, so
 897 # we ignore this at the expense of the cache file... Checking this
 898 # will just take longer ... bummer!
 899 #libtool_flags="--cache-file=$cache_file"
 900 #
 901 test "$enable_shared" = no && libtool_flags="$libtool_flags --disable-shared"
 902 test "$enable_static" = no && libtool_flags="$libtool_flags --disable-static"
 903 test "$enable_fast_install" = no && libtool_flags="$libtool_flags --disable-fast-install"
 904 test "$ac_cv_prog_gcc" = yes && libtool_flags="$libtool_flags --with-gcc"
 905 test "$ac_cv_prog_gnu_ld" = yes && libtool_flags="$libtool_flags --with-gnu-ld"
 906 ifdef([AC_PROVIDE_AC_LIBTOOL_DLOPEN],
 907 [libtool_flags="$libtool_flags --enable-dlopen"])
 908 ifdef([AC_PROVIDE_AC_LIBTOOL_WIN32_DLL],
 909 [libtool_flags="$libtool_flags --enable-win32-dll"])
 910 AC_ARG_ENABLE(libtool-lock,
 911   [  --disable-libtool-lock  avoid locking (might break parallel builds)])
 912 test "x$enable_libtool_lock" = xno && libtool_flags="$libtool_flags --disable-lock"
 913 test x"$silent" = xyes && libtool_flags="$libtool_flags --silent"
 914
 915 # Some flags need to be propagated to the compiler or linker for good
 916 # libtool support.
 917 case "$host" in
 918 *-*-irix6*)
 919   # Find out which ABI we are using.
 920   echo '[#]line __oline__ "configure"' > conftest.$ac_ext
 921   if AC_TRY_EVAL(ac_compile); then
 922     case "`/usr/bin/file conftest.o`" in
 923     *32-bit*)
 924       LD="${LD-ld} -32"
 925       ;;
 926     *N32*)
 927       LD="${LD-ld} -n32"
 928       ;;
 929     *64-bit*)
 930       LD="${LD-ld} -64"
 931       ;;
 932     esac
 933   fi
 934   rm -rf conftest*
 935   ;;
 936
 937 *-*-sco3.2v5*)
 938   # On SCO OpenServer 5, we need -belf to get full-featured binaries.
 939   SAVE_CFLAGS="$CFLAGS"
 940   CFLAGS="$CFLAGS -belf"
 941   AC_CACHE_CHECK([whether the C compiler needs -belf], lt_cv_cc_needs_belf,
 942     [AC_TRY_LINK([],[],[lt_cv_cc_needs_belf=yes],[lt_cv_cc_needs_belf=no])])
 943   if test x"$lt_cv_cc_needs_belf" != x"yes"; then
 944     # this is probably gcc 2.8.0, egcs 1.0 or newer; no need for -belf
 945     CFLAGS="$SAVE_CFLAGS"
 946   fi
 947   ;;
 948
 949 ifdef([AC_PROVIDE_AC_LIBTOOL_WIN32_DLL],
 950 [*-*-cygwin* | *-*-mingw*)
 951   AC_CHECK_TOOL(DLLTOOL, dlltool, false)
 952   AC_CHECK_TOOL(AS, as, false)
 953   AC_CHECK_TOOL(OBJDUMP, objdump, false)
 954   ;;
 955 ])
 956 esac
 957 ])
 958
 959 # AC_LIBTOOL_DLOPEN - enable checks for dlopen support
 960 AC_DEFUN(AC_LIBTOOL_DLOPEN, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])])
 961
 962 # AC_LIBTOOL_WIN32_DLL - declare package support for building win32 dll's
 963 AC_DEFUN(AC_LIBTOOL_WIN32_DLL, [AC_BEFORE([$0], [AC_LIBTOOL_SETUP])])
 964
 965 # AC_ENABLE_SHARED - implement the --enable-shared flag
 966 # Usage: AC_ENABLE_SHARED[(DEFAULT)]
 967 #   Where DEFAULT is either `yes' or `no'.  If omitted, it defaults to
 968 #   `yes'.
 969 AC_DEFUN(AC_ENABLE_SHARED, [dnl
 970 define([AC_ENABLE_SHARED_DEFAULT], ifelse($1, no, no, yes))dnl
 971 AC_ARG_ENABLE(shared,
 972 changequote(<<, >>)dnl
 973 <<  --enable-shared[=PKGS]  build shared libraries [default=>>AC_ENABLE_SHARED_DEFAULT],
 974 changequote([, ])dnl
 975 [p=${PACKAGE-default}
 976 case "$enableval" in
 977 yes) enable_shared=yes ;;
 978 no) enable_shared=no ;;
 979 *)
 980   enable_shared=no
 981   # Look at the argument we got.  We use all the common list separators.
 982   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 983   for pkg in $enableval; do
 984     if test "X$pkg" = "X$p"; then
 985       enable_shared=yes
 986     fi
 987   done
 988   IFS="$ac_save_ifs"
 989   ;;
 990 esac],
 991 enable_shared=AC_ENABLE_SHARED_DEFAULT)dnl
 992 ])
 993
 994 # AC_DISABLE_SHARED - set the default shared flag to --disable-shared
 995 AC_DEFUN(AC_DISABLE_SHARED, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
 996 AC_ENABLE_SHARED(no)])
 997
 998 # AC_ENABLE_STATIC - implement the --enable-static flag
 999 # Usage: AC_ENABLE_STATIC[(DEFAULT)]
1000 #   Where DEFAULT is either `yes' or `no'.  If omitted, it defaults to
1001 #   `yes'.
1002 AC_DEFUN(AC_ENABLE_STATIC, [dnl
1003 define([AC_ENABLE_STATIC_DEFAULT], ifelse($1, no, no, yes))dnl
1004 AC_ARG_ENABLE(static,
1005 changequote(<<, >>)dnl
1006 <<  --enable-static[=PKGS]  build static libraries [default=>>AC_ENABLE_STATIC_DEFAULT],
1007 changequote([, ])dnl
1008 [p=${PACKAGE-default}
1009 case "$enableval" in
1010 yes) enable_static=yes ;;
1011 no) enable_static=no ;;
1012 *)
1013   enable_static=no
1014   # Look at the argument we got.  We use all the common list separators.
1015   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
1016   for pkg in $enableval; do
1017     if test "X$pkg" = "X$p"; then
1018       enable_static=yes
1019     fi
1020   done
1021   IFS="$ac_save_ifs"
1022   ;;
1023 esac],
1024 enable_static=AC_ENABLE_STATIC_DEFAULT)dnl
1025 ])
1026
1027 # AC_DISABLE_STATIC - set the default static flag to --disable-static
1028 AC_DEFUN(AC_DISABLE_STATIC, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
1029 AC_ENABLE_STATIC(no)])
1030
1031
1032 # AC_ENABLE_FAST_INSTALL - implement the --enable-fast-install flag
1033 # Usage: AC_ENABLE_FAST_INSTALL[(DEFAULT)]
1034 #   Where DEFAULT is either `yes' or `no'.  If omitted, it defaults to
1035 #   `yes'.
1036 AC_DEFUN(AC_ENABLE_FAST_INSTALL, [dnl
1037 define([AC_ENABLE_FAST_INSTALL_DEFAULT], ifelse($1, no, no, yes))dnl
1038 AC_ARG_ENABLE(fast-install,
1039 changequote(<<, >>)dnl
1040 <<  --enable-fast-install[=PKGS]  optimize for fast installation [default=>>AC_ENABLE_FAST_INSTALL_DEFAULT],
1041 changequote([, ])dnl
1042 [p=${PACKAGE-default}
1043 case "$enableval" in
1044 yes) enable_fast_install=yes ;;
1045 no) enable_fast_install=no ;;
1046 *)
1047   enable_fast_install=no
1048   # Look at the argument we got.  We use all the common list separators.
1049   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
1050   for pkg in $enableval; do
1051     if test "X$pkg" = "X$p"; then
1052       enable_fast_install=yes
1053     fi
1054   done
1055   IFS="$ac_save_ifs"
1056   ;;
1057 esac],
1058 enable_fast_install=AC_ENABLE_FAST_INSTALL_DEFAULT)dnl
1059 ])
1060
1061 # AC_ENABLE_FAST_INSTALL - set the default to --disable-fast-install
1062 AC_DEFUN(AC_DISABLE_FAST_INSTALL, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
1063 AC_ENABLE_FAST_INSTALL(no)])
1064
1065 # AC_PROG_LD - find the path to the GNU or non-GNU linker
1066 AC_DEFUN(AC_PROG_LD,
1067 [AC_ARG_WITH(gnu-ld,
1068 [  --with-gnu-ld           assume the C compiler uses GNU ld [default=no]],
1069 test "$withval" = no || with_gnu_ld=yes, with_gnu_ld=no)
1070 AC_REQUIRE([AC_PROG_CC])dnl
1071 AC_REQUIRE([AC_CANONICAL_HOST])dnl
1072 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
1073 ac_prog=ld
1074 if test "$ac_cv_prog_gcc" = yes; then
1075   # Check if gcc -print-prog-name=ld gives a path.
1076   AC_MSG_CHECKING([for ld used by GCC])
1077   ac_prog=`($CC -print-prog-name=ld) 2>&5`
1078   case "$ac_prog" in
1079     # Accept absolute paths.
1080 changequote(,)dnl
1081     [\\/]* | [A-Za-z]:[\\/]*)
1082       re_direlt='/[^/][^/]*/\.\./'
1083 changequote([,])dnl
1084       # Canonicalize the path of ld
1085       ac_prog=`echo $ac_prog| sed 's%\\\\%/%g'`
1086       while echo $ac_prog | grep "$re_direlt" > /dev/null 2>&1; do
1087         ac_prog=`echo $ac_prog| sed "s%$re_direlt%/%"`
1088       done
1089       test -z "$LD" && LD="$ac_prog"
1090       ;;
1091   "")
1092     # If it fails, then pretend we aren't using GCC.
1093     ac_prog=ld
1094     ;;
1095   *)
1096     # If it is relative, then search for the first ld in PATH.
1097     with_gnu_ld=unknown
1098     ;;
1099   esac
1100 elif test "$with_gnu_ld" = yes; then
1101   AC_MSG_CHECKING([for GNU ld])
1102 else
1103   AC_MSG_CHECKING([for non-GNU ld])
1104 fi
1105 AC_CACHE_VAL(ac_cv_path_LD,
1106 [if test -z "$LD"; then
1107   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR-:}"
1108   for ac_dir in $PATH; do
1109     test -z "$ac_dir" && ac_dir=.
1110     if test -f "$ac_dir/$ac_prog" || test -f "$ac_dir/$ac_prog$ac_exeext"; then
1111       ac_cv_path_LD="$ac_dir/$ac_prog"
1112       # Check to see if the program is GNU ld.  I'd rather use --version,
1113       # but apparently some GNU ld's only accept -v.
1114       # Break only if it was the GNU/non-GNU ld that we prefer.
1115       if "$ac_cv_path_LD" -v 2>&1 < /dev/null | egrep '(GNU|with BFD)' > /dev/null; then
1116         test "$with_gnu_ld" != no && break
1117       else
1118         test "$with_gnu_ld" != yes && break
1119       fi
1120     fi
1121   done
1122   IFS="$ac_save_ifs"
1123 else
1124   ac_cv_path_LD="$LD" # Let the user override the test with a path.
1125 fi])
1126 LD="$ac_cv_path_LD"
1127 if test -n "$LD"; then
1128   AC_MSG_RESULT($LD)
1129 else
1130   AC_MSG_RESULT(no)
1131 fi
1132 test -z "$LD" && AC_MSG_ERROR([no acceptable ld found in \$PATH])
1133 AC_SUBST(LD)
1134 AC_PROG_LD_GNU
1135 ])
1136
1137 AC_DEFUN(AC_PROG_LD_GNU,
1138 [AC_CACHE_CHECK([if the linker ($LD) is GNU ld], ac_cv_prog_gnu_ld,
1139 [# I'd rather use --version here, but apparently some GNU ld's only accept -v.
1140 if $LD -v 2>&1 </dev/null | egrep '(GNU|with BFD)' 1>&5; then
1141   ac_cv_prog_gnu_ld=yes
1142 else
1143   ac_cv_prog_gnu_ld=no
1144 fi])
1145 ])
1146
1147 # AC_PROG_NM - find the path to a BSD-compatible name lister
1148 AC_DEFUN(AC_PROG_NM,
1149 [AC_MSG_CHECKING([for BSD-compatible nm])
1150 AC_CACHE_VAL(ac_cv_path_NM,
1151 [if test -n "$NM"; then
1152   # Let the user override the test.
1153   ac_cv_path_NM="$NM"
1154 else
1155   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR-:}"
1156   for ac_dir in $PATH /usr/ccs/bin /usr/ucb /bin; do
1157     test -z "$ac_dir" && ac_dir=.
1158     if test -f $ac_dir/nm || test -f $ac_dir/nm$ac_exeext ; then
1159       # Check to see if the nm accepts a BSD-compat flag.
1160       # Adding the `sed 1q' prevents false positives on HP-UX, which says:
1161       #   nm: unknown option "B" ignored
1162       if ($ac_dir/nm -B /dev/null 2>&1 | sed '1q'; exit 0) | egrep /dev/null >/dev/null; then
1163         ac_cv_path_NM="$ac_dir/nm -B"
1164         break
1165       elif ($ac_dir/nm -p /dev/null 2>&1 | sed '1q'; exit 0) | egrep /dev/null >/dev/null; then
1166         ac_cv_path_NM="$ac_dir/nm -p"
1167         break
1168       else
1169         ac_cv_path_NM=${ac_cv_path_NM="$ac_dir/nm"} # keep the first match, but
1170         continue # so that we can try to find one that supports BSD flags
1171       fi
1172     fi
1173   done
1174   IFS="$ac_save_ifs"
1175   test -z "$ac_cv_path_NM" && ac_cv_path_NM=nm
1176 fi])
1177 NM="$ac_cv_path_NM"
1178 AC_MSG_RESULT([$NM])
1179 AC_SUBST(NM)
1180 ])
1181
1182 # AC_CHECK_LIBM - check for math library
1183 AC_DEFUN(AC_CHECK_LIBM,
1184 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
1185 LIBM=
1186 case "$host" in
1187 *-*-beos* | *-*-cygwin*)
1188   # These system don't have libm
1189   ;;
1190 *-ncr-sysv4.3*)
1191   AC_CHECK_LIB(mw, _mwvalidcheckl, LIBM="-lmw")
1192   AC_CHECK_LIB(m, main, LIBM="$LIBM -lm")
1193   ;;
1194 *)
1195   AC_CHECK_LIB(m, main, LIBM="-lm")
1196   ;;
1197 esac
1198 ])
1199
1200 # AC_LIBLTDL_CONVENIENCE[(dir)] - sets LIBLTDL to the link flags for
1201 # the libltdl convenience library, adds --enable-ltdl-convenience to
1202 # the configure arguments.  Note that LIBLTDL is not AC_SUBSTed, nor
1203 # is AC_CONFIG_SUBDIRS called.  If DIR is not provided, it is assumed
1204 # to be `${top_builddir}/libltdl'.  Make sure you start DIR with
1205 # '${top_builddir}/' (note the single quotes!) if your package is not
1206 # flat, and, if you're not using automake, define top_builddir as
1207 # appropriate in the Makefiles.
1208 AC_DEFUN(AC_LIBLTDL_CONVENIENCE, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
1209   case "$enable_ltdl_convenience" in
1210   no) AC_MSG_ERROR([this package needs a convenience libltdl]) ;;
1211   "") enable_ltdl_convenience=yes
1212       ac_configure_args="$ac_configure_args --enable-ltdl-convenience" ;;
1213   esac
1214   LIBLTDL=ifelse($#,1,$1,['${top_builddir}/libltdl'])/libltdlc.la
1215   INCLTDL=ifelse($#,1,-I$1,['-I${top_builddir}/libltdl'])
1216 ])
1217
1218 # AC_LIBLTDL_INSTALLABLE[(dir)] - sets LIBLTDL to the link flags for
1219 # the libltdl installable library, and adds --enable-ltdl-install to
1220 # the configure arguments.  Note that LIBLTDL is not AC_SUBSTed, nor
1221 # is AC_CONFIG_SUBDIRS called.  If DIR is not provided, it is assumed
1222 # to be `${top_builddir}/libltdl'.  Make sure you start DIR with
1223 # '${top_builddir}/' (note the single quotes!) if your package is not
1224 # flat, and, if you're not using automake, define top_builddir as
1225 # appropriate in the Makefiles.
1226 # In the future, this macro may have to be called after AC_PROG_LIBTOOL.
1227 AC_DEFUN(AC_LIBLTDL_INSTALLABLE, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
1228   AC_CHECK_LIB(ltdl, main,
1229   [test x"$enable_ltdl_install" != xyes && enable_ltdl_install=no],
1230   [if test x"$enable_ltdl_install" = xno; then
1231      AC_MSG_WARN([libltdl not installed, but installation disabled])
1232    else
1233      enable_ltdl_install=yes
1234    fi
1235   ])
1236   if test x"$enable_ltdl_install" = x"yes"; then
1237     ac_configure_args="$ac_configure_args --enable-ltdl-install"
1238     LIBLTDL=ifelse($#,1,$1,['${top_builddir}/libltdl'])/libltdl.la
1239     INCLTDL=ifelse($#,1,-I$1,['-I${top_builddir}/libltdl'])
1240   else
1241     ac_configure_args="$ac_configure_args --enable-ltdl-install=no"
1242     LIBLTDL="-lltdl"
1243     INCLTDL=
1244   fi
1245 ])
1246
1247 dnl old names
1248 AC_DEFUN(AM_PROG_LIBTOOL, [indir([AC_PROG_LIBTOOL])])dnl
1249 AC_DEFUN(AM_ENABLE_SHARED, [indir([AC_ENABLE_SHARED], $@)])dnl
1250 AC_DEFUN(AM_ENABLE_STATIC, [indir([AC_ENABLE_STATIC], $@)])dnl
1251 AC_DEFUN(AM_DISABLE_SHARED, [indir([AC_DISABLE_SHARED], $@)])dnl
1252 AC_DEFUN(AM_DISABLE_STATIC, [indir([AC_DISABLE_STATIC], $@)])dnl
1253 AC_DEFUN(AM_PROG_LD, [indir([AC_PROG_LD])])dnl
1254 AC_DEFUN(AM_PROG_NM, [indir([AC_PROG_NM])])dnl
1255
1256 dnl This is just to silence aclocal about the macro not being used
1257 ifelse([AC_DISABLE_FAST_INSTALL])dnl