CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 include(LyXMacros)
  46
  47 # Usage LYX_OPTION
  48 # 1. parameter: option name without prefix 'LYX_'
  49 # 2. parameter: description
  50 # 3. parameter: default value, ON or OFF
  51 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  52
  53
  54 LYX_OPTION_INIT()
  55
  56 # Options for all compilers/systems
  57 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  58 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  59 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  60 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  61 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  62 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  63 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  64 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  65 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  66 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  67 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  68 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  69 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  70 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  71 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  72 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  73 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  74 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  75
  76 # GCC specific
  77 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  78 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  79 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  80 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  81 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  82 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  83 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
  84
  85 # MSVC specific
  86 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
  87 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
  88 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
  89 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
  90 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  91
  92 # APPLE specific
  93 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
  94 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
  95
  96
  97 if(help OR HELP)
  98         message(STATUS)
  99         message(STATUS "Available options: (dis/enable with -D=0/1)")
 100         message(STATUS)
 101         LYX_OPTION_LIST_ALL(help)
 102         message(STATUS)
 103 else()
 104
 105
 106 # Check option dependencies
 107
 108 if(LYX_CPACK)
 109         set(LYX_INSTALL ON)
 110 endif()
 111
 112 if(LYX_DMG)
 113         set(LYX_BUNDLE 1)
 114         set(LYX_CPACK 1)
 115 endif()
 116
 117 if(LYX_INSTALL)
 118         set(LYX_NLS ON)
 119         if (WIN32)
 120                 set(LYX_HUNSPELL ON)
 121         endif()
 122         set(LYX_CONSOLE OFF)
 123         set(LYX_PACKAGE_SUFFIX ON)
 124         set(LYX_RELEASE ON)
 125         set(LYX_PROFILE OFF)
 126 endif()
 127
 128
 129 if(LYX_MERGE_FILES)
 130         set(LYX_PCH OFF)
 131 else()
 132         set(LYX_MERGE_REBUILD OFF)
 133 endif()
 134
 135 if(LYX_DEPENDENCIES_DOWNLOAD)
 136         message(STATUS)
 137         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 138         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 139         set(deps_files lyx20-deps-msvc2010-x86.zip)
 140         foreach(it ${deps_files})
 141                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 142                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 143                 if(NOT already_downloaded)
 144                         message(STATUS "Downloading ${it} ...")
 145                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 146                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 147                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 148                 endif()
 149         endforeach()
 150         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 151 endif()
 152
 153
 154
 155 message(STATUS)
 156
 157 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 158 set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 159
 160
 161
 162 if(UNIX OR MINGW)
 163         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 164         message(STATUS "Using GCC version ${GCC_VERSION}")
 165         if(NOT GCC_VERSION VERSION_LESS 4.4)
 166                 set(LYX_USE_TR1 1)
 167                 # GCC <= 4.5 does not support regex: there are linker errors
 168                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 169                 set(LYX_USE_TR1_REGEX 0)
 170         endif()
 171 else()
 172         if(MSVC10)
 173                 set(LYX_USE_TR1 1)
 174                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 175         endif()
 176 endif()
 177
 178
 179 set(VERSION_INFO "CMake Build")
 180
 181 # Try to get some informations from configure.ac
 182
 183 include(LyXPaths)
 184 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 185
 186 if(WIN32)
 187         set(USE_WINDOWS_PACKAGING 1)
 188 elseif(APPLE)
 189         set(USE_MACOSX_PACKAGING 1)
 190 else()
 191         set(USE_POSIX_PACKAGING 1)
 192 endif()
 193
 194 macro(setstripped _varname _value)
 195         string(STRIP ${_value} _v)
 196         if(USE_POSIX_PACKAGING)
 197                 string(TOLOWER ${_v} ${_varname})
 198         else()
 199                 set(${_varname} ${_v})
 200         endif()
 201 endmacro(setstripped)
 202
 203 foreach(_c_l ${_config_lines} )
 204         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 205                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 206                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 207                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 208                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 209                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 210                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 211                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 212                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 213                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 214                 endif()
 215         endif()
 216         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 217                 set(LYX_DATE "${CMAKE_MATCH_1}")
 218         endif()
 219 endforeach(_c_l)
 220
 221
 222 if(LYX_PROGRAM_SUFFIX)
 223         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 224 else()
 225         set(PROGRAM_SUFFIX "")
 226 endif()
 227
 228
 229 if(LYX_BUNDLE)
 230         if(APPLE)
 231                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 232                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 233                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 234                 if(NOT LYX_INSTALL_PREFIX)
 235                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 236                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 237                 endif()
 238         endif()
 239
 240         message(STATUS)
 241         message(STATUS "Bundle creation is enabled (experimental):")
 242         message(STATUS "    make")
 243         message(STATUS "    make install/strip")
 244         message(STATUS "    make package")
 245         message(STATUS "To increase turn around speed use:")
 246         message(STATUS "    cmake -DLYX_MERGE_FILES=1 -DLYX_NO_OPTIMIZE=1 -DLYX_INSTALL=1 -DLYX_DMG=1 ../trunk")
 247         message(STATUS "or use the shell script 'development/cmake/dmg'")
 248         message(STATUS)
 249 endif()
 250
 251
 252 if(LYX_INSTALL_PREFIX)
 253         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 254         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 255 endif()
 256 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 257
 258 if(LYX_PACKAGE_SUFFIX)
 259         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 260 else()
 261         set(PACKAGE ${PACKAGE_BASE})
 262 endif()
 263
 264
 265
 266 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 267         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 268         if (UNIX)
 269                 # don't use the default "/usr/local"
 270                 # but respect the user-choice on the command-line
 271                 if(LYX_INSTALL_SUFFIX)
 272                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 273                 else()
 274                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 275                 endif()
 276         endif()
 277         if(WIN32)
 278                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 279         endif()
 280 endif()
 281
 282 if(NOT LYX_DATA_SUBDIR)
 283         if (WIN32)
 284                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 285         else()
 286                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 287         endif()
 288 endif()
 289
 290 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 291 set(LYX_LOCALEDIR "locale")
 292 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 293 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 294
 295
 296
 297 if(NOT GROUP_CODE)
 298         #set(GROUP_CODE "The Golden Code")
 299         set(GROUP_CODE flat)
 300 endif()
 301
 302 # lyx's source files
 303 set(LYX_CPP_FILES *.cpp)
 304 set(LYX_HPP_FILES *.h)
 305 set(LYX_MOC_FILES moc_*.cpp)
 306
 307 include(ProjectSourceGroup)
 308
 309
 310 if(LYX_PROFILE)
 311         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 312         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 313 endif()
 314
 315
 316 if(LYX_NO_OPTIMIZE)
 317         set(CMAKE_BUILD_TYPE None)
 318         set(LYX_DEBUG OFF)
 319         set(LYX_RELEASE OFF)
 320 elseif(LYX_RELEASE)
 321         set(CMAKE_BUILD_TYPE Release)
 322         set(LYX_DEBUG OFF)
 323 else()
 324         set(CMAKE_BUILD_TYPE Debug)
 325 endif()
 326
 327
 328 # When shared libs are supported enable this option
 329 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 330 if(LYX_SHARED_LIBRARIES)
 331         set(library_type SHARED)
 332 else()
 333         set(library_type STATIC)
 334 endif()
 335
 336 if(NOT MSVC)
 337         if(NOT LYX_QUIET)
 338                 set(CMAKE_VERBOSE_MAKEFILE ON)
 339         endif()
 340         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 341         if(LYX_STDLIB_DEBUG)
 342                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 343         endif()
 344         if(LYX_CONCEPT_CHECKS)
 345                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 346         endif()
 347         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 348         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 349         if(MINGW)
 350                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 351         else()
 352                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 353         endif()
 354         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 355 endif()
 356
 357
 358 find_package(Qt4 REQUIRED)
 359
 360
 361 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 362
 363 if(LYX_ASPELL)
 364         find_package(ASPELL)
 365         include_directories(${ASPELL_INCLUDE_DIR})
 366 endif()
 367
 368 if(LYX_ENCHANT)
 369         find_package(Enchant REQUIRED)
 370         include_directories(${ENCHANT_INCLUDE_DIR})
 371 endif()
 372
 373 if(LYX_HUNSPELL)
 374         find_package(Hunspell REQUIRED)
 375         include_directories(${HUNSPELL_INCLUDE_DIR})
 376 endif()
 377
 378 if(LYX_NLS)
 379         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 380         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 381                 message(FATAL_ERROR "Python 2.6 needed!")
 382         endif()
 383         find_package(LyXGettext REQUIRED)
 384         include_directories(${TOP_SRC_DIR}/po)
 385         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 386 endif()
 387
 388 if(LYX_NLS)
 389         if(LYX_EXTERNAL_LIBINTL)
 390                 find_package(Libintl REQUIRED)
 391                 if(DEFINED LIBINTL_LIBRARIES)
 392                         # find getext when configuring
 393                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 394                         # on mac use iconv also form ports
 395                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 396                 endif()
 397         else()
 398                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 399         endif()
 400 endif()
 401
 402 find_package(ICONV REQUIRED)
 403 find_package(ZLIB REQUIRED)
 404
 405 if(LYX_EXTERNAL_BOOST)
 406         message(STATUS "Searching for boost")
 407         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 408         if(Boost_FOUND)
 409                 message(STATUS "Boost found")
 410                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 411                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 412         else()
 413                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 414         endif()
 415 else()
 416         if(LYX_USE_TR1_REGEX)
 417                 set(Lyx_Boost_Libraries boost_signals)
 418         else()
 419                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 420         endif()
 421         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 422         include_directories(${TOP_SRC_DIR}/boost)
 423         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 424 endif()
 425
 426
 427
 428
 429 if(WIN32)
 430         if(NOT LYX_CONSOLE)
 431                 set(WIN32_CONSOLE WIN32)
 432                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 433         endif()
 434         if(MSVC)
 435                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 436                 # disable checked iterators for msvc release builds to get maximum speed
 437                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 438         else()
 439                 add_definitions(-DWINVER=0x0500)
 440         endif()
 441 endif()
 442
 443 message(STATUS "")
 444 foreach(_v PACKAGE PACKAGE_VERSION
 445         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 446         LYX_ABS_TOP_SRCDIR
 447         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 448         if(NOT DEFINED ${_v})
 449                 message(FATAL_ERROR "${_v} not defined")
 450         endif()
 451         string(SUBSTRING "${_v}                            " 0 28 _v1)
 452         message(STATUS "----- ${_v1}: ${${_v}}")
 453 endforeach(_v)
 454 message(STATUS "")
 455
 456
 457 if(LYX_PCH)
 458         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 459         # Not sure if it works for all non-msvc compilers
 460         include(PCHSupport_26)
 461         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 462         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 463         add_definitions(-DLYX_ENABLE_PCH)
 464
 465         if(MSVC)
 466                 macro(lyx_add_msvc_pch name_)
 467                         set_source_files_properties(${${name_}_sources} PROPERTIES
 468                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 469                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 470                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 471                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 472                                 ${TOP_BINARY_DIR}/pcheaders.h)
 473                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 474                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 475                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 476                 endmacro(lyx_add_msvc_pch)
 477                 macro(lyx_add_gcc_pch name_)
 478                 endmacro()
 479         else()
 480                 macro(lyx_add_msvc_pch name_)
 481                 endmacro()
 482                 macro(lyx_add_gcc_pch name_)
 483                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 484                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 485                 endmacro()
 486         endif()
 487 else()
 488         macro(lyx_add_msvc_pch)
 489         endmacro(lyx_add_msvc_pch)
 490         macro(lyx_add_gcc_pch name_)
 491         endmacro()
 492 endif()
 493
 494 if(MSVC)
 495         if(LYX_VLD)
 496                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 497                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 498                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 499                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 500         endif()
 501
 502         if(LYX_WALL)
 503                 # Use the highest warning level
 504                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 505
 506                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 507                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 508                 else()
 509                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 510                 endif()
 511
 512                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 513                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 514                 else()
 515                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 516                 endif()
 517
 518                 # add here warnings which should produce an error /weXXXX
 519                 set(MSVC_W_ERROR   "/we4101 /we4189")
 520                 # add here warnings which should be disabled /wdXXXX
 521                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 522
 523                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 524                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 525                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 526
 527         else()
 528                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 529
 530                 # add here warnings which should produce an error /weXXXX
 531                 set(MSVC_W_ERROR   "/we4101 /we4189")
 532                 # add here warnings which should be disabled /wdXXXX
 533                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 534
 535                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 536                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 537                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 538
 539         endif()
 540         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 541         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 542         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 543
 544         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 545         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 546         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 547         message(STATUS "")
 548 endif()
 549
 550
 551 if(LYX_DEBUG_GLIBC)
 552         set(_GLIBCXX_DEBUG 1)
 553 endif()
 554
 555 if(LYX_DEBUG_GLIBC_PEDANTIC)
 556         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 557 endif()
 558
 559 # compiler tests, config.h generation
 560 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 561         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 562 else()
 563         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 564         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 565 endif()
 566
 567 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 568
 569
 570 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 571 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 572 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 573
 574
 575 if(LYX_INSTALL)
 576         #FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 577         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 578                 message(STATUS "Python required to create doc!")
 579         else()
 580                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 581                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 582         endif()
 583         include(../Install)
 584 endif()
 585
 586 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 587
 588 message(STATUS)
 589 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 590 message(STATUS)
 591 LYX_OPTION_LIST_ALL(used)
 592
 593
 594 if(LYX_NLS)
 595         message(STATUS)
 596         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 597         message(STATUS)
 598         message(STATUS "  * intl")
 599         message(STATUS "     - header : ${LIBINTL_HEADER}")
 600         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 601         message(STATUS "  * iconv")
 602         message(STATUS "     - header : ${ICONV_HEADER}")
 603         message(STATUS "     - library: ${ICONV_LIBRARY}")
 604         message(STATUS "  * zlib")
 605         message(STATUS "     - header : ${ZLIB_HEADER}")
 606         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 607         message(STATUS)
 608 endif()
 609
 610
 611 # CPack packaging
 612 #
 613 # http://cmake.org/cmake/help/cmake-2-8-docs.html#module:CPack
 614
 615 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 616 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 617 FILE(STRINGS "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 618
 619 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 620 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 621
 622 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 623
 624 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 625 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 626 #
 627 # needed by rpm
 628 set(CPACK_SET_DESTDIR "ON")
 629 FILE(READ "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 630 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 631 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 632 #
 633 # the next ones are needed by deb
 634 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 635 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 636
 637 # This is experimental, valid on _my_ system (Kornel)
 638 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 639 if(ASPELL_FOUND)
 640         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 641 endif()
 642 if(ENCHANT_FOUND)
 643         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 644 endif()
 645 if(LYX_EXTERNAL_BOOST)
 646         if(Boost_FOUND)
 647                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 648         endif()
 649 endif()
 650 #
 651 # for the next ones, cpack insists on data with values in some file
 652 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_description.txt")
 653 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt")
 654
 655 # Find the revision number and use it as the release in rpm-package-build.
 656 # This way we may omit the otherwise needed "--force" parameter when
 657 # installing from that rpm package.
 658 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 659 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 660 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 661         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 662         # We use this value also to set the package-patch-value
 663         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 664                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 665         endif()
 666 endif()
 667
 668 # we do not have a readme or welcome data,
 669 # so we do not provide infofiles for
 670 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 671
 672 if(WIN32)
 673         set(CPACK_GENERATOR NSIS ZIP)
 674         set(CPACK_BINARY_ZIP 1)
 675 endif()
 676
 677
 678 set(CPACK_STRIP_FILES 1)
 679
 680 # sources
 681 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 682 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 683
 684
 685 set(CPACK_PACKAGE_NAME LyX)
 686 if(APPLE)
 687         set(CPACK_GENERATOR DragNDrop)
 688 elseif(WIN32)
 689         set(CPACK_GENERATOR ZIP)
 690         #TODO set(CPACK_GENERATOR ZIP NSIS)
 691 elseif()
 692         # .sh on linux?
 693 endif()
 694
 695 if(LYX_CPACK)
 696         include(CPack)
 697 endif()
 698
 699
 700 #Now it is possible to create some packages
 701 # cd <BuildDir>
 702 # make package
 703 #############################################################################################
 704 # So, e.g. for variables
 705 #    CMAKE_PROJECT_NAME                     : lyx
 706 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 707 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 708 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 709 #    CMAKE_SYSTEM_NAME                      : Linux
 710 #    CPACK_BINARY_DEB:BOOL                  : ON
 711 #
 712 # the package name builds as "lyx-2.0.1-Linux.deb"
 713 #
 714 ############################## rpm ################################### deb ##################
 715 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 716 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 717 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 718 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 719 #
 720 message(STATUS)
 721
 722 endif() #help
 723