CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 129 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 130 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 131 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 132 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 133 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 134 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 135 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 136 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 137 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 138 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 139 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 140 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 141 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 144 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 145
 146 # GCC specific
 147 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 148 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 149 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 150 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 151 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 152 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 153 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 154
 155 # MSVC specific
 156 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 157 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 158 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 159 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 160 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 161
 162 # APPLE specific
 163 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 164 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 165
 166
 167 if(help OR HELP)
 168         message(STATUS)
 169         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 170         message(STATUS)
 171         LYX_OPTION_LIST_ALL(help)
 172         message(STATUS)
 173         RETURN()
 174 endif()
 175
 176 # Check option dependencies
 177
 178 if(LYX_DMG)
 179         set(LYX_BUNDLE ON)
 180         set(LYX_CPACK ON)
 181 endif()
 182
 183 if(LYX_CPACK)
 184         set(LYX_INSTALL ON)
 185 endif()
 186
 187 if(LYX_INSTALL)
 188         set(LYX_NLS ON)
 189         if(WIN32 AND NOT MINGW)
 190                 set(LYX_HUNSPELL ON)
 191         endif()
 192         if(LYX_CONSOLE MATCHES "FORCE")
 193                 set(LYX_CONSOLE ON)
 194         else()
 195                 set(LYX_CONSOLE OFF)
 196         endif()
 197         set(LYX_PACKAGE_SUFFIX ON)
 198         if(NOT LYX_DEBUG)
 199                 set(LYX_RELEASE ON)
 200         endif()
 201         set(LYX_PROFILE OFF)
 202 endif()
 203
 204
 205 if(LYX_MERGE_FILES)
 206         set(LYX_PCH OFF)
 207 else()
 208         set(LYX_MERGE_REBUILD OFF)
 209 endif()
 210
 211
 212 if(LYX_DEPENDENCIES_DOWNLOAD)
 213         message(STATUS)
 214     if(MSVC12)
 215         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 216         set(deps_files lyx-windows-deps-msvc2013.zip)
 217         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 218         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 219     else()
 220         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 221             set(deps_files lyx20-deps-msvc2010-x86.zip)
 222             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 223         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 224     endif()
 225     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 226         foreach(it ${deps_files})
 227                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 228                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 229                 if(NOT already_downloaded)
 230                         message(STATUS "Downloading ${it} ...")
 231                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 232                         list(GET status 0 status_code)
 233                         list(GET status 1 status_string)
 234                         if(NOT status_code EQUAL 0)
 235                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 236                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 237                         endif()
 238                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 239                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 240                 endif()
 241         endforeach()
 242 endif()
 243
 244
 245
 246 message(STATUS)
 247
 248 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 249 if(WIN32)
 250         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 251 else()
 252         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 253 endif()
 254
 255
 256 # Set to some meaningful default
 257 find_package(CXX11Compiler)
 258 if(NOT CXX11COMPILER_FOUND)
 259         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 260 endif()
 261 set(LYX_GCC11_MODE)
 262 if(UNIX OR MINGW)
 263         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 264           # ignore the GCC_VERSION for clang
 265           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 266           message(STATUS "Using clang")
 267           if(CXX11_STD_REGEX)
 268             set(LYX_USE_STD_REGEX 1)
 269           else()
 270             set(LYX_USE_STD_REGEX 0)
 271           endif()
 272         else()
 273           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 274           message(STATUS "Using GCC version ${GCC_VERSION}")
 275           if(GCC_VERSION VERSION_LESS 4.9)
 276                   if(GCC_VERSION VERSION_LESS 4.3)
 277                           message(FATAL_ERROR "gcc >= 4.3 is required.")
 278                   endif()
 279                   # <regex> in gcc is unusable in versions less than 4.9.0
 280                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 281                   set(LYX_USE_STD_REGEX 0)
 282           else()
 283                   set(LYX_USE_STD_REGEX 1)
 284           endif()
 285         endif()
 286         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 287 else()
 288         set(LYX_USE_STD_REGEX 0)
 289 #       if(MSVC10)
 290 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 291 #       endif()
 292 endif()
 293
 294
 295 set(VERSION_INFO "CMake Build")
 296
 297 # Try to get some informations from configure.ac
 298
 299 include(LyXPaths)
 300 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 301
 302 if(WIN32)
 303         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 304         if(MSVC)
 305                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 306         endif()
 307         set(USE_WINDOWS_PACKAGING ON)
 308 elseif(APPLE)
 309         set(USE_MACOSX_PACKAGING ON)
 310 else()
 311         set(USE_POSIX_PACKAGING ON)
 312 endif()
 313
 314 macro(setstripped _varname)
 315         if(${ARGC} GREATER 1)
 316                 string(STRIP "${ARGV1}" _v)
 317                 if(USE_POSIX_PACKAGING)
 318                         string(TOLOWER ${_v} ${_varname})
 319                 else()
 320                         set(${_varname} ${_v})
 321                 endif()
 322         else()
 323                 set(${_varname})
 324         endif()
 325 endmacro(setstripped)
 326
 327 foreach(_c_l ${_config_lines} )
 328         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 329                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 330                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 331                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 332                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 333                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 334                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 335                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 336                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 337                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 338                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 339                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 340                         else()
 341                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 342                         endif()
 343                 endif()
 344         endif()
 345         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 346                 set(LYX_DATE "${CMAKE_MATCH_1}")
 347         endif()
 348 endforeach(_c_l)
 349
 350 FIND_PROGRAM(LYX_GITVERSION git)
 351 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 352 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 353 if(LYX_GITVERSION)
 354   if (LYX_LOCALVERSIONING)
 355     # Find the revision number and for later use
 356     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 357       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 358     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 359       # We will add offset of 40000 to get appropriate value to
 360       # previous svn.
 361       # We use this value than also to set the package-patch-value
 362       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 363       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 364       set(ENABLE_DIST ON)
 365     endif()
 366   endif()
 367 endif()
 368
 369 # Set the programs (lyx, tex2lyx, etc.) suffix
 370 # When building an OS X bundle, we will append
 371 # the suffix only to the bundle, not to the programs
 372 set(PROGRAM_SUFFIX "")
 373 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 374         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 375 endif()
 376 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 377 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 378
 379 add_custom_target(lyx_version ALL
 380   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 381   )
 382 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 383
 384 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 385 set(LYX_UTILITIES_INSTALL_PATH bin)
 386
 387 if(LYX_BUNDLE)
 388         set(LYX_CPACK ON)
 389
 390         message(STATUS)
 391         message(STATUS "Bundle creation is enabled (experimental):")
 392         message(STATUS "    make")
 393         message(STATUS "    make install/strip")
 394         message(STATUS "    make package")
 395         if(APPLE)
 396                 set(MACOSX_BUNDLE TRUE)
 397                 # This sets the bundle + executable names
 398                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 399                 # This sets the Info.plist executable name
 400                 set(osx_bundle_program_name ${_lyx})
 401                 # Bundle name
 402                 set(LYX_BUNDLE_NAME ${_lyx})
 403
 404                 # This will contain the list of files that need to be included
 405                 # in the bundle and their location within the bundle
 406                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 407                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 408
 409                 # Process Info.plist and lyxrc.dist
 410                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 411                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 412
 413                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 414                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 415
 416                 # Variables used by CPack
 417                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 418                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 419                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 420
 421                 # Set the install paths
 422                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 423                 if(NOT LYX_INSTALL_PREFIX)
 424                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 425                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 426                 endif()
 427                 # Change the owner so that the install can work
 428                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 429         elseif(UNIX)
 430                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 431                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 432                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 433         elseif(WIN32)
 434                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 435         endif()
 436 endif()
 437
 438 if(LYX_INSTALL_PREFIX)
 439         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 440         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 441 endif()
 442 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 443
 444 if(UNIX)
 445   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 446 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 447   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 448 else()
 449   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 450 endif()
 451
 452 if(LYX_PACKAGE_SUFFIX)
 453         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 454 else()
 455         set(PACKAGE ${PACKAGE_BASE})
 456 endif()
 457
 458 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 459         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 460         if (UNIX)
 461                 # use the default "/usr/local"
 462                 # but respect the user-choice on the command-line
 463                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 464         endif()
 465 endif()
 466 if(WIN32)
 467         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 468 endif()
 469 if(IS_ABSOLUTE)
 470         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 471 else()
 472         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 473 endif()
 474
 475
 476
 477 if(NOT LYX_DATA_SUBDIR)
 478         if (WIN32)
 479                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 480         else()
 481                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 482         endif()
 483 endif()
 484
 485 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 486 get_locale_destination(LYX_LOCALEDIR)
 487 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 488 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 489
 490 if(LYX_BUNDLE AND APPLE)
 491         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 492 else()
 493         if(WIN32)
 494                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 495         elseif(UNIX)
 496                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 497         else()
 498                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 499         endif()
 500 endif()
 501 mark_as_advanced(LYX_MAN_DIR)
 502
 503 if(LYX_INSTALL AND WIN32)
 504         message(STATUS "Configuring NSIS files")
 505         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 506         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 507         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 508         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 509 endif()
 510
 511 if(NOT GROUP_CODE)
 512         #set(GROUP_CODE "The Golden Code")
 513         set(GROUP_CODE flat)
 514 endif()
 515
 516 # lyx's source files
 517 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 518 set(LYX_HPP_FILES [a-zA-Z]*.h)
 519 set(LYX_MOC_FILES moc_*.cpp)
 520
 521 include(ProjectSourceGroup)
 522
 523
 524 if(LYX_PROFILE AND NOT MSVC)
 525         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 526         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 527         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 528 else()
 529         set(LYX_PROFILE OFF)
 530 endif()
 531
 532
 533 if(LYX_NO_OPTIMIZE)
 534         set(CMAKE_BUILD_TYPE None)
 535         set(LYX_DEBUG OFF)
 536         set(LYX_RELEASE OFF)
 537         set(LYX_PROFILE OFF)
 538 elseif(LYX_RELEASE)
 539         set(CMAKE_BUILD_TYPE Release)
 540         set(LYX_DEBUG OFF)
 541         set(LYX_PROFILE OFF)
 542 elseif(LYX_PROFILE)
 543         set(CMAKE_BUILD_TYPE Profile)
 544         set(LYX_DEBUG OFF)
 545 else()
 546         set(CMAKE_BUILD_TYPE Debug)
 547         set(LYX_DEBUG ON)
 548 endif()
 549
 550
 551 # When shared libs are supported enable this option
 552 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 553 if(LYX_SHARED_LIBRARIES)
 554         set(library_type SHARED)
 555 else()
 556         set(library_type STATIC)
 557 endif()
 558
 559 if(NOT MSVC)
 560         if(NOT LYX_QUIET)
 561                 set(CMAKE_VERBOSE_MAKEFILE ON)
 562         endif()
 563     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 564         if(LYX_STDLIB_DEBUG)
 565                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 566         endif()
 567         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 568         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 569         if(MINGW)
 570                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 571         else()
 572                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 573         endif()
 574 endif()
 575
 576 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 577 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 578 if(LYX_CXX_FLAGS_EXTRA)
 579         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 580                 add_definitions(${_flag})
 581         endforeach()
 582 endif()
 583
 584 if(LYX_XMINGW)
 585         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 586 endif()
 587
 588 if(LYX_USE_QT MATCHES "QT5")
 589         # set QPA_XCB if QT uses X11
 590         find_package(Qt5Core REQUIRED)
 591         if (Qt5Core_FOUND)
 592                 find_package(Qt5Widgets REQUIRED)
 593                 if(APPLE)
 594                         find_package(Qt5MacExtras REQUIRED)
 595                 endif()
 596                 find_package(Qt5X11Extras QUIET)
 597                 find_package(Qt5WinExtras QUIET)
 598                 set(QTVERSION ${Qt5Core_VERSION})
 599                 macro (qt_use_modules)
 600                         qt5_use_modules(${ARGN})
 601                 endmacro()
 602                 macro (qt_add_resources)
 603                         qt5_add_resources(${ARGN})
 604                 endmacro()
 605                 macro (qt_wrap_uifiles)
 606                         qt5_wrap_ui(${ARGN})
 607                 endmacro()
 608                 message(STATUS "Found Qt-Version ${QTVERSION}")
 609                 if(WIN32)
 610                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 611                 endif()
 612         endif()
 613 elseif(LYX_USE_QT MATCHES "QT4")
 614         if(LYX_XMINGW)
 615                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 616                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 617         endif()
 618         find_package(Qt4 "4.5.0" REQUIRED)
 619         macro (qt_use_modules)
 620         endmacro()
 621         macro (qt_add_resources)
 622                 qt4_add_resources(${ARGN})
 623         endmacro()
 624         macro (qt_wrap_uifiles)
 625                 qt4_wrap_ui(${ARGN})
 626         endmacro()
 627         if(WIN32)
 628                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 629         endif()
 630 else()
 631   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 632 endif()
 633
 634 find_package(Magic)
 635 if(Magic_FOUND)
 636         set(HAVE_MAGIC_H 1)
 637 endif()
 638
 639 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 640
 641 set(Spelling_FOUND OFF)
 642 set(Include_used_spellchecker)   # String will be inserted into config.h
 643
 644 if(LYX_3RDPARTY_BUILD)
 645     add_subdirectory(3rdparty/hunspell)
 646     add_definitions(-DHUNSPELL_STATIC)
 647     set(HUNSPELL_FOUND ON)
 648     message(STATUS "  * Hunspell:")
 649     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 650     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 651 endif()
 652
 653 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 654   string(TOUPPER ${_spell} _upspell)
 655   if (NOT ${_upspell}_FOUND)
 656     find_package(${_spell})
 657   endif()
 658   if (${_upspell}_FOUND)
 659     include_directories(${${_upspell}_INCLUDE_DIR})
 660     set(Spelling_FOUND ON)
 661     message(STATUS "Building with USE_${_upspell}")
 662     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 663   else()
 664     if(LYX_${_upspell})
 665       message(FATAL_ERROR "Required ${_spell} devel package not found")
 666     else()
 667       message(STATUS "${_upspell} not found, building without ${_spell} support")
 668     endif()
 669   endif()
 670 endforeach()
 671
 672 if(GNUWIN32_DIR)
 673         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 674 endif()
 675
 676 find_package(PythonInterp 2.7 QUIET)
 677 if(PYTHONINTERP_FOUND)
 678         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 679         unset(PYTHONINTERP_FOUND)
 680         endif()
 681 endif()
 682
 683 if(NOT PYTHONINTERP_FOUND)
 684   unset(PYTHON_EXECUTABLE CACHE)
 685   unset(PYTHON_VERSION_MAJOR)
 686   unset(PYTHON_VERSION_MINOR)
 687   unset(PYTHON_VERSION_STRING)
 688   find_package(PythonInterp 3.3 REQUIRED)
 689 endif()
 690
 691 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 692
 693 if(LYX_NLS)
 694         find_package(LyXGettext)
 695         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 696                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 697         else()
 698                 # Install only supplied .gmo-files
 699                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 700                 message(STATUS "Installing provided .gmo-files only")
 701                 foreach( _gmo ${_gmofiles})
 702                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 703                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 704                 endforeach()
 705         endif()
 706 endif()
 707
 708 if(UNIX)
 709     find_package(ICONV REQUIRED)
 710     find_package(ZLIB REQUIRED)
 711 else()
 712     if(LYX_3RDPARTY_BUILD)
 713         add_subdirectory(3rdparty/libiconv)
 714         set(HAVE_ICONV_CONST 1)
 715         add_subdirectory(3rdparty/zlib)
 716     endif()
 717 endif()
 718
 719 if(LYX_EXTERNAL_BOOST)
 720         message(STATUS "Searching for boost")
 721         if(NOT LYX_USE_STD_REGEX)
 722                 find_package(Boost COMPONENTS regex)
 723         endif()
 724         if(Boost_FOUND)
 725                 message(STATUS "Boost found")
 726                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 727                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 728                 if (LYX_STDLIB_DEBUG)
 729                         # Comment from  Jean-Marc Lasgouttes:
 730                         # In general, system boost libraries are incompatible with
 731                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 732                         # details.
 733                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 734                 endif()
 735         else()
 736                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 737         endif()
 738 else()
 739         if(NOT LYX_USE_STD_REGEX)
 740                 set(Lyx_Boost_Libraries boost_regex)
 741         endif()
 742         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 743         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 744         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 745 endif()
 746
 747
 748
 749
 750 if(WIN32)
 751         if(LYX_CONSOLE)
 752                 set(LYX_QTMAIN_LIBRARY)
 753         else()
 754                 set(WIN32_CONSOLE WIN32)
 755         endif()
 756         if(MSVC)
 757                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 758                 # disable checked iterators for msvc release builds to get maximum speed
 759                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 760         else()
 761                 add_definitions(-DWINVER=0x0500)
 762         endif()
 763 endif()
 764
 765 # Compute qt4-version from ${QTVERSION}
 766
 767 message(STATUS "")
 768 foreach(_v PACKAGE PACKAGE_VERSION
 769         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 770         LYX_ABS_TOP_SRCDIR
 771         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 772         if(NOT DEFINED ${_v})
 773                 message(FATAL_ERROR "${_v} not defined")
 774         endif()
 775         string(SUBSTRING "${_v}                            " 0 28 _v1)
 776         message(STATUS "----- ${_v1}: ${${_v}}")
 777 endforeach(_v)
 778 message(STATUS "")
 779
 780
 781 if(LYX_PCH)
 782         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 783         # Not sure if it works for all non-msvc compilers
 784         include(PCHSupport_26)
 785         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 786         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 787         add_definitions(-DLYX_ENABLE_PCH)
 788
 789         if(MSVC)
 790                 macro(lyx_add_msvc_pch name_)
 791                         set_source_files_properties(${${name_}_sources} PROPERTIES
 792                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 793                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 794                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 795                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 796                                 ${TOP_BINARY_DIR}/pcheaders.h)
 797                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 798                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 799                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 800                 endmacro(lyx_add_msvc_pch)
 801                 macro(lyx_add_gcc_pch name_)
 802                 endmacro()
 803         else()
 804                 macro(lyx_add_msvc_pch name_)
 805                 endmacro()
 806                 macro(lyx_add_gcc_pch name_)
 807                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 808                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 809                 endmacro()
 810         endif()
 811 else()
 812         macro(lyx_add_msvc_pch)
 813         endmacro(lyx_add_msvc_pch)
 814         macro(lyx_add_gcc_pch name_)
 815         endmacro()
 816 endif()
 817
 818
 819 if(MSVC)
 820
 821         if(LYX_VLD)
 822                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 823                 add_subdirectory(${vld_path}/cmake)
 824                 include(${vld_path}/cmake/vld.cmake) # forced include
 825                 set(vld_dll vld)
 826         endif()
 827
 828         if(LYX_WALL)
 829                 # Use the highest warning level
 830                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 831
 832                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 833                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 834                 else()
 835                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 836                 endif()
 837
 838                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 839                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 840                 else()
 841                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 842                 endif()
 843
 844                 # add here warnings which should produce an error /weXXXX
 845                 set(MSVC_W_ERROR   "/we4101 /we4189")
 846                 # add here warnings which should be disabled /wdXXXX
 847                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 848
 849                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 850                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 851                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 852
 853         else()
 854                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 855
 856                 # add here warnings which should produce an error /weXXXX
 857                 set(MSVC_W_ERROR   "/we4101 /we4189")
 858                 # add here warnings which should be disabled /wdXXXX
 859                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 860
 861                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 862                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 863                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 864
 865         endif()
 866
 867         if (NOT Qt5Core_FOUND)
 868                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 869                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 870                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 871         endif()
 872
 873         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 874         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 875         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 876         message(STATUS "")
 877 endif()
 878
 879
 880 if(LYX_DEBUG_GLIBC)
 881         set(_GLIBCXX_DEBUG ON)
 882 endif()
 883
 884 if(LYX_DEBUG_GLIBC_PEDANTIC)
 885         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 886 endif()
 887
 888 # Xcode compiler
 889 if (CMAKE_GENERATOR MATCHES Xcode)
 890         if (XCODE_VERSION VERSION_LESS "5.0")
 891                 # Automatically select the Xcode compiler if not set
 892                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 893                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 894                         if (XCODE_VERSION VERSION_GREATER "3.1")
 895                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 896                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 897                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 898                 # Print the selected compiler version
 899         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 900         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 901 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 902
 903 if (WIN32 AND Qt5Core_FOUND)
 904         set(Z_PREFIX 1)
 905 endif()
 906
 907 # compiler tests, config.h generation
 908 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 909         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 910 else()
 911         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 912         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 913 endif()
 914
 915 set(QPA_XCB)
 916 if(Qt5X11Extras_FOUND AND QT_USES_X11)
 917   # QPA_XCB is only valid if QT5+X11
 918   set(QPA_XCB 1)
 919 endif()
 920 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 921
 922 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 923         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 924 endif()
 925
 926 if (NOT HAVE_REGEX)
 927         set(LYX_USE_STD_REGEX 0)
 928 endif()
 929
 930
 931 set (cmd ${CMAKE_CTEST_COMMAND})
 932 if (MSVC)
 933         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 934 else ()
 935         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 936 endif ()
 937 add_custom_target (lyx_run_tests COMMAND ${cmd})
 938 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 939
 940 if(LYX_ASAN)
 941     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 942     message(STATUS)
 943     message(STATUS "Address sanitizer enabled. Usage:")
 944     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 945     message(STATUS "    chmod  +x ./asan_symbolize.py")
 946     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 947     message(STATUS)
 948 endif()
 949
 950 if(LYX_INSTALL)
 951         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 952                 message(STATUS "Python required to create doc!")
 953         else()
 954                 if(UNIX)
 955                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 956                 endif()
 957                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 958         endif()
 959         include(../Install)
 960 endif()
 961
 962 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 963 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 964 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 965 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 966 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 967 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 968 if(LYX_ENABLE_URLTESTS)
 969         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 970 endif()
 971
 972 message(STATUS)
 973 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 974 message(STATUS)
 975
 976 LYX_OPTION_LIST_ALL(used)
 977
 978
 979 if(LYX_NLS)
 980         message(STATUS)
 981         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 982         message(STATUS)
 983         message(STATUS "  * iconv")
 984         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 985         message(STATUS "     - library: ${ICONV_LIBRARY}")
 986         message(STATUS "  * zlib")
 987         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 988         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 989         message(STATUS)
 990 endif()
 991
 992 # Apple has builtin native spell checker,
 993 # no need to warn for missing Aspell, Hunspell or Enchant
 994 if(NOT Spelling_FOUND AND NOT APPLE)
 995   if(LYX_REQUIRE_SPELLCHECK)
 996     set(_mode "FATAL_ERROR")
 997   else()
 998     set(_mode "STATUS")
 999   endif()
1000   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1001 endif()
1002
1003 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1004
1005 if(ENABLE_DIST)
1006   # Use git to create the source package
1007   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1008   if(UNIX)
1009     set(DIST_FORMAT tgz)
1010   else()
1011     set(DIST_FORMAT zip)
1012   endif()
1013   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1014
1015   add_custom_command(
1016     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1017     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1018     WORKING_DIRECTORY ${TOP_SRC_DIR})
1019   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1020 endif()
1021
1022 # Last directory to be included so that the fixup code (OS X)
1023 # can be run last
1024 add_subdirectory(development/cmake/post_install)
1025
1026 message(STATUS)