CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103
 104 # Usage LYX_OPTION
 105 # 1. parameter: option name without prefix 'LYX_'
 106 # 2. parameter: description
 107 # 3. parameter: default value, ON or OFF
 108 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 109
 110 # Usage LYX_COMBO
 111 # 1. parameter: name without prefix 'LYX_'
 112 # 2. parameter: description
 113 # 3. parameter: default value
 114 # 4-n parameter: possible other string values
 115
 116 LYX_OPTION_INIT()
 117
 118 # Options for all compilers/systems
 119 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 120 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 121 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 122 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 123 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 124 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 125 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 126 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 127 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 133 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 134 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 135 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 136 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 137 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 138 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 139 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 140 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 141 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 142
 143 # GCC specific
 144 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 145 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 146 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 147 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 148 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 149 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 150 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 151 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 152
 153 # MSVC specific
 154 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 155 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 156 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 157 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 158 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 159
 160 # APPLE specific
 161 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 162 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 163
 164
 165 if(help OR HELP)
 166         message(STATUS)
 167         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 168         message(STATUS)
 169         LYX_OPTION_LIST_ALL(help)
 170         message(STATUS)
 171         RETURN()
 172 endif()
 173
 174 # Check option dependencies
 175
 176 if(LYX_DMG)
 177         set(LYX_BUNDLE ON)
 178         set(LYX_CPACK ON)
 179 endif()
 180
 181 if(LYX_CPACK)
 182         set(LYX_INSTALL ON)
 183 endif()
 184
 185 if(LYX_INSTALL)
 186         set(LYX_NLS ON)
 187         if(WIN32 AND NOT MINGW)
 188                 set(LYX_HUNSPELL ON)
 189         endif()
 190         if(LYX_CONSOLE MATCHES "FORCE")
 191                 set(LYX_CONSOLE ON)
 192         else()
 193                 set(LYX_CONSOLE OFF)
 194         endif()
 195         set(LYX_PACKAGE_SUFFIX ON)
 196         if(NOT LYX_DEBUG)
 197                 set(LYX_RELEASE ON)
 198         endif()
 199         set(LYX_PROFILE OFF)
 200 endif()
 201
 202
 203 if(LYX_MERGE_FILES)
 204         set(LYX_PCH OFF)
 205 else()
 206         set(LYX_MERGE_REBUILD OFF)
 207 endif()
 208
 209
 210 if(LYX_DEPENDENCIES_DOWNLOAD)
 211         message(STATUS)
 212     if(MSVC12)
 213         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 214         set(deps_files lyx-windows-deps-msvc2013.zip)
 215         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 216         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 217     else()
 218         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 219             set(deps_files lyx20-deps-msvc2010-x86.zip)
 220             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 221         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 222     endif()
 223     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 224         foreach(it ${deps_files})
 225                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 226                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 227                 if(NOT already_downloaded)
 228                         message(STATUS "Downloading ${it} ...")
 229                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 230                         list(GET status 0 status_code)
 231                         list(GET status 1 status_string)
 232                         if(NOT status_code EQUAL 0)
 233                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 234                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 235                         endif()
 236                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 237                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 238                 endif()
 239         endforeach()
 240 endif()
 241
 242
 243
 244 message(STATUS)
 245
 246 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 247 if(WIN32)
 248         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 249 else()
 250         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 251 endif()
 252
 253
 254 set(LYX_GCC11_MODE)
 255 if(UNIX OR MINGW)
 256         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 257         message(STATUS "Using GCC version ${GCC_VERSION}")
 258         if(GCC_VERSION VERSION_LESS 4.9)
 259                 # <regex> in gcc is unusable in versions less than 4.9.0
 260                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 261                 set(LYX_USE_STD_REGEX 0)
 262         else()
 263                 if (LYX_ENABLE_CXX11)
 264                         set(LYX_USE_STD_REGEX 1)
 265                 endif()
 266         endif()
 267         if (LYX_ENABLE_CXX11)
 268                 find_package(CXX11Compiler)
 269                 if(NOT CXX11COMPILER_FOUND)
 270                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 271                 endif()
 272                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 273         endif()
 274 else()
 275         set(LYX_USE_STD_REGEX 0)
 276 #       if(MSVC10)
 277 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 278 #       endif()
 279 endif()
 280
 281
 282 set(VERSION_INFO "CMake Build")
 283
 284 # Try to get some informations from configure.ac
 285
 286 include(LyXPaths)
 287 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 288
 289 if(WIN32)
 290         set(USE_WINDOWS_PACKAGING ON)
 291 elseif(APPLE)
 292         set(USE_MACOSX_PACKAGING ON)
 293 else()
 294         set(USE_POSIX_PACKAGING ON)
 295 endif()
 296
 297 macro(setstripped _varname)
 298         if(${ARGC} GREATER 1)
 299                 string(STRIP "${ARGV1}" _v)
 300                 if(USE_POSIX_PACKAGING)
 301                         string(TOLOWER ${_v} ${_varname})
 302                 else()
 303                         set(${_varname} ${_v})
 304                 endif()
 305         else()
 306                 set(${_varname})
 307         endif()
 308 endmacro(setstripped)
 309
 310 foreach(_c_l ${_config_lines} )
 311         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 312                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 313                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 314                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 315                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 316                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 317                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 318                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 319                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 320                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 321                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 322                 endif()
 323         endif()
 324         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 325                 set(LYX_DATE "${CMAKE_MATCH_1}")
 326         endif()
 327 endforeach(_c_l)
 328
 329 FIND_PROGRAM(LYX_GITVERSION git)
 330 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 331 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 332 if(LYX_GITVERSION)
 333   if (LYX_LOCALVERSIONING)
 334     # Find the revision number and for later use
 335     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 336       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 337     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 338       # We will add offset of 40000 to get appropriate value to
 339       # previous svn.
 340       # We use this value than also to set the package-patch-value
 341       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 342       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 343       set(ENABLE_DIST ON)
 344     endif()
 345   endif()
 346 endif()
 347
 348 # Set the programs (lyx, tex2lyx, etc.) suffix
 349 # When building an OS X bundle, we will append
 350 # the suffix only to the bundle, not to the programs
 351 set(PROGRAM_SUFFIX "")
 352 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 353         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 354 endif()
 355 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 356 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 357
 358 add_custom_target(lyx_version ALL
 359   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 360   )
 361 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 362
 363 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 364 set(LYX_UTILITIES_INSTALL_PATH bin)
 365
 366 if(LYX_BUNDLE)
 367         set(LYX_CPACK ON)
 368
 369         message(STATUS)
 370         message(STATUS "Bundle creation is enabled (experimental):")
 371         message(STATUS "    make")
 372         message(STATUS "    make install/strip")
 373         message(STATUS "    make package")
 374         if(APPLE)
 375                 set(MACOSX_BUNDLE TRUE)
 376                 # This sets the bundle + executable names
 377                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 378                 # This sets the Info.plist executable name
 379                 set(osx_bundle_program_name ${_lyx})
 380                 # Bundle name
 381                 set(LYX_BUNDLE_NAME ${_lyx})
 382
 383                 # This will contain the list of files that need to be included
 384                 # in the bundle and their location within the bundle
 385                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 386                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 387
 388                 # Process Info.plist and lyxrc.dist
 389                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 390                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 391
 392                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 393                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 394
 395                 # Variables used by CPack
 396                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 397                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 398                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 399
 400                 # Set the install paths
 401                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 402                 if(NOT LYX_INSTALL_PREFIX)
 403                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 404                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 405                 endif()
 406                 # Change the owner so that the install can work
 407                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 408         elseif(UNIX)
 409                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 410                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 411                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 412         elseif(WIN32)
 413                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 414         endif()
 415 endif()
 416
 417 if(LYX_INSTALL_PREFIX)
 418         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 419         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 420 endif()
 421 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 422
 423 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 424
 425 if(LYX_PACKAGE_SUFFIX)
 426         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 427 else()
 428         set(PACKAGE ${PACKAGE_BASE})
 429 endif()
 430
 431 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 432         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 433         if (UNIX)
 434                 # don't use the default "/usr/local"
 435                 # but respect the user-choice on the command-line
 436                 if(LYX_INSTALL_SUFFIX)
 437                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 438                 else()
 439                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 440                 endif()
 441         endif()
 442         if(WIN32)
 443                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 444         endif()
 445 endif()
 446 if(IS_ABSOLUTE)
 447         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 448 else()
 449         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 450 endif()
 451
 452
 453
 454 if(NOT LYX_DATA_SUBDIR)
 455         if (WIN32)
 456                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 457         else()
 458                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 459         endif()
 460 endif()
 461
 462 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 463 set(LYX_LOCALEDIR "locale")
 464 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 465 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 466
 467 if(LYX_BUNDLE AND APPLE)
 468         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 469 else()
 470         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 471 endif()
 472 mark_as_advanced(LYX_MAN_DIR)
 473
 474 if(LYX_INSTALL AND WIN32)
 475         message(STATUS "Configuring NSIS files")
 476         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 477         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 478         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 479         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 480 endif()
 481
 482 if(NOT GROUP_CODE)
 483         #set(GROUP_CODE "The Golden Code")
 484         set(GROUP_CODE flat)
 485 endif()
 486
 487 # lyx's source files
 488 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 489 set(LYX_HPP_FILES [a-zA-Z]*.h)
 490 set(LYX_MOC_FILES moc_*.cpp)
 491
 492 include(ProjectSourceGroup)
 493
 494
 495 if(LYX_PROFILE AND NOT MSVC)
 496         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 497         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 498         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 499 else()
 500         set(LYX_PROFILE OFF)
 501 endif()
 502
 503
 504 if(LYX_NO_OPTIMIZE)
 505         set(CMAKE_BUILD_TYPE None)
 506         set(LYX_DEBUG OFF)
 507         set(LYX_RELEASE OFF)
 508         set(LYX_PROFILE OFF)
 509 elseif(LYX_RELEASE)
 510         set(CMAKE_BUILD_TYPE Release)
 511         set(LYX_DEBUG OFF)
 512         set(LYX_PROFILE OFF)
 513 elseif(LYX_PROFILE)
 514         set(CMAKE_BUILD_TYPE Profile)
 515         set(LYX_DEBUG OFF)
 516 else()
 517         set(CMAKE_BUILD_TYPE Debug)
 518         set(LYX_DEBUG ON)
 519 endif()
 520
 521
 522 # When shared libs are supported enable this option
 523 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 524 if(LYX_SHARED_LIBRARIES)
 525         set(library_type SHARED)
 526 else()
 527         set(library_type STATIC)
 528 endif()
 529
 530 if(NOT MSVC)
 531         if(NOT LYX_QUIET)
 532                 set(CMAKE_VERBOSE_MAKEFILE ON)
 533         endif()
 534     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 535         if(LYX_STDLIB_DEBUG)
 536                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 537         endif()
 538         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 539         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 540         if(MINGW)
 541                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 542         else()
 543                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 544         endif()
 545 endif()
 546
 547 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 548 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 549 if(LYX_CXX_FLAGS_EXTRA)
 550         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 551                 add_definitions(${_flag})
 552         endforeach()
 553 endif()
 554
 555 if(LYX_XMINGW)
 556         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 557 endif()
 558
 559 if(LYX_USE_QT MATCHES "QT5")
 560         find_package(Qt5Core REQUIRED)
 561         if (Qt5Core_FOUND)
 562                 find_package(Qt5Widgets REQUIRED)
 563                 if(APPLE)
 564                         find_package(Qt5MacExtras REQUIRED)
 565                 endif()
 566                 find_package(Qt5X11Extras QUIET)
 567                 find_package(Qt5WinExtras QUIET)
 568                 set(QTVERSION ${Qt5Core_VERSION})
 569                 macro (qt_use_modules)
 570                         qt5_use_modules(${ARGN})
 571                 endmacro()
 572                 macro (qt_add_resources)
 573                         qt5_add_resources(${ARGN})
 574                 endmacro()
 575                 macro (qt_wrap_uifiles)
 576                         qt5_wrap_ui(${ARGN})
 577                 endmacro()
 578                 message(STATUS "Found Qt-Version ${QTVERSION}")
 579                 if(WIN32)
 580                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 581                 endif()
 582         endif()
 583 elseif(LYX_USE_QT MATCHES "QT4")
 584         if(LYX_XMINGW)
 585                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 586                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 587         endif()
 588         find_package(Qt4 "4.5.0" REQUIRED)
 589         macro (qt_use_modules)
 590         endmacro()
 591         macro (qt_add_resources)
 592                 qt4_add_resources(${ARGN})
 593         endmacro()
 594         macro (qt_wrap_uifiles)
 595                 qt4_wrap_ui(${ARGN})
 596         endmacro()
 597         if(WIN32)
 598                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 599         endif()
 600 else()
 601   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 602 endif()
 603
 604 find_package(Magic)
 605 if(Magic_FOUND)
 606         set(HAVE_MAGIC_H 1)
 607 endif()
 608
 609 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 610
 611 set(Spelling_FOUND OFF)
 612 set(Include_used_spellchecker)   # String will be inserted into config.h
 613
 614 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 615   string(TOUPPER ${_spell} _upspell)
 616   find_package(${_spell})
 617   if (${_upspell}_FOUND)
 618     include_directories(${${_upspell}_INCLUDE_DIR})
 619     set(Spelling_FOUND ON)
 620     message(STATUS "Building with USE_${_upspell}")
 621     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 622   else()
 623     if(LYX_${_upspell} AND NOT LYX_HUNSPELL)
 624       message(FATAL_ERROR "Required ${_spell} devel package not found")
 625     else()
 626       message(STATUS "${_upspell} not found, building without ${_spell} support")
 627     endif()
 628   endif()
 629 endforeach()
 630
 631 if(LYX_HUNSPELL AND NOT HUNSPELL_FOUND)
 632     add_subdirectory(src/3rdparty/hunspell)
 633     set(Spelling_FOUND ON)
 634 endif()
 635 message(STATUS "  * Hunspell:")
 636 message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 637 message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 638
 639
 640 find_package(PythonInterp 2.7 QUIET)
 641 if(PYTHONINTERP_FOUND)
 642   if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 643     unset(PYTHONINTERP_FOUND)
 644   endif()
 645 endif()
 646
 647 if (NOT PYTHONINTERP_FOUND)
 648   unset(PYTHON_EXECUTABLE CACHE)
 649   unset(PYTHON_VERSION_MAJOR)
 650   unset(PYTHON_VERSION_MINOR)
 651   unset(PYTHON_VERSION_STRING)
 652   find_package(PythonInterp 3.3 REQUIRED)
 653 endif()
 654
 655 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 656
 657 if(LYX_NLS)
 658         find_package(LyXGettext)
 659         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 660                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 661         else()
 662                 # Install only supplied .gmo-files
 663                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 664                 message(STATUS "Installing provided .gmo-files only")
 665                 foreach( _gmo ${_gmofiles})
 666                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 667                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 668                 endforeach()
 669         endif()
 670 endif()
 671
 672 if(UNIX)
 673     find_package(ICONV REQUIRED)
 674     find_package(ZLIB REQUIRED)
 675 endif()
 676
 677 if(NOT ICONV_FOUND)
 678     add_subdirectory(src/3rdparty/libiconv)
 679 endif()
 680
 681 if(NOT ZLIB_FOUND)
 682     add_subdirectory(src/3rdparty/zlib)
 683 endif()
 684
 685
 686 if(LYX_EXTERNAL_BOOST)
 687         message(STATUS "Searching for boost")
 688         if(LYX_USE_STD_REGEX)
 689                 find_package(Boost COMPONENTS signals)
 690         else()
 691                 find_package(Boost COMPONENTS signals regex)
 692         endif()
 693         if(Boost_FOUND)
 694                 message(STATUS "Boost found")
 695                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 696                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 697                 if (LYX_STDLIB_DEBUG)
 698                         # Comment from  Jean-Marc Lasgouttes:
 699                         # In general, system boost libraries are incompatible with
 700                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 701                         # details.
 702                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 703                 endif()
 704         else()
 705                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 706         endif()
 707 else()
 708         if(LYX_USE_STD_REGEX)
 709                 set(Lyx_Boost_Libraries boost_signals)
 710         else()
 711                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 712         endif()
 713         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 714         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 715         include_directories(${TOP_SRC_DIR}/boost)
 716         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 717 endif()
 718
 719
 720
 721
 722 if(WIN32)
 723         if(LYX_CONSOLE)
 724                 set(LYX_QTMAIN_LIBRARY)
 725         else()
 726                 set(WIN32_CONSOLE WIN32)
 727         endif()
 728         if(MSVC)
 729                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 730                 # disable checked iterators for msvc release builds to get maximum speed
 731                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 732         else()
 733                 add_definitions(-DWINVER=0x0500)
 734         endif()
 735 endif()
 736
 737 # Compute qt4-version from ${QTVERSION}
 738
 739 message(STATUS "")
 740 foreach(_v PACKAGE PACKAGE_VERSION
 741         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 742         LYX_ABS_TOP_SRCDIR
 743         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 744         if(NOT DEFINED ${_v})
 745                 message(FATAL_ERROR "${_v} not defined")
 746         endif()
 747         string(SUBSTRING "${_v}                            " 0 28 _v1)
 748         message(STATUS "----- ${_v1}: ${${_v}}")
 749 endforeach(_v)
 750 message(STATUS "")
 751
 752
 753 if(LYX_PCH)
 754         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 755         # Not sure if it works for all non-msvc compilers
 756         include(PCHSupport_26)
 757         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 758         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 759         add_definitions(-DLYX_ENABLE_PCH)
 760
 761         if(MSVC)
 762                 macro(lyx_add_msvc_pch name_)
 763                         set_source_files_properties(${${name_}_sources} PROPERTIES
 764                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 765                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 766                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 767                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 768                                 ${TOP_BINARY_DIR}/pcheaders.h)
 769                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 770                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 771                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 772                 endmacro(lyx_add_msvc_pch)
 773                 macro(lyx_add_gcc_pch name_)
 774                 endmacro()
 775         else()
 776                 macro(lyx_add_msvc_pch name_)
 777                 endmacro()
 778                 macro(lyx_add_gcc_pch name_)
 779                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 780                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 781                 endmacro()
 782         endif()
 783 else()
 784         macro(lyx_add_msvc_pch)
 785         endmacro(lyx_add_msvc_pch)
 786         macro(lyx_add_gcc_pch name_)
 787         endmacro()
 788 endif()
 789
 790
 791 if(MSVC)
 792
 793         if(LYX_VLD)
 794                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 795                 add_subdirectory(${vld_path}/cmake)
 796                 include(${vld_path}/cmake/vld.cmake) # forced include
 797                 set(vld_dll vld)
 798         endif()
 799
 800         if(LYX_WALL)
 801                 # Use the highest warning level
 802                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 803
 804                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 805                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 806                 else()
 807                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 808                 endif()
 809
 810                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 811                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 812                 else()
 813                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 814                 endif()
 815
 816                 # add here warnings which should produce an error /weXXXX
 817                 set(MSVC_W_ERROR   "/we4101 /we4189")
 818                 # add here warnings which should be disabled /wdXXXX
 819                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 820
 821                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 822                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 823                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 824
 825         else()
 826                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 827
 828                 # add here warnings which should produce an error /weXXXX
 829                 set(MSVC_W_ERROR   "/we4101 /we4189")
 830                 # add here warnings which should be disabled /wdXXXX
 831                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 832
 833                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 834                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 835                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 836
 837         endif()
 838
 839         if (NOT Qt5Core_FOUND)
 840                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 841                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 842                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 843         endif()
 844
 845         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 846         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 847         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 848         message(STATUS "")
 849 endif()
 850
 851
 852 if(LYX_DEBUG_GLIBC)
 853         set(_GLIBCXX_DEBUG ON)
 854 endif()
 855
 856 if(LYX_DEBUG_GLIBC_PEDANTIC)
 857         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 858 endif()
 859
 860 # Xcode compiler
 861 if (CMAKE_GENERATOR MATCHES Xcode)
 862         if (XCODE_VERSION VERSION_LESS "5.0")
 863                 # Automatically select the Xcode compiler if not set
 864                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 865                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 866                         if (XCODE_VERSION VERSION_GREATER "3.1")
 867                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 868                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 869                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 870                 # Print the selected compiler version
 871         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 872         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 873 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 874
 875 if (WIN32 AND Qt5Core_FOUND)
 876         set(Z_PREFIX 1)
 877 endif()
 878
 879 # compiler tests, config.h generation
 880 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 881         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 882 else()
 883         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 884         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 885 endif()
 886
 887 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 888
 889 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 890         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 891 endif()
 892
 893 if (NOT HAVE_REGEX)
 894         set(LYX_USE_STD_REGEX 0)
 895 endif()
 896
 897
 898 set (cmd ${CMAKE_CTEST_COMMAND})
 899 if (MSVC)
 900         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 901 else ()
 902         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 903 endif ()
 904 add_custom_target (lyx_run_tests COMMAND ${cmd})
 905 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 906
 907 if(LYX_ASAN)
 908     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 909     message(STATUS)
 910     message(STATUS "Address sanitizer enabled. Usage:")
 911     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 912     message(STATUS "    chmod  +x ./asan_symbolize.py")
 913     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 914     message(STATUS)
 915 endif()
 916
 917 if(LYX_INSTALL)
 918         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 919                 message(STATUS "Python required to create doc!")
 920         else()
 921                 if(UNIX)
 922                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 923                 endif()
 924                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 925         endif()
 926         include(../Install)
 927 endif()
 928
 929 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 930 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 931 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 932 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 933 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 934 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 935 if(LYX_ENABLE_URLTESTS)
 936         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 937 endif()
 938
 939 message(STATUS)
 940 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 941 message(STATUS)
 942
 943 LYX_OPTION_LIST_ALL(used)
 944
 945
 946 if(LYX_NLS)
 947         message(STATUS)
 948         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 949         message(STATUS)
 950         message(STATUS "  * iconv")
 951         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 952         message(STATUS "     - library: ${ICONV_LIBRARY}")
 953         message(STATUS "  * zlib")
 954         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 955         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 956         message(STATUS)
 957 endif()
 958
 959 # Apple has builtin native spell checker,
 960 # no need to warn for missing Aspell, Hunspell or Enchant
 961 if(NOT Spelling_FOUND AND NOT APPLE)
 962   if(LYX_REQUIRE_SPELLCHECK)
 963     set(_mode "FATAL_ERROR")
 964   else()
 965     set(_mode "STATUS")
 966   endif()
 967   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 968 endif()
 969
 970 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 971
 972 if(ENABLE_DIST)
 973   # Use git to create the source package
 974   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 975   if(UNIX)
 976     set(DIST_FORMAT tgz)
 977   else()
 978     set(DIST_FORMAT zip)
 979   endif()
 980   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 981
 982   add_custom_command(
 983     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 984     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 985     WORKING_DIRECTORY ${TOP_SRC_DIR})
 986   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 987 endif()
 988
 989 # Last directory to be included so that the fixup code (OS X)
 990 # can be run last
 991 add_subdirectory(development/cmake/post_install)
 992
 993 message(STATUS)