CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 include(LyXMacros)
  46
  47 # Usage LYX_OPTION
  48 # 1. parameter: option name without prefix 'LYX_'
  49 # 2. parameter: description
  50 # 3. parameter: default value, ON or OFF
  51 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  52
  53
  54 LYX_OPTION_INIT()
  55
  56 # Options for all compilers/systems
  57 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  58 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  59 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  60 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  61 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  62 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  63 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  64 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  65 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  66 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  67 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  68 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  69 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  70 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  71 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  72 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  73 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  74 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  75
  76 # GCC specific
  77 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  78 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  79 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  80 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  81 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  82 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  83 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
  84
  85 # MSVC specific
  86 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
  87 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
  88 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
  89 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
  90 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  91
  92 # APPLE specific
  93 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
  94 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
  95
  96
  97 if(help OR HELP)
  98         message(STATUS)
  99         message(STATUS "Available options: (dis/enable with -D=0/1)")
 100         message(STATUS)
 101         LYX_OPTION_LIST_ALL(help)
 102         message(STATUS)
 103 else()
 104
 105
 106 # Check option dependencies
 107
 108 if(LYX_CPACK)
 109         set(LYX_INSTALL ON)
 110 endif()
 111
 112 if(LYX_DMG)
 113         set(LYX_BUNDLE ON)
 114         set(LYX_CPACK ON)
 115 endif()
 116
 117 if(LYX_INSTALL)
 118         set(LYX_NLS ON)
 119         if (WIN32)
 120                 set(LYX_HUNSPELL ON)
 121         endif()
 122         set(LYX_CONSOLE OFF)
 123         set(LYX_PACKAGE_SUFFIX ON)
 124         set(LYX_RELEASE ON)
 125         set(LYX_PROFILE OFF)
 126 endif()
 127
 128
 129 if(LYX_MERGE_FILES)
 130         set(LYX_PCH OFF)
 131 else()
 132         set(LYX_MERGE_REBUILD OFF)
 133 endif()
 134
 135 if(LYX_DEPENDENCIES_DOWNLOAD)
 136         message(STATUS)
 137         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 138         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 139         set(deps_files lyx20-deps-msvc2010-x86.zip)
 140         foreach(it ${deps_files})
 141                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 142                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 143                 if(NOT already_downloaded)
 144                         message(STATUS "Downloading ${it} ...")
 145                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 146                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 147                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 148                 endif()
 149         endforeach()
 150         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 151 endif()
 152
 153
 154
 155 message(STATUS)
 156
 157 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 158 set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 159
 160
 161
 162 if(UNIX OR MINGW)
 163         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 164         message(STATUS "Using GCC version ${GCC_VERSION}")
 165         if(NOT GCC_VERSION VERSION_LESS 4.4)
 166                 set(LYX_USE_TR1 1)
 167                 # GCC <= 4.5 does not support regex: there are linker errors
 168                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 169                 set(LYX_USE_TR1_REGEX 0)
 170         endif()
 171 else()
 172         if(MSVC10)
 173                 set(LYX_USE_TR1 1)
 174                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 175         endif()
 176 endif()
 177
 178
 179 set(VERSION_INFO "CMake Build")
 180
 181 # Try to get some informations from configure.ac
 182
 183 include(LyXPaths)
 184 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 185
 186 if(WIN32)
 187         set(USE_WINDOWS_PACKAGING 1)
 188 elseif(APPLE)
 189         set(USE_MACOSX_PACKAGING 1)
 190 else()
 191         set(USE_POSIX_PACKAGING 1)
 192 endif()
 193
 194 macro(setstripped _varname _value)
 195         string(STRIP ${_value} _v)
 196         if(USE_POSIX_PACKAGING)
 197                 string(TOLOWER ${_v} ${_varname})
 198         else()
 199                 set(${_varname} ${_v})
 200         endif()
 201 endmacro(setstripped)
 202
 203 foreach(_c_l ${_config_lines} )
 204         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 205                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 206                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 207                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 208                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 209                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 210                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 211                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 212                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 213                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 214                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 215                 endif()
 216         endif()
 217         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 218                 set(LYX_DATE "${CMAKE_MATCH_1}")
 219         endif()
 220 endforeach(_c_l)
 221
 222 # Find the revision number and for later use
 223 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 224 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 225 if(LYX_SVNVERSION)
 226         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 227         # We use this value also to set the package-patch-value
 228         if(LYX_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 229                 set(LYX_REVISION_VERSION ${CMAKE_MATCH_1})
 230         endif()
 231 else()
 232         set(LYX_REVISION_VERSION svn) #TODO use date
 233 endif()
 234
 235
 236 if(LYX_PROGRAM_SUFFIX)
 237         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 238 else()
 239         set(PROGRAM_SUFFIX "")
 240 endif()
 241
 242
 243 if(LYX_BUNDLE)
 244         set(LYX_CPACK ON)
 245         message(STATUS)
 246         message(STATUS "Bundle creation is enabled (experimental):")
 247         message(STATUS "    make")
 248         message(STATUS "    make install/strip")
 249         message(STATUS "    make package")
 250         if(APPLE)
 251                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 252                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 253                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 254                 if(NOT LYX_INSTALL_PREFIX)
 255                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 256                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 257                 endif()
 258         elseif(UNIX)
 259                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 260                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 261                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 262         elseif(WIN32)
 263                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 264         endif()
 265 endif()
 266
 267 if(LYX_INSTALL_PREFIX)
 268         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 269         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 270 endif()
 271 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 272
 273 if(LYX_PACKAGE_SUFFIX)
 274         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 275 else()
 276         set(PACKAGE ${PACKAGE_BASE})
 277 endif()
 278
 279
 280 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 281         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 282         if (UNIX)
 283                 # don't use the default "/usr/local"
 284                 # but respect the user-choice on the command-line
 285                 if(LYX_INSTALL_SUFFIX)
 286                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 287                 else()
 288                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 289                 endif()
 290         endif()
 291         if(WIN32)
 292                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 293         endif()
 294 endif()
 295 if(IS_ABSOLUTE)
 296         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 297 else()
 298         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 299 endif()
 300
 301
 302
 303 if(NOT LYX_DATA_SUBDIR)
 304         if (WIN32)
 305                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 306         else()
 307                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 308         endif()
 309 endif()
 310
 311 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 312 set(LYX_LOCALEDIR "locale")
 313 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 314 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 315
 316
 317 if(LYX_INSTALL AND WIN32)
 318         message(STATUS "Configuring NSIS files")
 319         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 320         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 321         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 322         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 323 endif()
 324
 325 if(NOT GROUP_CODE)
 326         #set(GROUP_CODE "The Golden Code")
 327         set(GROUP_CODE flat)
 328 endif()
 329
 330 # lyx's source files
 331 set(LYX_CPP_FILES *.cpp)
 332 set(LYX_HPP_FILES *.h)
 333 set(LYX_MOC_FILES moc_*.cpp)
 334
 335 include(ProjectSourceGroup)
 336
 337
 338 if(LYX_PROFILE)
 339         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 340         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 341 endif()
 342
 343
 344 if(LYX_NO_OPTIMIZE)
 345         set(CMAKE_BUILD_TYPE None)
 346         set(LYX_DEBUG OFF)
 347         set(LYX_RELEASE OFF)
 348 elseif(LYX_RELEASE)
 349         set(CMAKE_BUILD_TYPE Release)
 350         set(LYX_DEBUG OFF)
 351 else()
 352         set(CMAKE_BUILD_TYPE Debug)
 353 endif()
 354
 355
 356 # When shared libs are supported enable this option
 357 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 358 if(LYX_SHARED_LIBRARIES)
 359         set(library_type SHARED)
 360 else()
 361         set(library_type STATIC)
 362 endif()
 363
 364 if(NOT MSVC)
 365         if(NOT LYX_QUIET)
 366                 set(CMAKE_VERBOSE_MAKEFILE ON)
 367         endif()
 368         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 369         if(LYX_STDLIB_DEBUG)
 370                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 371         endif()
 372         if(LYX_CONCEPT_CHECKS)
 373                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 374         endif()
 375         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 376         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 377         if(MINGW)
 378                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 379         else()
 380                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 381         endif()
 382         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 383 endif()
 384
 385
 386 find_package(Qt4 REQUIRED)
 387
 388
 389 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 390
 391 if(LYX_ASPELL)
 392         find_package(ASPELL)
 393         include_directories(${ASPELL_INCLUDE_DIR})
 394 endif()
 395
 396 if(LYX_ENCHANT)
 397         find_package(Enchant REQUIRED)
 398         include_directories(${ENCHANT_INCLUDE_DIR})
 399 endif()
 400
 401 if(LYX_HUNSPELL)
 402         find_package(Hunspell REQUIRED)
 403         include_directories(${HUNSPELL_INCLUDE_DIR})
 404 endif()
 405
 406 if(LYX_NLS)
 407         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 408         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 409                 message(FATAL_ERROR "Python 2.6 needed!")
 410         endif()
 411         find_package(LyXGettext REQUIRED)
 412         include_directories(${TOP_SRC_DIR}/po)
 413         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 414 endif()
 415
 416 if(LYX_NLS)
 417         if(LYX_EXTERNAL_LIBINTL)
 418                 find_package(Libintl REQUIRED)
 419                 if(DEFINED LIBINTL_LIBRARIES)
 420                         # find getext when configuring
 421                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 422                         # on mac use iconv also form ports
 423                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 424                 endif()
 425         else()
 426                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 427         endif()
 428 endif()
 429
 430 find_package(ICONV REQUIRED)
 431 find_package(ZLIB REQUIRED)
 432
 433 if(LYX_EXTERNAL_BOOST)
 434         message(STATUS "Searching for boost")
 435         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 436         if(Boost_FOUND)
 437                 message(STATUS "Boost found")
 438                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 439                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 440         else()
 441                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 442         endif()
 443 else()
 444         if(LYX_USE_TR1_REGEX)
 445                 set(Lyx_Boost_Libraries boost_signals)
 446         else()
 447                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 448         endif()
 449         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 450         include_directories(${TOP_SRC_DIR}/boost)
 451         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 452 endif()
 453
 454
 455
 456
 457 if(WIN32)
 458         if(NOT LYX_CONSOLE)
 459                 set(WIN32_CONSOLE WIN32)
 460                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 461         endif()
 462         if(MSVC)
 463                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 464                 # disable checked iterators for msvc release builds to get maximum speed
 465                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 466         else()
 467                 add_definitions(-DWINVER=0x0500)
 468         endif()
 469 endif()
 470
 471 message(STATUS "")
 472 foreach(_v PACKAGE PACKAGE_VERSION
 473         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 474         LYX_ABS_TOP_SRCDIR
 475         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 476         if(NOT DEFINED ${_v})
 477                 message(FATAL_ERROR "${_v} not defined")
 478         endif()
 479         string(SUBSTRING "${_v}                            " 0 28 _v1)
 480         message(STATUS "----- ${_v1}: ${${_v}}")
 481 endforeach(_v)
 482 message(STATUS "")
 483
 484
 485 if(LYX_PCH)
 486         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 487         # Not sure if it works for all non-msvc compilers
 488         include(PCHSupport_26)
 489         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 490         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 491         add_definitions(-DLYX_ENABLE_PCH)
 492
 493         if(MSVC)
 494                 macro(lyx_add_msvc_pch name_)
 495                         set_source_files_properties(${${name_}_sources} PROPERTIES
 496                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 497                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 498                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 499                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 500                                 ${TOP_BINARY_DIR}/pcheaders.h)
 501                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 502                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 503                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 504                 endmacro(lyx_add_msvc_pch)
 505                 macro(lyx_add_gcc_pch name_)
 506                 endmacro()
 507         else()
 508                 macro(lyx_add_msvc_pch name_)
 509                 endmacro()
 510                 macro(lyx_add_gcc_pch name_)
 511                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 512                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 513                 endmacro()
 514         endif()
 515 else()
 516         macro(lyx_add_msvc_pch)
 517         endmacro(lyx_add_msvc_pch)
 518         macro(lyx_add_gcc_pch name_)
 519         endmacro()
 520 endif()
 521
 522 if(MSVC)
 523         if(LYX_VLD)
 524                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 525                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 526                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 527                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 528         endif()
 529
 530         if(LYX_WALL)
 531                 # Use the highest warning level
 532                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 533
 534                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 535                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 536                 else()
 537                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 538                 endif()
 539
 540                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 541                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 542                 else()
 543                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 544                 endif()
 545
 546                 # add here warnings which should produce an error /weXXXX
 547                 set(MSVC_W_ERROR   "/we4101 /we4189")
 548                 # add here warnings which should be disabled /wdXXXX
 549                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 550
 551                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 552                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 553                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 554
 555         else()
 556                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 557
 558                 # add here warnings which should produce an error /weXXXX
 559                 set(MSVC_W_ERROR   "/we4101 /we4189")
 560                 # add here warnings which should be disabled /wdXXXX
 561                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 562
 563                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 564                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 565                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 566
 567         endif()
 568         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 569         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 570         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 571
 572         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 573         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 574         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 575         message(STATUS "")
 576 endif()
 577
 578
 579 if(LYX_DEBUG_GLIBC)
 580         set(_GLIBCXX_DEBUG 1)
 581 endif()
 582
 583 if(LYX_DEBUG_GLIBC_PEDANTIC)
 584         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 585 endif()
 586
 587 # compiler tests, config.h generation
 588 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 589         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 590 else()
 591         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 592         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 593 endif()
 594
 595 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 596
 597
 598 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 599 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 600 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 601
 602
 603 if(LYX_INSTALL)
 604         #FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 605         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 606                 message(STATUS "Python required to create doc!")
 607         else()
 608                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 609                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 610         endif()
 611         include(../Install)
 612 endif()
 613
 614 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 615
 616 message(STATUS)
 617 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 618 message(STATUS)
 619 LYX_OPTION_LIST_ALL(used)
 620
 621
 622 if(LYX_NLS)
 623         message(STATUS)
 624         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 625         message(STATUS)
 626         message(STATUS "  * intl")
 627         message(STATUS "     - header : ${LIBINTL_HEADER}")
 628         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 629         message(STATUS "  * iconv")
 630         message(STATUS "     - header : ${ICONV_HEADER}")
 631         message(STATUS "     - library: ${ICONV_LIBRARY}")
 632         message(STATUS "  * zlib")
 633         message(STATUS "     - header : ${ZLIB_HEADER}")
 634         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 635         message(STATUS)
 636 endif()
 637
 638 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 639
 640 message(STATUS)
 641
 642 endif() # help