CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2024 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.5.0)
   8
   9 set(LYX_PROJECT LyX)
  10 # Instruct cmake to not use gnu extensions,
  11 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  12 set(CMAKE_CXX_EXTENSIONS OFF)
  13
  14 enable_testing()
  15
  16 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  17 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  18 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  19
  20 set(LYX_CMAKE_DIR "development/cmake")
  21 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  22 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  23 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  24
  25 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  26
  27 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  28
  29 message(STATUS)
  30 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  31         message(STATUS "Building in-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  33 else()
  34         message(STATUS "Building out-of-source")
  35         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  36 endif()
  37
  38 # This directory should be used if some test uses lyx-executable
  39 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  40 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  41
  42 if(COMMAND cmake_policy)
  43         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  44         cmake_policy(SET CMP0006 NEW)
  45         if(POLICY CMP0043)
  46                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  47                 cmake_policy(SET CMP0043 NEW)
  48         endif()
  49         cmake_policy(SET CMP0020 NEW)
  50         if(POLICY CMP0075)
  51                 cmake_policy(SET CMP0075 NEW)
  52         endif()
  53         if(POLICY CMP0077)
  54                 cmake_policy(SET CMP0077 NEW)
  55         endif()
  56 endif()
  57
  58 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  59
  60 # Supress regeneration
  61 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  62
  63 if(LYX_XMINGW)
  64     set(CMAKE_SYSTEM_NAME Windows)
  65     set(TOOLNAME ${LYX_XMINGW})
  66     set(TOOLCHAIN "${TOOLNAME}-")
  67     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  68     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  69     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  70
  71     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  72     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  73     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  74 endif()
  75
  76 if(NOT help AND NOT HELP)
  77   # 'project' triggers the searching for a compiler
  78   project(${LYX_PROJECT})
  79   if (CMAKE_COMPILER_IS_GNUCXX)
  80     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.9")
  81       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  82       message(STATUS "is too old, should be >= 4.9")
  83       message(FATAL_ERROR "Exiting")
  84     endif()
  85   endif()
  86 endif()
  87
  88 if(UNIX)
  89         set(ARCH_TRIPLET )
  90         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  91         if(DPKG_ARCHITECTURE_EXECUTABLE)
  92                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  93                                 OUTPUT_VARIABLE ARCH_TRIPLET
  94                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  95                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  96         endif()
  97 endif()
  98 if(ARCH_TRIPLET)
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 100 else()
 101         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 102 endif()
 103
 104 include(LyXMacros)
 105 include(LyXDestinations)
 106
 107 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 108 if(WIN32)
 109         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 110         if(MSVC)
 111                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 112         endif()
 113         set(USE_WINDOWS_PACKAGING ON)
 114 elseif(APPLE)
 115         set(USE_MACOSX_PACKAGING ON)
 116 else()
 117         set(USE_POSIX_PACKAGING ON)
 118 endif()
 119
 120 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 121 list(GET _package_list 0 PACKAGE_BASE)
 122 list(GET _package_list 1 PACKAGE_VERSION)
 123 list(GET _package_list 2 PACKAGE_BUGREPORT)
 124 list(GET _envlist 0 LYX_DIR_VER)
 125 list(GET _envlist 1 LYX_USERDIR_VER)
 126 list(GET _version_list 0 LYX_VERSION)
 127 list(GET _version_list 1 LYX_MAJOR_VERSION)
 128 list(GET _version_list 2 LYX_MINOR_VERSION)
 129 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 130 list(GET _version_list 4 LYX_RELEASE_PATCH)
 131
 132 # Usage LYX_OPTION
 133 # 1. parameter: option name without prefix 'LYX_'
 134 # 2. parameter: description
 135 # 3. parameter: default value, ON or OFF
 136 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 137
 138 # Usage LYX_COMBO
 139 # 1. parameter: name without prefix 'LYX_'
 140 # 2. parameter: description
 141 # 3. parameter: default value
 142 # 4-n parameter: possible other string values
 143
 144 LYX_OPTION_INIT()
 145 LYX_COMBO(ENABLE_BUILD_TYPE  "Allows to tweak the compiled code" AUTO release prerelease development gprof)
 146
 147 if(LYX_ENABLE_BUILD_TYPE MATCHES "AUTO")
 148   message(STATUS "Selecting build type defaults from configure.ac")
 149 else()
 150   set(LYX_BUILD_TYPE "${LYX_ENABLE_BUILD_TYPE}")
 151   message(STATUS "Selecting build type defaults from LYX_ENABLE_BUILD_TYPE")
 152 endif()
 153
 154 # Select some defaults depending on LYX_BUILD_TYPE
 155 # they can always be overwritten by the respective command line settings
 156 # These settings are only effective on fresh(==empty) CMakeCache.txt
 157 if(LYX_BUILD_TYPE STREQUAL "development")
 158   set(DefaultLyxDebug ON)
 159   set(DefaultLyxRelease OFF)
 160   set(DefaultLyxStdlibDebug ON)
 161   set(DefaultLyxEnableAssertions ON)
 162   set(DefaultLyxProfile OFF)
 163   set(DefaultExternalLibs OFF)
 164 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 165   set(DefaultLyxDebug OFF)
 166   set(DefaultLyxRelease OFF)
 167   set(DefaultLyxStdlibDebug OFF)
 168   set(DefaultLyxEnableAssertions OFF)
 169   set(DefaultLyxProfile OFF)
 170   set(DefaultExternalLibs ON)
 171 elseif(LYX_BUILD_TYPE STREQUAL "release")
 172   set(DefaultLyxDebug OFF)
 173   set(DefaultLyxRelease ON)
 174   set(DefaultLyxStdlibDebug OFF)
 175   set(DefaultLyxEnableAssertions OFF)
 176   set(DefaultLyxProfile OFF)
 177   set(DefaultExternalLibs ON)
 178 elseif(LYX_BUILD_TYPE STREQUAL "gprof")
 179   set(DefaultLyxDebug ON)
 180   set(DefaultLyxRelease OFF)
 181   set(DefaultLyxStdlibDebug OFF)
 182   set(DefaultLyxEnableAssertions OFF)
 183   set(DefaultLyxProfile ON)
 184   set(DefaultExternalLibs OFF)
 185 else()
 186   message(FATAL_ERROR "Invalid build type (${LYX_BUILD_TYPE}) encountered")
 187 endif()
 188
 189 # Options for all compilers/systems
 190 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 191 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 192 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 193 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 194 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 195 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 196 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 197 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 198 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 199 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 200 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 201 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 202 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 203 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 204 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 205 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 206 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 207 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 208 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 209 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 210 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 211 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 212 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 213 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 214   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 215 else()
 216   if (LYX_ENABLE_VALGRIND_TESTS)
 217     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 218   endif()
 219 endif()
 220 LYX_COMBO(DEBUG_SANITIZE    "Use sanitize check" NONE ADDRESS UNSPECIFIED)
 221 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 222 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT5 QT6)
 223 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 224 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 225 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 226 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ${DefaultExternalLibs} ALL)
 227 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ${DefaultExternalLibs} ALL)
 228 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ${DefaultExternalLibs} ALL)
 229 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ${DefaultExternalLibs} ALL)
 230 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 231
 232 # GCC specific
 233 LYX_OPTION(PROFILE              "Build with options for gprof" ${DefaultLyxProfile} GCC)
 234 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" ${DefaultExternalLibs} GCC)
 235 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 236 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 237 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 238 LYX_OPTION(DEBUG_GLIBC_ASSERTIONS "Enable stdlib-assertions debug mode" OFF GCC)
 239 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 240
 241 # MSVC specific
 242 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 243 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 244 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 245 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 246
 247 # APPLE specific
 248 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 249 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 250
 251 # On Windows, download the dependencies if need be.
 252 if(LYX_DEPENDENCIES_DOWNLOAD)
 253         message(STATUS)
 254         # Do not check for bitness against CMAKE_SIZEOF_VOID_P, as it relates to the bitness of the CMake executable,
 255         # not that of the compiler.
 256         if(MSVC_VERSION GREATER_EQUAL 1920 AND "${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" MATCHES "x64")
 257                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2019-deps-64)
 258                 set(deps_files lyx-windows-deps-msvc2019_64.zip)
 259                 set(deps_server http://ftp.lyx.org/pub/lyx/devel/win_deps)
 260                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2019-64)
 261         elseif(MSVC_VERSION GREATER_EQUAL 1920)
 262                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2019-deps)
 263                 set(deps_files lyx-windows-deps-msvc2019_32.zip)
 264                 set(deps_server http://ftp.lyx.org/pub/lyx/devel/win_deps)
 265                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2019)
 266         elseif(MSVC_VERSION GREATER_EQUAL 1900 AND NOT "${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" MATCHES "x64")
 267                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 268                 set(deps_files lyx-windows-deps-msvc2015.zip)
 269                 set(deps_server http://ftp.lyx.org/pub/lyx/devel/win_deps)
 270                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 271         else()
 272                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 273         endif()
 274         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 275         foreach(it ${deps_files})
 276                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 277                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 278                 if(NOT already_downloaded)
 279                         message(STATUS "Downloading ${it} ...")
 280                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 281                         list(GET status 0 status_code)
 282                         list(GET status 1 status_string)
 283                         if(NOT status_code EQUAL 0)
 284                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 285                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 286                         endif()
 287                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 288                                         WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 289                 endif()
 290         endforeach()
 291 endif()
 292
 293 # Try to get some information from configure.ac
 294 include(LyXPaths)
 295
 296
 297 if(help OR HELP)
 298         message(STATUS)
 299         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 300         message(STATUS)
 301         LYX_OPTION_LIST_ALL(help)
 302         message(STATUS)
 303         unset(help CACHE)
 304         unset(HELP CACHE)
 305         RETURN()
 306 endif()
 307
 308 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 309   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 310 else()
 311   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 312 endif()
 313
 314 # Check option dependencies
 315 if (LYX_ENABLE_VALGRIND_TESTS)
 316         find_program(VALGRIND_EXECUTABLE "valgrind")
 317         if (NOT VALGRIND_EXECUTABLE)
 318                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 319         endif()
 320 endif()
 321 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 322   if (LYX_EXTERNAL_BOOST)
 323     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 324   endif()
 325 endif()
 326
 327 if(LYX_DMG)
 328         set(LYX_BUNDLE ON)
 329         set(LYX_CPACK ON)
 330 endif()
 331
 332 if(LYX_CPACK)
 333         set(LYX_INSTALL ON)
 334 endif()
 335
 336 if(LYX_INSTALL)
 337         set(LYX_NLS ON)
 338         if(WIN32 AND NOT MINGW)
 339                 set(LYX_HUNSPELL ON)
 340         endif()
 341         set(LYX_PACKAGE_SUFFIX ON)
 342         if(NOT LYX_DEBUG)
 343                 set(LYX_RELEASE ON)
 344         endif()
 345         set(LYX_PROFILE OFF)
 346 endif()
 347
 348
 349 if(LYX_MERGE_FILES)
 350         set(LYX_PCH OFF)
 351 else()
 352         set(LYX_MERGE_REBUILD OFF)
 353 endif()
 354
 355 message(STATUS)
 356
 357 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 358 if(WIN32)
 359         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 360 else()
 361         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 362 endif()
 363
 364 set(LYX_IPO_SUPPORTED OFF)
 365 if (POLICY CMP0069)
 366   cmake_policy(SET CMP0069 NEW)
 367   if(LYX_USE_IPO MATCHES "AUTO")
 368     # Enable LTO if supported and not debugging
 369     if (NOT LYX_DEBUG)
 370       include(CheckIPOSupported)
 371       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 372     endif()
 373   else()
 374     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 375   endif()
 376 endif()
 377 if (LYX_IPO_SUPPORTED)
 378   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 379 else()
 380   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 381 endif()
 382
 383 # Set to some meaningful default
 384 find_package(CXX11Compiler)
 385 if(NOT CXX11COMPILER_FOUND)
 386         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 387 endif()
 388 unset(LYX_GCC11_MODE)
 389 if(UNIX OR MINGW)
 390         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 391           # ignore the GCC_VERSION for clang
 392           message(STATUS "Using clang")
 393         else()
 394           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 395           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 396           if (_err)
 397             # previous check failed, try again with _old_ parameter
 398             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 399             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 400           endif()
 401           message(STATUS "Using GCC version ${GCC_VERSION}")
 402           if(GCC_VERSION VERSION_LESS 4.9)
 403                 message(FATAL_ERROR "gcc >= 4.9 is required.")
 404           endif()
 405         endif()
 406         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 407 else()
 408         if(MSVC_VERSION LESS 1900)
 409                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 410                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 411         endif()
 412 endif()
 413
 414 if(LYX_3RDPARTY_BUILD)
 415   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 416   # this enables the build of all 3rd_party libs
 417   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 418   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 419   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 420   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 421 endif()
 422
 423 FIND_PROGRAM(LYX_GITVERSION git)
 424 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 425 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 426 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 427 if(LYX_GITVERSION)
 428   if (LYX_LOCALVERSIONING)
 429     # Find the revision number for later use
 430     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 431       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 432       RESULT_VARIABLE tmp_GIT_RESULT
 433       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 434       ERROR_VARIABLE tmp_GIT_ERROR
 435       OUTPUT_STRIP_TRAILING_WHITESPACE)
 436     if (tmp_GIT_RESULT EQUAL 0)
 437       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 438         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 439         # We will add offset of 40000 to get appropriate value to
 440         # previous svn.
 441         # We use this value than also to set the package-patch-value
 442         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 443         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 444         set(ENABLE_DIST ON)
 445       endif()
 446     endif()
 447   endif()
 448 endif()
 449 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 450   set(LYX_PACKAGE_RELEASE  "1")
 451   if (LYX_RELEASE_PATCH GREATER 0)
 452     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 453   endif()
 454 endif()
 455
 456 # Set the programs (lyx, tex2lyx, etc.) suffix
 457 # When building an OS X bundle, we will append
 458 # the suffix only to the bundle, not to the programs
 459 set(PROGRAM_SUFFIX "")
 460 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 461         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 462 endif()
 463 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 464 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 465 set(_convert lyxconvert${PROGRAM_SUFFIX})
 466
 467 add_custom_target(lyx_version ALL
 468   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 469   )
 470 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 471
 472 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 473 set(LYX_UTILITIES_INSTALL_PATH bin)
 474
 475 if(LYX_BUNDLE)
 476         set(LYX_CPACK ON)
 477
 478         message(STATUS)
 479         message(STATUS "Bundle creation is enabled (experimental):")
 480         message(STATUS "    make")
 481         message(STATUS "    make install/strip")
 482         message(STATUS "    make package")
 483         if(APPLE)
 484                 set(MACOSX_BUNDLE TRUE)
 485                 # This sets the bundle + executable names
 486                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 487                 # This sets the Info.plist executable name
 488                 set(osx_bundle_program_name ${_lyx})
 489                 # Bundle name
 490                 set(LYX_BUNDLE_NAME ${_lyx})
 491
 492                 # This will contain the list of files that need to be included
 493                 # in the bundle and their location within the bundle
 494                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 495                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 496
 497                 # Process Info.plist and lyxrc.dist
 498                 # See development/cmake/Install.cmake
 499                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 500
 501                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 502                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 503
 504                 # Variables used by CPack
 505                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 506                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 507                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 508
 509                 # Set the install paths
 510                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 511                 if(NOT LYX_INSTALL_PREFIX)
 512                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 513                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 514                 endif()
 515                 # Change the owner so that the install can work
 516                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 517         elseif(UNIX)
 518                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 519                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 520                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 521         elseif(WIN32)
 522                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 523         endif()
 524 endif()
 525
 526 if(LYX_INSTALL_PREFIX)
 527         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 528         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 529 endif()
 530 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 531
 532 if(UNIX)
 533   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 534 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 535   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 536 else()
 537   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 538 endif()
 539
 540 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 541   # Not a GCC compiler, programs do not have a suffix
 542   set(suffixing ${LYX_PACKAGE_SUFFIX})
 543 elseif(WIN32 AND MINGW)
 544   # We want to use a suffix for the package in this case,
 545   # even if not for the program
 546   set(suffixing ${LYX_PACKAGE_SUFFIX})
 547 else()
 548   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 549   set(suffixing ${LYX_PROGRAM_SUFFIX})
 550 endif()
 551
 552 # The define PACKAGE below allows lyx-executable to find its default configuration files
 553 # see routines
 554 #    Package::messages_file()
 555 #    get_default_user_support_dir()
 556 #    relative_system_support_dir()
 557 # in src/support/Package.cpp
 558 if(suffixing)
 559         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 560 else()
 561         set(PACKAGE ${PACKAGE_BASE})
 562 endif()
 563
 564 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 565         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 566         if (UNIX)
 567                 # use the default "/usr/local"
 568                 # but respect the user-choice on the command-line
 569                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 570         endif()
 571 endif()
 572 if(WIN32)
 573         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 574 endif()
 575 if(IS_ABSOLUTE)
 576         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 577 else()
 578         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 579 endif()
 580
 581
 582
 583 if(NOT LYX_DATA_SUBDIR)
 584         if (WIN32)
 585                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 586         else()
 587                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 588         endif()
 589 endif()
 590
 591 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 592 get_locale_destination(LYX_LOCALEDIR)
 593 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 594 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 595
 596 if(LYX_BUNDLE AND APPLE)
 597         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 598 else()
 599         if(WIN32)
 600                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 601         elseif(UNIX)
 602                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 603         else()
 604                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 605         endif()
 606 endif()
 607 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 608         unset(LYX_MAN_DIR CACHE)
 609         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 610 endif()
 611 unset(LYX_MAN_DIR_tmp)
 612 mark_as_advanced(LYX_MAN_DIR)
 613
 614 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 615 # see the Readme.txt of the installer
 616 #if(LYX_INSTALL AND WIN32)
 617 #       message(STATUS "Configuring NSIS files")
 618 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 619 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 620 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 621 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 622 #endif()
 623
 624 if(NOT GROUP_CODE)
 625         #set(GROUP_CODE "The Golden Code")
 626         set(GROUP_CODE flat)
 627 endif()
 628
 629 # lyx's source files
 630 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 631 set(LYX_HPP_FILES [a-zA-Z]*.h)
 632 set(LYX_MOC_FILES moc_*.cpp)
 633
 634 include(ProjectSourceGroup)
 635
 636
 637 if(LYX_PROFILE AND NOT MSVC)
 638         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 639         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 640         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 641 else()
 642         set(LYX_PROFILE OFF)
 643 endif()
 644
 645
 646 if(LYX_NO_OPTIMIZE)
 647         set(CMAKE_BUILD_TYPE None)
 648         set(LYX_DEBUG OFF)
 649         set(LYX_RELEASE OFF)
 650         set(LYX_PROFILE OFF)
 651 elseif(LYX_RELEASE)
 652         set(CMAKE_BUILD_TYPE Release)
 653         set(LYX_DEBUG OFF)
 654         set(LYX_PROFILE OFF)
 655 elseif(LYX_PROFILE)
 656         set(CMAKE_BUILD_TYPE Profile)
 657         set(LYX_DEBUG OFF)
 658 else()
 659         set(CMAKE_BUILD_TYPE Debug)
 660         set(LYX_DEBUG ON)
 661 endif()
 662
 663 set(min_qt5_version "5.6")
 664 if(LYX_USE_QT MATCHES "AUTO")
 665         # try qt6 first
 666         find_package(Qt6Core CONFIG QUIET)
 667         if (Qt6Core_FOUND)
 668                 set(LYX_USE_QT "QT6" CACHE STRING "Valid qt version" FORCE)
 669                 message(STATUS "Qt6Core_VERSION = ${Qt6Core_VERSION}")
 670         else()
 671                 find_package(Qt5Core CONFIG QUIET)
 672                 if(Qt5Core_FOUND)
 673                         set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 674                         message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 675                         if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 676                                 message(FATAL_ERROR "No appropriate QT-version found")
 677                         endif()
 678                 else()
 679                         message(FATAL_ERROR "No appropriate QT-version found")
 680                 endif()
 681         endif()
 682 endif()
 683
 684 # When shared libs are supported enable this option
 685 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 686 if(LYX_SHARED_LIBRARIES)
 687         set(library_type SHARED)
 688 else()
 689         set(library_type STATIC)
 690 endif()
 691
 692 if(LYX_ENABLE_ASSERTIONS)
 693   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 694 else()
 695   set(LYX_CXX_FLAGS "")
 696 endif()
 697
 698 if (LYX_DEBUG_SANITIZE MATCHES "ADDRESS")
 699     set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 700     message(STATUS)
 701     message(STATUS "Address sanitizer enabled. Usage:")
 702     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 703     message(STATUS "    chmod  +x ./asan_symbolize.py")
 704     message(STATUS "    ./bin/${_lyx} 2>&1 | ./asan_symbolize.py  | c++filt ")
 705     message(STATUS)
 706 elseif (LYX_DEBUG_SANITIZE MATCHES "UNSPECIFIED")
 707     set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 708     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 709 endif()
 710
 711 if(MSVC)
 712   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 713     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 714     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 715   endif()
 716   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 717 else()
 718         if(NOT LYX_QUIET)
 719                 set(CMAKE_VERBOSE_MAKEFILE ON)
 720         endif()
 721         if(LYX_GCC11_MODE MATCHES "\\+\\+([0-9][0-9])")
 722           # Thanks to Brad King <brad.king@kitware.com>
 723           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 724           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 725           # and still use our own c++ extension tests
 726           set(std_num ${CMAKE_MATCH_1})
 727           set(CMAKE_CXX_STANDARD ${std_num})
 728         else()
 729           message(STATUS "Setting CMAKE_CXX_STANDARD 11 as fallback")
 730           set(CMAKE_CXX_STANDARD 11)
 731           set(LYX_GCC11_MODE "--std=c++11")
 732         endif()
 733         # The following setting with LYX_GCC11_MODE is needed because cmake does not honor
 734         # CMAKE_CXX_STANDARD while performing tests like
 735         # check_cxx_source_compiles("..." HAVE_DEF_MAKE_UNIQUE)
 736         include(CheckCXXCompilerFlag)
 737         unset(CHECK_WNODEPRECATEDCOPY_FLAG CACHE)
 738         CHECK_CXX_COMPILER_FLAG("-Wdeprecated-copy" CHECK_WNODEPRECATEDCOPY_FLAG)
 739         if(${CHECK_WNODEPRECATEDCOPY_FLAG})
 740                 set(LYX_CXX_FLAGS "-Wall -Wextra -Wno-deprecated-copy ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 741         else()
 742                 set(LYX_CXX_FLAGS "-Wall -Wextra ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 743         endif()
 744         message(STATUS "LYX_USE_QT = ${LYX_USE_QT}")
 745         if(LYX_USE_QT MATCHES "QT6")
 746           if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC)
 747             message(WARNING "Compiling LyX with stdlib-debug and Qt6 library may lead to crashes. Consider dropping -DLYX_DEBUG_GLIBC=ON and -DLYX_DEBUG_GLIBC_PEDANTIC=ON")
 748           endif()
 749         endif()
 750         if(LYX_STDLIB_DEBUG OR LYX_DEBUG_GLIBC_ASSERTIONS)
 751           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_ASSERTIONS")
 752         endif()
 753         if(LYX_DEBUG_GLIBC)
 754           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 755         endif()
 756         if(LYX_DEBUG_GLIBC_PEDANTIC)
 757           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 758         endif()
 759         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 760         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 761         if(MINGW)
 762                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 763         else()
 764                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 765         endif()
 766 endif()
 767
 768 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 769 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 770 if(LYX_CXX_FLAGS_EXTRA)
 771         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 772                 add_definitions(${_flag})
 773         endforeach()
 774 endif()
 775
 776 if(LYX_XMINGW)
 777         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 778 endif()
 779
 780 set(QtCore5CompatLibrary)
 781 set(QtCore5CompatModule)
 782 if(LYX_USE_QT MATCHES "QT6|QT5")
 783         if (LYX_USE_QT MATCHES "QT6")
 784                 set(QtVal "Qt6")
 785                 macro (qt_add_resources)
 786                         Qt6_add_resources(${ARGN})
 787                 endmacro()
 788                 macro (qt_wrap_uifiles)
 789                         Qt6_wrap_ui(${ARGN})
 790                 endmacro()
 791         else()
 792                 set(QtVal "Qt5")
 793                 macro (qt_add_resources)
 794                         Qt5_add_resources(${ARGN})
 795                 endmacro()
 796                 macro (qt_wrap_uifiles)
 797                         Qt5_wrap_ui(${ARGN})
 798                 endmacro()
 799         endif()
 800         # set QPA_XCB if QT uses X11
 801         find_package(${QtVal}Core CONFIG REQUIRED)
 802         if (${QtVal}Core_FOUND)
 803                 find_package(${QtVal}Widgets CONFIG REQUIRED)
 804                 if(APPLE)
 805                         if (LYX_USE_QT MATCHES "QT6")
 806                                 find_package(${QtVal}MacExtras CONFIG QUIET)
 807                         else()
 808                                 find_package(${QtVal}MacExtras CONFIG REQUIRED)
 809                         endif()
 810                 endif()
 811                 find_package(${QtVal}X11Extras CONFIG QUIET)
 812                 find_package(${QtVal}WinExtras CONFIG QUIET)
 813                 set(QTVERSION ${${QtVal}Core_VERSION})
 814                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 815                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 816                         message(STATUS "This version is not recommended,")
 817                         message(STATUS "please install QT-Version >= \"${min_qt5_version}\"")
 818                         # see thread in lyx-devel list
 819                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 820                         # Date 11.03.2017
 821                         # Subject: cmake compilation error
 822                         #message(FATAL_ERROR "Wrong Qt-Version")
 823                 endif()
 824                 macro (qt_use_modules lyxtarget)
 825                         foreach (_tg ${ARGN})
 826                                 find_package(${QtVal}${_tg} CONFIG REQUIRED)
 827                                 target_link_libraries(${lyxtarget} ${QtVal}::${_tg})
 828                         endforeach()
 829                 endmacro()
 830                 message(STATUS "Found Qt-Version ${QTVERSION}")
 831                 if(WIN32)
 832                         set(LYX_QTMAIN_LIBRARY ${${QtVal}Core_QTMAIN_LIBRARIES})
 833                 endif()
 834                 if (LYX_USE_QT MATCHES "QT6")
 835                         get_target_property(QT_MOC_EXECUTABLE Qt6::moc LOCATION)
 836                         #find_package(Qt6 COMPONENTS Core5Compat REQUIRED)
 837                         # We don't know why QtZlib is included, and ideally we
 838                         # would have a different fix than relying on this
 839                         # variable (which as "Private" in the name indicates,
 840                         # it might be a fragile workaround).
 841                         # See ML discussion here:
 842                         # https://www.mail-archive.com/search?l=mid&q=CAGU9VOqpkngYBumnNh%3DcuzQ585GsS7TJbhHa903nJSfy-davRg%40mail.gmail.com
 843                         list(REMOVE_ITEM Qt6Core5Compat_INCLUDE_DIRS ${_Qt6ZlibPrivate_OWN_INCLUDE_DIRS})
 844                         include_directories(${Qt6Core5Compat_INCLUDE_DIRS})
 845                         #set(QtCore5CompatLibrary Qt6::Core5Compat)
 846                         #set(QtCore5CompatModule Core5Compat)
 847                 endif()
 848         endif()
 849 else()
 850   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 851 endif()
 852
 853 find_package(Magic)
 854 if(Magic_FOUND)
 855   set(HAVE_MAGIC_H 1)
 856   include_directories(${Magic_INCLUDE_DIR})
 857 endif()
 858
 859 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 860
 861 set(Spelling_FOUND OFF)
 862 set(Include_used_spellchecker)   # String will be inserted into config.h
 863
 864 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 865   # try system library first
 866   find_package(MYTHESLIB)
 867   if (MYTHESLIB_FOUND)
 868     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 869   else()
 870     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 871   endif()
 872 endif()
 873 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 874   find_package(MYTHESLIB REQUIRED)
 875 else()
 876   add_subdirectory(3rdparty/mythes)
 877 endif()
 878 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 879
 880 if(NOT LYX_EXTERNAL_HUNSPELL)
 881     add_subdirectory(3rdparty/hunspell)
 882     add_definitions(-DHUNSPELL_STATIC)
 883     set(HUNSPELL_FOUND ON)
 884     message(STATUS "  * Hunspell:")
 885     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 886     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 887 endif()
 888
 889 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 890   string(TOUPPER ${_spell} _upspell)
 891   if (NOT ${_upspell}_FOUND)
 892     find_package(${_spell})
 893   endif()
 894   if (${_upspell}_FOUND)
 895     include_directories(${${_upspell}_INCLUDE_DIR})
 896     set(Spelling_FOUND ON)
 897     message(STATUS "Building with USE_${_upspell}")
 898     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 899   else()
 900     if(LYX_${_upspell})
 901       message(FATAL_ERROR "Required ${_spell} devel package not found")
 902     else()
 903       message(STATUS "${_upspell} not found, building without ${_spell} support")
 904     endif()
 905   endif()
 906 endforeach()
 907
 908 if(GNUWIN32_DIR)
 909         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 910         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Perl/bin" )
 911 endif()
 912
 913 # Search for python default version first
 914 unset(PYTHON_EXECUTABLE CACHE)
 915 unset(LYX_PYTHON_EXECUTABLE CACHE)
 916 unset(PYTHON_VERSION_MAJOR)
 917 unset(PYTHON_VERSION_MINOR)
 918 unset(PYTHON_VERSION_STRING)
 919 if (CMAKE_VERSION VERSION_LESS "3.13")
 920   find_package(PythonInterp 3.5 QUIET)
 921   if(NOT PYTHONINTERP_FOUND)
 922     find_package(PythonInterp 2.0 REQUIRED)
 923     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 924       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 925     endif()
 926   endif()
 927   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 928 else()
 929   find_package(Python3 3.5 QUIET)
 930   if(NOT Python3_Interpreter_FOUND)
 931     unset(PYTHON_EXECUTABLE CACHE)
 932     find_package(Python2 2.0 REQUIRED)
 933     if(NOT Python2_VERSION VERSION_LESS 2.8)
 934       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 935     endif()
 936     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 937   else()
 938     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 939   endif()
 940 endif()
 941
 942 if(LYX_NLS)
 943         find_package(LyXGettext)
 944         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 945                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 946         else()
 947                 # Install only supplied .gmo-files
 948                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 949                 message(STATUS "Installing provided .gmo-files only")
 950                 foreach( _gmo ${_gmofiles})
 951                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 952                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 953                 endforeach()
 954         endif()
 955 endif()
 956
 957 if(LYX_EXTERNAL_ICONV)
 958   # Possible remnants of previous run without external iconv
 959   file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/libiconv" "${CMAKE_BINARY_DIR}/3rdparty/libiconv")
 960   find_package(ICONV REQUIRED)
 961 else()
 962   add_subdirectory(3rdparty/libiconv)
 963   set(HAVE_ICONV_CONST 1)
 964 endif()
 965
 966 if(LYX_EXTERNAL_Z)
 967   find_package(ZLIB REQUIRED)
 968 else()
 969   add_subdirectory(3rdparty/zlib)
 970 endif()
 971
 972 if(NOT LYX_EXTERNAL_DTL)
 973   add_subdirectory(3rdparty/dtl)
 974 endif()
 975
 976 # Set only include path.
 977 # Use internal boost, which is known to exist
 978 # we don't need any libraries
 979 set(Lyx_Boost_Libraries)
 980 add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 981 include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 982
 983 include_directories(${TOP_SRC_DIR}/3rdparty/nod)
 984
 985 if(WIN32)
 986         if(LYX_CONSOLE)
 987                 set(LYX_QTMAIN_LIBRARY)
 988         else()
 989                 set(WIN32_CONSOLE WIN32)
 990         endif()
 991         if(MSVC)
 992                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 993                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 994                 # disable checked iterators for msvc release builds to get maximum speed
 995                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 996         else()
 997                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 998                 # does not use it and always declares the vista compatible API.
 999                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
1000                 add_definitions(-DWINVER=0x0500)
1001         endif()
1002 endif()
1003
1004 # Compute qt-version from ${QTVERSION}
1005
1006 message(STATUS "")
1007 foreach(_v PACKAGE PACKAGE_VERSION
1008         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
1009         LYX_ABS_TOP_SRCDIR
1010         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
1011         if(NOT DEFINED ${_v})
1012                 message(FATAL_ERROR "${_v} not defined")
1013         endif()
1014         string(SUBSTRING "${_v}                            " 0 28 _v1)
1015         message(STATUS "----- ${_v1}: ${${_v}}")
1016 endforeach(_v)
1017 message(STATUS "")
1018
1019
1020 if(LYX_PCH)
1021         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
1022         # Not sure if it works for all non-msvc compilers
1023         include(PCHSupport_26)
1024         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
1025         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
1026         add_definitions(-DLYX_ENABLE_PCH)
1027
1028         if(MSVC)
1029                 macro(lyx_add_msvc_pch name_)
1030                         set_source_files_properties(${${name_}_sources} PROPERTIES
1031                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
1032                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
1033                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
1034                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
1035                                 ${TOP_BINARY_DIR}/pcheaders.h)
1036                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1037                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1038                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
1039                 endmacro(lyx_add_msvc_pch)
1040                 macro(lyx_add_gcc_pch name_)
1041                 endmacro()
1042         else()
1043                 macro(lyx_add_msvc_pch name_)
1044                 endmacro()
1045                 macro(lyx_add_gcc_pch name_)
1046                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1047                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1048                 endmacro()
1049         endif()
1050 else()
1051         macro(lyx_add_msvc_pch)
1052         endmacro(lyx_add_msvc_pch)
1053         macro(lyx_add_gcc_pch name_)
1054         endmacro()
1055 endif()
1056
1057
1058 if(MSVC)
1059
1060         if(LYX_VLD)
1061                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1062                 add_subdirectory(${vld_path}/cmake)
1063                 include(${vld_path}/cmake/vld.cmake) # forced include
1064                 set(vld_dll vld)
1065         endif()
1066
1067         if(LYX_WALL)
1068                 # Use the highest warning level
1069                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1070
1071                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1072                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1073                 else()
1074                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1075                 endif()
1076
1077                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1078                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1079                 else()
1080                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1081                 endif()
1082
1083                 # add here warnings which should produce an error /weXXXX
1084                 set(MSVC_W_ERROR   "/we4101 /we4189")
1085                 # add here warnings which should be disabled /wdXXXX
1086                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1087
1088                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1089                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1090                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1091
1092         else()
1093                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1094
1095                 # add here warnings which should produce an error /weXXXX
1096                 set(MSVC_W_ERROR   "/we4101 /we4189")
1097                 # add here warnings which should be disabled /wdXXXX
1098                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1099
1100                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1101                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1102                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1103
1104         endif()
1105
1106         if (NOT (Qt5Core_FOUND OR Qt6Core_FOUND))
1107                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1108                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1109                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1110         endif()
1111
1112         if (MSVC_VERSION GREATER_EQUAL 1914)
1113                 # Ensure the __cplusplus macro is set to a sensible value.
1114                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:__cplusplus")
1115                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:__cplusplus")
1116                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:__cplusplus")
1117         endif()
1118
1119         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1120         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1121         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1122         message(STATUS "")
1123 endif()
1124
1125
1126 # Xcode compiler
1127 if (CMAKE_GENERATOR MATCHES Xcode)
1128         if (XCODE_VERSION VERSION_LESS "5.0")
1129                 # Automatically select the Xcode compiler if not set
1130                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1131                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1132                         if (XCODE_VERSION VERSION_GREATER "3.1")
1133                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1134                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1135                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1136                 # Print the selected compiler version
1137         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1138         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1139 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1140
1141 if (WIN32 AND Qt5Core_FOUND)
1142         set(Z_PREFIX 1)
1143 endif()
1144
1145 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1146 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1147 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1148
1149 unset(opts)
1150 foreach(_option ${LYX_OPTIONS})
1151   if(${_option}_show_message)
1152     string(SUBSTRING "${_option}                            " 0 31 _var)
1153     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1154     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1155     if (${_index} GREATER -1)
1156       set(_isset ${${_option}})
1157     elseif(${_option})
1158       set(_isset ON)
1159     else()
1160       set(_isset OFF)
1161     endif()
1162     string(SUBSTRING "${_isset}           " 0 10 _val)
1163     set(opts "${opts} ${_option}(${${_option}})")
1164   endif()
1165 endforeach()
1166 set(tmp_vi "CMake Build")
1167 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1168 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1169 list(APPEND tmp_vi "  Build flags:             ${opts}")
1170 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1171 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1172 if (LYX_DEBUG)
1173 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1174 else()
1175 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1176 endif()
1177 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1178 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1179 get_data_destination(dest_data)
1180 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1181 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1182
1183 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1184 unset(opts)
1185 unset(tmp_vi)
1186
1187 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1188         MATH(EXPR QTx_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1189 endif()
1190
1191
1192 set (cmd ${CMAKE_CTEST_COMMAND})
1193 if (MSVC)
1194         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1195 else ()
1196         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1197 endif ()
1198 add_custom_target (lyx_run_tests COMMAND ${cmd})
1199 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1200
1201 if(LYX_INSTALL)
1202         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1203                 message(STATUS "Python required to create doc!")
1204         else()
1205                 if(UNIX)
1206                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1207                 endif()
1208                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1209         endif()
1210 endif()
1211 include(../Install)
1212
1213 # By running the URL tests first, time can be saved when running the ctests in
1214 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1215
1216 # Needed, because of perl scripts in checkurls autotests and batchtests
1217 find_package(Perl REQUIRED)
1218
1219 if(LYX_ENABLE_URLTESTS)
1220         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1221 endif()
1222 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1223 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1224 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1225 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1226 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1227 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1228 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1229
1230 message(STATUS)
1231 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1232 message(STATUS)
1233
1234 LYX_OPTION_LIST_ALL(used)
1235
1236
1237 if(LYX_NLS)
1238         message(STATUS)
1239         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1240         message(STATUS)
1241         message(STATUS "  * iconv")
1242         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1243         message(STATUS "     - library: ${ICONV_LIBRARY}")
1244         message(STATUS "  * zlib")
1245         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1246         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1247         message(STATUS)
1248 endif()
1249
1250 # Apple has builtin native spell checker,
1251 # no need to warn for missing Aspell, Hunspell or Enchant
1252 if(NOT Spelling_FOUND AND NOT APPLE)
1253   if(LYX_REQUIRE_SPELLCHECK)
1254     set(_mode "FATAL_ERROR")
1255   else()
1256     set(_mode "STATUS")
1257   endif()
1258   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1259 endif()
1260
1261 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1262
1263 if(ENABLE_DIST)
1264   # Use git to create the source package
1265   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1266   if(UNIX)
1267     set(DIST_FORMAT tgz)
1268   else()
1269     set(DIST_FORMAT zip)
1270   endif()
1271   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1272
1273   add_custom_command(
1274     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1275     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1276     WORKING_DIRECTORY ${TOP_SRC_DIR})
1277   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1278 endif()
1279
1280 # Last directory to be included so that the fixup code (OS X)
1281 # can be run last
1282 add_subdirectory(development/cmake/post_install)
1283
1284 string(TIMESTAMP current_date "%Y-%m-%d %H:%M")
1285 execute_process(COMMAND ${LYX_GITVERSION} describe --tags
1286         WORKING_DIRECTORY "${TOP_SRC_DIR}"
1287         OUTPUT_VARIABLE current_version
1288         OUTPUT_STRIP_TRAILING_WHITESPACE)
1289 file(APPEND "${TOP_BINARY_DIR}/Testing/IgnoredCount" "${current_date} ${current_version} Ignored tests = ${LYX_ignored_count}\n")
1290 message(STATUS)