CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT LyX)
  11
  12 enable_testing()
  13
  14 set(LYX_CMAKE_DIR "development/cmake")
  15 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19
  20 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  21
  22 message(STATUS)
  23 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  24         message(STATUS "Building in-source")
  25         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  26 else()
  27         message(STATUS "Building out-of-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  29 endif()
  30
  31
  32 if(COMMAND cmake_policy)
  33         cmake_policy(SET CMP0003 OLD)
  34         cmake_policy(SET CMP0005 OLD)
  35 endif()
  36
  37 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  38
  39 # Supress regeneration
  40 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  41
  42 if(NOT help AND NOT HELP)
  43         # 'project' triggers the searching for a compiler
  44         project(${LYX_PROJECT})
  45 endif()
  46
  47 if(UNIX)
  48         set(ARCH_TRIPLET )
  49         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  50         if(DPKG_ARCHITECTURE_EXECUTABLE)
  51                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  52                                 OUTPUT_VARIABLE ARCH_TRIPLET
  53                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  54                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  55         endif()
  56 endif()
  57 if(ARCH_TRIPLET)
  58         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  59 else()
  60         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  61 endif()
  62
  63 include(LyXMacros)
  64
  65 # Usage LYX_OPTION
  66 # 1. parameter: option name without prefix 'LYX_'
  67 # 2. parameter: description
  68 # 3. parameter: default value, ON or OFF
  69 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  70
  71
  72 LYX_OPTION_INIT()
  73
  74 # Options for all compilers/systems
  75 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  76 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  77 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  78 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  79 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  80 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  81 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  82 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  83 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  84 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  85 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  86 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  87 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  88 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  89 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  90 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  91 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  92 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  93 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  94
  95 # GCC specific
  96 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  97 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  98 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  99 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 100 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
 101 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 102 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 103 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 104 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 105
 106 # MSVC specific
 107 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 108 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 109 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 110 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 111 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 112
 113 # APPLE specific
 114 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 115 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 116
 117
 118 if(help OR HELP)
 119         message(STATUS)
 120         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 121         message(STATUS)
 122         LYX_OPTION_LIST_ALL(help)
 123         message(STATUS)
 124         RETURN()
 125 endif()
 126
 127 # Check option dependencies
 128
 129 if(LYX_CPACK)
 130         set(LYX_INSTALL ON)
 131 endif()
 132
 133 if(LYX_DMG)
 134         set(LYX_BUNDLE ON)
 135         set(LYX_CPACK ON)
 136 endif()
 137
 138 if(LYX_INSTALL)
 139         set(LYX_NLS ON)
 140         if (WIN32)
 141                 set(LYX_HUNSPELL ON)
 142         endif()
 143         if(LYX_CONSOLE MATCHES "FORCE")
 144                 set(LYX_CONSOLE ON)
 145         else()
 146                 set(LYX_CONSOLE OFF)
 147         endif()
 148         set(LYX_PACKAGE_SUFFIX ON)
 149         set(LYX_RELEASE ON)
 150         set(LYX_PROFILE OFF)
 151 endif()
 152
 153
 154 if(LYX_MERGE_FILES)
 155         set(LYX_PCH OFF)
 156 else()
 157         set(LYX_MERGE_REBUILD OFF)
 158 endif()
 159
 160 if(LYX_DEPENDENCIES_DOWNLOAD)
 161         message(STATUS)
 162         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 163         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 164         set(deps_files lyx20-deps-msvc2010-x86.zip)
 165         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 166         foreach(it ${deps_files})
 167                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 168                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 169                 if(NOT already_downloaded)
 170                         message(STATUS "Downloading ${it} ...")
 171                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 172                         list(GET status 0 status_code)
 173                         list(GET status 1 status_string)
 174                         if(NOT status_code EQUAL 0)
 175                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 176                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 177                         endif()
 178                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 179                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 180                 endif()
 181         endforeach()
 182         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 183 endif()
 184
 185
 186
 187 message(STATUS)
 188
 189 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 190 if(WIN32)
 191         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 192 else()
 193         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 194 endif()
 195
 196
 197 set(LYX_GCC11_MODE)
 198 if(UNIX OR MINGW)
 199         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 200         message(STATUS "Using GCC version ${GCC_VERSION}")
 201         if(NOT GCC_VERSION VERSION_LESS 4.4)
 202                 set(LYX_USE_TR1 1)
 203                 # GCC <= 4.5 does not support regex: there are linker errors
 204                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 205                 set(LYX_USE_TR1_REGEX 0)
 206         endif()
 207         if (LYX_ENABLE_CXX11)
 208                 if(GCC_VERSION VERSION_GREATER 4.7)
 209                         set(LYX_GCC11_MODE "-std=gnu++11")
 210                 elseif(GCC_VERSION VERSION_GREATER 4.2)
 211                         set(LYX_GCC11_MODE "-std=gnu++0x")
 212                 endif()
 213         endif()
 214 else()
 215         if(MSVC10)
 216                 set(LYX_USE_TR1 1)
 217                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 218         endif()
 219 endif()
 220
 221
 222 set(VERSION_INFO "CMake Build")
 223
 224 # Try to get some informations from configure.ac
 225
 226 include(LyXPaths)
 227 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 228
 229 if(WIN32)
 230         set(USE_WINDOWS_PACKAGING ON)
 231 elseif(APPLE)
 232         set(USE_MACOSX_PACKAGING ON)
 233 else()
 234         set(USE_POSIX_PACKAGING ON)
 235 endif()
 236
 237 macro(setstripped _varname _value)
 238         string(STRIP ${_value} _v)
 239         if(USE_POSIX_PACKAGING)
 240                 string(TOLOWER ${_v} ${_varname})
 241         else()
 242                 set(${_varname} ${_v})
 243         endif()
 244 endmacro(setstripped)
 245
 246 foreach(_c_l ${_config_lines} )
 247         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 248                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 249                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 250                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 251                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 252                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 253                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 254                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 255                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 256                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 257                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 258                 endif()
 259         endif()
 260         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 261                 set(LYX_DATE "${CMAKE_MATCH_1}")
 262         endif()
 263 endforeach(_c_l)
 264
 265 if (LYX_LOCALVERSIONING)
 266         # Find the revision number and for later use
 267         FIND_PROGRAM(LYX_GITVERSION git)
 268         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 269         if(LYX_GITVERSION)
 270                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "describe" WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 271                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 272                   # We will add offset of 40000 to get appropriate value to
 273                   # previous svn.
 274                   # We use this value than also to set the package-patch-value
 275                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 276                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 277                 endif()
 278         else()
 279                 set(LYX_REVISION_VERSION git) #TODO use date
 280         endif()
 281 else()
 282         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 283 endif()
 284
 285 if(LYX_PROGRAM_SUFFIX)
 286         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 287 else()
 288         set(PROGRAM_SUFFIX "")
 289 endif()
 290
 291 add_custom_target(lyx_version ALL
 292   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DLYX_CMAKE_DIR=${LYX_CMAKE_DIR} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/modules/LyXGetVersion.cmake
 293   )
 294
 295 if(APPLE)
 296         set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 297         configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 298 endif()
 299
 300 if(LYX_BUNDLE)
 301         set(LYX_CPACK ON)
 302         message(STATUS)
 303         message(STATUS "Bundle creation is enabled (experimental):")
 304         message(STATUS "    make")
 305         message(STATUS "    make install/strip")
 306         message(STATUS "    make package")
 307         if(APPLE)
 308                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 309                 set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 310                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 311                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 312                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 313                 if(NOT LYX_INSTALL_PREFIX)
 314                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 315                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 316                 endif()
 317                 # Change the owner so that the install can work
 318                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
 319         elseif(UNIX)
 320                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 321                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 322                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 323         elseif(WIN32)
 324                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 325         endif()
 326 endif()
 327
 328 if(LYX_INSTALL_PREFIX)
 329         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 330         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 331 endif()
 332 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 333
 334 if(LYX_PACKAGE_SUFFIX)
 335         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 336 else()
 337         set(PACKAGE ${PACKAGE_BASE})
 338 endif()
 339
 340
 341 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 342         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 343         if (UNIX)
 344                 # don't use the default "/usr/local"
 345                 # but respect the user-choice on the command-line
 346                 if(LYX_INSTALL_SUFFIX)
 347                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 348                 else()
 349                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 350                 endif()
 351         endif()
 352         if(WIN32)
 353                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 354         endif()
 355 endif()
 356 if(IS_ABSOLUTE)
 357         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 358 else()
 359         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 360 endif()
 361
 362
 363
 364 if(NOT LYX_DATA_SUBDIR)
 365         if (WIN32)
 366                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 367         else()
 368                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 369         endif()
 370 endif()
 371
 372 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 373 set(LYX_LOCALEDIR "locale")
 374 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 375 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 376
 377
 378 if(LYX_INSTALL AND WIN32)
 379         message(STATUS "Configuring NSIS files")
 380         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 381         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 382         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 383         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 384 endif()
 385
 386 if(NOT GROUP_CODE)
 387         #set(GROUP_CODE "The Golden Code")
 388         set(GROUP_CODE flat)
 389 endif()
 390
 391 # lyx's source files
 392 set(LYX_CPP_FILES *.cpp)
 393 set(LYX_HPP_FILES *.h)
 394 set(LYX_MOC_FILES moc_*.cpp)
 395
 396 include(ProjectSourceGroup)
 397
 398
 399 if(LYX_PROFILE AND NOT MSVC)
 400         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 401         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 402         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 403 else()
 404         set(LYX_PROFILE OFF)
 405 endif()
 406
 407
 408 if(LYX_NO_OPTIMIZE)
 409         set(CMAKE_BUILD_TYPE None)
 410         set(LYX_DEBUG OFF)
 411         set(LYX_RELEASE OFF)
 412         set(LYX_PROFILE OFF)
 413 elseif(LYX_RELEASE)
 414         set(CMAKE_BUILD_TYPE Release)
 415         set(LYX_DEBUG OFF)
 416         set(LYX_PROFILE OFF)
 417 elseif(LYX_PROFILE)
 418         set(CMAKE_BUILD_TYPE Profile)
 419         set(LYX_DEBUG OFF)
 420 else()
 421         set(CMAKE_BUILD_TYPE Debug)
 422         set(LYX_DEBUG ON)
 423 endif()
 424
 425
 426 # When shared libs are supported enable this option
 427 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 428 if(LYX_SHARED_LIBRARIES)
 429         set(library_type SHARED)
 430 else()
 431         set(library_type STATIC)
 432 endif()
 433
 434 if(NOT MSVC)
 435         if(NOT LYX_QUIET)
 436                 set(CMAKE_VERBOSE_MAKEFILE ON)
 437         endif()
 438         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 439         if(LYX_STDLIB_DEBUG)
 440                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 441         endif()
 442         if(LYX_CONCEPT_CHECKS)
 443                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 444         endif()
 445         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 446         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 447         if(MINGW)
 448                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 449         else()
 450                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 451         endif()
 452 endif()
 453
 454
 455 find_package(Qt4 REQUIRED)
 456 find_package(Magic)
 457 if(Magic_FOUND)
 458         set(HAVE_MAGIC_H 1)
 459 endif()
 460
 461 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 462
 463 if(LYX_ASPELL)
 464         find_package(ASPELL)
 465         include_directories(${ASPELL_INCLUDE_DIR})
 466 endif()
 467
 468 if(LYX_ENCHANT)
 469         find_package(Enchant REQUIRED)
 470         include_directories(${ENCHANT_INCLUDE_DIR})
 471 endif()
 472
 473 if(LYX_HUNSPELL)
 474         find_package(Hunspell REQUIRED)
 475         include_directories(${HUNSPELL_INCLUDE_DIR})
 476 endif()
 477
 478 if(LYX_NLS)
 479         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 480         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 481                 message(FATAL_ERROR "Python 2.6 needed!")
 482         endif()
 483         find_package(LyXGettext REQUIRED)
 484         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 485 endif()
 486
 487 if(LYX_NLS)
 488         if(LYX_EXTERNAL_LIBINTL)
 489                 find_package(Libintl REQUIRED)
 490                 if(DEFINED LIBINTL_LIBRARIES)
 491                         # find getext when configuring
 492                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 493                         # on mac use iconv also form ports
 494                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 495                 endif()
 496         else()
 497                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 498         endif()
 499 endif()
 500
 501 if(LYX_EXTERNAL_LIBINTL)
 502         set(intl_link ${LIBINTL_LIBRARIES})
 503 else()
 504         set(intl_link intl)
 505 endif()
 506
 507 find_package(ICONV REQUIRED)
 508 find_package(ZLIB REQUIRED)
 509
 510 if(LYX_EXTERNAL_BOOST)
 511         message(STATUS "Searching for boost")
 512         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 513         if(Boost_FOUND)
 514                 message(STATUS "Boost found")
 515                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 516                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 517         else()
 518                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 519         endif()
 520 else()
 521         if(LYX_USE_TR1_REGEX)
 522                 set(Lyx_Boost_Libraries boost_signals)
 523         else()
 524                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 525         endif()
 526         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 527         include_directories(${TOP_SRC_DIR}/boost)
 528         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 529 endif()
 530
 531
 532
 533
 534 if(WIN32)
 535         if(NOT LYX_CONSOLE)
 536                 set(WIN32_CONSOLE WIN32)
 537                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 538         endif()
 539         if(MSVC)
 540                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 541                 # disable checked iterators for msvc release builds to get maximum speed
 542                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 543         else()
 544                 add_definitions(-DWINVER=0x0500)
 545         endif()
 546 endif()
 547
 548 # Compute qt4-version from ${QTVERSION}
 549
 550 message(STATUS "")
 551 foreach(_v PACKAGE PACKAGE_VERSION
 552         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 553         LYX_ABS_TOP_SRCDIR
 554         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 555         if(NOT DEFINED ${_v})
 556                 message(FATAL_ERROR "${_v} not defined")
 557         endif()
 558         string(SUBSTRING "${_v}                            " 0 28 _v1)
 559         message(STATUS "----- ${_v1}: ${${_v}}")
 560 endforeach(_v)
 561 message(STATUS "")
 562
 563
 564 if(LYX_PCH)
 565         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 566         # Not sure if it works for all non-msvc compilers
 567         include(PCHSupport_26)
 568         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 569         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 570         add_definitions(-DLYX_ENABLE_PCH)
 571
 572         if(MSVC)
 573                 macro(lyx_add_msvc_pch name_)
 574                         set_source_files_properties(${${name_}_sources} PROPERTIES
 575                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 576                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 577                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 578                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 579                                 ${TOP_BINARY_DIR}/pcheaders.h)
 580                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 581                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 582                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 583                 endmacro(lyx_add_msvc_pch)
 584                 macro(lyx_add_gcc_pch name_)
 585                 endmacro()
 586         else()
 587                 macro(lyx_add_msvc_pch name_)
 588                 endmacro()
 589                 macro(lyx_add_gcc_pch name_)
 590                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 591                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 592                 endmacro()
 593         endif()
 594 else()
 595         macro(lyx_add_msvc_pch)
 596         endmacro(lyx_add_msvc_pch)
 597         macro(lyx_add_gcc_pch name_)
 598         endmacro()
 599 endif()
 600
 601
 602 if(MSVC)
 603
 604         if(LYX_VLD)
 605                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 606                 add_subdirectory(${vld_path}/cmake)
 607                 include(${vld_path}/cmake/vld.cmake) # forced include
 608                 set(vld_dll vld)
 609         endif()
 610
 611         if(LYX_WALL)
 612                 # Use the highest warning level
 613                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 614
 615                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 616                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 617                 else()
 618                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 619                 endif()
 620
 621                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 622                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 623                 else()
 624                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 625                 endif()
 626
 627                 # add here warnings which should produce an error /weXXXX
 628                 set(MSVC_W_ERROR   "/we4101 /we4189")
 629                 # add here warnings which should be disabled /wdXXXX
 630                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 631
 632                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 633                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 634                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 635
 636         else()
 637                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 638
 639                 # add here warnings which should produce an error /weXXXX
 640                 set(MSVC_W_ERROR   "/we4101 /we4189")
 641                 # add here warnings which should be disabled /wdXXXX
 642                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 643
 644                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 645                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 646                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 647
 648         endif()
 649         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 650         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 651         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 652
 653         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 654         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 655         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 656         message(STATUS "")
 657 endif()
 658
 659
 660 if(LYX_DEBUG_GLIBC)
 661         set(_GLIBCXX_DEBUG ON)
 662 endif()
 663
 664 if(LYX_DEBUG_GLIBC_PEDANTIC)
 665         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 666 endif()
 667
 668 # Xcode compiler
 669 if (CMAKE_GENERATOR MATCHES Xcode)
 670         # Automatically select the Xcode compiler if not set
 671         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 672                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 673                 if (XCODE_VERSION VERSION_GREATER "3.1")
 674                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 675                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 676         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 677
 678         # Print the selected compiler version
 679     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 680 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 681
 682
 683 # compiler tests, config.h generation
 684 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 685         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 686 else()
 687         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 688         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 689 endif()
 690
 691 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 692
 693 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 694         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 695 endif()
 696
 697 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 698 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 699 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 700 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 701
 702
 703 if(LYX_INSTALL)
 704         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 705                 message(STATUS "Python required to create doc!")
 706         else()
 707                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 708                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 709         endif()
 710         if(NOT(LYX_BUNDLE AND APPLE))
 711                 include(../Install)
 712         endif()
 713 endif()
 714
 715 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 716
 717 message(STATUS)
 718 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 719 message(STATUS)
 720 LYX_OPTION_LIST_ALL(used)
 721
 722
 723 if(LYX_NLS)
 724         message(STATUS)
 725         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 726         message(STATUS)
 727         message(STATUS "  * intl")
 728         message(STATUS "     - header : ${LIBINTL_HEADER}")
 729         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 730         message(STATUS "  * iconv")
 731         message(STATUS "     - header : ${ICONV_HEADER}")
 732         message(STATUS "     - library: ${ICONV_LIBRARY}")
 733         message(STATUS "  * zlib")
 734         message(STATUS "     - header : ${ZLIB_HEADER}")
 735         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 736         message(STATUS)
 737 endif()
 738
 739 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 740
 741 message(STATUS)