CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41 endif()
  42
  43 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  44
  45 # Supress regeneration
  46 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  47
  48 if(NOT help AND NOT HELP)
  49         # 'project' triggers the searching for a compiler
  50         project(${LYX_PROJECT})
  51 endif()
  52
  53 if(UNIX)
  54         set(ARCH_TRIPLET )
  55         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  56         if(DPKG_ARCHITECTURE_EXECUTABLE)
  57                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  58                                 OUTPUT_VARIABLE ARCH_TRIPLET
  59                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  60                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  61         endif()
  62 endif()
  63 if(ARCH_TRIPLET)
  64         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  65 else()
  66         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  67 endif()
  68
  69 include(LyXMacros)
  70
  71 # Usage LYX_OPTION
  72 # 1. parameter: option name without prefix 'LYX_'
  73 # 2. parameter: description
  74 # 3. parameter: default value, ON or OFF
  75 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  76
  77
  78 LYX_OPTION_INIT()
  79
  80 # Options for all compilers/systems
  81 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  82 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  83 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  84 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  85 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  86 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  87 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  88 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  89 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  90 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  91 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  92 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  93 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  94 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  95 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  96 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  97 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  98 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  99 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 100
 101 # GCC specific
 102 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 103 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 104 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 105 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 106 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 107 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 108 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 109 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 110 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 111
 112 # MSVC specific
 113 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 114 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 115 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 116 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 117 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 118
 119 # APPLE specific
 120 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 121 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 122
 123
 124 if(help OR HELP)
 125         message(STATUS)
 126         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 127         message(STATUS)
 128         LYX_OPTION_LIST_ALL(help)
 129         message(STATUS)
 130         RETURN()
 131 endif()
 132
 133 # Check option dependencies
 134
 135 if(LYX_DMG)
 136         set(LYX_BUNDLE ON)
 137         set(LYX_CPACK ON)
 138 endif()
 139
 140 if(LYX_CPACK)
 141         set(LYX_INSTALL ON)
 142 endif()
 143
 144 if(LYX_INSTALL)
 145         set(LYX_NLS ON)
 146         if (WIN32)
 147                 set(LYX_HUNSPELL ON)
 148         endif()
 149         if(LYX_CONSOLE MATCHES "FORCE")
 150                 set(LYX_CONSOLE ON)
 151         else()
 152                 set(LYX_CONSOLE OFF)
 153         endif()
 154         set(LYX_PACKAGE_SUFFIX ON)
 155         if(NOT LYX_DEBUG)
 156                 set(LYX_RELEASE ON)
 157         endif()
 158         set(LYX_PROFILE OFF)
 159 endif()
 160
 161
 162 if(LYX_MERGE_FILES)
 163         set(LYX_PCH OFF)
 164 else()
 165         set(LYX_MERGE_REBUILD OFF)
 166 endif()
 167
 168 if(LYX_DEPENDENCIES_DOWNLOAD)
 169         message(STATUS)
 170         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 171         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 172         set(deps_files lyx20-deps-msvc2010-x86.zip)
 173         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 174         foreach(it ${deps_files})
 175                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 176                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 177                 if(NOT already_downloaded)
 178                         message(STATUS "Downloading ${it} ...")
 179                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 180                         list(GET status 0 status_code)
 181                         list(GET status 1 status_string)
 182                         if(NOT status_code EQUAL 0)
 183                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 184                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 185                         endif()
 186                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 187                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 188                 endif()
 189         endforeach()
 190         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 191 endif()
 192
 193
 194
 195 message(STATUS)
 196
 197 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 198 if(WIN32)
 199         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 200 else()
 201         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 202 endif()
 203
 204
 205 # Variable that hold the flags that should only be used with C++ files
 206 set(LYX_CXX_SPECIFIC_FLAGS)
 207 if(UNIX OR MINGW)
 208         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 209         message(STATUS "Using GCC version ${GCC_VERSION}")
 210         if(NOT GCC_VERSION VERSION_LESS 4.4)
 211                 set(LYX_USE_TR1 1)
 212                 # GCC <= 4.5 does not support regex: there are linker errors
 213                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 214                 set(LYX_USE_TR1_REGEX 0)
 215         endif()
 216         if (LYX_ENABLE_CXX11)
 217                 find_package(CXX11Compiler)
 218                 if(NOT CXX11COMPILER_FOUND)
 219                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 220                 endif()
 221                 set(LYX_CXX_SPECIFIC_FLAGS "${LYX_CXX_SPECIFIC_FLAGS} ${CXX11_FLAG}")
 222         endif()
 223 else()
 224         if(MSVC10)
 225                 set(LYX_USE_TR1 1)
 226                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 227         endif()
 228 endif()
 229
 230
 231 set(VERSION_INFO "CMake Build")
 232
 233 # Try to get some informations from configure.ac
 234
 235 include(LyXPaths)
 236 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 237
 238 if(WIN32)
 239         set(USE_WINDOWS_PACKAGING ON)
 240 elseif(APPLE)
 241         set(USE_MACOSX_PACKAGING ON)
 242 else()
 243         set(USE_POSIX_PACKAGING ON)
 244 endif()
 245
 246 macro(setstripped _varname)
 247         if(${ARGC} GREATER 1)
 248                 string(STRIP "${ARGV1}" _v)
 249                 if(USE_POSIX_PACKAGING)
 250                         string(TOLOWER ${_v} ${_varname})
 251                 else()
 252                         set(${_varname} ${_v})
 253                 endif()
 254         else()
 255                 set(${_varname})
 256         endif()
 257 endmacro(setstripped)
 258
 259 foreach(_c_l ${_config_lines} )
 260         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 261                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 262                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 263                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 264                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 265                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 266                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 267                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 268                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 269                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 270                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 271                 endif()
 272         endif()
 273         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 274                 set(LYX_DATE "${CMAKE_MATCH_1}")
 275         endif()
 276 endforeach(_c_l)
 277
 278 if (LYX_LOCALVERSIONING)
 279         # Find the revision number and for later use
 280         FIND_PROGRAM(LYX_GITVERSION git)
 281         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 282         if(LYX_GITVERSION)
 283                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 284                 WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 285                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 286                   # We will add offset of 40000 to get appropriate value to
 287                   # previous svn.
 288                   # We use this value than also to set the package-patch-value
 289                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 290                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 291                   set(ENABLE_DIST ON)
 292                 endif()
 293         else()
 294                 set(LYX_REVISION_VERSION git) #TODO use date
 295         endif()
 296 else()
 297         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 298 endif()
 299
 300 if(LYX_PROGRAM_SUFFIX)
 301         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 302 else()
 303         set(PROGRAM_SUFFIX "")
 304 endif()
 305
 306 add_custom_target(lyx_version ALL
 307   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 308   )
 309 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 310
 311 if(APPLE)
 312         set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 313         configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 314 endif()
 315
 316 if(LYX_BUNDLE)
 317         set(LYX_CPACK ON)
 318         message(STATUS)
 319         message(STATUS "Bundle creation is enabled (experimental):")
 320         message(STATUS "    make")
 321         message(STATUS "    make install/strip")
 322         message(STATUS "    make package")
 323         if(APPLE)
 324                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 325                 set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 326                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 327                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 328                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 329                 if(NOT LYX_INSTALL_PREFIX)
 330                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 331                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 332                 endif()
 333                 # Change the owner so that the install can work
 334                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
 335         elseif(UNIX)
 336                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 337                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 338                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 339         elseif(WIN32)
 340                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 341         endif()
 342 endif()
 343
 344 if(LYX_INSTALL_PREFIX)
 345         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 346         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 347 endif()
 348 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 349
 350 if(LYX_PACKAGE_SUFFIX)
 351         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 352 else()
 353         set(PACKAGE ${PACKAGE_BASE})
 354 endif()
 355
 356
 357 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 358         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 359         if (UNIX)
 360                 # don't use the default "/usr/local"
 361                 # but respect the user-choice on the command-line
 362                 if(LYX_INSTALL_SUFFIX)
 363                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 364                 else()
 365                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 366                 endif()
 367         endif()
 368         if(WIN32)
 369                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 370         endif()
 371 endif()
 372 if(IS_ABSOLUTE)
 373         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 374 else()
 375         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 376 endif()
 377
 378
 379
 380 if(NOT LYX_DATA_SUBDIR)
 381         if (WIN32)
 382                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 383         else()
 384                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 385         endif()
 386 endif()
 387
 388 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 389 set(LYX_LOCALEDIR "locale")
 390 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 391 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 392
 393 set(LYX_MAN_DIR "/usr/local/man" CACHE STRING
 394   "Install location for man pages.")
 395 mark_as_advanced(LYX_MAN_DIR)
 396
 397 if(LYX_INSTALL AND WIN32)
 398         message(STATUS "Configuring NSIS files")
 399         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 400         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 401         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 402         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 403 endif()
 404
 405 if(NOT GROUP_CODE)
 406         #set(GROUP_CODE "The Golden Code")
 407         set(GROUP_CODE flat)
 408 endif()
 409
 410 # lyx's source files
 411 set(LYX_CPP_FILES *.cpp)
 412 set(LYX_HPP_FILES *.h)
 413 set(LYX_MOC_FILES moc_*.cpp)
 414
 415 include(ProjectSourceGroup)
 416
 417
 418 if(LYX_PROFILE AND NOT MSVC)
 419         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 420         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 421         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 422 else()
 423         set(LYX_PROFILE OFF)
 424 endif()
 425
 426
 427 if(LYX_NO_OPTIMIZE)
 428         set(CMAKE_BUILD_TYPE None)
 429         set(LYX_DEBUG OFF)
 430         set(LYX_RELEASE OFF)
 431         set(LYX_PROFILE OFF)
 432 elseif(LYX_RELEASE)
 433         set(CMAKE_BUILD_TYPE Release)
 434         set(LYX_DEBUG OFF)
 435         set(LYX_PROFILE OFF)
 436 elseif(LYX_PROFILE)
 437         set(CMAKE_BUILD_TYPE Profile)
 438         set(LYX_DEBUG OFF)
 439 else()
 440         set(CMAKE_BUILD_TYPE Debug)
 441         set(LYX_DEBUG ON)
 442 endif()
 443
 444
 445 # When shared libs are supported enable this option
 446 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 447 if(LYX_SHARED_LIBRARIES)
 448         set(library_type SHARED)
 449 else()
 450         set(library_type STATIC)
 451 endif()
 452
 453 if(NOT MSVC)
 454         if(NOT LYX_QUIET)
 455                 set(CMAKE_VERBOSE_MAKEFILE ON)
 456         endif()
 457         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 458         if(LYX_STDLIB_DEBUG)
 459                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 460         endif()
 461         if(LYX_CONCEPT_CHECKS)
 462                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 463         endif()
 464         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 465         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 466         if(MINGW)
 467                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 468         else()
 469                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 470         endif()
 471 endif()
 472
 473 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 474 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 475 if(LYX_CXX_FLAGS_EXTRA)
 476         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 477                 add_definitions(${_flag})
 478         endforeach()
 479 endif()
 480
 481 find_package(Qt5Core QUIET)
 482 if (Qt5Core_FOUND)
 483         find_package(Qt5Widgets REQUIRED)
 484         set(QTVERSION ${Qt5Core_VERSION})
 485         macro (qt_use_modules)
 486                 qt5_use_modules(${ARGN})
 487         endmacro()
 488         macro (qt_add_resources)
 489                 qt5_add_resources(${ARGN})
 490         endmacro()
 491         macro (qt_wrap_uifiles)
 492                 qt5_wrap_ui(${ARGN})
 493         endmacro()
 494 else()
 495         find_package(Qt4 "4.5.0" REQUIRED)
 496         macro (qt_use_modules)
 497         endmacro()
 498         macro (qt_add_resources)
 499                 qt4_add_resources(${ARGN})
 500         endmacro()
 501         macro (qt_wrap_uifiles)
 502                 qt4_wrap_ui(${ARGN})
 503         endmacro()
 504 endif()
 505
 506 find_package(Magic)
 507 if(Magic_FOUND)
 508         set(HAVE_MAGIC_H 1)
 509 endif()
 510
 511 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 512
 513 if(LYX_ASPELL)
 514         find_package(ASPELL)
 515         include_directories(${ASPELL_INCLUDE_DIR})
 516 endif()
 517
 518 if(LYX_ENCHANT)
 519         find_package(Enchant REQUIRED)
 520         include_directories(${ENCHANT_INCLUDE_DIR})
 521 endif()
 522
 523 if(LYX_HUNSPELL)
 524         find_package(Hunspell REQUIRED)
 525         include_directories(${HUNSPELL_INCLUDE_DIR})
 526 endif()
 527
 528 if(LYX_NLS)
 529         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 530         find_package(LyXGettext)
 531         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 532                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 533         else()
 534                 # Install only supplied .gmo-files
 535                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 536                 message(STATUS "Installing provided .gmo-files only")
 537                 foreach( _gmo ${_gmofiles})
 538                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 539                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 540                 endforeach()
 541         endif()
 542 endif()
 543
 544 find_package(ICONV REQUIRED)
 545 find_package(ZLIB REQUIRED)
 546
 547 if(LYX_EXTERNAL_BOOST)
 548         message(STATUS "Searching for boost")
 549         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 550         if(Boost_FOUND)
 551                 message(STATUS "Boost found")
 552                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 553                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 554         else()
 555                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 556         endif()
 557 else()
 558         if(LYX_USE_TR1_REGEX)
 559                 set(Lyx_Boost_Libraries boost_signals)
 560         else()
 561                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 562         endif()
 563         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 564         include_directories(${TOP_SRC_DIR}/boost)
 565         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 566 endif()
 567
 568
 569
 570
 571 if(WIN32)
 572         if(NOT LYX_CONSOLE)
 573                 set(WIN32_CONSOLE WIN32)
 574                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 575         endif()
 576         if(MSVC)
 577                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 578                 # disable checked iterators for msvc release builds to get maximum speed
 579                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 580         else()
 581                 add_definitions(-DWINVER=0x0500)
 582         endif()
 583 endif()
 584
 585 # Compute qt4-version from ${QTVERSION}
 586
 587 message(STATUS "")
 588 foreach(_v PACKAGE PACKAGE_VERSION
 589         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 590         LYX_ABS_TOP_SRCDIR
 591         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 592         if(NOT DEFINED ${_v})
 593                 message(FATAL_ERROR "${_v} not defined")
 594         endif()
 595         string(SUBSTRING "${_v}                            " 0 28 _v1)
 596         message(STATUS "----- ${_v1}: ${${_v}}")
 597 endforeach(_v)
 598 message(STATUS "")
 599
 600
 601 if(LYX_PCH)
 602         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 603         # Not sure if it works for all non-msvc compilers
 604         include(PCHSupport_26)
 605         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 606         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 607         add_definitions(-DLYX_ENABLE_PCH)
 608
 609         if(MSVC)
 610                 macro(lyx_add_msvc_pch name_)
 611                         set_source_files_properties(${${name_}_sources} PROPERTIES
 612                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 613                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 614                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 615                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 616                                 ${TOP_BINARY_DIR}/pcheaders.h)
 617                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 618                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 619                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 620                 endmacro(lyx_add_msvc_pch)
 621                 macro(lyx_add_gcc_pch name_)
 622                 endmacro()
 623         else()
 624                 macro(lyx_add_msvc_pch name_)
 625                 endmacro()
 626                 macro(lyx_add_gcc_pch name_)
 627                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 628                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 629                 endmacro()
 630         endif()
 631 else()
 632         macro(lyx_add_msvc_pch)
 633         endmacro(lyx_add_msvc_pch)
 634         macro(lyx_add_gcc_pch name_)
 635         endmacro()
 636 endif()
 637
 638
 639 if(MSVC)
 640
 641         if(LYX_VLD)
 642                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 643                 add_subdirectory(${vld_path}/cmake)
 644                 include(${vld_path}/cmake/vld.cmake) # forced include
 645                 set(vld_dll vld)
 646         endif()
 647
 648         if(LYX_WALL)
 649                 # Use the highest warning level
 650                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 651
 652                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 653                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 654                 else()
 655                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 656                 endif()
 657
 658                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 659                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 660                 else()
 661                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 662                 endif()
 663
 664                 # add here warnings which should produce an error /weXXXX
 665                 set(MSVC_W_ERROR   "/we4101 /we4189")
 666                 # add here warnings which should be disabled /wdXXXX
 667                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 668
 669                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 670                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 671                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 672
 673         else()
 674                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 675
 676                 # add here warnings which should produce an error /weXXXX
 677                 set(MSVC_W_ERROR   "/we4101 /we4189")
 678                 # add here warnings which should be disabled /wdXXXX
 679                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 680
 681                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 682                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 683                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 684
 685         endif()
 686
 687         if (NOT Qt5Core_FOUND)
 688                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 689                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 690                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 691         endif()
 692
 693         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 694         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 695         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 696         message(STATUS "")
 697 endif()
 698
 699
 700 if(LYX_DEBUG_GLIBC)
 701         set(_GLIBCXX_DEBUG ON)
 702 endif()
 703
 704 if(LYX_DEBUG_GLIBC_PEDANTIC)
 705         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 706 endif()
 707
 708 # Xcode compiler
 709 if (CMAKE_GENERATOR MATCHES Xcode)
 710         if (XCODE_VERSION VERSION_LESS "5.0")
 711                 # Automatically select the Xcode compiler if not set
 712                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 713                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 714                         if (XCODE_VERSION VERSION_GREATER "3.1")
 715                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 716                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 717                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 718                 # Print the selected compiler version
 719         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 720         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 721 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 722
 723 if (WIN32 AND Qt5Core_FOUND)
 724         set(Z_PREFIX 1)
 725 endif()
 726
 727 # compiler tests, config.h generation
 728 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 729         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 730 else()
 731         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 732         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 733 endif()
 734
 735 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 736
 737 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 738         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 739 endif()
 740
 741 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 742 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 743
 744 set (cmd ${CMAKE_CTEST_COMMAND})
 745 if (MSVC)
 746         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 747 else ()
 748         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 749 endif ()
 750 add_custom_target (lyx_run_tests COMMAND ${cmd})
 751 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 752
 753
 754 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 755 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 756 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 757 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 758
 759
 760 if(LYX_INSTALL)
 761         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 762                 message(STATUS "Python required to create doc!")
 763         else()
 764                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 765                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 766         endif()
 767         if(NOT(LYX_BUNDLE AND APPLE))
 768                 include(../Install)
 769         endif()
 770 endif()
 771
 772 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 773 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 774 if(LYX_ENABLE_URLTESTS)
 775         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 776 endif()
 777
 778 message(STATUS)
 779 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 780 message(STATUS)
 781 LYX_OPTION_LIST_ALL(used)
 782
 783
 784 if(LYX_NLS)
 785         message(STATUS)
 786         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 787         message(STATUS)
 788         message(STATUS "  * iconv")
 789         message(STATUS "     - header : ${ICONV_HEADER}")
 790         message(STATUS "     - library: ${ICONV_LIBRARY}")
 791         message(STATUS "  * zlib")
 792         message(STATUS "     - header : ${ZLIB_HEADER}")
 793         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 794         message(STATUS)
 795 endif()
 796
 797 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 798
 799 if(ENABLE_DIST)
 800   # Use git to create the source package
 801   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 802   if(UNIX)
 803     set(DIST_FORMAT tgz)
 804   else()
 805     set(DIST_FORMAT zip)
 806   endif()
 807   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 808
 809   add_custom_command(
 810     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 811     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 812     WORKING_DIRECTORY ${TOP_SRC_DIR})
 813   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 814 endif()
 815
 816 message(STATUS)