CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 OLD)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84   # Enable LTO if supported
  85   if (POLICY CMP0069)
  86     cmake_policy(SET CMP0069 NEW)
  87     include(CheckIPOSupported)
  88     check_ipo_supported(RESULT result OUTPUT reason LANGUAGES CXX)
  89     if(result)
  90       message(STATUS "Setting IPO True")
  91       set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
  92     else()
  93       message(STATUS "Not setting IPO , result = ${result}, reason = ${reason}")
  94     endif()
  95   endif()
  96 endif()
  97
  98 if(UNIX)
  99         set(ARCH_TRIPLET )
 100         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
 101         if(DPKG_ARCHITECTURE_EXECUTABLE)
 102                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
 103                                 OUTPUT_VARIABLE ARCH_TRIPLET
 104                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
 105                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
 106         endif()
 107 endif()
 108 if(ARCH_TRIPLET)
 109         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 110 else()
 111         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 112 endif()
 113
 114 include(LyXMacros)
 115 include(LyXDestinations)
 116
 117 # Usage LYX_OPTION
 118 # 1. parameter: option name without prefix 'LYX_'
 119 # 2. parameter: description
 120 # 3. parameter: default value, ON or OFF
 121 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 122
 123 # Usage LYX_COMBO
 124 # 1. parameter: name without prefix 'LYX_'
 125 # 2. parameter: description
 126 # 3. parameter: default value
 127 # 4-n parameter: possible other string values
 128
 129 LYX_OPTION_INIT()
 130
 131 # Options for all compilers/systems
 132 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 133 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 134 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 135 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 136 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 137 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 138 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 139 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 140 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 141 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 142 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 143 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 144 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 145 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 146 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 147 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 148 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 149 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 150 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 151 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 152 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 153 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 154 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 155 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 156 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 157 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 158 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 159 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 160 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 161 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 162 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 163
 164 # GCC specific
 165 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 166 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 167 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 168 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 169 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 170 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 171 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 172
 173 # MSVC specific
 174 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 175 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 176 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 177 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 178
 179 # APPLE specific
 180 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 181 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 182
 183
 184 if(help OR HELP)
 185         message(STATUS)
 186         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 187         message(STATUS)
 188         LYX_OPTION_LIST_ALL(help)
 189         message(STATUS)
 190         RETURN()
 191 endif()
 192
 193 # Check option dependencies
 194
 195 if(LYX_DMG)
 196         set(LYX_BUNDLE ON)
 197         set(LYX_CPACK ON)
 198 endif()
 199
 200 if(LYX_CPACK)
 201         set(LYX_INSTALL ON)
 202 endif()
 203
 204 if(LYX_INSTALL)
 205         set(LYX_NLS ON)
 206         if(WIN32 AND NOT MINGW)
 207                 set(LYX_HUNSPELL ON)
 208         endif()
 209         set(LYX_PACKAGE_SUFFIX ON)
 210         if(NOT LYX_DEBUG)
 211                 set(LYX_RELEASE ON)
 212         endif()
 213         set(LYX_PROFILE OFF)
 214 endif()
 215
 216
 217 if(LYX_MERGE_FILES)
 218         set(LYX_PCH OFF)
 219 else()
 220         set(LYX_MERGE_REBUILD OFF)
 221 endif()
 222
 223 if(LYX_DEPENDENCIES_DOWNLOAD)
 224         message(STATUS)
 225         if(MSVC14)
 226                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 227                 set(deps_files lyx-windows-deps-msvc2015.zip)
 228                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 229                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 230         elseif(MSVC10)
 231                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 232                 set(deps_files lyx-windows-deps-msvc2010.zip)
 233                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 234                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 235         else()
 236                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 237         endif()
 238     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 239         foreach(it ${deps_files})
 240                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 241                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 242                 if(NOT already_downloaded)
 243                         message(STATUS "Downloading ${it} ...")
 244                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 245                         list(GET status 0 status_code)
 246                         list(GET status 1 status_string)
 247                         if(NOT status_code EQUAL 0)
 248                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 249                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 250                         endif()
 251                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 252                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 253                 endif()
 254         endforeach()
 255 endif()
 256
 257
 258
 259 message(STATUS)
 260
 261 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 262 if(WIN32)
 263         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 264 else()
 265         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 266 endif()
 267
 268
 269 # Set to some meaningful default
 270 find_package(CXX11Compiler)
 271 if(NOT CXX11COMPILER_FOUND)
 272         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 273 endif()
 274 set(LYX_GCC11_MODE)
 275 if(UNIX OR MINGW)
 276         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 277           # ignore the GCC_VERSION for clang
 278           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 279           message(STATUS "Using clang")
 280           if(CXX11_STD_REGEX)
 281             set(LYX_USE_STD_REGEX 1)
 282           else()
 283             set(LYX_USE_STD_REGEX 0)
 284           endif()
 285         else()
 286           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 287           message(STATUS "Using GCC version ${GCC_VERSION}")
 288           if(GCC_VERSION VERSION_LESS 4.9)
 289                   if(GCC_VERSION VERSION_LESS 4.6)
 290                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 291                   endif()
 292                   # <regex> in gcc is unusable in versions less than 4.9.0
 293                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 294                   set(LYX_USE_STD_REGEX 0)
 295           else()
 296                   set(LYX_USE_STD_REGEX 1)
 297           endif()
 298         endif()
 299         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 300 else()
 301         if(MSVC_VERSION LESS 1915)
 302                 set(LYX_USE_STD_REGEX 0)
 303         else()
 304                 set(LYX_USE_STD_REGEX 1)
 305         endif()
 306 endif()
 307
 308
 309 set(VERSION_INFO "CMake Build")
 310
 311 # Try to get some informations from configure.ac
 312
 313 include(LyXPaths)
 314 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 315
 316 if(WIN32)
 317         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 318         if(MSVC)
 319                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 320         endif()
 321         set(USE_WINDOWS_PACKAGING ON)
 322 elseif(APPLE)
 323         set(USE_MACOSX_PACKAGING ON)
 324 else()
 325         set(USE_POSIX_PACKAGING ON)
 326 endif()
 327
 328 if(LYX_3RDPARTY_BUILD)
 329   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 330   # this enables the build of all 3rd_party libs
 331   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 332   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 333   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 334   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 335 endif()
 336
 337 macro(setstripped _varname)
 338         if(${ARGC} GREATER 1)
 339                 string(STRIP "${ARGV1}" _v)
 340                 if(USE_POSIX_PACKAGING)
 341                         string(TOLOWER ${_v} ${_varname})
 342                 else()
 343                         set(${_varname} ${_v})
 344                 endif()
 345         else()
 346                 set(${_varname})
 347         endif()
 348 endmacro(setstripped)
 349
 350 foreach(_c_l ${_config_lines} )
 351         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 352                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 353                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 354                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 355                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 356                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 357                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 358                         set(LYX_RELEASE_VERSION ${CMAKE_MATCH_4})
 359                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 360                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 361                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 362                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 363                         else()
 364                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 365                         endif()
 366                 endif()
 367         endif()
 368         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 369                 set(LYX_DATE "${CMAKE_MATCH_1}")
 370         endif()
 371 endforeach(_c_l)
 372
 373 FIND_PROGRAM(LYX_GITVERSION git)
 374 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 375 set(LYX_REVISION_VERSION ${LYX_RELEASE_VERSION})
 376 set(LYX_PACKAGE_RELEASE "1")
 377 if(LYX_GITVERSION)
 378   if (LYX_LOCALVERSIONING)
 379     # Find the revision number and for later use
 380     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 381       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 382     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 383       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 384       # We will add offset of 40000 to get appropriate value to
 385       # previous svn.
 386       # We use this value than also to set the package-patch-value
 387       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 388       set(LYX_REVISION_VERSION "${LYX_RELEASE_VERSION}-${tmp_REVISION_VERSION}git")
 389       set(ENABLE_DIST ON)
 390     endif()
 391   endif()
 392 endif()
 393
 394 # Set the programs (lyx, tex2lyx, etc.) suffix
 395 # When building an OS X bundle, we will append
 396 # the suffix only to the bundle, not to the programs
 397 set(PROGRAM_SUFFIX "")
 398 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 399         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 400 endif()
 401 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 402 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 403 set(_convert lyxconvert${PROGRAM_SUFFIX})
 404
 405 add_custom_target(lyx_version ALL
 406   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 407   )
 408 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 409
 410 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 411 set(LYX_UTILITIES_INSTALL_PATH bin)
 412
 413 if(LYX_BUNDLE)
 414         set(LYX_CPACK ON)
 415
 416         message(STATUS)
 417         message(STATUS "Bundle creation is enabled (experimental):")
 418         message(STATUS "    make")
 419         message(STATUS "    make install/strip")
 420         message(STATUS "    make package")
 421         if(APPLE)
 422                 set(MACOSX_BUNDLE TRUE)
 423                 # This sets the bundle + executable names
 424                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 425                 # This sets the Info.plist executable name
 426                 set(osx_bundle_program_name ${_lyx})
 427                 # Bundle name
 428                 set(LYX_BUNDLE_NAME ${_lyx})
 429
 430                 # This will contain the list of files that need to be included
 431                 # in the bundle and their location within the bundle
 432                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 433                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 434
 435                 # Process Info.plist and lyxrc.dist
 436                 # See development/cmake/Install.cmake
 437                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 438
 439                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 440                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 441
 442                 # Variables used by CPack
 443                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 444                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 445                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 446
 447                 # Set the install paths
 448                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 449                 if(NOT LYX_INSTALL_PREFIX)
 450                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 451                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 452                 endif()
 453                 # Change the owner so that the install can work
 454                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 455         elseif(UNIX)
 456                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 457                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 458                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 459         elseif(WIN32)
 460                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 461         endif()
 462 endif()
 463
 464 if(LYX_INSTALL_PREFIX)
 465         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 466         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 467 endif()
 468 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 469
 470 if(UNIX)
 471   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 472 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 473   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 474 else()
 475   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 476 endif()
 477
 478 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 479   # Not a GCC compiler, programs do not have a suffix
 480   set(suffixing ${LYX_PACKAGE_SUFFIX})
 481 elseif(WIN32 AND MINGW)
 482   # We want to use a suffix for the package in this case,
 483   # even if not for the program
 484   set(suffixing ${LYX_PACKAGE_SUFFIX})
 485 else()
 486   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 487   set(suffixing ${LYX_PROGRAM_SUFFIX})
 488 endif()
 489
 490 # The define PACKAGE below allows lyx-executable to find its default configuration files
 491 # see routines
 492 #    Package::messages_file()
 493 #    get_default_user_support_dir()
 494 #    relative_system_support_dir()
 495 # in src/support/Package.cpp
 496 if(suffixing)
 497         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 498 else()
 499         set(PACKAGE ${PACKAGE_BASE})
 500 endif()
 501
 502 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 503         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 504         if (UNIX)
 505                 # use the default "/usr/local"
 506                 # but respect the user-choice on the command-line
 507                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 508         endif()
 509 endif()
 510 if(WIN32)
 511         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 512 endif()
 513 if(IS_ABSOLUTE)
 514         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 515 else()
 516         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 517 endif()
 518
 519
 520
 521 if(NOT LYX_DATA_SUBDIR)
 522         if (WIN32)
 523                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 524         else()
 525                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 526         endif()
 527 endif()
 528
 529 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 530 get_locale_destination(LYX_LOCALEDIR)
 531 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 532 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 533
 534 if(LYX_BUNDLE AND APPLE)
 535         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 536 else()
 537         if(WIN32)
 538                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 539         elseif(UNIX)
 540                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 541         else()
 542                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 543         endif()
 544 endif()
 545 mark_as_advanced(LYX_MAN_DIR)
 546
 547 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 548 # see the Readme.txt of the installer
 549 #if(LYX_INSTALL AND WIN32)
 550 #       message(STATUS "Configuring NSIS files")
 551 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 552 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 553 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 554 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 555 #endif()
 556
 557 if(NOT GROUP_CODE)
 558         #set(GROUP_CODE "The Golden Code")
 559         set(GROUP_CODE flat)
 560 endif()
 561
 562 # lyx's source files
 563 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 564 set(LYX_HPP_FILES [a-zA-Z]*.h)
 565 set(LYX_MOC_FILES moc_*.cpp)
 566
 567 include(ProjectSourceGroup)
 568
 569
 570 if(LYX_PROFILE AND NOT MSVC)
 571         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 572         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 573         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 574 else()
 575         set(LYX_PROFILE OFF)
 576 endif()
 577
 578
 579 if(LYX_NO_OPTIMIZE)
 580         set(CMAKE_BUILD_TYPE None)
 581         set(LYX_DEBUG OFF)
 582         set(LYX_RELEASE OFF)
 583         set(LYX_PROFILE OFF)
 584 elseif(LYX_RELEASE)
 585         set(CMAKE_BUILD_TYPE Release)
 586         set(LYX_DEBUG OFF)
 587         set(LYX_PROFILE OFF)
 588 elseif(LYX_PROFILE)
 589         set(CMAKE_BUILD_TYPE Profile)
 590         set(LYX_DEBUG OFF)
 591 else()
 592         set(CMAKE_BUILD_TYPE Debug)
 593         set(LYX_DEBUG ON)
 594 endif()
 595
 596
 597 # When shared libs are supported enable this option
 598 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 599 if(LYX_SHARED_LIBRARIES)
 600         set(library_type SHARED)
 601 else()
 602         set(library_type STATIC)
 603 endif()
 604
 605 if(NOT MSVC)
 606         if(NOT LYX_QUIET)
 607                 set(CMAKE_VERBOSE_MAKEFILE ON)
 608         endif()
 609         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 610         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 611           # Thanks to Brad King <brad.king@kitware.com>
 612           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 613           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 614           # and still use our own c++ extension tests
 615           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 616           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 617         endif()
 618         if(LYX_STDLIB_DEBUG)
 619                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 620         endif()
 621         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 622         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 623         if(MINGW)
 624                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 625         else()
 626                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 627         endif()
 628 endif()
 629
 630 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 631 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 632 if(LYX_CXX_FLAGS_EXTRA)
 633         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 634                 add_definitions(${_flag})
 635         endforeach()
 636 endif()
 637
 638 if(LYX_XMINGW)
 639         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 640 endif()
 641
 642 set(min_qt5_version "5.6")
 643 if(LYX_USE_QT MATCHES "AUTO")
 644         # try qt5 first
 645         find_package(Qt5Core CONFIG QUIET)
 646         if(Qt5Core_FOUND)
 647                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 648                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 649                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 650                         find_package(Qt4 "4.5.0" QUIET)
 651                         if(QT4_FOUND)
 652                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 653                         endif()
 654                 endif()
 655         else()
 656                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 657         endif()
 658 endif()
 659 if(LYX_USE_QT MATCHES "QT5")
 660         # set QPA_XCB if QT uses X11
 661         find_package(Qt5Core CONFIG REQUIRED)
 662         if (Qt5Core_FOUND)
 663                 find_package(Qt5Widgets CONFIG REQUIRED)
 664                 if(APPLE)
 665                         find_package(Qt5MacExtras CONFIG REQUIRED)
 666                 endif()
 667                 find_package(Qt5X11Extras CONFIG QUIET)
 668                 find_package(Qt5WinExtras CONFIG QUIET)
 669                 set(QTVERSION ${Qt5Core_VERSION})
 670                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 671                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 672                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 673                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 674                         # see thread in lyx-devel list
 675                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 676                         # Date 11.03.2017
 677                         # Subject: cmake compilation error
 678                         #message(FATAL_ERROR "Wrong Qt-Version")
 679                 endif()
 680                 macro (qt_use_modules lyxtarget)
 681                         foreach (_tg ${ARGN})
 682                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 683                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 684                         endforeach()
 685                 endmacro()
 686                 macro (qt_add_resources)
 687                         qt5_add_resources(${ARGN})
 688                 endmacro()
 689                 macro (qt_wrap_uifiles)
 690                         qt5_wrap_ui(${ARGN})
 691                 endmacro()
 692                 message(STATUS "Found Qt-Version ${QTVERSION}")
 693                 if(WIN32)
 694                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 695                 endif()
 696         endif()
 697 elseif(LYX_USE_QT MATCHES "QT4")
 698         if(LYX_XMINGW)
 699                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 700                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 701         endif()
 702         find_package(Qt4 "4.5.0" REQUIRED)
 703         macro (qt_use_modules)
 704         endmacro()
 705         macro (qt_add_resources)
 706                 qt4_add_resources(${ARGN})
 707         endmacro()
 708         macro (qt_wrap_uifiles)
 709                 qt4_wrap_ui(${ARGN})
 710         endmacro()
 711         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 712         if(WIN32)
 713                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 714         endif()
 715 else()
 716   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 717 endif()
 718
 719 find_package(Magic)
 720 if(Magic_FOUND)
 721   set(HAVE_MAGIC_H 1)
 722   include_directories(${Magic_INCLUDE_DIR})
 723 endif()
 724
 725 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 726
 727 set(Spelling_FOUND OFF)
 728 set(Include_used_spellchecker)   # String will be inserted into config.h
 729
 730 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 731   # try system library first
 732   find_package(MyThesLIB)
 733   if (MYTHESLIB_FOUND)
 734     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 735   else()
 736     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 737   endif()
 738 endif()
 739 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 740   find_package(MyThesLIB REQUIRED)
 741 else()
 742   add_subdirectory(3rdparty/mythes)
 743 endif()
 744 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 745
 746 if(NOT LYX_EXTERNAL_HUNSPELL)
 747     add_subdirectory(3rdparty/hunspell)
 748     add_definitions(-DHUNSPELL_STATIC)
 749     set(HUNSPELL_FOUND ON)
 750     message(STATUS "  * Hunspell:")
 751     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 752     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 753 endif()
 754
 755 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 756   string(TOUPPER ${_spell} _upspell)
 757   if (NOT ${_upspell}_FOUND)
 758     find_package(${_spell})
 759   endif()
 760   if (${_upspell}_FOUND)
 761     include_directories(${${_upspell}_INCLUDE_DIR})
 762     set(Spelling_FOUND ON)
 763     message(STATUS "Building with USE_${_upspell}")
 764     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 765   else()
 766     if(LYX_${_upspell})
 767       message(FATAL_ERROR "Required ${_spell} devel package not found")
 768     else()
 769       message(STATUS "${_upspell} not found, building without ${_spell} support")
 770     endif()
 771   endif()
 772 endforeach()
 773
 774 if(GNUWIN32_DIR)
 775         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 776 endif()
 777
 778 # Search for python default version first
 779 unset(PYTHON_EXECUTABLE CACHE)
 780 unset(LYX_PYTHON_EXECUTABLE CACHE)
 781 unset(PYTHON_VERSION_MAJOR)
 782 unset(PYTHON_VERSION_MINOR)
 783 unset(PYTHON_VERSION_STRING)
 784 find_package(PythonInterp 3.3 QUIET)
 785 if(NOT PYTHONINTERP_FOUND)
 786   unset(PYTHON_EXECUTABLE CACHE)
 787   find_package(PythonInterp 2.0 REQUIRED)
 788   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 789     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 790   endif()
 791 endif()
 792
 793 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 794
 795 if(LYX_NLS)
 796         find_package(LyXGettext)
 797         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 798                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 799         else()
 800                 # Install only supplied .gmo-files
 801                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 802                 message(STATUS "Installing provided .gmo-files only")
 803                 foreach( _gmo ${_gmofiles})
 804                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 805                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 806                 endforeach()
 807         endif()
 808 endif()
 809
 810 if(LYX_EXTERNAL_ICONV)
 811   find_package(ICONV REQUIRED)
 812 else()
 813   add_subdirectory(3rdparty/libiconv)
 814   set(HAVE_ICONV_CONST 1)
 815 endif()
 816
 817 if(LYX_EXTERNAL_Z)
 818   find_package(ZLIB REQUIRED)
 819 else()
 820   add_subdirectory(3rdparty/zlib)
 821 endif()
 822
 823 if(LYX_USE_STD_REGEX)
 824   # Set only include path.
 825   # Use internal boost, which is known to exist
 826   # we don't need any libraries
 827   set(Lyx_Boost_Libraries)
 828   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 829   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 830 else()
 831   # Using boost-regex
 832   if(LYX_EXTERNAL_BOOST)
 833     message(STATUS "Searching for external boost")
 834     find_package(Boost COMPONENTS regex)
 835     if(Boost_FOUND)
 836       message(STATUS "Boost found")
 837       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 838       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 839       if (LYX_STDLIB_DEBUG)
 840         # Comment from  Jean-Marc Lasgouttes:
 841         # In general, system boost libraries are incompatible with
 842         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 843         # details.
 844         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 845       endif()
 846     else()
 847       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 848     endif()
 849   else()
 850     # Using included boost
 851     set(Lyx_Boost_Libraries boost_regex)
 852     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 853     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 854     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 855   endif()
 856 endif()
 857
 858 if(WIN32)
 859         if(LYX_CONSOLE)
 860                 set(LYX_QTMAIN_LIBRARY)
 861         else()
 862                 set(WIN32_CONSOLE WIN32)
 863         endif()
 864         if(MSVC)
 865                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 866                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 867                 # disable checked iterators for msvc release builds to get maximum speed
 868                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 869         else()
 870                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 871                 # does not use it and always declares the vista compatible API.
 872                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 873                 add_definitions(-DWINVER=0x0500)
 874         endif()
 875 endif()
 876
 877 # Compute qt-version from ${QTVERSION}
 878
 879 message(STATUS "")
 880 foreach(_v PACKAGE PACKAGE_VERSION
 881         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 882         LYX_ABS_TOP_SRCDIR
 883         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 884         if(NOT DEFINED ${_v})
 885                 message(FATAL_ERROR "${_v} not defined")
 886         endif()
 887         string(SUBSTRING "${_v}                            " 0 28 _v1)
 888         message(STATUS "----- ${_v1}: ${${_v}}")
 889 endforeach(_v)
 890 message(STATUS "")
 891
 892
 893 if(LYX_PCH)
 894         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 895         # Not sure if it works for all non-msvc compilers
 896         include(PCHSupport_26)
 897         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 898         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 899         add_definitions(-DLYX_ENABLE_PCH)
 900
 901         if(MSVC)
 902                 macro(lyx_add_msvc_pch name_)
 903                         set_source_files_properties(${${name_}_sources} PROPERTIES
 904                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 905                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 906                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 907                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 908                                 ${TOP_BINARY_DIR}/pcheaders.h)
 909                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 910                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 911                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 912                 endmacro(lyx_add_msvc_pch)
 913                 macro(lyx_add_gcc_pch name_)
 914                 endmacro()
 915         else()
 916                 macro(lyx_add_msvc_pch name_)
 917                 endmacro()
 918                 macro(lyx_add_gcc_pch name_)
 919                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 920                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 921                 endmacro()
 922         endif()
 923 else()
 924         macro(lyx_add_msvc_pch)
 925         endmacro(lyx_add_msvc_pch)
 926         macro(lyx_add_gcc_pch name_)
 927         endmacro()
 928 endif()
 929
 930
 931 if(MSVC)
 932
 933         if(LYX_VLD)
 934                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 935                 add_subdirectory(${vld_path}/cmake)
 936                 include(${vld_path}/cmake/vld.cmake) # forced include
 937                 set(vld_dll vld)
 938         endif()
 939
 940         if(LYX_WALL)
 941                 # Use the highest warning level
 942                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
 943
 944                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 945                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 946                 else()
 947                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 948                 endif()
 949
 950                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 951                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 952                 else()
 953                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 954                 endif()
 955
 956                 # add here warnings which should produce an error /weXXXX
 957                 set(MSVC_W_ERROR   "/we4101 /we4189")
 958                 # add here warnings which should be disabled /wdXXXX
 959                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 960
 961                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 962                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 963                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 964
 965         else()
 966                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
 967
 968                 # add here warnings which should produce an error /weXXXX
 969                 set(MSVC_W_ERROR   "/we4101 /we4189")
 970                 # add here warnings which should be disabled /wdXXXX
 971                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 972
 973                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 974                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 975                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 976
 977         endif()
 978
 979         if (NOT Qt5Core_FOUND)
 980                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 981                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 982                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 983         endif()
 984
 985         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 986         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 987         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 988         message(STATUS "")
 989 endif()
 990
 991
 992 if(LYX_DEBUG_GLIBC)
 993         set(_GLIBCXX_DEBUG ON)
 994 endif()
 995
 996 if(LYX_DEBUG_GLIBC_PEDANTIC)
 997         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 998 endif()
 999
1000 # Xcode compiler
1001 if (CMAKE_GENERATOR MATCHES Xcode)
1002         if (XCODE_VERSION VERSION_LESS "5.0")
1003                 # Automatically select the Xcode compiler if not set
1004                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1005                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1006                         if (XCODE_VERSION VERSION_GREATER "3.1")
1007                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1008                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1009                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1010                 # Print the selected compiler version
1011         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1012         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1013 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1014
1015 if (WIN32 AND Qt5Core_FOUND)
1016         set(Z_PREFIX 1)
1017 endif()
1018
1019 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1020 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1021 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1022
1023 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1024
1025 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1026         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1027 endif()
1028
1029 if (NOT HAVE_REGEX)
1030         set(LYX_USE_STD_REGEX 0)
1031 endif()
1032
1033
1034 set (cmd ${CMAKE_CTEST_COMMAND})
1035 if (MSVC)
1036         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1037 else ()
1038         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1039 endif ()
1040 add_custom_target (lyx_run_tests COMMAND ${cmd})
1041 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1042
1043 if(LYX_ASAN)
1044     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1045     message(STATUS)
1046     message(STATUS "Address sanitizer enabled. Usage:")
1047     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1048     message(STATUS "    chmod  +x ./asan_symbolize.py")
1049     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1050     message(STATUS)
1051 endif()
1052
1053 if(LYX_INSTALL)
1054         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1055                 message(STATUS "Python required to create doc!")
1056         else()
1057                 if(UNIX)
1058                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1059                 endif()
1060                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1061         endif()
1062 endif()
1063 include(../Install)
1064
1065 # By running the URL tests first, time can be saved when running the ctests in
1066 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1067 if(LYX_ENABLE_URLTESTS)
1068         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1069 endif()
1070 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1071 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1072 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1073 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1074 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1075 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1076 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1077
1078 message(STATUS)
1079 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1080 message(STATUS)
1081
1082 LYX_OPTION_LIST_ALL(used)
1083
1084
1085 if(LYX_NLS)
1086         message(STATUS)
1087         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1088         message(STATUS)
1089         message(STATUS "  * iconv")
1090         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1091         message(STATUS "     - library: ${ICONV_LIBRARY}")
1092         message(STATUS "  * zlib")
1093         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1094         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1095         message(STATUS)
1096 endif()
1097
1098 # Apple has builtin native spell checker,
1099 # no need to warn for missing Aspell, Hunspell or Enchant
1100 if(NOT Spelling_FOUND AND NOT APPLE)
1101   if(LYX_REQUIRE_SPELLCHECK)
1102     set(_mode "FATAL_ERROR")
1103   else()
1104     set(_mode "STATUS")
1105   endif()
1106   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1107 endif()
1108
1109 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1110
1111 if(ENABLE_DIST)
1112   # Use git to create the source package
1113   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1114   if(UNIX)
1115     set(DIST_FORMAT tgz)
1116   else()
1117     set(DIST_FORMAT zip)
1118   endif()
1119   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1120
1121   add_custom_command(
1122     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1123     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1124     WORKING_DIRECTORY ${TOP_SRC_DIR})
1125   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1126 endif()
1127
1128 # Last directory to be included so that the fixup code (OS X)
1129 # can be run last
1130 add_subdirectory(development/cmake/post_install)
1131
1132 message(STATUS)