CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2020 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10 # Instruct cmake to not use gnu extensions,
  11 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  12 set(CMAKE_CXX_EXTENSIONS OFF)
  13
  14 enable_testing()
  15
  16 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  17 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  18 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  19
  20 set(LYX_CMAKE_DIR "development/cmake")
  21 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  22 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  23 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  24
  25 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  26
  27 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  28
  29 message(STATUS)
  30 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  31         message(STATUS "Building in-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  33 else()
  34         message(STATUS "Building out-of-source")
  35         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  36 endif()
  37
  38 # This directory should be used if some test uses lyx-executable
  39 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  40 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  41
  42 if(COMMAND cmake_policy)
  43         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  44         cmake_policy(SET CMP0006 NEW)
  45         if(POLICY CMP0043)
  46                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  47                 cmake_policy(SET CMP0043 NEW)
  48         endif()
  49         cmake_policy(SET CMP0020 NEW)
  50         if(POLICY CMP0075)
  51                 cmake_policy(SET CMP0075 NEW)
  52         endif()
  53         if(POLICY CMP0077)
  54                 cmake_policy(SET CMP0077 NEW)
  55         endif()
  56 endif()
  57
  58 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  59
  60 # Supress regeneration
  61 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  62
  63 if(LYX_XMINGW)
  64     set(CMAKE_SYSTEM_NAME Windows)
  65     set(TOOLNAME ${LYX_XMINGW})
  66     set(TOOLCHAIN "${TOOLNAME}-")
  67     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  68     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  69     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  70
  71     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  72     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  73     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  74 endif()
  75
  76 if(NOT help AND NOT HELP)
  77   # 'project' triggers the searching for a compiler
  78   project(${LYX_PROJECT})
  79   if (CMAKE_COMPILER_IS_GNUCXX)
  80     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  81       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  82       message(STATUS "is too old, should be >= 4.0")
  83       message(FATAL_ERROR "Exiting")
  84     endif()
  85   endif()
  86 endif()
  87
  88 if(UNIX)
  89         set(ARCH_TRIPLET )
  90         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  91         if(DPKG_ARCHITECTURE_EXECUTABLE)
  92                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  93                                 OUTPUT_VARIABLE ARCH_TRIPLET
  94                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  95                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  96         endif()
  97 endif()
  98 if(ARCH_TRIPLET)
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 100 else()
 101         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 102 endif()
 103
 104 include(LyXMacros)
 105 include(LyXDestinations)
 106
 107 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 108 if(WIN32)
 109         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 110         if(MSVC)
 111                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 112         endif()
 113         set(USE_WINDOWS_PACKAGING ON)
 114 elseif(APPLE)
 115         set(USE_MACOSX_PACKAGING ON)
 116 else()
 117         set(USE_POSIX_PACKAGING ON)
 118 endif()
 119
 120 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 121 list(GET _package_list 0 PACKAGE_BASE)
 122 list(GET _package_list 1 PACKAGE_VERSION)
 123 list(GET _package_list 2 PACKAGE_BUGREPORT)
 124 list(GET _envlist 0 LYX_DIR_VER)
 125 list(GET _envlist 1 LYX_USERDIR_VER)
 126 list(GET _version_list 0 LYX_VERSION)
 127 list(GET _version_list 1 LYX_MAJOR_VERSION)
 128 list(GET _version_list 2 LYX_MINOR_VERSION)
 129 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 130 list(GET _version_list 4 LYX_RELEASE_PATCH)
 131
 132 # Usage LYX_OPTION
 133 # 1. parameter: option name without prefix 'LYX_'
 134 # 2. parameter: description
 135 # 3. parameter: default value, ON or OFF
 136 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 137
 138 # Usage LYX_COMBO
 139 # 1. parameter: name without prefix 'LYX_'
 140 # 2. parameter: description
 141 # 3. parameter: default value
 142 # 4-n parameter: possible other string values
 143
 144 LYX_OPTION_INIT()
 145 LYX_COMBO(ENABLE_BUILD_TYPE  "Allows to tweak the compiled code" AUTO release prerelease development gprof)
 146
 147 if(LYX_ENABLE_BUILD_TYPE MATCHES "AUTO")
 148   message(STATUS "Selecting build type defaults from configure.ac")
 149 else()
 150   set(LYX_BUILD_TYPE "${LYX_ENABLE_BUILD_TYPE}")
 151   message(STATUS "Selecting build type defaults from LYX_ENABLE_BUILD_TYPE")
 152 endif()
 153
 154 # Select some defaults depending on LYX_BUILD_TYPE
 155 # they can always be overwritten by the respective command line settings
 156 # These settings are only effective on fresh(==empty) CMakeCache.txt
 157 if(LYX_BUILD_TYPE STREQUAL "development")
 158   set(DefaultLyxDebug ON)
 159   set(DefaultLyxRelease OFF)
 160   set(DefaultLyxStdlibDebug ON)
 161   set(DefaultLyxEnableAssertions ON)
 162   set(DefaultLyxProfile OFF)
 163   set(DefaultExternalLibs OFF)
 164 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 165   set(DefaultLyxDebug OFF)
 166   set(DefaultLyxRelease OFF)
 167   set(DefaultLyxStdlibDebug OFF)
 168   set(DefaultLyxEnableAssertions OFF)
 169   set(DefaultLyxProfile OFF)
 170   set(DefaultExternalLibs ON)
 171 elseif(LYX_BUILD_TYPE STREQUAL "release")
 172   set(DefaultLyxDebug OFF)
 173   set(DefaultLyxRelease ON)
 174   set(DefaultLyxStdlibDebug OFF)
 175   set(DefaultLyxEnableAssertions OFF)
 176   set(DefaultLyxProfile OFF)
 177   set(DefaultExternalLibs ON)
 178 elseif(LYX_BUILD_TYPE STREQUAL "gprof")
 179   set(DefaultLyxDebug ON)
 180   set(DefaultLyxRelease OFF)
 181   set(DefaultLyxStdlibDebug OFF)
 182   set(DefaultLyxEnableAssertions OFF)
 183   set(DefaultLyxProfile ON)
 184   set(DefaultExternalLibs OFF)
 185 else()
 186   message(FATAL_ERROR "Invalid build type (${LYX_BUILD_TYPE}) encountered")
 187 endif()
 188
 189 # Options for all compilers/systems
 190 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 191 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 192 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 193 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 194 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 195 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 196 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 197 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 198 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 199 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 200 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 201 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 202 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 203 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 204 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 205 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 206 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 207 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 208 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 209 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 210 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 211 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 212 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 213 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 214   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 215 else()
 216   if (LYX_ENABLE_VALGRIND_TESTS)
 217     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 218   endif()
 219 endif()
 220 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 221 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 222 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 223 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 224 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 225 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 226 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ${DefaultExternalLibs} ALL)
 227 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ${DefaultExternalLibs} ALL)
 228 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ${DefaultExternalLibs} ALL)
 229 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ${DefaultExternalLibs} ALL)
 230 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 231
 232 # GCC specific
 233 LYX_OPTION(PROFILE              "Build with options for gprof" ${DefaultLyxProfile} GCC)
 234 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" ${DefaultExternalLibs} GCC)
 235 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 236 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 237 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 238 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 239
 240 # MSVC specific
 241 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 242 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 243 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 244 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 245
 246 # APPLE specific
 247 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 248 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 249
 250 # Try to get some informations from configure.ac
 251 include(LyXPaths)
 252
 253
 254 if(help OR HELP)
 255         message(STATUS)
 256         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 257         message(STATUS)
 258         LYX_OPTION_LIST_ALL(help)
 259         message(STATUS)
 260         unset(help CACHE)
 261         unset(HELP CACHE)
 262         RETURN()
 263 endif()
 264
 265 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 266   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 267 else()
 268   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 269 endif()
 270
 271 # Check option dependencies
 272 if (LYX_ENABLE_VALGRIND_TESTS)
 273         find_program(VALGRIND_EXECUTABLE "valgrind")
 274         if (NOT VALGRIND_EXECUTABLE)
 275                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 276         endif()
 277 endif()
 278 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 279   if (LYX_EXTERNAL_BOOST)
 280     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 281   endif()
 282 endif()
 283
 284 if(LYX_DMG)
 285         set(LYX_BUNDLE ON)
 286         set(LYX_CPACK ON)
 287 endif()
 288
 289 if(LYX_CPACK)
 290         set(LYX_INSTALL ON)
 291 endif()
 292
 293 if(LYX_INSTALL)
 294         set(LYX_NLS ON)
 295         if(WIN32 AND NOT MINGW)
 296                 set(LYX_HUNSPELL ON)
 297         endif()
 298         set(LYX_PACKAGE_SUFFIX ON)
 299         if(NOT LYX_DEBUG)
 300                 set(LYX_RELEASE ON)
 301         endif()
 302         set(LYX_PROFILE OFF)
 303 endif()
 304
 305
 306 if(LYX_MERGE_FILES)
 307         set(LYX_PCH OFF)
 308 else()
 309         set(LYX_MERGE_REBUILD OFF)
 310 endif()
 311
 312 if(LYX_DEPENDENCIES_DOWNLOAD)
 313         message(STATUS)
 314         if(MSVC14)
 315                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 316                 set(deps_files lyx-windows-deps-msvc2015.zip)
 317                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 318                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 319         elseif(MSVC10)
 320                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 321                 set(deps_files lyx-windows-deps-msvc2010.zip)
 322                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 323                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 324         else()
 325                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 326         endif()
 327     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 328         foreach(it ${deps_files})
 329                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 330                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 331                 if(NOT already_downloaded)
 332                         message(STATUS "Downloading ${it} ...")
 333                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 334                         list(GET status 0 status_code)
 335                         list(GET status 1 status_string)
 336                         if(NOT status_code EQUAL 0)
 337                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 338                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 339                         endif()
 340                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 341                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 342                 endif()
 343         endforeach()
 344 endif()
 345
 346 message(STATUS)
 347
 348 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 349 if(WIN32)
 350         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 351 else()
 352         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 353 endif()
 354
 355 set(LYX_IPO_SUPPORTED OFF)
 356 if (POLICY CMP0069)
 357   cmake_policy(SET CMP0069 NEW)
 358   if(LYX_USE_IPO MATCHES "AUTO")
 359     # Enable LTO if supported and not debugging
 360     if (NOT LYX_DEBUG)
 361       include(CheckIPOSupported)
 362       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 363     endif()
 364   else()
 365     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 366   endif()
 367 endif()
 368 if (LYX_IPO_SUPPORTED)
 369   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 370 else()
 371   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 372 endif()
 373
 374 # Set to some meaningful default
 375 find_package(CXX11Compiler)
 376 if(NOT CXX11COMPILER_FOUND)
 377         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 378 endif()
 379 unset(LYX_GCC11_MODE)
 380 if(UNIX OR MINGW)
 381         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 382           # ignore the GCC_VERSION for clang
 383           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 384           message(STATUS "Using clang")
 385           if(CXX11_STD_REGEX)
 386             set(LYX_USE_STD_REGEX 1)
 387           else()
 388             set(LYX_USE_STD_REGEX 0)
 389           endif()
 390         else()
 391           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 392           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 393           if (_err)
 394             # previous check failed, try again with _old_ parameter
 395             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 396             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 397           endif()
 398           message(STATUS "Using GCC version ${GCC_VERSION}")
 399           if(GCC_VERSION VERSION_LESS 4.6)
 400                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 401           elseif(GCC_VERSION VERSION_LESS 4.9)
 402                 # <regex> in gcc is unusable in versions less than 4.9.0
 403                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 404                 set(LYX_USE_STD_REGEX 0)
 405           else()
 406                 set(LYX_USE_STD_REGEX 1)
 407           endif()
 408         endif()
 409         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 410 else()
 411         if(MSVC_VERSION LESS 1900)
 412                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 413                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 414                 set(LYX_USE_STD_REGEX 0)
 415         else()
 416                 set(LYX_USE_STD_REGEX 1)
 417         endif()
 418 endif()
 419
 420 if(LYX_3RDPARTY_BUILD)
 421   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 422   # this enables the build of all 3rd_party libs
 423   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 424   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 425   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 426   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 427 endif()
 428
 429 FIND_PROGRAM(LYX_GITVERSION git)
 430 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 431 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 432 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 433 if(LYX_GITVERSION)
 434   if (LYX_LOCALVERSIONING)
 435     # Find the revision number for later use
 436     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 437       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 438       RESULT_VARIABLE tmp_GIT_RESULT
 439       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 440       ERROR_VARIABLE tmp_GIT_ERROR
 441       OUTPUT_STRIP_TRAILING_WHITESPACE)
 442     if (tmp_GIT_RESULT EQUAL 0)
 443       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 444         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 445         # We will add offset of 40000 to get appropriate value to
 446         # previous svn.
 447         # We use this value than also to set the package-patch-value
 448         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 449         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 450         set(ENABLE_DIST ON)
 451       endif()
 452     endif()
 453   endif()
 454 endif()
 455 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 456   set(LYX_PACKAGE_RELEASE  "1")
 457   if (LYX_RELEASE_PATCH GREATER 0)
 458     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 459   endif()
 460 endif()
 461
 462 # Set the programs (lyx, tex2lyx, etc.) suffix
 463 # When building an OS X bundle, we will append
 464 # the suffix only to the bundle, not to the programs
 465 set(PROGRAM_SUFFIX "")
 466 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 467         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 468 endif()
 469 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 470 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 471 set(_convert lyxconvert${PROGRAM_SUFFIX})
 472
 473 add_custom_target(lyx_version ALL
 474   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 475   )
 476 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 477
 478 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 479 set(LYX_UTILITIES_INSTALL_PATH bin)
 480
 481 if(LYX_BUNDLE)
 482         set(LYX_CPACK ON)
 483
 484         message(STATUS)
 485         message(STATUS "Bundle creation is enabled (experimental):")
 486         message(STATUS "    make")
 487         message(STATUS "    make install/strip")
 488         message(STATUS "    make package")
 489         if(APPLE)
 490                 set(MACOSX_BUNDLE TRUE)
 491                 # This sets the bundle + executable names
 492                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 493                 # This sets the Info.plist executable name
 494                 set(osx_bundle_program_name ${_lyx})
 495                 # Bundle name
 496                 set(LYX_BUNDLE_NAME ${_lyx})
 497
 498                 # This will contain the list of files that need to be included
 499                 # in the bundle and their location within the bundle
 500                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 501                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 502
 503                 # Process Info.plist and lyxrc.dist
 504                 # See development/cmake/Install.cmake
 505                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 506
 507                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 508                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 509
 510                 # Variables used by CPack
 511                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 512                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 513                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 514
 515                 # Set the install paths
 516                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 517                 if(NOT LYX_INSTALL_PREFIX)
 518                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 519                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 520                 endif()
 521                 # Change the owner so that the install can work
 522                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 523         elseif(UNIX)
 524                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 525                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 526                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 527         elseif(WIN32)
 528                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 529         endif()
 530 endif()
 531
 532 if(LYX_INSTALL_PREFIX)
 533         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 534         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 535 endif()
 536 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 537
 538 if(UNIX)
 539   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 540 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 541   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 542 else()
 543   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 544 endif()
 545
 546 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 547   # Not a GCC compiler, programs do not have a suffix
 548   set(suffixing ${LYX_PACKAGE_SUFFIX})
 549 elseif(WIN32 AND MINGW)
 550   # We want to use a suffix for the package in this case,
 551   # even if not for the program
 552   set(suffixing ${LYX_PACKAGE_SUFFIX})
 553 else()
 554   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 555   set(suffixing ${LYX_PROGRAM_SUFFIX})
 556 endif()
 557
 558 # The define PACKAGE below allows lyx-executable to find its default configuration files
 559 # see routines
 560 #    Package::messages_file()
 561 #    get_default_user_support_dir()
 562 #    relative_system_support_dir()
 563 # in src/support/Package.cpp
 564 if(suffixing)
 565         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 566 else()
 567         set(PACKAGE ${PACKAGE_BASE})
 568 endif()
 569
 570 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 571         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 572         if (UNIX)
 573                 # use the default "/usr/local"
 574                 # but respect the user-choice on the command-line
 575                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 576         endif()
 577 endif()
 578 if(WIN32)
 579         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 580 endif()
 581 if(IS_ABSOLUTE)
 582         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 583 else()
 584         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 585 endif()
 586
 587
 588
 589 if(NOT LYX_DATA_SUBDIR)
 590         if (WIN32)
 591                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 592         else()
 593                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 594         endif()
 595 endif()
 596
 597 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 598 get_locale_destination(LYX_LOCALEDIR)
 599 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 600 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 601
 602 if(LYX_BUNDLE AND APPLE)
 603         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 604 else()
 605         if(WIN32)
 606                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 607         elseif(UNIX)
 608                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 609         else()
 610                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 611         endif()
 612 endif()
 613 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 614         unset(LYX_MAN_DIR CACHE)
 615         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 616 endif()
 617 unset(LYX_MAN_DIR_tmp)
 618 mark_as_advanced(LYX_MAN_DIR)
 619
 620 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 621 # see the Readme.txt of the installer
 622 #if(LYX_INSTALL AND WIN32)
 623 #       message(STATUS "Configuring NSIS files")
 624 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 625 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 626 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 627 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 628 #endif()
 629
 630 if(NOT GROUP_CODE)
 631         #set(GROUP_CODE "The Golden Code")
 632         set(GROUP_CODE flat)
 633 endif()
 634
 635 # lyx's source files
 636 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 637 set(LYX_HPP_FILES [a-zA-Z]*.h)
 638 set(LYX_MOC_FILES moc_*.cpp)
 639
 640 include(ProjectSourceGroup)
 641
 642
 643 if(LYX_PROFILE AND NOT MSVC)
 644         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 645         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 646         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 647 else()
 648         set(LYX_PROFILE OFF)
 649 endif()
 650
 651
 652 if(LYX_NO_OPTIMIZE)
 653         set(CMAKE_BUILD_TYPE None)
 654         set(LYX_DEBUG OFF)
 655         set(LYX_RELEASE OFF)
 656         set(LYX_PROFILE OFF)
 657 elseif(LYX_RELEASE)
 658         set(CMAKE_BUILD_TYPE Release)
 659         set(LYX_DEBUG OFF)
 660         set(LYX_PROFILE OFF)
 661 elseif(LYX_PROFILE)
 662         set(CMAKE_BUILD_TYPE Profile)
 663         set(LYX_DEBUG OFF)
 664 else()
 665         set(CMAKE_BUILD_TYPE Debug)
 666         set(LYX_DEBUG ON)
 667 endif()
 668
 669
 670 # When shared libs are supported enable this option
 671 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 672 if(LYX_SHARED_LIBRARIES)
 673         set(library_type SHARED)
 674 else()
 675         set(library_type STATIC)
 676 endif()
 677
 678 if(LYX_ENABLE_ASSERTIONS)
 679   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 680 else()
 681   set(LYX_CXX_FLAGS "")
 682 endif()
 683
 684 if(MSVC)
 685   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 686     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 687     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 688   endif()
 689   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 690 else()
 691         if(NOT LYX_QUIET)
 692                 set(CMAKE_VERBOSE_MAKEFILE ON)
 693         endif()
 694         if(LYX_GCC11_MODE MATCHES "\\+\\+([0-9][0-9])")
 695           # Thanks to Brad King <brad.king@kitware.com>
 696           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 697           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 698           # and still use our own c++ extension tests
 699           set(std_num ${CMAKE_MATCH_1})
 700           set(CMAKE_CXX_STANDARD ${std_num})
 701         else()
 702           message(STATUS "Setting CMAKE_CXX_STANDARD 11 as fallback")
 703           set(CMAKE_CXX_STANDARD 11)
 704           set(LYX_GCC11_MODE "--std=c++11")
 705         endif()
 706         # The following setting with LYX_GCC11_MODE is needed because cmake does not honor
 707         # CMAKE_CXX_STANDARD while performing tests like
 708         # check_cxx_source_compiles("..." HAVE_DEF_MAKE_UNIQUE)
 709         set(LYX_CXX_FLAGS "-Wall -Wextra -Wno-deprecated-copy ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 710         if(LYX_STDLIB_DEBUG)
 711           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 712         else()
 713           if(LYX_DEBUG_GLIBC)
 714             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 715           endif()
 716           if(LYX_DEBUG_GLIBC_PEDANTIC)
 717             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 718           endif()
 719         endif()
 720         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 721         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 722         if(MINGW)
 723                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 724         else()
 725                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 726         endif()
 727 endif()
 728
 729 if(LYX_ASAN)
 730     set(CMAKE_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g ${CMAKE_CXX_FLAGS}")
 731     message(STATUS)
 732     message(STATUS "Address sanitizer enabled. Usage:")
 733     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 734     message(STATUS "    chmod  +x ./asan_symbolize.py")
 735     message(STATUS "    ./bin/${_lyx} 2>&1 | ./asan_symbolize.py  | c++filt ")
 736     message(STATUS)
 737 endif()
 738
 739 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 740 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 741 if(LYX_CXX_FLAGS_EXTRA)
 742         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 743                 add_definitions(${_flag})
 744         endforeach()
 745 endif()
 746
 747 if(LYX_XMINGW)
 748         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 749 endif()
 750
 751 set(min_qt5_version "5.6")
 752 if(LYX_USE_QT MATCHES "AUTO")
 753         # try qt5 first
 754         find_package(Qt5Core CONFIG QUIET)
 755         if(Qt5Core_FOUND)
 756                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 757                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 758                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 759                         find_package(Qt4 "4.5.0" QUIET)
 760                         if(QT4_FOUND)
 761                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 762                         endif()
 763                 endif()
 764         else()
 765                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 766         endif()
 767 endif()
 768 if(LYX_USE_QT MATCHES "QT5")
 769         # set QPA_XCB if QT uses X11
 770         find_package(Qt5Core CONFIG REQUIRED)
 771         if (Qt5Core_FOUND)
 772                 find_package(Qt5Widgets CONFIG REQUIRED)
 773                 if(APPLE)
 774                         find_package(Qt5MacExtras CONFIG REQUIRED)
 775                 endif()
 776                 find_package(Qt5X11Extras CONFIG QUIET)
 777                 find_package(Qt5WinExtras CONFIG QUIET)
 778                 set(QTVERSION ${Qt5Core_VERSION})
 779                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 780                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 781                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 782                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 783                         # see thread in lyx-devel list
 784                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 785                         # Date 11.03.2017
 786                         # Subject: cmake compilation error
 787                         #message(FATAL_ERROR "Wrong Qt-Version")
 788                 endif()
 789                 macro (qt_use_modules lyxtarget)
 790                         foreach (_tg ${ARGN})
 791                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 792                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 793                         endforeach()
 794                 endmacro()
 795                 macro (qt_add_resources)
 796                         qt5_add_resources(${ARGN})
 797                 endmacro()
 798                 macro (qt_wrap_uifiles)
 799                         qt5_wrap_ui(${ARGN})
 800                 endmacro()
 801                 message(STATUS "Found Qt-Version ${QTVERSION}")
 802                 if(WIN32)
 803                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 804                 endif()
 805         endif()
 806 elseif(LYX_USE_QT MATCHES "QT4")
 807         if(LYX_XMINGW)
 808                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 809                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 810         endif()
 811         find_package(Qt4 "4.5.0" REQUIRED)
 812         macro (qt_use_modules)
 813         endmacro()
 814         macro (qt_add_resources)
 815                 qt4_add_resources(${ARGN})
 816         endmacro()
 817         macro (qt_wrap_uifiles)
 818                 qt4_wrap_ui(${ARGN})
 819         endmacro()
 820         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 821         if(WIN32)
 822                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 823         endif()
 824 else()
 825   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 826 endif()
 827
 828 find_package(Magic)
 829 if(Magic_FOUND)
 830   set(HAVE_MAGIC_H 1)
 831   include_directories(${Magic_INCLUDE_DIR})
 832 endif()
 833
 834 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 835
 836 set(Spelling_FOUND OFF)
 837 set(Include_used_spellchecker)   # String will be inserted into config.h
 838
 839 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 840   # try system library first
 841   find_package(MYTHESLIB)
 842   if (MYTHESLIB_FOUND)
 843     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 844   else()
 845     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 846   endif()
 847 endif()
 848 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 849   find_package(MYTHESLIB REQUIRED)
 850 else()
 851   add_subdirectory(3rdparty/mythes)
 852 endif()
 853 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 854
 855 if(NOT LYX_EXTERNAL_HUNSPELL)
 856     add_subdirectory(3rdparty/hunspell)
 857     add_definitions(-DHUNSPELL_STATIC)
 858     set(HUNSPELL_FOUND ON)
 859     message(STATUS "  * Hunspell:")
 860     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 861     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 862 endif()
 863
 864 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 865   string(TOUPPER ${_spell} _upspell)
 866   if (NOT ${_upspell}_FOUND)
 867     find_package(${_spell})
 868   endif()
 869   if (${_upspell}_FOUND)
 870     include_directories(${${_upspell}_INCLUDE_DIR})
 871     set(Spelling_FOUND ON)
 872     message(STATUS "Building with USE_${_upspell}")
 873     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 874   else()
 875     if(LYX_${_upspell})
 876       message(FATAL_ERROR "Required ${_spell} devel package not found")
 877     else()
 878       message(STATUS "${_upspell} not found, building without ${_spell} support")
 879     endif()
 880   endif()
 881 endforeach()
 882
 883 if(GNUWIN32_DIR)
 884         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 885         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Perl/bin" )
 886 endif()
 887
 888 # Search for python default version first
 889 unset(PYTHON_EXECUTABLE CACHE)
 890 unset(LYX_PYTHON_EXECUTABLE CACHE)
 891 unset(PYTHON_VERSION_MAJOR)
 892 unset(PYTHON_VERSION_MINOR)
 893 unset(PYTHON_VERSION_STRING)
 894 if (CMAKE_VERSION VERSION_LESS "3.13")
 895   find_package(PythonInterp 3.5 QUIET)
 896   if(NOT PYTHONINTERP_FOUND)
 897     find_package(PythonInterp 2.0 REQUIRED)
 898     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 899       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 900     endif()
 901   endif()
 902   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 903 else()
 904   find_package(Python3 3.5 QUIET)
 905   if(NOT Python3_Interpreter_FOUND)
 906     unset(PYTHON_EXECUTABLE CACHE)
 907     find_package(Python2 2.0 REQUIRED)
 908     if(NOT Python2_VERSION VERSION_LESS 2.8)
 909       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 910     endif()
 911     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 912   else()
 913     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 914   endif()
 915 endif()
 916
 917 if(LYX_NLS)
 918         find_package(LyXGettext)
 919         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 920                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 921         else()
 922                 # Install only supplied .gmo-files
 923                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 924                 message(STATUS "Installing provided .gmo-files only")
 925                 foreach( _gmo ${_gmofiles})
 926                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 927                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 928                 endforeach()
 929         endif()
 930 endif()
 931
 932 if(LYX_EXTERNAL_ICONV)
 933   # Possible remnants of previous run without external iconv
 934   file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/libiconv" "${CMAKE_BINARY_DIR}/3rdparty/libiconv")
 935   find_package(ICONV REQUIRED)
 936 else()
 937   add_subdirectory(3rdparty/libiconv)
 938   set(HAVE_ICONV_CONST 1)
 939 endif()
 940
 941 if(LYX_EXTERNAL_Z)
 942   find_package(ZLIB REQUIRED)
 943 else()
 944   add_subdirectory(3rdparty/zlib)
 945 endif()
 946
 947 if(NOT LYX_EXTERNAL_DTL)
 948   add_subdirectory(3rdparty/dtl)
 949 endif()
 950
 951 if(LYX_USE_STD_REGEX)
 952   # Set only include path.
 953   # Use internal boost, which is known to exist
 954   # we don't need any libraries
 955   set(Lyx_Boost_Libraries)
 956   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 957   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 958 else()
 959   # Using boost-regex
 960   if(LYX_EXTERNAL_BOOST)
 961     message(STATUS "Searching for external boost")
 962     find_package(Boost COMPONENTS regex)
 963     if(Boost_FOUND)
 964       message(STATUS "Boost found")
 965       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 966       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 967       if (LYX_STDLIB_DEBUG OR LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC)
 968         # Comment from  Jean-Marc Lasgouttes:
 969         # In general, system boost libraries are incompatible with
 970         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 971         # details.
 972         message(FATAL_ERROR "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF -DLYX_DEBUG_GLIBC=OFF -DLYX_DEBUG_GLIBC_PEDANTIC=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 973       endif()
 974     else()
 975       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 976     endif()
 977   else()
 978     # Using included boost
 979     set(Lyx_Boost_Libraries boost_regex)
 980     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 981     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 982     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 983   endif()
 984 endif()
 985
 986 if(WIN32)
 987         if(LYX_CONSOLE)
 988                 set(LYX_QTMAIN_LIBRARY)
 989         else()
 990                 set(WIN32_CONSOLE WIN32)
 991         endif()
 992         if(MSVC)
 993                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 994                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 995                 # disable checked iterators for msvc release builds to get maximum speed
 996                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 997         else()
 998                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 999                 # does not use it and always declares the vista compatible API.
1000                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
1001                 add_definitions(-DWINVER=0x0500)
1002         endif()
1003 endif()
1004
1005 # Compute qt-version from ${QTVERSION}
1006
1007 message(STATUS "")
1008 foreach(_v PACKAGE PACKAGE_VERSION
1009         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
1010         LYX_ABS_TOP_SRCDIR
1011         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
1012         if(NOT DEFINED ${_v})
1013                 message(FATAL_ERROR "${_v} not defined")
1014         endif()
1015         string(SUBSTRING "${_v}                            " 0 28 _v1)
1016         message(STATUS "----- ${_v1}: ${${_v}}")
1017 endforeach(_v)
1018 message(STATUS "")
1019
1020
1021 if(LYX_PCH)
1022         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
1023         # Not sure if it works for all non-msvc compilers
1024         include(PCHSupport_26)
1025         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
1026         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
1027         add_definitions(-DLYX_ENABLE_PCH)
1028
1029         if(MSVC)
1030                 macro(lyx_add_msvc_pch name_)
1031                         set_source_files_properties(${${name_}_sources} PROPERTIES
1032                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
1033                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
1034                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
1035                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
1036                                 ${TOP_BINARY_DIR}/pcheaders.h)
1037                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1038                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1039                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
1040                 endmacro(lyx_add_msvc_pch)
1041                 macro(lyx_add_gcc_pch name_)
1042                 endmacro()
1043         else()
1044                 macro(lyx_add_msvc_pch name_)
1045                 endmacro()
1046                 macro(lyx_add_gcc_pch name_)
1047                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1048                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1049                 endmacro()
1050         endif()
1051 else()
1052         macro(lyx_add_msvc_pch)
1053         endmacro(lyx_add_msvc_pch)
1054         macro(lyx_add_gcc_pch name_)
1055         endmacro()
1056 endif()
1057
1058
1059 if(MSVC)
1060
1061         if(LYX_VLD)
1062                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1063                 add_subdirectory(${vld_path}/cmake)
1064                 include(${vld_path}/cmake/vld.cmake) # forced include
1065                 set(vld_dll vld)
1066         endif()
1067
1068         if(LYX_WALL)
1069                 # Use the highest warning level
1070                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1071
1072                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1073                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1074                 else()
1075                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1076                 endif()
1077
1078                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1079                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1080                 else()
1081                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1082                 endif()
1083
1084                 # add here warnings which should produce an error /weXXXX
1085                 set(MSVC_W_ERROR   "/we4101 /we4189")
1086                 # add here warnings which should be disabled /wdXXXX
1087                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1088
1089                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1090                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1091                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1092
1093         else()
1094                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1095
1096                 # add here warnings which should produce an error /weXXXX
1097                 set(MSVC_W_ERROR   "/we4101 /we4189")
1098                 # add here warnings which should be disabled /wdXXXX
1099                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1100
1101                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1102                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1103                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1104
1105         endif()
1106
1107         if (NOT Qt5Core_FOUND)
1108                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1109                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1110                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1111         endif()
1112
1113         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1114         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1115         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1116         message(STATUS "")
1117 endif()
1118
1119
1120 # Xcode compiler
1121 if (CMAKE_GENERATOR MATCHES Xcode)
1122         if (XCODE_VERSION VERSION_LESS "5.0")
1123                 # Automatically select the Xcode compiler if not set
1124                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1125                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1126                         if (XCODE_VERSION VERSION_GREATER "3.1")
1127                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1128                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1129                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1130                 # Print the selected compiler version
1131         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1132         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1133 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1134
1135 if (WIN32 AND Qt5Core_FOUND)
1136         set(Z_PREFIX 1)
1137 endif()
1138
1139 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1140 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1141 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1142
1143 unset(opts)
1144 foreach(_option ${LYX_OPTIONS})
1145   if(${_option}_show_message)
1146     string(SUBSTRING "${_option}                            " 0 31 _var)
1147     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1148     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1149     if (${_index} GREATER -1)
1150       set(_isset ${${_option}})
1151     elseif(${_option})
1152       set(_isset ON)
1153     else()
1154       set(_isset OFF)
1155     endif()
1156     string(SUBSTRING "${_isset}           " 0 10 _val)
1157     set(opts "${opts} ${_option}(${${_option}})")
1158   endif()
1159 endforeach()
1160 set(tmp_vi "CMake Build")
1161 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1162 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1163 list(APPEND tmp_vi "  Build flags:             ${opts}")
1164 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1165 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1166 if (LYX_DEBUG)
1167 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1168 else()
1169 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1170 endif()
1171 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1172 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1173 get_data_destination(dest_data)
1174 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1175 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1176
1177 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1178 unset(opts)
1179 unset(tmp_vi)
1180
1181 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1182         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1183 endif()
1184
1185 if (NOT HAVE_REGEX)
1186         set(LYX_USE_STD_REGEX 0)
1187 endif()
1188
1189
1190 set (cmd ${CMAKE_CTEST_COMMAND})
1191 if (MSVC)
1192         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1193 else ()
1194         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1195 endif ()
1196 add_custom_target (lyx_run_tests COMMAND ${cmd})
1197 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1198
1199 if(LYX_INSTALL)
1200         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1201                 message(STATUS "Python required to create doc!")
1202         else()
1203                 if(UNIX)
1204                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1205                 endif()
1206                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1207         endif()
1208 endif()
1209 include(../Install)
1210
1211 # By running the URL tests first, time can be saved when running the ctests in
1212 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1213
1214 # Needed, because of perl scripts in checkurls autotests and batchtests
1215 find_package(Perl REQUIRED)
1216
1217 if(LYX_ENABLE_URLTESTS)
1218         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1219 endif()
1220 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1221 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1222 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1223 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1224 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1225 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1226 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1227
1228 message(STATUS)
1229 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1230 message(STATUS)
1231
1232 LYX_OPTION_LIST_ALL(used)
1233
1234
1235 if(LYX_NLS)
1236         message(STATUS)
1237         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1238         message(STATUS)
1239         message(STATUS "  * iconv")
1240         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1241         message(STATUS "     - library: ${ICONV_LIBRARY}")
1242         message(STATUS "  * zlib")
1243         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1244         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1245         message(STATUS)
1246 endif()
1247
1248 # Apple has builtin native spell checker,
1249 # no need to warn for missing Aspell, Hunspell or Enchant
1250 if(NOT Spelling_FOUND AND NOT APPLE)
1251   if(LYX_REQUIRE_SPELLCHECK)
1252     set(_mode "FATAL_ERROR")
1253   else()
1254     set(_mode "STATUS")
1255   endif()
1256   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1257 endif()
1258
1259 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1260
1261 if(ENABLE_DIST)
1262   # Use git to create the source package
1263   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1264   if(UNIX)
1265     set(DIST_FORMAT tgz)
1266   else()
1267     set(DIST_FORMAT zip)
1268   endif()
1269   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1270
1271   add_custom_command(
1272     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1273     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1274     WORKING_DIRECTORY ${TOP_SRC_DIR})
1275   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1276 endif()
1277
1278 # Last directory to be included so that the fixup code (OS X)
1279 # can be run last
1280 add_subdirectory(development/cmake/post_install)
1281
1282 message(STATUS)