CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41 endif()
  42
  43 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  44
  45 # Supress regeneration
  46 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  47
  48 if(NOT help AND NOT HELP)
  49         # 'project' triggers the searching for a compiler
  50         project(${LYX_PROJECT})
  51 endif()
  52
  53 if(UNIX)
  54         set(ARCH_TRIPLET )
  55         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  56         if(DPKG_ARCHITECTURE_EXECUTABLE)
  57                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  58                                 OUTPUT_VARIABLE ARCH_TRIPLET
  59                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  60                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  61         endif()
  62 endif()
  63 if(ARCH_TRIPLET)
  64         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  65 else()
  66         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  67 endif()
  68
  69 include(LyXMacros)
  70
  71 # Usage LYX_OPTION
  72 # 1. parameter: option name without prefix 'LYX_'
  73 # 2. parameter: description
  74 # 3. parameter: default value, ON or OFF
  75 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  76
  77
  78 LYX_OPTION_INIT()
  79
  80 # Options for all compilers/systems
  81 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  82 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  83 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  84 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  85 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  86 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  87 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  88 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  89 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  90 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  91 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  92 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  93 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  94 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  95 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  96 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  97 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  98 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  99 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 100
 101 # GCC specific
 102 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 103 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 104 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 105 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 106 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 107 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 108 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 109 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 110 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 111
 112 # MSVC specific
 113 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 114 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 115 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 116 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 117 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 118
 119 # APPLE specific
 120 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 121 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 122
 123
 124 if(help OR HELP)
 125         message(STATUS)
 126         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 127         message(STATUS)
 128         LYX_OPTION_LIST_ALL(help)
 129         message(STATUS)
 130         RETURN()
 131 endif()
 132
 133 # Check option dependencies
 134
 135 if(LYX_DMG)
 136         set(LYX_BUNDLE ON)
 137         set(LYX_CPACK ON)
 138 endif()
 139
 140 if(LYX_CPACK)
 141         set(LYX_INSTALL ON)
 142 endif()
 143
 144 if(LYX_INSTALL)
 145         set(LYX_NLS ON)
 146         if (WIN32)
 147                 set(LYX_HUNSPELL ON)
 148         endif()
 149         if(LYX_CONSOLE MATCHES "FORCE")
 150                 set(LYX_CONSOLE ON)
 151         else()
 152                 set(LYX_CONSOLE OFF)
 153         endif()
 154         set(LYX_PACKAGE_SUFFIX ON)
 155         if(NOT LYX_DEBUG)
 156                 set(LYX_RELEASE ON)
 157         endif()
 158         set(LYX_PROFILE OFF)
 159 endif()
 160
 161
 162 if(LYX_MERGE_FILES)
 163         set(LYX_PCH OFF)
 164 else()
 165         set(LYX_MERGE_REBUILD OFF)
 166 endif()
 167
 168 if(LYX_DEPENDENCIES_DOWNLOAD)
 169         message(STATUS)
 170         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 171         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 172         set(deps_files lyx20-deps-msvc2010-x86.zip)
 173         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 174         foreach(it ${deps_files})
 175                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 176                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 177                 if(NOT already_downloaded)
 178                         message(STATUS "Downloading ${it} ...")
 179                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 180                         list(GET status 0 status_code)
 181                         list(GET status 1 status_string)
 182                         if(NOT status_code EQUAL 0)
 183                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 184                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 185                         endif()
 186                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 187                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 188                 endif()
 189         endforeach()
 190         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 191 endif()
 192
 193
 194
 195 message(STATUS)
 196
 197 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 198 if(WIN32)
 199         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 200 else()
 201         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 202 endif()
 203
 204
 205 set(LYX_GCC11_MODE)
 206 if(UNIX OR MINGW)
 207         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 208         message(STATUS "Using GCC version ${GCC_VERSION}")
 209         if(NOT GCC_VERSION VERSION_LESS 4.4)
 210                 set(LYX_USE_TR1 1)
 211                 # GCC <= 4.5 does not support regex: there are linker errors
 212                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 213                 set(LYX_USE_TR1_REGEX 0)
 214         endif()
 215         if (LYX_ENABLE_CXX11)
 216                 if(GCC_VERSION VERSION_GREATER 4.7)
 217                         set(LYX_GCC11_MODE "-std=gnu++11")
 218                 elseif(GCC_VERSION VERSION_GREATER 4.2)
 219                         set(LYX_GCC11_MODE "-std=gnu++0x")
 220                 endif()
 221         endif()
 222 else()
 223         if(MSVC10)
 224                 set(LYX_USE_TR1 1)
 225                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 226         endif()
 227 endif()
 228
 229
 230 set(VERSION_INFO "CMake Build")
 231
 232 # Try to get some informations from configure.ac
 233
 234 include(LyXPaths)
 235 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 236
 237 if(WIN32)
 238         set(USE_WINDOWS_PACKAGING ON)
 239 elseif(APPLE)
 240         set(USE_MACOSX_PACKAGING ON)
 241 else()
 242         set(USE_POSIX_PACKAGING ON)
 243 endif()
 244
 245 macro(setstripped _varname)
 246         if(${ARGC} GREATER 1)
 247                 string(STRIP "${ARGV1}" _v)
 248                 if(USE_POSIX_PACKAGING)
 249                         string(TOLOWER ${_v} ${_varname})
 250                 else()
 251                         set(${_varname} ${_v})
 252                 endif()
 253         else()
 254                 set(${_varname})
 255         endif()
 256 endmacro(setstripped)
 257
 258 foreach(_c_l ${_config_lines} )
 259         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 260                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 261                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 262                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 263                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 264                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 265                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 266                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 267                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 268                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 269                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 270                 endif()
 271         endif()
 272         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 273                 set(LYX_DATE "${CMAKE_MATCH_1}")
 274         endif()
 275 endforeach(_c_l)
 276
 277 if (LYX_LOCALVERSIONING)
 278         # Find the revision number and for later use
 279         FIND_PROGRAM(LYX_GITVERSION git)
 280         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 281         if(LYX_GITVERSION)
 282                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 283                 WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 284                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 285                   # We will add offset of 40000 to get appropriate value to
 286                   # previous svn.
 287                   # We use this value than also to set the package-patch-value
 288                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 289                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 290                   set(ENABLE_DIST ON)
 291                 endif()
 292         else()
 293                 set(LYX_REVISION_VERSION git) #TODO use date
 294         endif()
 295 else()
 296         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 297 endif()
 298
 299 if(LYX_PROGRAM_SUFFIX)
 300         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 301 else()
 302         set(PROGRAM_SUFFIX "")
 303 endif()
 304
 305 add_custom_target(lyx_version ALL
 306   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 307   )
 308 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 309
 310 if(APPLE)
 311         set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 312         configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 313 endif()
 314
 315 if(LYX_BUNDLE)
 316         set(LYX_CPACK ON)
 317         message(STATUS)
 318         message(STATUS "Bundle creation is enabled (experimental):")
 319         message(STATUS "    make")
 320         message(STATUS "    make install/strip")
 321         message(STATUS "    make package")
 322         if(APPLE)
 323                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 324                 set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 325                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 326                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 327                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 328                 if(NOT LYX_INSTALL_PREFIX)
 329                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 330                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 331                 endif()
 332                 # Change the owner so that the install can work
 333                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
 334         elseif(UNIX)
 335                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 336                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 337                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 338         elseif(WIN32)
 339                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 340         endif()
 341 endif()
 342
 343 if(LYX_INSTALL_PREFIX)
 344         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 345         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 346 endif()
 347 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 348
 349 if(LYX_PACKAGE_SUFFIX)
 350         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 351 else()
 352         set(PACKAGE ${PACKAGE_BASE})
 353 endif()
 354
 355
 356 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 357         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 358         if (UNIX)
 359                 # don't use the default "/usr/local"
 360                 # but respect the user-choice on the command-line
 361                 if(LYX_INSTALL_SUFFIX)
 362                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 363                 else()
 364                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 365                 endif()
 366         endif()
 367         if(WIN32)
 368                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 369         endif()
 370 endif()
 371 if(IS_ABSOLUTE)
 372         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 373 else()
 374         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 375 endif()
 376
 377
 378
 379 if(NOT LYX_DATA_SUBDIR)
 380         if (WIN32)
 381                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 382         else()
 383                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 384         endif()
 385 endif()
 386
 387 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 388 set(LYX_LOCALEDIR "locale")
 389 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 390 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 391
 392 set(LYX_MAN_DIR "/usr/local/man" CACHE STRING
 393   "Install location for man pages.")
 394 mark_as_advanced(LYX_MAN_DIR)
 395
 396 if(LYX_INSTALL AND WIN32)
 397         message(STATUS "Configuring NSIS files")
 398         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 399         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 400         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 401         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 402 endif()
 403
 404 if(NOT GROUP_CODE)
 405         #set(GROUP_CODE "The Golden Code")
 406         set(GROUP_CODE flat)
 407 endif()
 408
 409 # lyx's source files
 410 set(LYX_CPP_FILES *.cpp)
 411 set(LYX_HPP_FILES *.h)
 412 set(LYX_MOC_FILES moc_*.cpp)
 413
 414 include(ProjectSourceGroup)
 415
 416
 417 if(LYX_PROFILE AND NOT MSVC)
 418         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 419         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 420         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 421 else()
 422         set(LYX_PROFILE OFF)
 423 endif()
 424
 425
 426 if(LYX_NO_OPTIMIZE)
 427         set(CMAKE_BUILD_TYPE None)
 428         set(LYX_DEBUG OFF)
 429         set(LYX_RELEASE OFF)
 430         set(LYX_PROFILE OFF)
 431 elseif(LYX_RELEASE)
 432         set(CMAKE_BUILD_TYPE Release)
 433         set(LYX_DEBUG OFF)
 434         set(LYX_PROFILE OFF)
 435 elseif(LYX_PROFILE)
 436         set(CMAKE_BUILD_TYPE Profile)
 437         set(LYX_DEBUG OFF)
 438 else()
 439         set(CMAKE_BUILD_TYPE Debug)
 440         set(LYX_DEBUG ON)
 441 endif()
 442
 443
 444 # When shared libs are supported enable this option
 445 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 446 if(LYX_SHARED_LIBRARIES)
 447         set(library_type SHARED)
 448 else()
 449         set(library_type STATIC)
 450 endif()
 451
 452 if(NOT MSVC)
 453         if(NOT LYX_QUIET)
 454                 set(CMAKE_VERBOSE_MAKEFILE ON)
 455         endif()
 456         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 457         if(LYX_STDLIB_DEBUG)
 458                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 459         endif()
 460         if(LYX_CONCEPT_CHECKS)
 461                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 462         endif()
 463         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 464         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 465         if(MINGW)
 466                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 467         else()
 468                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 469         endif()
 470 endif()
 471
 472 if(LYX_CXX_FLAGS_EXTRA)
 473         add_definitions(${LYX_CXX_FLAGS_EXTRA})
 474 endif()
 475
 476 find_package(Qt5Core QUIET)
 477 if (Qt5Core_FOUND)
 478         find_package(Qt5Widgets REQUIRED)
 479         set(QTVERSION ${Qt5Core_VERSION})
 480         macro (qt_use_modules)
 481                 qt5_use_modules(${ARGN})
 482         endmacro()
 483         macro (qt_add_resources)
 484                 qt5_add_resources(${ARGN})
 485         endmacro()
 486         macro (qt_wrap_uifiles)
 487                 qt5_wrap_ui(${ARGN})
 488         endmacro()
 489 else()
 490         find_package(Qt4 "4.5.0" REQUIRED)
 491         macro (qt_use_modules)
 492         endmacro()
 493         macro (qt_add_resources)
 494                 qt4_add_resources(${ARGN})
 495         endmacro()
 496         macro (qt_wrap_uifiles)
 497                 qt4_wrap_ui(${ARGN})
 498         endmacro()
 499 endif()
 500
 501 find_package(Magic)
 502 if(Magic_FOUND)
 503         set(HAVE_MAGIC_H 1)
 504 endif()
 505
 506 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 507
 508 if(LYX_ASPELL)
 509         find_package(ASPELL)
 510         include_directories(${ASPELL_INCLUDE_DIR})
 511 endif()
 512
 513 if(LYX_ENCHANT)
 514         find_package(Enchant REQUIRED)
 515         include_directories(${ENCHANT_INCLUDE_DIR})
 516 endif()
 517
 518 if(LYX_HUNSPELL)
 519         find_package(Hunspell REQUIRED)
 520         include_directories(${HUNSPELL_INCLUDE_DIR})
 521 endif()
 522
 523 if(LYX_NLS)
 524         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 525         find_package(LyXGettext)
 526         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 527                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 528         else()
 529                 # Install only supplied .gmo-files
 530                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 531                 message(STATUS "Installing provided .gmo-files only")
 532                 foreach( _gmo ${_gmofiles})
 533                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 534                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 535                 endforeach()
 536         endif()
 537 endif()
 538
 539 find_package(ICONV REQUIRED)
 540 find_package(ZLIB REQUIRED)
 541
 542 if(LYX_EXTERNAL_BOOST)
 543         message(STATUS "Searching for boost")
 544         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 545         if(Boost_FOUND)
 546                 message(STATUS "Boost found")
 547                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 548                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 549         else()
 550                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 551         endif()
 552 else()
 553         if(LYX_USE_TR1_REGEX)
 554                 set(Lyx_Boost_Libraries boost_signals)
 555         else()
 556                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 557         endif()
 558         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 559         include_directories(${TOP_SRC_DIR}/boost)
 560         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 561 endif()
 562
 563
 564
 565
 566 if(WIN32)
 567         if(NOT LYX_CONSOLE)
 568                 set(WIN32_CONSOLE WIN32)
 569                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 570         endif()
 571         if(MSVC)
 572                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 573                 # disable checked iterators for msvc release builds to get maximum speed
 574                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 575         else()
 576                 add_definitions(-DWINVER=0x0500)
 577         endif()
 578 endif()
 579
 580 # Compute qt4-version from ${QTVERSION}
 581
 582 message(STATUS "")
 583 foreach(_v PACKAGE PACKAGE_VERSION
 584         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 585         LYX_ABS_TOP_SRCDIR
 586         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 587         if(NOT DEFINED ${_v})
 588                 message(FATAL_ERROR "${_v} not defined")
 589         endif()
 590         string(SUBSTRING "${_v}                            " 0 28 _v1)
 591         message(STATUS "----- ${_v1}: ${${_v}}")
 592 endforeach(_v)
 593 message(STATUS "")
 594
 595
 596 if(LYX_PCH)
 597         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 598         # Not sure if it works for all non-msvc compilers
 599         include(PCHSupport_26)
 600         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 601         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 602         add_definitions(-DLYX_ENABLE_PCH)
 603
 604         if(MSVC)
 605                 macro(lyx_add_msvc_pch name_)
 606                         set_source_files_properties(${${name_}_sources} PROPERTIES
 607                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 608                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 609                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 610                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 611                                 ${TOP_BINARY_DIR}/pcheaders.h)
 612                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 613                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 614                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 615                 endmacro(lyx_add_msvc_pch)
 616                 macro(lyx_add_gcc_pch name_)
 617                 endmacro()
 618         else()
 619                 macro(lyx_add_msvc_pch name_)
 620                 endmacro()
 621                 macro(lyx_add_gcc_pch name_)
 622                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 623                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 624                 endmacro()
 625         endif()
 626 else()
 627         macro(lyx_add_msvc_pch)
 628         endmacro(lyx_add_msvc_pch)
 629         macro(lyx_add_gcc_pch name_)
 630         endmacro()
 631 endif()
 632
 633
 634 if(MSVC)
 635
 636         if(LYX_VLD)
 637                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 638                 add_subdirectory(${vld_path}/cmake)
 639                 include(${vld_path}/cmake/vld.cmake) # forced include
 640                 set(vld_dll vld)
 641         endif()
 642
 643         if(LYX_WALL)
 644                 # Use the highest warning level
 645                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 646
 647                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 648                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 649                 else()
 650                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 651                 endif()
 652
 653                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 654                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 655                 else()
 656                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 657                 endif()
 658
 659                 # add here warnings which should produce an error /weXXXX
 660                 set(MSVC_W_ERROR   "/we4101 /we4189")
 661                 # add here warnings which should be disabled /wdXXXX
 662                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 663
 664                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 665                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 666                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 667
 668         else()
 669                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 670
 671                 # add here warnings which should produce an error /weXXXX
 672                 set(MSVC_W_ERROR   "/we4101 /we4189")
 673                 # add here warnings which should be disabled /wdXXXX
 674                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 675
 676                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 677                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 678                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 679
 680         endif()
 681
 682         if (NOT Qt5Core_FOUND)
 683                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 684                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 685                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 686         endif()
 687
 688         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 689         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 690         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 691         message(STATUS "")
 692 endif()
 693
 694
 695 if(LYX_DEBUG_GLIBC)
 696         set(_GLIBCXX_DEBUG ON)
 697 endif()
 698
 699 if(LYX_DEBUG_GLIBC_PEDANTIC)
 700         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 701 endif()
 702
 703 # Xcode compiler
 704 if (CMAKE_GENERATOR MATCHES Xcode)
 705         # Automatically select the Xcode compiler if not set
 706         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 707                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 708                 if (XCODE_VERSION VERSION_GREATER "3.1")
 709                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 710                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 711         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 712
 713         # Print the selected compiler version
 714     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 715 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 716
 717 if (WIN32 AND Qt5Core_FOUND)
 718         set(Z_PREFIX 1)
 719 endif()
 720
 721 # compiler tests, config.h generation
 722 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 723         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 724 else()
 725         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 726         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 727 endif()
 728
 729 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 730
 731 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 732         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 733 endif()
 734
 735 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 736 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 737
 738 set (cmd ${CMAKE_CTEST_COMMAND})
 739 if (MSVC)
 740         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 741 else ()
 742         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 743 endif ()
 744 add_custom_target (lyx_run_tests COMMAND ${cmd})
 745 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 746
 747
 748 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 749 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 750 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 751 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 752
 753
 754 if(LYX_INSTALL)
 755         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 756                 message(STATUS "Python required to create doc!")
 757         else()
 758                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 759                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 760         endif()
 761         if(NOT(LYX_BUNDLE AND APPLE))
 762                 include(../Install)
 763         endif()
 764 endif()
 765
 766 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 767 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 768 if(LYX_ENABLE_URLTESTS)
 769         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 770 endif()
 771
 772 message(STATUS)
 773 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 774 message(STATUS)
 775 LYX_OPTION_LIST_ALL(used)
 776
 777
 778 if(LYX_NLS)
 779         message(STATUS)
 780         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 781         message(STATUS)
 782         message(STATUS "  * iconv")
 783         message(STATUS "     - header : ${ICONV_HEADER}")
 784         message(STATUS "     - library: ${ICONV_LIBRARY}")
 785         message(STATUS "  * zlib")
 786         message(STATUS "     - header : ${ZLIB_HEADER}")
 787         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 788         message(STATUS)
 789 endif()
 790
 791 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 792
 793 if(ENABLE_DIST)
 794   # Use git to create the source package
 795   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 796   if(UNIX)
 797     set(DIST_FORMAT tgz)
 798   else()
 799     set(DIST_FORMAT zip)
 800   endif()
 801   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 802
 803   add_custom_command(
 804     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 805     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 806     WORKING_DIRECTORY ${TOP_SRC_DIR})
 807   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 808 endif()
 809
 810 message(STATUS)