CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 129 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 130 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 131 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 132 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 133 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 134 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 135 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 136 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 137 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 138 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 139 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 140 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 141 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 142 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 143 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 144 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 145 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 146 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 147 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 148 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 149 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 150
 151 # GCC specific
 152 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 153 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 154 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 155 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 156 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 157 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 158 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 159
 160 # MSVC specific
 161 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 162 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 163 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 164 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 165
 166 # APPLE specific
 167 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 168 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 169
 170
 171 if(help OR HELP)
 172         message(STATUS)
 173         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 174         message(STATUS)
 175         LYX_OPTION_LIST_ALL(help)
 176         message(STATUS)
 177         RETURN()
 178 endif()
 179
 180 # Check option dependencies
 181
 182 if(LYX_DMG)
 183         set(LYX_BUNDLE ON)
 184         set(LYX_CPACK ON)
 185 endif()
 186
 187 if(LYX_CPACK)
 188         set(LYX_INSTALL ON)
 189 endif()
 190
 191 if(LYX_INSTALL)
 192         set(LYX_NLS ON)
 193         if(WIN32 AND NOT MINGW)
 194                 set(LYX_HUNSPELL ON)
 195         endif()
 196         if(LYX_CONSOLE MATCHES "FORCE")
 197                 set(LYX_CONSOLE ON)
 198         else()
 199                 set(LYX_CONSOLE OFF)
 200         endif()
 201         set(LYX_PACKAGE_SUFFIX ON)
 202         if(NOT LYX_DEBUG)
 203                 set(LYX_RELEASE ON)
 204         endif()
 205         set(LYX_PROFILE OFF)
 206 endif()
 207
 208
 209 if(LYX_MERGE_FILES)
 210         set(LYX_PCH OFF)
 211 else()
 212         set(LYX_MERGE_REBUILD OFF)
 213 endif()
 214
 215 if(LYX_DEPENDENCIES_DOWNLOAD)
 216         message(STATUS)
 217         if(MSVC14)
 218                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 219                 set(deps_files lyx-windows-deps-msvc2015.zip)
 220                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 221                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 222         elseif(MSVC10)
 223                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 224                 set(deps_files lyx-windows-deps-msvc2010.zip)
 225                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 226                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 227         else()
 228                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 229         endif()
 230     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 231         foreach(it ${deps_files})
 232                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 233                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 234                 if(NOT already_downloaded)
 235                         message(STATUS "Downloading ${it} ...")
 236                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 237                         list(GET status 0 status_code)
 238                         list(GET status 1 status_string)
 239                         if(NOT status_code EQUAL 0)
 240                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 241                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 242                         endif()
 243                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 244                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 245                 endif()
 246         endforeach()
 247 endif()
 248
 249
 250
 251 message(STATUS)
 252
 253 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 254 if(WIN32)
 255         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 256 else()
 257         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 258 endif()
 259
 260
 261 # Set to some meaningful default
 262 find_package(CXX11Compiler)
 263 if(NOT CXX11COMPILER_FOUND)
 264         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 265 endif()
 266 set(LYX_GCC11_MODE)
 267 if(UNIX OR MINGW)
 268         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 269           # ignore the GCC_VERSION for clang
 270           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 271           message(STATUS "Using clang")
 272           if(CXX11_STD_REGEX)
 273             set(LYX_USE_STD_REGEX 1)
 274           else()
 275             set(LYX_USE_STD_REGEX 0)
 276           endif()
 277         else()
 278           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 279           message(STATUS "Using GCC version ${GCC_VERSION}")
 280           if(GCC_VERSION VERSION_LESS 4.9)
 281                   if(GCC_VERSION VERSION_LESS 4.6)
 282                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 283                   endif()
 284                   # <regex> in gcc is unusable in versions less than 4.9.0
 285                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 286                   set(LYX_USE_STD_REGEX 0)
 287           else()
 288                   set(LYX_USE_STD_REGEX 0)
 289           endif()
 290         endif()
 291         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 292 else()
 293         set(LYX_USE_STD_REGEX 0)
 294 #       if(MSVC10)
 295 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 296 #       endif()
 297 endif()
 298
 299
 300 set(VERSION_INFO "CMake Build")
 301
 302 # Try to get some informations from configure.ac
 303
 304 include(LyXPaths)
 305 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 306
 307 if(WIN32)
 308         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 309         if(MSVC)
 310                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 311         endif()
 312         set(USE_WINDOWS_PACKAGING ON)
 313 elseif(APPLE)
 314         set(USE_MACOSX_PACKAGING ON)
 315 else()
 316         set(USE_POSIX_PACKAGING ON)
 317 endif()
 318
 319 if(LYX_3RDPARTY_BUILD)
 320   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 321   # this enables the build of all 3rd_party libs
 322   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 323   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 324   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 325   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 326 endif()
 327
 328 macro(setstripped _varname)
 329         if(${ARGC} GREATER 1)
 330                 string(STRIP "${ARGV1}" _v)
 331                 if(USE_POSIX_PACKAGING)
 332                         string(TOLOWER ${_v} ${_varname})
 333                 else()
 334                         set(${_varname} ${_v})
 335                 endif()
 336         else()
 337                 set(${_varname})
 338         endif()
 339 endmacro(setstripped)
 340
 341 foreach(_c_l ${_config_lines} )
 342         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 343                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 344                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 345                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 346                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 347                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 348                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 349                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 350                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 351                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 352                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 353                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 354                         else()
 355                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 356                         endif()
 357                 endif()
 358         endif()
 359         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 360                 set(LYX_DATE "${CMAKE_MATCH_1}")
 361         endif()
 362 endforeach(_c_l)
 363
 364 FIND_PROGRAM(LYX_GITVERSION git)
 365 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 366 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 367 if(LYX_GITVERSION)
 368   if (LYX_LOCALVERSIONING)
 369     # Find the revision number and for later use
 370     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 371       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 372     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 373       # We will add offset of 40000 to get appropriate value to
 374       # previous svn.
 375       # We use this value than also to set the package-patch-value
 376       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 377       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 378       set(ENABLE_DIST ON)
 379     endif()
 380   endif()
 381 endif()
 382
 383 # Set the programs (lyx, tex2lyx, etc.) suffix
 384 # When building an OS X bundle, we will append
 385 # the suffix only to the bundle, not to the programs
 386 set(PROGRAM_SUFFIX "")
 387 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 388         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 389 endif()
 390 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 391 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 392
 393 add_custom_target(lyx_version ALL
 394   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 395   )
 396 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 397
 398 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 399 set(LYX_UTILITIES_INSTALL_PATH bin)
 400
 401 if(LYX_BUNDLE)
 402         set(LYX_CPACK ON)
 403
 404         message(STATUS)
 405         message(STATUS "Bundle creation is enabled (experimental):")
 406         message(STATUS "    make")
 407         message(STATUS "    make install/strip")
 408         message(STATUS "    make package")
 409         if(APPLE)
 410                 set(MACOSX_BUNDLE TRUE)
 411                 # This sets the bundle + executable names
 412                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 413                 # This sets the Info.plist executable name
 414                 set(osx_bundle_program_name ${_lyx})
 415                 # Bundle name
 416                 set(LYX_BUNDLE_NAME ${_lyx})
 417
 418                 # This will contain the list of files that need to be included
 419                 # in the bundle and their location within the bundle
 420                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 421                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 422
 423                 # Process Info.plist and lyxrc.dist
 424                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 425                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 426
 427                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 428                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 429
 430                 # Variables used by CPack
 431                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 432                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 433                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 434
 435                 # Set the install paths
 436                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 437                 if(NOT LYX_INSTALL_PREFIX)
 438                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 439                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 440                 endif()
 441                 # Change the owner so that the install can work
 442                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 443         elseif(UNIX)
 444                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 445                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 446                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 447         elseif(WIN32)
 448                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 449         endif()
 450 endif()
 451
 452 if(LYX_INSTALL_PREFIX)
 453         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 454         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 455 endif()
 456 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 457
 458 if(UNIX)
 459   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 460 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 461   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 462 else()
 463   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 464 endif()
 465
 466 # The define below allows lyx-executable to find its default configuration files
 467 # see routines
 468 #    Package::messages_file()
 469 #    get_default_user_support_dir()
 470 #    relative_system_support_dir()
 471 # in src/support/Package.cpp
 472 #
 473 if(LYX_PROGRAM_SUFFIX)
 474         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 475 else()
 476         set(PACKAGE ${PACKAGE_BASE})
 477 endif()
 478
 479 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 480         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 481         if (UNIX)
 482                 # use the default "/usr/local"
 483                 # but respect the user-choice on the command-line
 484                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 485         endif()
 486 endif()
 487 if(WIN32)
 488         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 489 endif()
 490 if(IS_ABSOLUTE)
 491         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 492 else()
 493         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 494 endif()
 495
 496
 497
 498 if(NOT LYX_DATA_SUBDIR)
 499         if (WIN32)
 500                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 501         else()
 502                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 503         endif()
 504 endif()
 505
 506 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 507 get_locale_destination(LYX_LOCALEDIR)
 508 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 509 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 510
 511 if(LYX_BUNDLE AND APPLE)
 512         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 513 else()
 514         if(WIN32)
 515                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 516         elseif(UNIX)
 517                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 518         else()
 519                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 520         endif()
 521 endif()
 522 mark_as_advanced(LYX_MAN_DIR)
 523
 524 if(LYX_INSTALL AND WIN32)
 525         message(STATUS "Configuring NSIS files")
 526         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 527         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 528         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 529         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 530 endif()
 531
 532 if(NOT GROUP_CODE)
 533         #set(GROUP_CODE "The Golden Code")
 534         set(GROUP_CODE flat)
 535 endif()
 536
 537 # lyx's source files
 538 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 539 set(LYX_HPP_FILES [a-zA-Z]*.h)
 540 set(LYX_MOC_FILES moc_*.cpp)
 541
 542 include(ProjectSourceGroup)
 543
 544
 545 if(LYX_PROFILE AND NOT MSVC)
 546         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 547         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 548         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 549 else()
 550         set(LYX_PROFILE OFF)
 551 endif()
 552
 553
 554 if(LYX_NO_OPTIMIZE)
 555         set(CMAKE_BUILD_TYPE None)
 556         set(LYX_DEBUG OFF)
 557         set(LYX_RELEASE OFF)
 558         set(LYX_PROFILE OFF)
 559 elseif(LYX_RELEASE)
 560         set(CMAKE_BUILD_TYPE Release)
 561         set(LYX_DEBUG OFF)
 562         set(LYX_PROFILE OFF)
 563 elseif(LYX_PROFILE)
 564         set(CMAKE_BUILD_TYPE Profile)
 565         set(LYX_DEBUG OFF)
 566 else()
 567         set(CMAKE_BUILD_TYPE Debug)
 568         set(LYX_DEBUG ON)
 569 endif()
 570
 571
 572 # When shared libs are supported enable this option
 573 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 574 if(LYX_SHARED_LIBRARIES)
 575         set(library_type SHARED)
 576 else()
 577         set(library_type STATIC)
 578 endif()
 579
 580 if(NOT MSVC)
 581         if(NOT LYX_QUIET)
 582                 set(CMAKE_VERBOSE_MAKEFILE ON)
 583         endif()
 584         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 585         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 586           # Thanks to Brad King <brad.king@kitware.com>
 587           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 588           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 589           # and still use our own c++ extension tests
 590           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 591           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 592         endif()
 593         if(LYX_STDLIB_DEBUG)
 594                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 595         endif()
 596         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 597         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 598         if(MINGW)
 599                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 600         else()
 601                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 602         endif()
 603 endif()
 604
 605 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 606 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 607 if(LYX_CXX_FLAGS_EXTRA)
 608         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 609                 add_definitions(${_flag})
 610         endforeach()
 611 endif()
 612
 613 if(LYX_XMINGW)
 614         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 615 endif()
 616
 617 if(LYX_USE_QT MATCHES "QT5")
 618         # set QPA_XCB if QT uses X11
 619         find_package(Qt5Core REQUIRED)
 620         if (Qt5Core_FOUND)
 621                 find_package(Qt5Widgets REQUIRED)
 622                 if(APPLE)
 623                         find_package(Qt5MacExtras REQUIRED)
 624                 endif()
 625                 find_package(Qt5X11Extras QUIET)
 626                 find_package(Qt5WinExtras QUIET)
 627                 set(QTVERSION ${Qt5Core_VERSION})
 628                 if (QTVERSION VERSION_LESS "5.4")
 629                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 630                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 631                         message(STATUS "install QT-Version >= \"5.4\"")
 632                         # see thread in lyx-devel list
 633                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 634                         # Date 11.03.2017
 635                         # Subject: cmake compilation error
 636                         #message(FATAL_ERROR "Wrong Qt-Version")
 637                 endif()
 638                 macro (qt_use_modules)
 639                         qt5_use_modules(${ARGN})
 640                 endmacro()
 641                 macro (qt_add_resources)
 642                         qt5_add_resources(${ARGN})
 643                 endmacro()
 644                 macro (qt_wrap_uifiles)
 645                         qt5_wrap_ui(${ARGN})
 646                 endmacro()
 647                 message(STATUS "Found Qt-Version ${QTVERSION}")
 648                 if(WIN32)
 649                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 650                 endif()
 651         endif()
 652 elseif(LYX_USE_QT MATCHES "QT4")
 653         if(LYX_XMINGW)
 654                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 655                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 656         endif()
 657         find_package(Qt4 "4.5.0" REQUIRED)
 658         macro (qt_use_modules)
 659         endmacro()
 660         macro (qt_add_resources)
 661                 qt4_add_resources(${ARGN})
 662         endmacro()
 663         macro (qt_wrap_uifiles)
 664                 qt4_wrap_ui(${ARGN})
 665         endmacro()
 666         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 667         if(WIN32)
 668                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 669         endif()
 670 else()
 671   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 672 endif()
 673
 674 find_package(Magic)
 675 if(Magic_FOUND)
 676         set(HAVE_MAGIC_H 1)
 677 endif()
 678
 679 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 680
 681 set(Spelling_FOUND OFF)
 682 set(Include_used_spellchecker)   # String will be inserted into config.h
 683
 684 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 685   # try system library first
 686   find_package(MyThesLIB)
 687   if (MYTHESLIB_FOUND)
 688     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 689   else()
 690     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 691   endif()
 692 endif()
 693 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 694   find_package(MyThesLIB REQUIRED)
 695 else()
 696   add_subdirectory(3rdparty/mythes)
 697 endif()
 698 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 699
 700 if(NOT LYX_EXTERNAL_HUNSPELL)
 701     add_subdirectory(3rdparty/hunspell)
 702     add_definitions(-DHUNSPELL_STATIC)
 703     set(HUNSPELL_FOUND ON)
 704     message(STATUS "  * Hunspell:")
 705     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 706     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 707 endif()
 708
 709 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 710   string(TOUPPER ${_spell} _upspell)
 711   if (NOT ${_upspell}_FOUND)
 712     find_package(${_spell})
 713   endif()
 714   if (${_upspell}_FOUND)
 715     include_directories(${${_upspell}_INCLUDE_DIR})
 716     set(Spelling_FOUND ON)
 717     message(STATUS "Building with USE_${_upspell}")
 718     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 719   else()
 720     if(LYX_${_upspell})
 721       message(FATAL_ERROR "Required ${_spell} devel package not found")
 722     else()
 723       message(STATUS "${_upspell} not found, building without ${_spell} support")
 724     endif()
 725   endif()
 726 endforeach()
 727
 728 if(GNUWIN32_DIR)
 729         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 730 endif()
 731
 732 find_package(PythonInterp 2.7 QUIET)
 733 if(PYTHONINTERP_FOUND)
 734         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 735         unset(PYTHONINTERP_FOUND)
 736         endif()
 737 endif()
 738
 739 if(NOT PYTHONINTERP_FOUND)
 740   unset(PYTHON_EXECUTABLE CACHE)
 741   unset(PYTHON_VERSION_MAJOR)
 742   unset(PYTHON_VERSION_MINOR)
 743   unset(PYTHON_VERSION_STRING)
 744   find_package(PythonInterp 3.3 REQUIRED)
 745 endif()
 746
 747 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 748
 749 if(LYX_NLS)
 750         find_package(LyXGettext)
 751         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 752                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 753         else()
 754                 # Install only supplied .gmo-files
 755                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 756                 message(STATUS "Installing provided .gmo-files only")
 757                 foreach( _gmo ${_gmofiles})
 758                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 759                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 760                 endforeach()
 761         endif()
 762 endif()
 763
 764 if(LYX_EXTERNAL_ICONV)
 765   find_package(ICONV REQUIRED)
 766 else()
 767   add_subdirectory(3rdparty/libiconv)
 768   set(HAVE_ICONV_CONST 1)
 769 endif()
 770
 771 if(LYX_EXTERNAL_Z)
 772   find_package(ZLIB REQUIRED)
 773 else()
 774   add_subdirectory(3rdparty/zlib)
 775 endif()
 776
 777 if(LYX_EXTERNAL_BOOST)
 778         message(STATUS "Searching for boost")
 779         if(NOT LYX_USE_STD_REGEX)
 780                 find_package(Boost COMPONENTS regex)
 781         endif()
 782         if(Boost_FOUND)
 783                 message(STATUS "Boost found")
 784                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 785                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 786                 if (LYX_STDLIB_DEBUG)
 787                         # Comment from  Jean-Marc Lasgouttes:
 788                         # In general, system boost libraries are incompatible with
 789                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 790                         # details.
 791                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 792                 endif()
 793         else()
 794                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 795         endif()
 796 else()
 797         if(NOT LYX_USE_STD_REGEX)
 798                 set(Lyx_Boost_Libraries boost_regex)
 799         endif()
 800         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 801         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 802         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 803 endif()
 804
 805
 806
 807
 808 if(WIN32)
 809         if(LYX_CONSOLE)
 810                 set(LYX_QTMAIN_LIBRARY)
 811         else()
 812                 set(WIN32_CONSOLE WIN32)
 813         endif()
 814         if(MSVC)
 815                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 816                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 817                 # disable checked iterators for msvc release builds to get maximum speed
 818                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 819         else()
 820                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 821                 # does not use it and always declares the vista compatible API.
 822                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 823                 add_definitions(-DWINVER=0x0500)
 824         endif()
 825 endif()
 826
 827 # Compute qt-version from ${QTVERSION}
 828
 829 message(STATUS "")
 830 foreach(_v PACKAGE PACKAGE_VERSION
 831         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 832         LYX_ABS_TOP_SRCDIR
 833         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 834         if(NOT DEFINED ${_v})
 835                 message(FATAL_ERROR "${_v} not defined")
 836         endif()
 837         string(SUBSTRING "${_v}                            " 0 28 _v1)
 838         message(STATUS "----- ${_v1}: ${${_v}}")
 839 endforeach(_v)
 840 message(STATUS "")
 841
 842
 843 if(LYX_PCH)
 844         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 845         # Not sure if it works for all non-msvc compilers
 846         include(PCHSupport_26)
 847         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 848         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 849         add_definitions(-DLYX_ENABLE_PCH)
 850
 851         if(MSVC)
 852                 macro(lyx_add_msvc_pch name_)
 853                         set_source_files_properties(${${name_}_sources} PROPERTIES
 854                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 855                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 856                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 857                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 858                                 ${TOP_BINARY_DIR}/pcheaders.h)
 859                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 860                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 861                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 862                 endmacro(lyx_add_msvc_pch)
 863                 macro(lyx_add_gcc_pch name_)
 864                 endmacro()
 865         else()
 866                 macro(lyx_add_msvc_pch name_)
 867                 endmacro()
 868                 macro(lyx_add_gcc_pch name_)
 869                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 870                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 871                 endmacro()
 872         endif()
 873 else()
 874         macro(lyx_add_msvc_pch)
 875         endmacro(lyx_add_msvc_pch)
 876         macro(lyx_add_gcc_pch name_)
 877         endmacro()
 878 endif()
 879
 880
 881 if(MSVC)
 882
 883         if(LYX_VLD)
 884                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 885                 add_subdirectory(${vld_path}/cmake)
 886                 include(${vld_path}/cmake/vld.cmake) # forced include
 887                 set(vld_dll vld)
 888         endif()
 889
 890         if(LYX_WALL)
 891                 # Use the highest warning level
 892                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 893
 894                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 895                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 896                 else()
 897                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 898                 endif()
 899
 900                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 901                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 902                 else()
 903                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 904                 endif()
 905
 906                 # add here warnings which should produce an error /weXXXX
 907                 set(MSVC_W_ERROR   "/we4101 /we4189")
 908                 # add here warnings which should be disabled /wdXXXX
 909                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 910
 911                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 912                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 913                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 914
 915         else()
 916                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 917
 918                 # add here warnings which should produce an error /weXXXX
 919                 set(MSVC_W_ERROR   "/we4101 /we4189")
 920                 # add here warnings which should be disabled /wdXXXX
 921                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 922
 923                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 924                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 925                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 926
 927         endif()
 928
 929         if (NOT Qt5Core_FOUND)
 930                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 931                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 932                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 933         endif()
 934
 935         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 936         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 937         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 938         message(STATUS "")
 939 endif()
 940
 941
 942 if(LYX_DEBUG_GLIBC)
 943         set(_GLIBCXX_DEBUG ON)
 944 endif()
 945
 946 if(LYX_DEBUG_GLIBC_PEDANTIC)
 947         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 948 endif()
 949
 950 # Xcode compiler
 951 if (CMAKE_GENERATOR MATCHES Xcode)
 952         if (XCODE_VERSION VERSION_LESS "5.0")
 953                 # Automatically select the Xcode compiler if not set
 954                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 955                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 956                         if (XCODE_VERSION VERSION_GREATER "3.1")
 957                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 958                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 959                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 960                 # Print the selected compiler version
 961         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 962         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 963 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 964
 965 if (WIN32 AND Qt5Core_FOUND)
 966         set(Z_PREFIX 1)
 967 endif()
 968
 969 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 970 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 971 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 972
 973 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 974
 975 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 976         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 977 endif()
 978
 979 if (NOT HAVE_REGEX)
 980         set(LYX_USE_STD_REGEX 0)
 981 endif()
 982
 983
 984 set (cmd ${CMAKE_CTEST_COMMAND})
 985 if (MSVC)
 986         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 987 else ()
 988         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 989 endif ()
 990 add_custom_target (lyx_run_tests COMMAND ${cmd})
 991 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 992
 993 if(LYX_ASAN)
 994     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 995     message(STATUS)
 996     message(STATUS "Address sanitizer enabled. Usage:")
 997     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 998     message(STATUS "    chmod  +x ./asan_symbolize.py")
 999     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1000     message(STATUS)
1001 endif()
1002
1003 if(LYX_INSTALL)
1004         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1005                 message(STATUS "Python required to create doc!")
1006         else()
1007                 if(UNIX)
1008                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1009                 endif()
1010                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1011         endif()
1012         include(../Install)
1013 endif()
1014
1015 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1016 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1017 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1018 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1019 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1020 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1021 if(LYX_ENABLE_URLTESTS)
1022         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1023 endif()
1024
1025 message(STATUS)
1026 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1027 message(STATUS)
1028
1029 LYX_OPTION_LIST_ALL(used)
1030
1031
1032 if(LYX_NLS)
1033         message(STATUS)
1034         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1035         message(STATUS)
1036         message(STATUS "  * iconv")
1037         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1038         message(STATUS "     - library: ${ICONV_LIBRARY}")
1039         message(STATUS "  * zlib")
1040         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1041         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1042         message(STATUS)
1043 endif()
1044
1045 # Apple has builtin native spell checker,
1046 # no need to warn for missing Aspell, Hunspell or Enchant
1047 if(NOT Spelling_FOUND AND NOT APPLE)
1048   if(LYX_REQUIRE_SPELLCHECK)
1049     set(_mode "FATAL_ERROR")
1050   else()
1051     set(_mode "STATUS")
1052   endif()
1053   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1054 endif()
1055
1056 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1057
1058 if(ENABLE_DIST)
1059   # Use git to create the source package
1060   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1061   if(UNIX)
1062     set(DIST_FORMAT tgz)
1063   else()
1064     set(DIST_FORMAT zip)
1065   endif()
1066   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1067
1068   add_custom_command(
1069     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1070     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1071     WORKING_DIRECTORY ${TOP_SRC_DIR})
1072   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1073 endif()
1074
1075 # Last directory to be included so that the fixup code (OS X)
1076 # can be run last
1077 add_subdirectory(development/cmake/post_install)
1078
1079 message(STATUS)