CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT LyX)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 if(UNIX)
  46         set(ARCH_TRIPLET )
  47         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  48         if(DPKG_ARCHITECTURE_EXECUTABLE)
  49                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  50                                 OUTPUT_VARIABLE ARCH_TRIPLET
  51                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  52                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  53         endif()
  54 endif()
  55 if(ARCH_TRIPLET)
  56         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  57 else()
  58         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  59 endif()
  60
  61 include(LyXMacros)
  62
  63 # Usage LYX_OPTION
  64 # 1. parameter: option name without prefix 'LYX_'
  65 # 2. parameter: description
  66 # 3. parameter: default value, ON or OFF
  67 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  68
  69
  70 LYX_OPTION_INIT()
  71
  72 # Options for all compilers/systems
  73 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  74 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  75 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  76 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  77 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  78 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  79 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  80 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  81 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  82 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  83 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  84 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  85 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  86 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  87 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  88 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  89 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  90 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  91 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  92
  93 # GCC specific
  94 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  95 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  96 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  97 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  98 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  99 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 100 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 101 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 102
 103 # MSVC specific
 104 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 105 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 106 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 107 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 108 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 109
 110 # APPLE specific
 111 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 112 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 113
 114
 115 if(help OR HELP)
 116         message(STATUS)
 117         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 118         message(STATUS)
 119         LYX_OPTION_LIST_ALL(help)
 120         message(STATUS)
 121         RETURN()
 122 endif()
 123
 124 # Check option dependencies
 125
 126 if(LYX_CPACK)
 127         set(LYX_INSTALL ON)
 128 endif()
 129
 130 if(LYX_DMG)
 131         set(LYX_BUNDLE ON)
 132         set(LYX_CPACK ON)
 133 endif()
 134
 135 if(LYX_INSTALL)
 136         set(LYX_NLS ON)
 137         if (WIN32)
 138                 set(LYX_HUNSPELL ON)
 139         endif()
 140         if(LYX_CONSOLE MATCHES "FORCE")
 141                 set(LYX_CONSOLE ON)
 142         else()
 143                 set(LYX_CONSOLE OFF)
 144         endif()
 145         set(LYX_PACKAGE_SUFFIX ON)
 146         set(LYX_RELEASE ON)
 147         set(LYX_PROFILE OFF)
 148 endif()
 149
 150
 151 if(LYX_MERGE_FILES)
 152         set(LYX_PCH OFF)
 153 else()
 154         set(LYX_MERGE_REBUILD OFF)
 155 endif()
 156
 157 if(LYX_DEPENDENCIES_DOWNLOAD)
 158         message(STATUS)
 159         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 160         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 161         set(deps_files lyx20-deps-msvc2010-x86.zip)
 162         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 163         foreach(it ${deps_files})
 164                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 165                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 166                 if(NOT already_downloaded)
 167                         message(STATUS "Downloading ${it} ...")
 168                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 169                         list(GET status 0 status_code)
 170                         list(GET status 1 status_string)
 171                         if(NOT status_code EQUAL 0)
 172                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 173                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 174                         endif()
 175                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 176                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 177                 endif()
 178         endforeach()
 179         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 180 endif()
 181
 182
 183
 184 message(STATUS)
 185
 186 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 187 if(WIN32)
 188         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 189 else()
 190         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 191 endif()
 192
 193
 194 if(UNIX OR MINGW)
 195         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 196         message(STATUS "Using GCC version ${GCC_VERSION}")
 197         if(NOT GCC_VERSION VERSION_LESS 4.4)
 198                 set(LYX_USE_TR1 1)
 199                 # GCC <= 4.5 does not support regex: there are linker errors
 200                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 201                 set(LYX_USE_TR1_REGEX 0)
 202         endif()
 203 else()
 204         if(MSVC10)
 205                 set(LYX_USE_TR1 1)
 206                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 207         endif()
 208 endif()
 209
 210
 211 set(VERSION_INFO "CMake Build")
 212
 213 # Try to get some informations from configure.ac
 214
 215 include(LyXPaths)
 216 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 217
 218 if(WIN32)
 219         set(USE_WINDOWS_PACKAGING ON)
 220 elseif(APPLE)
 221         set(USE_MACOSX_PACKAGING ON)
 222 else()
 223         set(USE_POSIX_PACKAGING ON)
 224 endif()
 225
 226 macro(setstripped _varname _value)
 227         string(STRIP ${_value} _v)
 228         if(USE_POSIX_PACKAGING)
 229                 string(TOLOWER ${_v} ${_varname})
 230         else()
 231                 set(${_varname} ${_v})
 232         endif()
 233 endmacro(setstripped)
 234
 235 foreach(_c_l ${_config_lines} )
 236         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 237                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 238                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 239                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 240                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 241                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 242                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 243                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 244                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 245                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 246                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 247                 endif()
 248         endif()
 249         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 250                 set(LYX_DATE "${CMAKE_MATCH_1}")
 251         endif()
 252 endforeach(_c_l)
 253
 254 if (LYX_LOCALVERSIONING)
 255         # Find the revision number and for later use
 256         FIND_PROGRAM(LYX_GITVERSION git)
 257         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 258         if(LYX_GITVERSION)
 259                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "describe" WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 260                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 261                   # We will add offset of 40000 to get appropriate value to
 262                   # previous svn.
 263                   # We use this value than also to set the package-patch-value
 264                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 265                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 266                 endif()
 267         else()
 268                 set(LYX_REVISION_VERSION git) #TODO use date
 269         endif()
 270 else()
 271         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 272 endif()
 273
 274 if(LYX_PROGRAM_SUFFIX)
 275         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 276 else()
 277         set(PROGRAM_SUFFIX "")
 278 endif()
 279
 280
 281 if(LYX_BUNDLE)
 282         set(LYX_CPACK ON)
 283         message(STATUS)
 284         message(STATUS "Bundle creation is enabled (experimental):")
 285         message(STATUS "    make")
 286         message(STATUS "    make install/strip")
 287         message(STATUS "    make package")
 288         if(APPLE)
 289                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 290                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 291                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 292                 if(NOT LYX_INSTALL_PREFIX)
 293                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 294                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 295                 endif()
 296         elseif(UNIX)
 297                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 298                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 299                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 300         elseif(WIN32)
 301                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 302         endif()
 303 endif()
 304
 305 if(LYX_INSTALL_PREFIX)
 306         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 307         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 308 endif()
 309 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 310
 311 if(LYX_PACKAGE_SUFFIX)
 312         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 313 else()
 314         set(PACKAGE ${PACKAGE_BASE})
 315 endif()
 316
 317
 318 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 319         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 320         if (UNIX)
 321                 # don't use the default "/usr/local"
 322                 # but respect the user-choice on the command-line
 323                 if(LYX_INSTALL_SUFFIX)
 324                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 325                 else()
 326                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 327                 endif()
 328         endif()
 329         if(WIN32)
 330                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 331         endif()
 332 endif()
 333 if(IS_ABSOLUTE)
 334         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 335 else()
 336         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 337 endif()
 338
 339
 340
 341 if(NOT LYX_DATA_SUBDIR)
 342         if (WIN32)
 343                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 344         else()
 345                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 346         endif()
 347 endif()
 348
 349 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 350 set(LYX_LOCALEDIR "locale")
 351 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 352 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 353
 354
 355 if(LYX_INSTALL AND WIN32)
 356         message(STATUS "Configuring NSIS files")
 357         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 358         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 359         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 360         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 361 endif()
 362
 363 if(NOT GROUP_CODE)
 364         #set(GROUP_CODE "The Golden Code")
 365         set(GROUP_CODE flat)
 366 endif()
 367
 368 # lyx's source files
 369 set(LYX_CPP_FILES *.cpp)
 370 set(LYX_HPP_FILES *.h)
 371 set(LYX_MOC_FILES moc_*.cpp)
 372
 373 include(ProjectSourceGroup)
 374
 375
 376 if(LYX_PROFILE AND NOT MSVC)
 377         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 378         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 379         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 380 else()
 381         set(LYX_PROFILE OFF)
 382 endif()
 383
 384
 385 if(LYX_NO_OPTIMIZE)
 386         set(CMAKE_BUILD_TYPE None)
 387         set(LYX_DEBUG OFF)
 388         set(LYX_RELEASE OFF)
 389         set(LYX_PROFILE OFF)
 390 elseif(LYX_RELEASE)
 391         set(CMAKE_BUILD_TYPE Release)
 392         set(LYX_DEBUG OFF)
 393         set(LYX_PROFILE OFF)
 394 elseif(LYX_PROFILE)
 395         set(CMAKE_BUILD_TYPE Profile)
 396         set(LYX_DEBUG OFF)
 397 else()
 398         set(CMAKE_BUILD_TYPE Debug)
 399         set(LYX_DEBUG ON)
 400 endif()
 401
 402
 403 # When shared libs are supported enable this option
 404 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 405 if(LYX_SHARED_LIBRARIES)
 406         set(library_type SHARED)
 407 else()
 408         set(library_type STATIC)
 409 endif()
 410
 411 if(NOT MSVC)
 412         if(NOT LYX_QUIET)
 413                 set(CMAKE_VERBOSE_MAKEFILE ON)
 414         endif()
 415         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 416         if(LYX_STDLIB_DEBUG)
 417                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 418         endif()
 419         if(LYX_CONCEPT_CHECKS)
 420                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 421         endif()
 422         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 423         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 424         if(MINGW)
 425                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 426         else()
 427                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 428         endif()
 429 endif()
 430
 431
 432 find_package(Qt4 REQUIRED)
 433 find_package(Magic)
 434 if(Magic_FOUND)
 435         set(HAVE_MAGIC_H 1)
 436 endif()
 437
 438 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 439
 440 if(LYX_ASPELL)
 441         find_package(ASPELL)
 442         include_directories(${ASPELL_INCLUDE_DIR})
 443 endif()
 444
 445 if(LYX_ENCHANT)
 446         find_package(Enchant REQUIRED)
 447         include_directories(${ENCHANT_INCLUDE_DIR})
 448 endif()
 449
 450 if(LYX_HUNSPELL)
 451         find_package(Hunspell REQUIRED)
 452         include_directories(${HUNSPELL_INCLUDE_DIR})
 453 endif()
 454
 455 if(LYX_NLS)
 456         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 457         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 458                 message(FATAL_ERROR "Python 2.6 needed!")
 459         endif()
 460         find_package(LyXGettext REQUIRED)
 461         include_directories(${TOP_SRC_DIR}/po)
 462         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 463 endif()
 464
 465 if(LYX_NLS)
 466         if(LYX_EXTERNAL_LIBINTL)
 467                 find_package(Libintl REQUIRED)
 468                 if(DEFINED LIBINTL_LIBRARIES)
 469                         # find getext when configuring
 470                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 471                         # on mac use iconv also form ports
 472                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 473                 endif()
 474         else()
 475                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 476         endif()
 477 endif()
 478
 479 find_package(ICONV REQUIRED)
 480 find_package(ZLIB REQUIRED)
 481
 482 if(LYX_EXTERNAL_BOOST)
 483         message(STATUS "Searching for boost")
 484         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 485         if(Boost_FOUND)
 486                 message(STATUS "Boost found")
 487                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 488                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 489         else()
 490                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 491         endif()
 492 else()
 493         if(LYX_USE_TR1_REGEX)
 494                 set(Lyx_Boost_Libraries boost_signals)
 495         else()
 496                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 497         endif()
 498         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 499         include_directories(${TOP_SRC_DIR}/boost)
 500         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 501 endif()
 502
 503
 504
 505
 506 if(WIN32)
 507         if(NOT LYX_CONSOLE)
 508                 set(WIN32_CONSOLE WIN32)
 509                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 510         endif()
 511         if(MSVC)
 512                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 513                 # disable checked iterators for msvc release builds to get maximum speed
 514                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 515         else()
 516                 add_definitions(-DWINVER=0x0500)
 517         endif()
 518 endif()
 519
 520 message(STATUS "")
 521 foreach(_v PACKAGE PACKAGE_VERSION
 522         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 523         LYX_ABS_TOP_SRCDIR
 524         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 525         if(NOT DEFINED ${_v})
 526                 message(FATAL_ERROR "${_v} not defined")
 527         endif()
 528         string(SUBSTRING "${_v}                            " 0 28 _v1)
 529         message(STATUS "----- ${_v1}: ${${_v}}")
 530 endforeach(_v)
 531 message(STATUS "")
 532
 533
 534 if(LYX_PCH)
 535         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 536         # Not sure if it works for all non-msvc compilers
 537         include(PCHSupport_26)
 538         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 539         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 540         add_definitions(-DLYX_ENABLE_PCH)
 541
 542         if(MSVC)
 543                 macro(lyx_add_msvc_pch name_)
 544                         set_source_files_properties(${${name_}_sources} PROPERTIES
 545                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 546                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 547                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 548                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 549                                 ${TOP_BINARY_DIR}/pcheaders.h)
 550                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 551                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 552                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 553                 endmacro(lyx_add_msvc_pch)
 554                 macro(lyx_add_gcc_pch name_)
 555                 endmacro()
 556         else()
 557                 macro(lyx_add_msvc_pch name_)
 558                 endmacro()
 559                 macro(lyx_add_gcc_pch name_)
 560                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 561                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 562                 endmacro()
 563         endif()
 564 else()
 565         macro(lyx_add_msvc_pch)
 566         endmacro(lyx_add_msvc_pch)
 567         macro(lyx_add_gcc_pch name_)
 568         endmacro()
 569 endif()
 570
 571
 572 if(MSVC)
 573
 574         if(LYX_VLD)
 575                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 576                 add_subdirectory(${vld_path}/cmake)
 577                 include(${vld_path}/cmake/vld.cmake) # forced include
 578                 set(vld_dll vld)
 579         endif()
 580
 581         if(LYX_WALL)
 582                 # Use the highest warning level
 583                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 584
 585                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 586                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 587                 else()
 588                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 589                 endif()
 590
 591                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 592                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 593                 else()
 594                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 595                 endif()
 596
 597                 # add here warnings which should produce an error /weXXXX
 598                 set(MSVC_W_ERROR   "/we4101 /we4189")
 599                 # add here warnings which should be disabled /wdXXXX
 600                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 601
 602                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 603                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 604                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 605
 606         else()
 607                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 608
 609                 # add here warnings which should produce an error /weXXXX
 610                 set(MSVC_W_ERROR   "/we4101 /we4189")
 611                 # add here warnings which should be disabled /wdXXXX
 612                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 613
 614                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 615                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 616                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 617
 618         endif()
 619         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 620         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 621         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 622
 623         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 624         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 625         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 626         message(STATUS "")
 627 endif()
 628
 629
 630 if(LYX_DEBUG_GLIBC)
 631         set(_GLIBCXX_DEBUG ON)
 632 endif()
 633
 634 if(LYX_DEBUG_GLIBC_PEDANTIC)
 635         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 636 endif()
 637
 638 # Xcode compiler
 639 if (CMAKE_GENERATOR MATCHES Xcode)
 640         # Automatically select the Xcode compiler if not set
 641         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 642                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 643                 if (XCODE_VERSION VERSION_GREATER "3.1")
 644                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 645                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 646         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 647
 648         # Print the selected compiler version
 649     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 650 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 651
 652
 653 # compiler tests, config.h generation
 654 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 655         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 656 else()
 657         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 658         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 659 endif()
 660
 661 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 662
 663 # Compute qt4-version from ${QTVERSION}
 664 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 665         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 666 endif()
 667
 668 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 669 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 670 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 671 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 672
 673
 674 if(LYX_INSTALL)
 675         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 676                 message(STATUS "Python required to create doc!")
 677         else()
 678                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 679                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 680         endif()
 681         include(../Install)
 682 endif()
 683
 684 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 685
 686 message(STATUS)
 687 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 688 message(STATUS)
 689 LYX_OPTION_LIST_ALL(used)
 690
 691
 692 if(LYX_NLS)
 693         message(STATUS)
 694         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 695         message(STATUS)
 696         message(STATUS "  * intl")
 697         message(STATUS "     - header : ${LIBINTL_HEADER}")
 698         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 699         message(STATUS "  * iconv")
 700         message(STATUS "     - header : ${ICONV_HEADER}")
 701         message(STATUS "     - library: ${ICONV_LIBRARY}")
 702         message(STATUS "  * zlib")
 703         message(STATUS "     - header : ${ZLIB_HEADER}")
 704         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 705         message(STATUS)
 706 endif()
 707
 708 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 709
 710 message(STATUS)