CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 include(LyXMacros)
  46
  47 # Usage LYX_OPTION
  48 # 1. parameter: option name without prefix 'LYX_'
  49 # 2. parameter: description
  50 # 3. parameter: default value, ON or OFF
  51 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  52
  53
  54 LYX_OPTION_INIT()
  55
  56 # Options for all compilers/systems
  57 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  58 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  59 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  60 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  61 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  62 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  63 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  64 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  65 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  66 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  67 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  68 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  69 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  70 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  71 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  72 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  73 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  74 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  75
  76 # GCC specific
  77 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  78 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  79 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  80 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  81 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  82 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  83 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
  84
  85 # MSVC specific
  86 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
  87 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
  88 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
  89 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
  90 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  91
  92 # APPLE specific
  93 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
  94 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
  95
  96
  97 if(help OR HELP)
  98         message(STATUS)
  99         message(STATUS "Available options: (dis/enable with -D=0/1)")
 100         message(STATUS)
 101         LYX_OPTION_LIST_ALL(help)
 102         message(STATUS)
 103 else()
 104
 105
 106 # Check option dependencies
 107
 108 if(LYX_CPACK)
 109         set(LYX_INSTALL ON)
 110 endif()
 111
 112 if(LYX_DMG)
 113         set(LYX_BUNDLE 1)
 114         set(LYX_CPACK 1)
 115 endif()
 116
 117 if(LYX_INSTALL)
 118         set(LYX_NLS ON)
 119         if (WIN32)
 120                 set(LYX_HUNSPELL ON)
 121         endif()
 122         set(LYX_CONSOLE OFF)
 123         set(LYX_PACKAGE_SUFFIX ON)
 124         set(LYX_RELEASE ON)
 125         set(LYX_PROFILE OFF)
 126 endif()
 127
 128
 129 if(LYX_MERGE_FILES)
 130         set(LYX_PCH OFF)
 131 else()
 132         set(LYX_MERGE_REBUILD OFF)
 133 endif()
 134
 135 if(LYX_DEPENDENCIES_DOWNLOAD)
 136         message(STATUS)
 137         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 138         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 139         set(deps_files lyx20-deps-msvc2010-x86.zip)
 140         foreach(it ${deps_files})
 141                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 142                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 143                 if(NOT already_downloaded)
 144                         message(STATUS "Downloading ${it} ...")
 145                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 146                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 147                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 148                 endif()
 149         endforeach()
 150         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 151 endif()
 152
 153
 154
 155 message(STATUS)
 156
 157 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 158 set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 159
 160
 161
 162 if(UNIX OR MINGW)
 163         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 164         message(STATUS "Using GCC version ${GCC_VERSION}")
 165         if(NOT GCC_VERSION VERSION_LESS 4.4)
 166                 set(LYX_USE_TR1 1)
 167                 # GCC <= 4.5 does not support regex: there are linker errors
 168                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 169                 set(LYX_USE_TR1_REGEX 0)
 170         endif()
 171 else()
 172         if(MSVC10)
 173                 set(LYX_USE_TR1 1)
 174                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 175         endif()
 176 endif()
 177
 178
 179 set(VERSION_INFO "CMake Build")
 180
 181 # Try to get some informations from configure.ac
 182
 183 include(LyXPaths)
 184 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 185
 186 if(WIN32)
 187         set(USE_WINDOWS_PACKAGING 1)
 188 elseif(APPLE)
 189         set(USE_MACOSX_PACKAGING 1)
 190 else()
 191         set(USE_POSIX_PACKAGING 1)
 192 endif()
 193
 194 macro(setstripped _varname _value)
 195         string(STRIP ${_value} _v)
 196         if(USE_POSIX_PACKAGING)
 197                 string(TOLOWER ${_v} ${_varname})
 198         else()
 199                 set(${_varname} ${_v})
 200         endif()
 201 endmacro(setstripped)
 202
 203 foreach(_c_l ${_config_lines} )
 204         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 205                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 206                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 207                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 208                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 209                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 210                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 211                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4}) # TODO 2.1.0svn, LYX_PATCH_VERSION == 0
 212                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 213                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 214                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 215                 endif()
 216         endif()
 217         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 218                 set(LYX_DATE "${CMAKE_MATCH_1}")
 219         endif()
 220 endforeach(_c_l)
 221
 222 # Find the revision number and use it as the release in rpm-package-build.
 223 # This way we may omit the otherwise needed "--force" parameter when
 224 # installing from that rpm package.
 225 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 226 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 227 if(LYX_SVNVERSION)
 228         # TODO revision number has nothing to do with cpack vars: split out
 229         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 230         # We use this value also to set the package-patch-value
 231         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 232                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1}) # TODO this is not the patch level
 233                 set(LYX_REVISION_VERSION ${CMAKE_MATCH_1})
 234         endif()
 235 else()
 236         set(LYX_REVISION_VERSION svn) #TODO use date
 237 endif()
 238
 239
 240
 241 if(LYX_PROGRAM_SUFFIX)
 242         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 243 else()
 244         set(PROGRAM_SUFFIX "")
 245 endif()
 246
 247
 248 if(LYX_BUNDLE)
 249         set(LYX_CPACK 1)
 250         message(STATUS)
 251         message(STATUS "Bundle creation is enabled (experimental):")
 252         message(STATUS "    make")
 253         message(STATUS "    make install/strip")
 254         message(STATUS "    make package")
 255         if(APPLE)
 256                 set(CPACK_GENERATOR DragNDrop)
 257                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 258                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 259                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 260                 if(NOT LYX_INSTALL_PREFIX)
 261                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 262                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 263                 endif()
 264         elseif(UNIX)
 265                 set(CPACK_GENERATOR STGZ)
 266                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 267                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 268                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 269         elseif(WIN32)
 270                 set(CPACK_GENERATOR ZIP)
 271                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 272         endif()
 273 endif()
 274
 275
 276 if(LYX_INSTALL_PREFIX)
 277         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 278         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 279 endif()
 280 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 281
 282 if(LYX_PACKAGE_SUFFIX)
 283         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 284 else()
 285         set(PACKAGE ${PACKAGE_BASE})
 286 endif()
 287
 288
 289
 290 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 291         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 292         if (UNIX)
 293                 # don't use the default "/usr/local"
 294                 # but respect the user-choice on the command-line
 295                 if(LYX_INSTALL_SUFFIX)
 296                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 297                 else()
 298                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 299                 endif()
 300         endif()
 301         if(WIN32)
 302                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 303         endif()
 304 endif()
 305 if(IS_ABSOLUTE)
 306         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 307 else()
 308         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 309 endif()
 310
 311
 312
 313 if(NOT LYX_DATA_SUBDIR)
 314         if (WIN32)
 315                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 316         else()
 317                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 318         endif()
 319 endif()
 320
 321 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 322 set(LYX_LOCALEDIR "locale")
 323 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 324 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 325
 326
 327 if(LYX_INSTALL AND WIN32)
 328         message(STATUS "Configuring NSIS files")
 329         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 330         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 331         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 332         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 333 endif()
 334
 335 if(NOT GROUP_CODE)
 336         #set(GROUP_CODE "The Golden Code")
 337         set(GROUP_CODE flat)
 338 endif()
 339
 340 # lyx's source files
 341 set(LYX_CPP_FILES *.cpp)
 342 set(LYX_HPP_FILES *.h)
 343 set(LYX_MOC_FILES moc_*.cpp)
 344
 345 include(ProjectSourceGroup)
 346
 347
 348 if(LYX_PROFILE)
 349         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 350         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 351 endif()
 352
 353
 354 if(LYX_NO_OPTIMIZE)
 355         set(CMAKE_BUILD_TYPE None)
 356         set(LYX_DEBUG OFF)
 357         set(LYX_RELEASE OFF)
 358 elseif(LYX_RELEASE)
 359         set(CMAKE_BUILD_TYPE Release)
 360         set(LYX_DEBUG OFF)
 361 else()
 362         set(CMAKE_BUILD_TYPE Debug)
 363 endif()
 364
 365
 366 # When shared libs are supported enable this option
 367 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 368 if(LYX_SHARED_LIBRARIES)
 369         set(library_type SHARED)
 370 else()
 371         set(library_type STATIC)
 372 endif()
 373
 374 if(NOT MSVC)
 375         if(NOT LYX_QUIET)
 376                 set(CMAKE_VERBOSE_MAKEFILE ON)
 377         endif()
 378         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 379         if(LYX_STDLIB_DEBUG)
 380                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 381         endif()
 382         if(LYX_CONCEPT_CHECKS)
 383                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 384         endif()
 385         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 386         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 387         if(MINGW)
 388                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 389         else()
 390                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 391         endif()
 392         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 393 endif()
 394
 395
 396 find_package(Qt4 REQUIRED)
 397
 398
 399 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 400
 401 if(LYX_ASPELL)
 402         find_package(ASPELL)
 403         include_directories(${ASPELL_INCLUDE_DIR})
 404 endif()
 405
 406 if(LYX_ENCHANT)
 407         find_package(Enchant REQUIRED)
 408         include_directories(${ENCHANT_INCLUDE_DIR})
 409 endif()
 410
 411 if(LYX_HUNSPELL)
 412         find_package(Hunspell REQUIRED)
 413         include_directories(${HUNSPELL_INCLUDE_DIR})
 414 endif()
 415
 416 if(LYX_NLS)
 417         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 418         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 419                 message(FATAL_ERROR "Python 2.6 needed!")
 420         endif()
 421         find_package(LyXGettext REQUIRED)
 422         include_directories(${TOP_SRC_DIR}/po)
 423         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 424 endif()
 425
 426 if(LYX_NLS)
 427         if(LYX_EXTERNAL_LIBINTL)
 428                 find_package(Libintl REQUIRED)
 429                 if(DEFINED LIBINTL_LIBRARIES)
 430                         # find getext when configuring
 431                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 432                         # on mac use iconv also form ports
 433                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 434                 endif()
 435         else()
 436                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 437         endif()
 438 endif()
 439
 440 find_package(ICONV REQUIRED)
 441 find_package(ZLIB REQUIRED)
 442
 443 if(LYX_EXTERNAL_BOOST)
 444         message(STATUS "Searching for boost")
 445         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 446         if(Boost_FOUND)
 447                 message(STATUS "Boost found")
 448                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 449                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 450         else()
 451                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 452         endif()
 453 else()
 454         if(LYX_USE_TR1_REGEX)
 455                 set(Lyx_Boost_Libraries boost_signals)
 456         else()
 457                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 458         endif()
 459         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 460         include_directories(${TOP_SRC_DIR}/boost)
 461         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 462 endif()
 463
 464
 465
 466
 467 if(WIN32)
 468         if(NOT LYX_CONSOLE)
 469                 set(WIN32_CONSOLE WIN32)
 470                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 471         endif()
 472         if(MSVC)
 473                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 474                 # disable checked iterators for msvc release builds to get maximum speed
 475                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 476         else()
 477                 add_definitions(-DWINVER=0x0500)
 478         endif()
 479 endif()
 480
 481 message(STATUS "")
 482 foreach(_v PACKAGE PACKAGE_VERSION
 483         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 484         LYX_ABS_TOP_SRCDIR
 485         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 486         if(NOT DEFINED ${_v})
 487                 message(FATAL_ERROR "${_v} not defined")
 488         endif()
 489         string(SUBSTRING "${_v}                            " 0 28 _v1)
 490         message(STATUS "----- ${_v1}: ${${_v}}")
 491 endforeach(_v)
 492 message(STATUS "")
 493
 494
 495 if(LYX_PCH)
 496         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 497         # Not sure if it works for all non-msvc compilers
 498         include(PCHSupport_26)
 499         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 500         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 501         add_definitions(-DLYX_ENABLE_PCH)
 502
 503         if(MSVC)
 504                 macro(lyx_add_msvc_pch name_)
 505                         set_source_files_properties(${${name_}_sources} PROPERTIES
 506                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 507                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 508                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 509                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 510                                 ${TOP_BINARY_DIR}/pcheaders.h)
 511                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 512                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 513                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 514                 endmacro(lyx_add_msvc_pch)
 515                 macro(lyx_add_gcc_pch name_)
 516                 endmacro()
 517         else()
 518                 macro(lyx_add_msvc_pch name_)
 519                 endmacro()
 520                 macro(lyx_add_gcc_pch name_)
 521                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 522                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 523                 endmacro()
 524         endif()
 525 else()
 526         macro(lyx_add_msvc_pch)
 527         endmacro(lyx_add_msvc_pch)
 528         macro(lyx_add_gcc_pch name_)
 529         endmacro()
 530 endif()
 531
 532 if(MSVC)
 533         if(LYX_VLD)
 534                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 535                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 536                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 537                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 538         endif()
 539
 540         if(LYX_WALL)
 541                 # Use the highest warning level
 542                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 543
 544                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 545                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 546                 else()
 547                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 548                 endif()
 549
 550                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 551                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 552                 else()
 553                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 554                 endif()
 555
 556                 # add here warnings which should produce an error /weXXXX
 557                 set(MSVC_W_ERROR   "/we4101 /we4189")
 558                 # add here warnings which should be disabled /wdXXXX
 559                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 560
 561                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 562                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 563                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 564
 565         else()
 566                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 567
 568                 # add here warnings which should produce an error /weXXXX
 569                 set(MSVC_W_ERROR   "/we4101 /we4189")
 570                 # add here warnings which should be disabled /wdXXXX
 571                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 572
 573                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 574                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 575                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 576
 577         endif()
 578         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 579         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 580         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 581
 582         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 583         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 584         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 585         message(STATUS "")
 586 endif()
 587
 588
 589 if(LYX_DEBUG_GLIBC)
 590         set(_GLIBCXX_DEBUG 1)
 591 endif()
 592
 593 if(LYX_DEBUG_GLIBC_PEDANTIC)
 594         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 595 endif()
 596
 597 # compiler tests, config.h generation
 598 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 599         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 600 else()
 601         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 602         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 603 endif()
 604
 605 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 606
 607
 608 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 609 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 610 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 611
 612
 613 if(LYX_INSTALL)
 614         #FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 615         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 616                 message(STATUS "Python required to create doc!")
 617         else()
 618                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 619                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 620         endif()
 621         include(../Install)
 622 endif()
 623
 624 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 625
 626 message(STATUS)
 627 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 628 message(STATUS)
 629 LYX_OPTION_LIST_ALL(used)
 630
 631
 632 if(LYX_NLS)
 633         message(STATUS)
 634         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 635         message(STATUS)
 636         message(STATUS "  * intl")
 637         message(STATUS "     - header : ${LIBINTL_HEADER}")
 638         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 639         message(STATUS "  * iconv")
 640         message(STATUS "     - header : ${ICONV_HEADER}")
 641         message(STATUS "     - library: ${ICONV_LIBRARY}")
 642         message(STATUS "  * zlib")
 643         message(STATUS "     - header : ${ZLIB_HEADER}")
 644         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 645         message(STATUS)
 646 endif()
 647
 648
 649 # CPack packaging
 650 #
 651 # http://cmake.org/cmake/help/cmake-2-8-docs.html#module:CPack
 652
 653 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 654 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 655 FILE(STRINGS "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 656
 657
 658 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 659
 660 #
 661 # needed by rpm
 662 set(CPACK_SET_DESTDIR "ON")
 663 FILE(READ "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 664 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 665 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 666 #
 667 # the next ones are needed by deb
 668 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 669 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 670
 671 # This is experimental, valid on _my_ system (Kornel)
 672 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 673 if(ASPELL_FOUND)
 674         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 675 endif()
 676 if(ENCHANT_FOUND)
 677         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 678 endif()
 679 if(LYX_EXTERNAL_BOOST)
 680         if(Boost_FOUND)
 681                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 682         endif()
 683 endif()
 684 #
 685 # for the next ones, cpack insists on data with values in some file
 686 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_description.txt")
 687 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt")
 688
 689
 690
 691 # we do not have a readme or welcome data,
 692 # so we do not provide infofiles for
 693 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 694
 695 # sources
 696 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 697
 698
 699 set(CPACK_STRIP_FILES 1)
 700
 701
 702
 703 if(LYX_CPACK)
 704         include(CPack)
 705 endif()
 706
 707
 708 #Now it is possible to create some packages
 709 # cd <BuildDir>
 710 # make package
 711 #############################################################################################
 712 # So, e.g. for variables
 713 #    CMAKE_PROJECT_NAME                     : lyx
 714 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 715 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 716 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 717 #    CMAKE_SYSTEM_NAME                      : Linux
 718 #    CPACK_BINARY_DEB:BOOL                  : ON
 719 #
 720 # the package name builds as "lyx-2.0.1-Linux.deb"
 721 #
 722 ############################## rpm ################################### deb ##################
 723 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 724 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 725 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 726 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 727 #
 728 message(STATUS)
 729
 730 endif() #help
 731