CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 if(UNIX)
  46         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  47         if(DPKG_ARCHITECTURE_EXECUTABLE)
  48                 EXECUTE_PROCESS(COMMAND dpkg-architecture -qDEB_HOST_MULTIARCH OUTPUT_VARIABLE ARCH_TRIPLET OUTPUT_STRIP_TRAILING_WHITESPACE)
  49         endif()
  50 endif()
  51 if(ARCH_TRIPLET)
  52         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  53 else()
  54         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  55 endif()
  56
  57 include(LyXMacros)
  58
  59 # Usage LYX_OPTION
  60 # 1. parameter: option name without prefix 'LYX_'
  61 # 2. parameter: description
  62 # 3. parameter: default value, ON or OFF
  63 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  64
  65
  66 LYX_OPTION_INIT()
  67
  68 # Options for all compilers/systems
  69 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  70 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  71 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  72 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  73 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  74 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  75 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  76 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  77 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  78 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  79 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  80 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  81 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  82 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  83 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  84 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  85 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  86 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  87
  88 # GCC specific
  89 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  90 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  91 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  92 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  93 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  94 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  95 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
  96
  97 # MSVC specific
  98 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
  99 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 100 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 101 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 102 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 103
 104 # APPLE specific
 105 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 106 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 107
 108
 109 if(help OR HELP)
 110         message(STATUS)
 111         message(STATUS "Available options: (dis/enable with -D=0/1)")
 112         message(STATUS)
 113         LYX_OPTION_LIST_ALL(help)
 114         message(STATUS)
 115 else()
 116
 117 # Check option dependencies
 118
 119 if(LYX_CPACK)
 120         set(LYX_INSTALL ON)
 121 endif()
 122
 123 if(LYX_DMG)
 124         set(LYX_BUNDLE ON)
 125         set(LYX_CPACK ON)
 126 endif()
 127
 128 if(LYX_INSTALL)
 129         set(LYX_NLS ON)
 130         if (WIN32)
 131                 set(LYX_HUNSPELL ON)
 132         endif()
 133         set(LYX_CONSOLE OFF)
 134         set(LYX_PACKAGE_SUFFIX ON)
 135         set(LYX_RELEASE ON)
 136         set(LYX_PROFILE OFF)
 137 endif()
 138
 139
 140 if(LYX_MERGE_FILES)
 141         set(LYX_PCH OFF)
 142 else()
 143         set(LYX_MERGE_REBUILD OFF)
 144 endif()
 145
 146 if(LYX_DEPENDENCIES_DOWNLOAD)
 147         message(STATUS)
 148         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 149         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 150         set(deps_files lyx20-deps-msvc2010-x86.zip)
 151         foreach(it ${deps_files})
 152                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 153                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 154                 if(NOT already_downloaded)
 155                         message(STATUS "Downloading ${it} ...")
 156                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 157                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 158                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 159                 endif()
 160         endforeach()
 161         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 162 endif()
 163
 164
 165
 166 message(STATUS)
 167
 168 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 169 if(WIN32)
 170         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 171 else()
 172         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 173 endif()
 174
 175
 176 if(UNIX OR MINGW)
 177         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 178         message(STATUS "Using GCC version ${GCC_VERSION}")
 179         if(NOT GCC_VERSION VERSION_LESS 4.4)
 180                 set(LYX_USE_TR1 1)
 181                 # GCC <= 4.5 does not support regex: there are linker errors
 182                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 183                 set(LYX_USE_TR1_REGEX 0)
 184         endif()
 185 else()
 186         if(MSVC10)
 187                 set(LYX_USE_TR1 1)
 188                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 189         endif()
 190 endif()
 191
 192
 193 set(VERSION_INFO "CMake Build")
 194
 195 # Try to get some informations from configure.ac
 196
 197 include(LyXPaths)
 198 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 199
 200 if(WIN32)
 201         set(USE_WINDOWS_PACKAGING 1)
 202 elseif(APPLE)
 203         set(USE_MACOSX_PACKAGING 1)
 204 else()
 205         set(USE_POSIX_PACKAGING 1)
 206 endif()
 207
 208 macro(setstripped _varname _value)
 209         string(STRIP ${_value} _v)
 210         if(USE_POSIX_PACKAGING)
 211                 string(TOLOWER ${_v} ${_varname})
 212         else()
 213                 set(${_varname} ${_v})
 214         endif()
 215 endmacro(setstripped)
 216
 217 foreach(_c_l ${_config_lines} )
 218         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 219                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 220                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 221                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 222                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 223                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 224                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 225                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 226                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 227                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 228                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 229                 endif()
 230         endif()
 231         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 232                 set(LYX_DATE "${CMAKE_MATCH_1}")
 233         endif()
 234 endforeach(_c_l)
 235
 236 # Find the revision number and for later use
 237 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 238 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 239 if(LYX_SVNVERSION)
 240         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 241         # We use this value also to set the package-patch-value
 242         if(LYX_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 243                 set(LYX_REVISION_VERSION ${CMAKE_MATCH_1})
 244         endif()
 245 else()
 246         set(LYX_REVISION_VERSION svn) #TODO use date
 247 endif()
 248
 249
 250 if(LYX_PROGRAM_SUFFIX)
 251         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 252 else()
 253         set(PROGRAM_SUFFIX "")
 254 endif()
 255
 256
 257 if(LYX_BUNDLE)
 258         set(LYX_CPACK ON)
 259         message(STATUS)
 260         message(STATUS "Bundle creation is enabled (experimental):")
 261         message(STATUS "    make")
 262         message(STATUS "    make install/strip")
 263         message(STATUS "    make package")
 264         if(APPLE)
 265                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 266                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 267                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 268                 if(NOT LYX_INSTALL_PREFIX)
 269                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 270                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 271                 endif()
 272         elseif(UNIX)
 273                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 274                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 275                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 276         elseif(WIN32)
 277                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 278         endif()
 279 endif()
 280
 281 if(LYX_INSTALL_PREFIX)
 282         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 283         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 284 endif()
 285 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 286
 287 if(LYX_PACKAGE_SUFFIX)
 288         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 289 else()
 290         set(PACKAGE ${PACKAGE_BASE})
 291 endif()
 292
 293
 294 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 295         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 296         if (UNIX)
 297                 # don't use the default "/usr/local"
 298                 # but respect the user-choice on the command-line
 299                 if(LYX_INSTALL_SUFFIX)
 300                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 301                 else()
 302                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 303                 endif()
 304         endif()
 305         if(WIN32)
 306                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 307         endif()
 308 endif()
 309 if(IS_ABSOLUTE)
 310         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 311 else()
 312         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 313 endif()
 314
 315
 316
 317 if(NOT LYX_DATA_SUBDIR)
 318         if (WIN32)
 319                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 320         else()
 321                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 322         endif()
 323 endif()
 324
 325 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 326 set(LYX_LOCALEDIR "locale")
 327 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 328 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 329
 330
 331 if(LYX_INSTALL AND WIN32)
 332         message(STATUS "Configuring NSIS files")
 333         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 334         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 335         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 336         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 337 endif()
 338
 339 if(NOT GROUP_CODE)
 340         #set(GROUP_CODE "The Golden Code")
 341         set(GROUP_CODE flat)
 342 endif()
 343
 344 # lyx's source files
 345 set(LYX_CPP_FILES *.cpp)
 346 set(LYX_HPP_FILES *.h)
 347 set(LYX_MOC_FILES moc_*.cpp)
 348
 349 include(ProjectSourceGroup)
 350
 351
 352 if(LYX_PROFILE)
 353         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 354         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 355 endif()
 356
 357
 358 if(LYX_NO_OPTIMIZE)
 359         set(CMAKE_BUILD_TYPE None)
 360         set(LYX_DEBUG OFF)
 361         set(LYX_RELEASE OFF)
 362 elseif(LYX_RELEASE)
 363         set(CMAKE_BUILD_TYPE Release)
 364         set(LYX_DEBUG OFF)
 365 else()
 366         set(CMAKE_BUILD_TYPE Debug)
 367 endif()
 368
 369
 370 # When shared libs are supported enable this option
 371 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 372 if(LYX_SHARED_LIBRARIES)
 373         set(library_type SHARED)
 374 else()
 375         set(library_type STATIC)
 376 endif()
 377
 378 if(NOT MSVC)
 379         if(NOT LYX_QUIET)
 380                 set(CMAKE_VERBOSE_MAKEFILE ON)
 381         endif()
 382         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 383         if(LYX_STDLIB_DEBUG)
 384                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 385         endif()
 386         if(LYX_CONCEPT_CHECKS)
 387                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 388         endif()
 389         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 390         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 391         if(MINGW)
 392                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 393         else()
 394                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 395         endif()
 396         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 397 endif()
 398
 399
 400 find_package(Qt4 REQUIRED)
 401
 402
 403 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 404
 405 if(LYX_ASPELL)
 406         find_package(ASPELL)
 407         include_directories(${ASPELL_INCLUDE_DIR})
 408 endif()
 409
 410 if(LYX_ENCHANT)
 411         find_package(Enchant REQUIRED)
 412         include_directories(${ENCHANT_INCLUDE_DIR})
 413 endif()
 414
 415 if(LYX_HUNSPELL)
 416         find_package(Hunspell REQUIRED)
 417         include_directories(${HUNSPELL_INCLUDE_DIR})
 418 endif()
 419
 420 if(LYX_NLS)
 421         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 422         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 423                 message(FATAL_ERROR "Python 2.6 needed!")
 424         endif()
 425         find_package(LyXGettext REQUIRED)
 426         include_directories(${TOP_SRC_DIR}/po)
 427         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 428 endif()
 429
 430 if(LYX_NLS)
 431         if(LYX_EXTERNAL_LIBINTL)
 432                 find_package(Libintl REQUIRED)
 433                 if(DEFINED LIBINTL_LIBRARIES)
 434                         # find getext when configuring
 435                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 436                         # on mac use iconv also form ports
 437                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 438                 endif()
 439         else()
 440                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 441         endif()
 442 endif()
 443
 444 find_package(ICONV REQUIRED)
 445 find_package(ZLIB REQUIRED)
 446
 447 if(LYX_EXTERNAL_BOOST)
 448         message(STATUS "Searching for boost")
 449         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 450         if(Boost_FOUND)
 451                 message(STATUS "Boost found")
 452                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 453                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 454         else()
 455                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 456         endif()
 457 else()
 458         if(LYX_USE_TR1_REGEX)
 459                 set(Lyx_Boost_Libraries boost_signals)
 460         else()
 461                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 462         endif()
 463         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 464         include_directories(${TOP_SRC_DIR}/boost)
 465         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 466 endif()
 467
 468
 469
 470
 471 if(WIN32)
 472         if(NOT LYX_CONSOLE)
 473                 set(WIN32_CONSOLE WIN32)
 474                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 475         endif()
 476         if(MSVC)
 477                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 478                 # disable checked iterators for msvc release builds to get maximum speed
 479                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 480         else()
 481                 add_definitions(-DWINVER=0x0500)
 482         endif()
 483 endif()
 484
 485 message(STATUS "")
 486 foreach(_v PACKAGE PACKAGE_VERSION
 487         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 488         LYX_ABS_TOP_SRCDIR
 489         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 490         if(NOT DEFINED ${_v})
 491                 message(FATAL_ERROR "${_v} not defined")
 492         endif()
 493         string(SUBSTRING "${_v}                            " 0 28 _v1)
 494         message(STATUS "----- ${_v1}: ${${_v}}")
 495 endforeach(_v)
 496 message(STATUS "")
 497
 498
 499 if(LYX_PCH)
 500         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 501         # Not sure if it works for all non-msvc compilers
 502         include(PCHSupport_26)
 503         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 504         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 505         add_definitions(-DLYX_ENABLE_PCH)
 506
 507         if(MSVC)
 508                 macro(lyx_add_msvc_pch name_)
 509                         set_source_files_properties(${${name_}_sources} PROPERTIES
 510                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 511                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 512                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 513                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 514                                 ${TOP_BINARY_DIR}/pcheaders.h)
 515                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 516                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 517                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 518                 endmacro(lyx_add_msvc_pch)
 519                 macro(lyx_add_gcc_pch name_)
 520                 endmacro()
 521         else()
 522                 macro(lyx_add_msvc_pch name_)
 523                 endmacro()
 524                 macro(lyx_add_gcc_pch name_)
 525                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 526                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 527                 endmacro()
 528         endif()
 529 else()
 530         macro(lyx_add_msvc_pch)
 531         endmacro(lyx_add_msvc_pch)
 532         macro(lyx_add_gcc_pch name_)
 533         endmacro()
 534 endif()
 535
 536
 537 if(MSVC)
 538
 539         if(LYX_VLD)
 540                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 541                 add_subdirectory(${vld_path}/cmake)
 542                 include(${vld_path}/cmake/vld.cmake) # forced include
 543                 set(vld_dll vld)
 544         endif()
 545
 546         if(LYX_WALL)
 547                 # Use the highest warning level
 548                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 549
 550                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 551                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 552                 else()
 553                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 554                 endif()
 555
 556                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 557                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 558                 else()
 559                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 560                 endif()
 561
 562                 # add here warnings which should produce an error /weXXXX
 563                 set(MSVC_W_ERROR   "/we4101 /we4189")
 564                 # add here warnings which should be disabled /wdXXXX
 565                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 566
 567                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 568                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 569                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 570
 571         else()
 572                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 573
 574                 # add here warnings which should produce an error /weXXXX
 575                 set(MSVC_W_ERROR   "/we4101 /we4189")
 576                 # add here warnings which should be disabled /wdXXXX
 577                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 578
 579                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 580                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 581                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 582
 583         endif()
 584         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 585         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 586         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 587
 588         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 589         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 590         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 591         message(STATUS "")
 592 endif()
 593
 594
 595 if(LYX_DEBUG_GLIBC)
 596         set(_GLIBCXX_DEBUG 1)
 597 endif()
 598
 599 if(LYX_DEBUG_GLIBC_PEDANTIC)
 600         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 601 endif()
 602
 603 # compiler tests, config.h generation
 604 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 605         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 606 else()
 607         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 608         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 609 endif()
 610
 611 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 612
 613
 614 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 615 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 616 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 617
 618
 619 if(LYX_INSTALL)
 620         #FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 621         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 622                 message(STATUS "Python required to create doc!")
 623         else()
 624                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 625                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 626         endif()
 627         include(../Install)
 628 endif()
 629
 630 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 631
 632 message(STATUS)
 633 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 634 message(STATUS)
 635 LYX_OPTION_LIST_ALL(used)
 636
 637
 638 if(LYX_NLS)
 639         message(STATUS)
 640         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 641         message(STATUS)
 642         message(STATUS "  * intl")
 643         message(STATUS "     - header : ${LIBINTL_HEADER}")
 644         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 645         message(STATUS "  * iconv")
 646         message(STATUS "     - header : ${ICONV_HEADER}")
 647         message(STATUS "     - library: ${ICONV_LIBRARY}")
 648         message(STATUS "  * zlib")
 649         message(STATUS "     - header : ${ZLIB_HEADER}")
 650         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 651         message(STATUS)
 652 endif()
 653
 654 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 655
 656 message(STATUS)
 657
 658 endif() # help