acinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4
   5
   6 dnl Usage LYX_GET_VERSION   Sets "lyx_version" to the version of LyX being
   7 dnl   built, displays it and sets variable "lyx_devel" to yes or no depending
   8 dnl   whether the version is a development release or not.
   9 AC_DEFUN(LYX_GET_VERSION,[
  10 changequote(, ) dnl
  11 VERSION=`grep '#define *LYX_VERSION' $1 |
  12               sed -e 's/^.*"\(.*\)"$/\1/' 2>/dev/null`
  13 echo "configuring LyX version $VERSION"
  14 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  15   lyx_devel_version=yes
  16   echo "WARNING: This is a development version. Expect bugs."
  17 else
  18   lyx_devel_version=no
  19 fi
  20 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  21     lyx_prerelease=yes
  22     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  23 else
  24     lyx_prerelease=no
  25 fi
  26 changequote([, ]) dnl
  27 PACKAGE=lyx${program_suffix}
  28 AC_SUBST(lyx_devel_version)
  29 if test $lyx_devel_version = yes ; then
  30   AC_DEFINE(DEVEL_VERSION, 1, Define if you are building a development version of LyX)
  31 fi])
  32
  33 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  34 dnl flag lyx_error to yes.
  35 AC_DEFUN(LYX_ERROR,[
  36 lyx_error_txt="$lyx_error_txt
  37 ** $1
  38 "
  39 lyx_error=yes])
  40
  41
  42 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  43 dnl flag lyx_warning to yes.
  44 AC_DEFUN(LYX_WARNING,[
  45 lyx_warning_txt="$lyx_warning_txt
  46 == $1
  47 "
  48 lyx_warning=yes])
  49
  50
  51 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  52 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  53 AC_DEFUN(LYX_LIB_ERROR,[
  54 LYX_ERROR([Cannot find $1. Please check that the $2 library
  55    is correctly installed on your system.])])
  56
  57
  58 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  59 dnl   has occured previously.
  60 AC_DEFUN(LYX_CHECK_ERRORS,[
  61 if test x$lyx_error = xyes; then
  62 cat <<EOF
  63 **** The following problems have been detected by configure.
  64 **** Please check the messages below before running 'make'.
  65 **** (see the section 'Problems' in the INSTALL file)
  66 $lyx_error_txt
  67 $lyx_warning_txt
  68 deleting cache $cache_file
  69 EOF
  70   rm -f $cache_file
  71 else
  72
  73 if test x$lyx_warning = xyes; then
  74 cat <<EOF
  75 === The following minor problems have been detected by configure.
  76 === Please check the messages below before running 'make'.
  77 === (see the section 'Problems' in the INSTALL file)
  78 $lyx_warning_txt
  79 EOF
  80 fi
  81 cat <<EOF
  82 Configuration of LyX was successful.
  83 Type 'make' to compile the program,
  84 and then 'make install' to install it.
  85 EOF
  86 fi])
  87
  88
  89 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
  90 dnl
  91 define(LYX_SEARCH_PROG,[dnl
  92 for ac_prog in $2 ; do
  93 # Extract the first word of "$ac_prog", so it can be a program name with args.
  94   set dummy $ac_prog ; ac_word=$[2]
  95   if test -z "[$]$1"; then
  96     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
  97     for ac_dir in $PATH; do
  98       test -z "$ac_dir" && ac_dir=.
  99       if test -f [$ac_dir/$ac_word]; then
 100         $1="$ac_prog"
 101         break
 102       fi
 103     done
 104     IFS="$ac_save_ifs"
 105   fi
 106
 107   if test -n "[$]$1"; then
 108     ac_result=yes
 109   else
 110     ac_result=no
 111   fi
 112   ifelse($3,,,[$3])
 113   test -n "[$]$1" && break
 114 done
 115 ])dnl
 116
 117
 118 AC_DEFUN(LYX_PROG_CXX_WORKS,
 119 [AC_LANG_SAVE
 120 AC_LANG_CPLUSPLUS
 121 AC_TRY_COMPILER([class foo { int bar; }; int main(){return(0);}], ac_cv_prog_cxx_works, ac_cv_prog_cxx_cross)
 122 AC_LANG_RESTORE
 123 if test $ac_cv_prog_cxx_works = no; then
 124   CXX=
 125 fi
 126 cross_compiling=$ac_cv_prog_cxx_cross
 127 ])
 128
 129
 130 AC_DEFUN(LYX_PROG_CXX,
 131 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 132 AC_MSG_CHECKING([for a working C++ compiler])
 133 LYX_SEARCH_PROG(CXX, $CCC g++ gcc c++ CC cxx xlC cc++, LYX_PROG_CXX_WORKS)
 134
 135 if test -z "$CXX" ; then
 136   AC_ERROR([Unable to find a working C++ compiler])
 137 fi
 138
 139 AC_SUBST(CXX)
 140 AC_MSG_RESULT($CXX)
 141
 142 AC_MSG_CHECKING([whether the C++ compiler ($CXX $CXXFLAGS $LDFLAGS) is a cross-compiler])
 143 AC_MSG_RESULT($cross_compiling)
 144
 145 AC_PROG_CXX_GNU
 146
 147 dnl We might want to get or shut warnings.
 148 AC_ARG_WITH(warnings,
 149   [  --with-warnings         tell GNU C++ to display more warnings],,
 150   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 151         with_warnings=yes;
 152     else
 153         with_warnings=no;
 154     fi;])
 155 if test x$with_warnings = xyes ; then
 156   lyx_flags="$lyx_flags warnings"
 157   AC_DEFINE(WITH_WARNINGS, 1,
 158   [Define this if you want to see the warning directives put here and
 159    there by the developpers to get attention])
 160 fi
 161
 162 # optimize less for development versions
 163 if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 164   lyx_opt="-O"
 165 else
 166   lyx_opt="-O2"
 167 fi
 168
 169 # set the debug flags correctly.
 170 if test $ac_cv_prog_gxx = yes; then
 171   GXX=yes
 172 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 173 dnl plays around with CXXFLAGS (such as to build both debugging and
 174 dnl normal versions of a library), tasteless as that idea is.
 175   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 176   ac_save_CXXFLAGS="$CXXFLAGS"
 177   CXXFLAGS=
 178 dnl Check the version of g++
 179   gxx_version=`g++ --version`
 180
 181   AC_PROG_CXX_G
 182   if test "$ac_test_CXXFLAGS" = set; then
 183     CXXFLAGS="$ac_save_CXXFLAGS"
 184   elif test $ac_cv_prog_cxx_g = yes; then
 185     case $gxx_version in
 186       2.7*) CXXFLAGS="$lyx_opt";;
 187       *)    CXXFLAGS="-g $lyx_opt -fno-exceptions -fno-rtti";;
 188     esac
 189   else
 190     CXXFLAGS="$lyx_opt"
 191   fi
 192   if test x$with_warnings = xyes ; then
 193     CXXFLAGS="$CXXFLAGS -ansi -Wall"
 194     if test $lyx_devel_version = yes ; then
 195         CXXFLAGS="$CXXFLAGS -pedantic"
 196     fi
 197   fi
 198 else
 199   GXX=
 200   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 201 fi
 202 ])dnl
 203
 204
 205 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 206 dnl   supports RTTI
 207 AC_DEFUN(LYX_CXX_RTTI,[
 208 ### Check whether the compiler supports runtime type information
 209 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 210  [AC_TRY_RUN([
 211 class rtti {
 212 public:
 213    virtual int tag() { return 0; }
 214 };
 215 class derived1 : public rtti {
 216 public:
 217     int tag() { return 1; }
 218 };
 219 class derived2 : public rtti {
 220 public:
 221     int tag() { return 2; }
 222 };
 223 int main() {
 224     derived1 * foo1 = new derived1();
 225     derived2 * foo2 = new derived2();
 226     rtti * bar = foo1;
 227     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 228     if (bar1 == 0)
 229         exit(1);
 230     bar = foo2;
 231     bar1 = dynamic_cast<derived1 *>(bar);
 232     if (bar1 != 0)
 233         exit(1);
 234     return 0;
 235 }
 236 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 237 ])
 238 if test x$lyx_cv_rtti = xyes ; then
 239   AC_DEFINE(HAVE_RTTI, 1,
 240    [Define to 1 if your compiler supports runtime type information])
 241 fi])
 242
 243
 244 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 245 dnl   understands the "explicit" directive.
 246 AC_DEFUN(LYX_CXX_EXPLICIT,[
 247 ### Check whether the compiler understands the keyword `explicit'
 248 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 249  [AC_TRY_COMPILE([
 250 class Expl {
 251 public:
 252         explicit Expl() {};
 253 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 254 ])
 255 if test $lyx_cv_explicit = no ; then
 256   AC_DEFINE(explicit,[ ],
 257    [Define to nothing if your compiler does not understand the
 258    'explicit' directive])
 259 fi])
 260
 261
 262 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 263 dnl   has a working stl stack template
 264 AC_DEFUN(LYX_CXX_STL_STACK,[
 265 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 266  [AC_TRY_COMPILE([
 267 #include <stack>
 268 using std::stack;
 269 ],[
 270     stack<int> stakk;
 271     stakk.push(0);
 272 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 273 ])
 274 if test $lyx_cv_broken_stack = yes ; then
 275   AC_DEFINE(BROKEN_STL_STACK, 1,
 276    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 277    correctly])
 278 fi])
 279
 280
 281 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 282 dnl   supports modern STL streams
 283 AC_DEFUN(LYX_CXX_STL_MODERN_STREAMS,[
 284 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 285  [AC_TRY_COMPILE([
 286 #include <fstream>
 287 ],[
 288  std::streambuf * test = std::cerr.rdbuf();
 289  test->pubsync();
 290 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 291 ])
 292 if test $lyx_cv_modern_streams = yes ; then
 293   AC_DEFINE(MODERN_STL_STREAMS, 1,
 294    [Define if you have modern standard-compliant STL streams])
 295 fi])
 296
 297
 298 dnl Usage: LYX_CXX_STL_STRING : checks whether the C++ compiler
 299 dnl   has a working stl string container, the check is really stupid
 300 dnl   and could need some improvement.
 301 AC_DEFUN(LYX_CXX_STL_STRING,[
 302     AC_REQUIRE([LYX_PROG_CXX])
 303     AC_MSG_CHECKING(whether the included std::string should be used)
 304     AC_ARG_WITH(included-string,[
 305         --with-included-string  use LyX string class instead of STL string
 306     ],[
 307         with_included_string=$withval
 308     ],[
 309         AC_TRY_COMPILE([
 310             #include <string>
 311             using std::string;
 312         ],[
 313             string a("hello there");
 314             a.clear();
 315             a = "hey";
 316             a.erase();
 317         ],[
 318             with_included_string=no
 319         ],[
 320             with_included_string=yes
 321
 322         ])
 323     ])
 324     if test x$with_included_string = xyes ; then
 325         AC_DEFINE(USE_INCLUDED_STRING, 1,
 326             [Define to use the lyxstring class bundled with LyX.])
 327             lyx_flags="$lyx_flags included-string"
 328     fi
 329     AM_CONDITIONAL(USE_LYXSTRING, test x$with_included_string = xyes)
 330     AC_MSG_RESULT([$with_included_string])
 331 ])
 332
 333
 334 dnl LYX_CXX_MUTABLE
 335 AC_DEFUN(LYX_CXX_MUTABLE, [
 336 AC_REQUIRE([LYX_PROG_CXX])
 337 AC_MSG_CHECKING(if C++ compiler supports mutable)
 338 AC_TRY_COMPILE(
 339 [
 340 class k {
 341         mutable char *c;
 342 public:
 343    void foo() const { c=0; }
 344 };
 345 ],[
 346 ],[
 347   ac_mutable=yes
 348   AC_DEFINE(HAVE_MUTABLE, 1,
 349    [Defined if you compiler supports 'mutable'.])
 350 ],[
 351   ac_mutable=no
 352 ])
 353 AC_MSG_RESULT([$ac_mutable])
 354 ])
 355
 356
 357 dnl LYX_CXX_PARTIAL
 358 AC_DEFUN(LYX_CXX_PARTIAL, [
 359 AC_REQUIRE([LYX_PROG_CXX])
 360 AC_MSG_CHECKING(if C++ compiler supports partial specialization)
 361 AC_TRY_COMPILE(
 362 [
 363 template<class T, class K>
 364 class k {
 365 public:
 366 };
 367 template<class T> class k<void,T> { };
 368 ],[
 369   k<float, float> b;
 370   k<void,void> a;
 371 ],[
 372   ac_partial_specialization=yes
 373   AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 374    [Defined if your compiler supports partial specialization.])
 375 ],[
 376   ac_partial_specialization=no
 377 ])
 378 AC_MSG_RESULT([$ac_partial_specialization])
 379 ])
 380
 381
 382 dnl Usage: LYX_CXX_NAMESPACES : checks whether the C++ compiler
 383 dnl   has a correct namespace handling and define CXX_WORKING_NAMESPACES
 384 dnl   if true. This macro does not do a thourough test, but it should be
 385 dnl   good enough to suit our needs.
 386 AC_DEFUN(LYX_CXX_NAMESPACES,[
 387 AC_CACHE_CHECK(for correct namespaces support,lyx_cv_cxx_namespace,
 388  [AC_TRY_COMPILE([
 389   #include <vector>
 390   using std::vector;
 391 ],[
 392         vector<int> test;
 393         return 0;
 394 ],lyx_cv_cxx_namespace=yes,lyx_cv_cxx_namespace=no)
 395 ])
 396 if test $lyx_cv_cxx_namespace = yes ; then
 397   AC_DEFINE(CXX_WORKING_NAMESPACES, 1,
 398    [Define if your C++ compiler has correct support for namespaces])
 399 fi])
 400
 401
 402 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 403 dnl   provides wrappers for C headers and use our alternate version otherwise.
 404 AC_DEFUN(LYX_CXX_CHEADERS,[
 405 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 406  [AC_TRY_CPP([
 407 #include <clocale>
 408 #include <cctype>
 409 #include <cerrno>
 410 #include <cmath>
 411 #include <csignal>
 412 #include <cstdio>
 413 #include <cstdlib>
 414 #include <cstring>
 415 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 416 if test $lyx_cv_cxx_cheaders = no ; then
 417   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 418 fi])
 419
 420
 421 dnl Usage LYX_PATH_XPM: Checks for xpm library and header
 422 AC_DEFUN(LYX_PATH_XPM,[
 423 ### Check for Xpm library
 424 AC_CHECK_LIB(Xpm, XpmCreateBufferFromImage,LYX_LIBS="-lXpm $LYX_LIBS",
 425         [LYX_LIB_ERROR(libXpm,Xpm)], $LYX_LIBS)
 426
 427 ### Check for Xpm headers
 428 lyx_cv_xpm_h_location="<xpm.h>"
 429 AC_CHECK_HEADER(X11/xpm.h,[
 430   ac_cv_header_xpm_h=yes
 431   lyx_cv_xpm_h_location="<X11/xpm.h>"],[
 432 AC_CHECK_HEADER(xpm.h,[],[
 433 LYX_LIB_ERROR(xpm.h,Xpm)])])
 434 AC_DEFINE_UNQUOTED(XPM_H_LOCATION,$lyx_cv_xpm_h_location)
 435
 436 ### Test for the header version
 437 if test $ac_cv_header_xpm_h = yes; then
 438   AC_CACHE_CHECK([xpm header version],lyx_cv_xpmversion,
 439   [ cat > conftest.$ac_ext <<EOF
 440 #line __oline__ "configure"
 441 #include "confdefs.h"
 442
 443 #include XPM_H_LOCATION
 444 "%%%"lyx_cv_xpmv=XpmVersion;lyx_cv_xpmr=XpmRevision"%%%"
 445 EOF
 446     eval `(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 447       grep '^"%%%"'  2>/dev/null | \
 448       sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 449     case "$lyx_cv_xpmr" in
 450 changequote(,)
 451      [0-9]) lyxxpmr_alpha=`echo $lyx_cv_xpmr |tr 123456789 abcdefghi`
 452             lyxxpmv_alpha=" (aka 3.$lyx_cv_xpmv$lyxxpmr_alpha)";;
 453 changequote([,])
 454          *) ;;
 455     esac
 456     lyx_cv_xpmversion="$lyx_cv_xpmv.$lyx_cv_xpmr$lyxxpmv_alpha"
 457     rm -f conftest*])
 458   case "$lyx_cv_xpmr" in
 459 changequote(,)
 460         [789]|[0-9][0-9]*) ;;
 461 changequote([,])
 462         *) LYX_WARNING([Version $lyx_cv_xpmversion of the Xpm library is a bit old.
 463    If you experience strange crashes with LyX, try to upgrade
 464    to at least version 4.7 (aka 3.4g).
 465    If you have installed a newer version of the library, check whether you
 466    have an old xpm.h header file in your include path.]);;
 467   esac
 468 fi])
 469
 470
 471 dnl Usage LYX_PATH_XFORMS: Checks for xforms library and flags
 472 AC_DEFUN(LYX_PATH_XFORMS,[
 473 ### Check for xforms library
 474 AC_CHECK_LIB(forms, fl_initialize, LYX_LIBS="-lforms $LYX_LIBS",
 475   [AC_CHECK_LIB(xforms, fl_initialize, LYX_LIBS="-lxforms $LYX_LIBS",
 476     [LYX_LIB_ERROR(libforms or libxforms,xforms)], $LYX_LIBS)], $LYX_LIBS)
 477
 478 ### Check for xforms headers
 479 lyx_cv_forms_h_location="<forms.h>"
 480 AC_CHECK_HEADER(X11/forms.h,[
 481   ac_cv_header_forms_h=yes
 482   lyx_cv_forms_h_location="<X11/forms.h>"],[
 483 AC_CHECK_HEADER(forms.h,[],[
 484 LYX_LIB_ERROR(forms.h,forms)])])
 485 AC_DEFINE_UNQUOTED(FORMS_H_LOCATION,$lyx_cv_forms_h_location)
 486 if test $ac_cv_header_forms_h = yes; then
 487   AC_CACHE_CHECK([xforms header version],lyx_cv_xfversion,
 488   [ cat > conftest.$ac_ext <<EOF
 489 #line __oline__ "configure"
 490 #include "confdefs.h"
 491
 492 #include FORMS_H_LOCATION
 493 #if ! defined(FL_INCLUDE_VERSION)
 494 "%%%"(unknown)"%%%"
 495 #else
 496 "%%%"FL_VERSION.FL_REVISION"%%%"
 497 #endif
 498 EOF
 499 lyx_cv_xfversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 500   grep '^"%%%"'  2>/dev/null | \
 501   sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 502 rm -f conftest*])
 503 case "$lyx_cv_xfversion" in
 504   "(unknown)"|0.82|0.83|0.84|0.85)
 505      LYX_ERROR(dnl
 506 Version $lyx_cv_xfversion of xforms is not compatible with LyX.
 507    This version of LyX works best with version 0.88[,] although it
 508    supports also versions 0.81[,] 0.86 and 0.87.) ;;
 509   0.81|0.86|0.87)
 510      LYX_WARNING(dnl
 511 While LyX is compatible with version $lyx_cv_xfversion of xforms[,]
 512    it is recommended that you upgrade to version 0.88.) ;;
 513      0.88) ;;
 514      0.89) LYX_WARNING(dnl
 515 LyX should work ok with version $lyx_cv_xfversion of xforms[,] but
 516 it is an unproven version and might still have some bugs. If you
 517 have problems[,] please use version 0.88 instead.) ;;
 518           *) LYX_WARNING(dnl
 519 Version $lyx_cv_xfversion of xforms might not be compatible with LyX[,]
 520    since it is newer than 0.88. You might have slight problems with it.);;
 521 esac
 522 fi])
 523
 524
 525 dnl Usage: LYX_HPUX  Checks for HP-UX and update CXXFLAGS accordingly
 526 AC_DEFUN(LYX_HPUX,
 527 [#It seems that HPUX requires using -fpcc-struct-return with gcc.
 528 AC_CACHE_CHECK(for HP-UX,ac_cv_hpux,[
 529 os=`uname -s | tr '[A-Z]' '[a-z]'`
 530 ac_cv_hpux=no
 531 test "$os" = hp-ux && ac_cv_hpux=yes])
 532 if test "$ac_cv_hpux" = yes; then
 533  test "x$GXX" = xyes && CXXFLAGS="$CXXFLAGS -fpcc-struct-return"
 534 fi])
 535
 536
 537 dnl Usage: LYX_SUNOS4 Checks for SunOS 4.x and sets the flag lyx_broken_headers
 538 dnl   if necessary
 539 AC_DEFUN(LYX_SUNOS4,
 540 [#The headers are not correct under SunOS4
 541 AC_CACHE_CHECK(for SunOS 4.x,ac_cv_sunos4,[
 542 changequote(, ) dnl
 543 os=`uname -a | sed -e 's/^\([^ ]*\) [^ ]* \([0-9]\)\..*/\1\2/'`
 544 changequote([, ]) dnl
 545 ac_cv_sunos4=no
 546 test "$os" = SunOS4 && ac_cv_sunos4=yes])
 547 if test "$ac_cv_sunos4" = yes; then
 548  test "x$GXX" = xyes && lyx_broken_headers=yes
 549 fi])
 550
 551
 552 dnl Usage: LYX_SCO Checks for SCO and sets the flag lyx_broken_headers
 553 dnl   if necessary
 554 AC_DEFUN(LYX_SCO,
 555 [AC_CACHE_CHECK(for SCO 3.2v4,ac_cv_sco,[
 556 ac_cv_sco=no
 557 if test `uname -s` != "SCO_SV"; then
 558   lyx_machine_rel=`uname -m`:`uname -r`
 559   if test $lyx_machine_rel = i386:3.2 || test $lyx_machine_rel = i486:3.2;
 560   then
 561     if test -f /usr/options/cb.name; then
 562       ac_cv_sco=no
 563     elif /bin/uname -X 2>/dev/null >/dev/null ; then
 564       ac_cv_sco=yes
 565     fi
 566   fi
 567 fi])
 568 if test "$ac_cv_sco" = yes; then
 569  test "x$GXX" = xyes && lyx_broken_headers=yes
 570 fi])
 571
 572
 573 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 574 dnl                       [default-yes-value])
 575 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 576 dnl  resulting directory name in 'dir-var-name'.
 577 AC_DEFUN(LYX_WITH_DIR,[
 578   AC_ARG_WITH($1,[  --with-$1     specify $2])
 579   AC_MSG_CHECKING([for $2])
 580   if test -z "$with_$3"; then
 581      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 582   else
 583     test "x$with_$3" = xyes && with_$3=$5
 584     lyx_cv_$3="$with_$3"
 585   fi
 586   AC_MSG_RESULT($lyx_cv_$3)])
 587
 588
 589 dnl Usage: LYX_LOOP_DIR(value,action)
 590 dnl Executes action for values of variable `dir' in `values'. `values' can
 591 dnl use ":" as a separator.
 592 AC_DEFUN(LYX_LOOP_DIR,[
 593 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 594 for dir in `eval "echo $1"`; do
 595   if test ! "$dir" = NONE; then
 596     test ! -d "$dir" && AC_ERROR([\"$dir\" is not a directory])
 597     $2
 598   fi
 599 done
 600 IFS=$ac_save_ifs
 601 ])
 602
 603
 604 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 605 dnl var-name.
 606 AC_DEFUN(LYX_ADD_LIB_DIR,[
 607 $1="${$1} -L$2"
 608 if test "`(uname) 2>/dev/null`" = SunOS &&
 609     uname -r | grep '^5' >/dev/null; then
 610   if test $ac_cv_prog_gxx = yes ; then
 611     $1="${$1} -Wl[,]-R$2"
 612   else
 613     $1="${$1} -R$2"
 614   fi
 615 fi])
 616
 617
 618 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 619 dnl var-name.
 620 AC_DEFUN(LYX_ADD_INC_DIR,[$1="${$1} -I$2 "])
 621
 622
 623 dnl AC_VALIDATE_CACHE_SYSTEM_TYPE[(cmd)]
 624 dnl if the cache file is inconsistent with the current host,
 625 dnl target and build system types, execute CMD or print a default
 626 dnl error message.
 627 AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE, [
 628     AC_REQUIRE([AC_CANONICAL_SYSTEM])
 629     AC_MSG_CHECKING([config.cache system type])
 630     if { test x"${ac_cv_host_system_type+set}" = x"set" &&
 631          test x"$ac_cv_host_system_type" != x"$host"; } ||
 632        { test x"${ac_cv_build_system_type+set}" = x"set" &&
 633          test x"$ac_cv_build_system_type" != x"$build"; } ||
 634        { test x"${ac_cv_target_system_type+set}" = x"set" &&
 635          test x"$ac_cv_target_system_type" != x"$target"; }; then
 636         AC_MSG_RESULT([different])
 637         ifelse($#, 1, [$1],
 638                 [AC_MSG_ERROR(["you must remove config.cache and restart configure"])])
 639     else
 640         AC_MSG_RESULT([same])
 641     fi
 642     ac_cv_host_system_type="$host"
 643     ac_cv_build_system_type="$build"
 644     ac_cv_target_system_type="$target"
 645 ])
 646
 647
 648 dnl We use this until autoconf fixes its version.
 649 AC_DEFUN(LYX_FUNC_SELECT_ARGTYPES,
 650 [AC_MSG_CHECKING([types of arguments for select()])
 651  AC_CACHE_VAL(ac_cv_func_select_arg234,dnl
 652  [AC_CACHE_VAL(ac_cv_func_select_arg1,dnl
 653   [AC_CACHE_VAL(ac_cv_func_select_arg5,dnl
 654    [for ac_cv_func_select_arg234 in 'fd_set *' 'int *' 'void *'; do
 655      for ac_cv_func_select_arg1 in 'int' 'size_t' 'unsigned long' 'unsigned'; do      for ac_cv_func_select_arg5 in 'struct timeval *' 'const struct timeval *'; do
 656        AC_TRY_COMPILE(dnl
 657 [#ifdef HAVE_SYS_TYPES_H
 658 #include <sys/types.h>
 659 #endif
 660 #ifdef HAVE_SYS_TIME_H
 661 #include <sys/time.h>
 662 #endif
 663 #ifdef HAVE_SYS_SELECT_H
 664 #include <sys/select.h>
 665 #endif
 666 #ifdef HAVE_SYS_SOCKET_H
 667 #include <sys/socket.h>
 668 #endif
 669 extern int select ($ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5);],,dnl
 670         [ac_not_found=no ; break 3],ac_not_found=yes)
 671       done
 672      done
 673     done
 674    ])dnl AC_CACHE_VAL
 675   ])dnl AC_CACHE_VAL
 676  ])dnl AC_CACHE_VAL
 677  if test "$ac_not_found" = yes; then
 678   ac_cv_func_select_arg1=int
 679   ac_cv_func_select_arg234='int *'
 680   ac_cv_func_select_arg5='struct timeval *'
 681  fi
 682  AC_MSG_RESULT([$ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5])
 683  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG1,$ac_cv_func_select_arg1)
 684  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG234,($ac_cv_func_select_arg234))
 685  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG5,($ac_cv_func_select_arg5))
 686 ])