CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 include(LyXMacros)
  46
  47 # Usage LYX_OPTION
  48 # 1. parameter: option name without prefix 'LYX_'
  49 # 2. parameter: description
  50 # 3. parameter: default value, ON or OFF
  51 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  52
  53
  54 LYX_OPTION_INIT()
  55
  56 # Options for all compilers/systems
  57 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  58 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  59 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  60 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  61 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  62 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  63 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  64 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  65 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  66 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  67 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  68 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  69 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  70 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  71 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  72 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  73 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  74 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  75
  76 # GCC specific
  77 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  78 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  79 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  80 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  81 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  82 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  83 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
  84
  85 # MSVC specific
  86 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
  87 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
  88 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
  89 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
  90 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  91
  92 # APPLE specific
  93 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
  94 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
  95
  96
  97 if(help OR HELP)
  98         message(STATUS)
  99         message(STATUS "Available options: (dis/enable with -D=0/1)")
 100         message(STATUS)
 101         LYX_OPTION_LIST_ALL(help)
 102         message(STATUS)
 103 else()
 104
 105
 106 # Check option dependencies
 107
 108 if(LYX_CPACK)
 109         set(LYX_INSTALL ON)
 110 endif()
 111
 112 if(LYX_DMG)
 113         set(LYX_BUNDLE ON)
 114         set(LYX_CPACK ON)
 115 endif()
 116
 117 if(LYX_INSTALL)
 118         set(LYX_NLS ON)
 119         if (WIN32)
 120                 set(LYX_HUNSPELL ON)
 121         endif()
 122         set(LYX_CONSOLE OFF)
 123         set(LYX_PACKAGE_SUFFIX ON)
 124         set(LYX_RELEASE ON)
 125         set(LYX_PROFILE OFF)
 126 endif()
 127
 128
 129 if(LYX_MERGE_FILES)
 130         set(LYX_PCH OFF)
 131 else()
 132         set(LYX_MERGE_REBUILD OFF)
 133 endif()
 134
 135 if(LYX_DEPENDENCIES_DOWNLOAD)
 136         message(STATUS)
 137         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 138         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 139         set(deps_files lyx20-deps-msvc2010-x86.zip)
 140         foreach(it ${deps_files})
 141                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 142                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 143                 if(NOT already_downloaded)
 144                         message(STATUS "Downloading ${it} ...")
 145                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 146                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 147                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 148                 endif()
 149         endforeach()
 150         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 151 endif()
 152
 153
 154
 155 message(STATUS)
 156
 157 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 158 if(WIN32)
 159         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 160 else()
 161         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 162 endif()
 163
 164
 165 if(UNIX OR MINGW)
 166         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 167         message(STATUS "Using GCC version ${GCC_VERSION}")
 168         if(NOT GCC_VERSION VERSION_LESS 4.4)
 169                 set(LYX_USE_TR1 1)
 170                 # GCC <= 4.5 does not support regex: there are linker errors
 171                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 172                 set(LYX_USE_TR1_REGEX 0)
 173         endif()
 174 else()
 175         if(MSVC10)
 176                 set(LYX_USE_TR1 1)
 177                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 178         endif()
 179 endif()
 180
 181
 182 set(VERSION_INFO "CMake Build")
 183
 184 # Try to get some informations from configure.ac
 185
 186 include(LyXPaths)
 187 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 188
 189 if(WIN32)
 190         set(USE_WINDOWS_PACKAGING 1)
 191 elseif(APPLE)
 192         set(USE_MACOSX_PACKAGING 1)
 193 else()
 194         set(USE_POSIX_PACKAGING 1)
 195 endif()
 196
 197 macro(setstripped _varname _value)
 198         string(STRIP ${_value} _v)
 199         if(USE_POSIX_PACKAGING)
 200                 string(TOLOWER ${_v} ${_varname})
 201         else()
 202                 set(${_varname} ${_v})
 203         endif()
 204 endmacro(setstripped)
 205
 206 foreach(_c_l ${_config_lines} )
 207         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 208                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 209                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 210                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 211                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 212                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 213                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 214                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 215                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 216                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 217                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 218                 endif()
 219         endif()
 220         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 221                 set(LYX_DATE "${CMAKE_MATCH_1}")
 222         endif()
 223 endforeach(_c_l)
 224
 225 # Find the revision number and for later use
 226 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 227 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 228 if(LYX_SVNVERSION)
 229         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 230         # We use this value also to set the package-patch-value
 231         if(LYX_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 232                 set(LYX_REVISION_VERSION ${CMAKE_MATCH_1})
 233         endif()
 234 else()
 235         set(LYX_REVISION_VERSION svn) #TODO use date
 236 endif()
 237
 238
 239 if(LYX_PROGRAM_SUFFIX)
 240         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 241 else()
 242         set(PROGRAM_SUFFIX "")
 243 endif()
 244
 245
 246 if(LYX_BUNDLE)
 247         set(LYX_CPACK ON)
 248         message(STATUS)
 249         message(STATUS "Bundle creation is enabled (experimental):")
 250         message(STATUS "    make")
 251         message(STATUS "    make install/strip")
 252         message(STATUS "    make package")
 253         if(APPLE)
 254                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 255                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 256                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 257                 if(NOT LYX_INSTALL_PREFIX)
 258                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 259                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 260                 endif()
 261         elseif(UNIX)
 262                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 263                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 264                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 265         elseif(WIN32)
 266                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 267         endif()
 268 endif()
 269
 270 if(LYX_INSTALL_PREFIX)
 271         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 272         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 273 endif()
 274 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 275
 276 if(LYX_PACKAGE_SUFFIX)
 277         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 278 else()
 279         set(PACKAGE ${PACKAGE_BASE})
 280 endif()
 281
 282
 283 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 284         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 285         if (UNIX)
 286                 # don't use the default "/usr/local"
 287                 # but respect the user-choice on the command-line
 288                 if(LYX_INSTALL_SUFFIX)
 289                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 290                 else()
 291                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 292                 endif()
 293         endif()
 294         if(WIN32)
 295                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 296         endif()
 297 endif()
 298 if(IS_ABSOLUTE)
 299         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 300 else()
 301         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 302 endif()
 303
 304
 305
 306 if(NOT LYX_DATA_SUBDIR)
 307         if (WIN32)
 308                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 309         else()
 310                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 311         endif()
 312 endif()
 313
 314 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 315 set(LYX_LOCALEDIR "locale")
 316 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 317 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 318
 319
 320 if(LYX_INSTALL AND WIN32)
 321         message(STATUS "Configuring NSIS files")
 322         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 323         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 324         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 325         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 326 endif()
 327
 328 if(NOT GROUP_CODE)
 329         #set(GROUP_CODE "The Golden Code")
 330         set(GROUP_CODE flat)
 331 endif()
 332
 333 # lyx's source files
 334 set(LYX_CPP_FILES *.cpp)
 335 set(LYX_HPP_FILES *.h)
 336 set(LYX_MOC_FILES moc_*.cpp)
 337
 338 include(ProjectSourceGroup)
 339
 340
 341 if(LYX_PROFILE)
 342         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 343         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 344 endif()
 345
 346
 347 if(LYX_NO_OPTIMIZE)
 348         set(CMAKE_BUILD_TYPE None)
 349         set(LYX_DEBUG OFF)
 350         set(LYX_RELEASE OFF)
 351 elseif(LYX_RELEASE)
 352         set(CMAKE_BUILD_TYPE Release)
 353         set(LYX_DEBUG OFF)
 354 else()
 355         set(CMAKE_BUILD_TYPE Debug)
 356 endif()
 357
 358
 359 # When shared libs are supported enable this option
 360 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 361 if(LYX_SHARED_LIBRARIES)
 362         set(library_type SHARED)
 363 else()
 364         set(library_type STATIC)
 365 endif()
 366
 367 if(NOT MSVC)
 368         if(NOT LYX_QUIET)
 369                 set(CMAKE_VERBOSE_MAKEFILE ON)
 370         endif()
 371         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 372         if(LYX_STDLIB_DEBUG)
 373                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 374         endif()
 375         if(LYX_CONCEPT_CHECKS)
 376                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 377         endif()
 378         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 379         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 380         if(MINGW)
 381                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 382         else()
 383                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 384         endif()
 385         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 386 endif()
 387
 388
 389 find_package(Qt4 REQUIRED)
 390
 391
 392 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 393
 394 if(LYX_ASPELL)
 395         find_package(ASPELL)
 396         include_directories(${ASPELL_INCLUDE_DIR})
 397 endif()
 398
 399 if(LYX_ENCHANT)
 400         find_package(Enchant REQUIRED)
 401         include_directories(${ENCHANT_INCLUDE_DIR})
 402 endif()
 403
 404 if(LYX_HUNSPELL)
 405         find_package(Hunspell REQUIRED)
 406         include_directories(${HUNSPELL_INCLUDE_DIR})
 407 endif()
 408
 409 if(LYX_NLS)
 410         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 411         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 412                 message(FATAL_ERROR "Python 2.6 needed!")
 413         endif()
 414         find_package(LyXGettext REQUIRED)
 415         include_directories(${TOP_SRC_DIR}/po)
 416         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 417 endif()
 418
 419 if(LYX_NLS)
 420         if(LYX_EXTERNAL_LIBINTL)
 421                 find_package(Libintl REQUIRED)
 422                 if(DEFINED LIBINTL_LIBRARIES)
 423                         # find getext when configuring
 424                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 425                         # on mac use iconv also form ports
 426                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 427                 endif()
 428         else()
 429                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 430         endif()
 431 endif()
 432
 433 find_package(ICONV REQUIRED)
 434 find_package(ZLIB REQUIRED)
 435
 436 if(LYX_EXTERNAL_BOOST)
 437         message(STATUS "Searching for boost")
 438         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 439         if(Boost_FOUND)
 440                 message(STATUS "Boost found")
 441                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 442                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 443         else()
 444                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 445         endif()
 446 else()
 447         if(LYX_USE_TR1_REGEX)
 448                 set(Lyx_Boost_Libraries boost_signals)
 449         else()
 450                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 451         endif()
 452         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 453         include_directories(${TOP_SRC_DIR}/boost)
 454         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 455 endif()
 456
 457
 458
 459
 460 if(WIN32)
 461         if(NOT LYX_CONSOLE)
 462                 set(WIN32_CONSOLE WIN32)
 463                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 464         endif()
 465         if(MSVC)
 466                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 467                 # disable checked iterators for msvc release builds to get maximum speed
 468                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 469         else()
 470                 add_definitions(-DWINVER=0x0500)
 471         endif()
 472 endif()
 473
 474 message(STATUS "")
 475 foreach(_v PACKAGE PACKAGE_VERSION
 476         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 477         LYX_ABS_TOP_SRCDIR
 478         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 479         if(NOT DEFINED ${_v})
 480                 message(FATAL_ERROR "${_v} not defined")
 481         endif()
 482         string(SUBSTRING "${_v}                            " 0 28 _v1)
 483         message(STATUS "----- ${_v1}: ${${_v}}")
 484 endforeach(_v)
 485 message(STATUS "")
 486
 487
 488 if(LYX_PCH)
 489         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 490         # Not sure if it works for all non-msvc compilers
 491         include(PCHSupport_26)
 492         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 493         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 494         add_definitions(-DLYX_ENABLE_PCH)
 495
 496         if(MSVC)
 497                 macro(lyx_add_msvc_pch name_)
 498                         set_source_files_properties(${${name_}_sources} PROPERTIES
 499                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 500                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 501                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 502                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 503                                 ${TOP_BINARY_DIR}/pcheaders.h)
 504                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 505                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 506                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 507                 endmacro(lyx_add_msvc_pch)
 508                 macro(lyx_add_gcc_pch name_)
 509                 endmacro()
 510         else()
 511                 macro(lyx_add_msvc_pch name_)
 512                 endmacro()
 513                 macro(lyx_add_gcc_pch name_)
 514                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 515                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 516                 endmacro()
 517         endif()
 518 else()
 519         macro(lyx_add_msvc_pch)
 520         endmacro(lyx_add_msvc_pch)
 521         macro(lyx_add_gcc_pch name_)
 522         endmacro()
 523 endif()
 524
 525
 526 if(MSVC)
 527
 528         if(LYX_VLD)
 529                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 530                 add_subdirectory(${vld_path}/cmake)
 531                 include(${vld_path}/cmake/vld.cmake) # forced include
 532                 set(vld_dll vld)
 533         endif()
 534
 535         if(LYX_WALL)
 536                 # Use the highest warning level
 537                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 538
 539                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 540                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 541                 else()
 542                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 543                 endif()
 544
 545                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 546                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 547                 else()
 548                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 549                 endif()
 550
 551                 # add here warnings which should produce an error /weXXXX
 552                 set(MSVC_W_ERROR   "/we4101 /we4189")
 553                 # add here warnings which should be disabled /wdXXXX
 554                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 555
 556                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 557                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 558                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 559
 560         else()
 561                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 562
 563                 # add here warnings which should produce an error /weXXXX
 564                 set(MSVC_W_ERROR   "/we4101 /we4189")
 565                 # add here warnings which should be disabled /wdXXXX
 566                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 567
 568                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 569                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 570                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 571
 572         endif()
 573         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 574         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 575         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 576
 577         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 578         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 579         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 580         message(STATUS "")
 581 endif()
 582
 583
 584 if(LYX_DEBUG_GLIBC)
 585         set(_GLIBCXX_DEBUG 1)
 586 endif()
 587
 588 if(LYX_DEBUG_GLIBC_PEDANTIC)
 589         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 590 endif()
 591
 592 # compiler tests, config.h generation
 593 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 594         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 595 else()
 596         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 597         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 598 endif()
 599
 600 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 601
 602
 603 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 604 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 605 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 606
 607
 608 if(LYX_INSTALL)
 609         #FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 610         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 611                 message(STATUS "Python required to create doc!")
 612         else()
 613                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 614                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 615         endif()
 616         include(../Install)
 617 endif()
 618
 619 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 620
 621 message(STATUS)
 622 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 623 message(STATUS)
 624 LYX_OPTION_LIST_ALL(used)
 625
 626
 627 if(LYX_NLS)
 628         message(STATUS)
 629         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 630         message(STATUS)
 631         message(STATUS "  * intl")
 632         message(STATUS "     - header : ${LIBINTL_HEADER}")
 633         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 634         message(STATUS "  * iconv")
 635         message(STATUS "     - header : ${ICONV_HEADER}")
 636         message(STATUS "     - library: ${ICONV_LIBRARY}")
 637         message(STATUS "  * zlib")
 638         message(STATUS "     - header : ${ZLIB_HEADER}")
 639         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 640         message(STATUS)
 641 endif()
 642
 643 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 644
 645 message(STATUS)
 646
 647 endif() # help