CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 OLD)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84   # Enable LTO if supported
  85   if (POLICY CMP0069)
  86     cmake_policy(SET CMP0069 NEW)
  87     include(CheckIPOSupported)
  88     check_ipo_supported(RESULT result OUTPUT reason LANGUAGES CXX)
  89     if(result)
  90       message(STATUS "Setting IPO True")
  91       set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
  92     else()
  93       message(STATUS "Not setting IPO , result = ${result}, reason = ${reason}")
  94     endif()
  95   endif()
  96 endif()
  97
  98 if(UNIX)
  99         set(ARCH_TRIPLET )
 100         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
 101         if(DPKG_ARCHITECTURE_EXECUTABLE)
 102                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
 103                                 OUTPUT_VARIABLE ARCH_TRIPLET
 104                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
 105                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
 106         endif()
 107 endif()
 108 if(ARCH_TRIPLET)
 109         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 110 else()
 111         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 112 endif()
 113
 114 include(LyXMacros)
 115 include(LyXDestinations)
 116
 117 # Usage LYX_OPTION
 118 # 1. parameter: option name without prefix 'LYX_'
 119 # 2. parameter: description
 120 # 3. parameter: default value, ON or OFF
 121 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 122
 123 # Usage LYX_COMBO
 124 # 1. parameter: name without prefix 'LYX_'
 125 # 2. parameter: description
 126 # 3. parameter: default value
 127 # 4-n parameter: possible other string values
 128
 129 LYX_OPTION_INIT()
 130
 131 # Options for all compilers/systems
 132 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 133 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 134 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 135 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 136 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 137 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 138 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 139 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 140 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 141 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 142 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 143 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 144 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 145 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 146 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 147 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 148 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 149 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 150 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 151 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 152 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 153 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 154 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 155 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 156 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 157 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 158 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 159 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 160 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 161 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 162 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 163
 164 # GCC specific
 165 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 166 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 167 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 168 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 169 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 170 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 171
 172 # MSVC specific
 173 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 174 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 175 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 176 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 177
 178 # APPLE specific
 179 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 180 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 181
 182
 183 if(help OR HELP)
 184         message(STATUS)
 185         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 186         message(STATUS)
 187         LYX_OPTION_LIST_ALL(help)
 188         message(STATUS)
 189         RETURN()
 190 endif()
 191
 192 # Check option dependencies
 193
 194 if(LYX_DMG)
 195         set(LYX_BUNDLE ON)
 196         set(LYX_CPACK ON)
 197 endif()
 198
 199 if(LYX_CPACK)
 200         set(LYX_INSTALL ON)
 201 endif()
 202
 203 if(LYX_INSTALL)
 204         set(LYX_NLS ON)
 205         if(WIN32 AND NOT MINGW)
 206                 set(LYX_HUNSPELL ON)
 207         endif()
 208         set(LYX_PACKAGE_SUFFIX ON)
 209         if(NOT LYX_DEBUG)
 210                 set(LYX_RELEASE ON)
 211         endif()
 212         set(LYX_PROFILE OFF)
 213 endif()
 214
 215
 216 if(LYX_MERGE_FILES)
 217         set(LYX_PCH OFF)
 218 else()
 219         set(LYX_MERGE_REBUILD OFF)
 220 endif()
 221
 222 if(LYX_DEPENDENCIES_DOWNLOAD)
 223         message(STATUS)
 224         if(MSVC14)
 225                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 226                 set(deps_files lyx-windows-deps-msvc2015.zip)
 227                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 228                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 229         elseif(MSVC10)
 230                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 231                 set(deps_files lyx-windows-deps-msvc2010.zip)
 232                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 233                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 234         else()
 235                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 236         endif()
 237     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 238         foreach(it ${deps_files})
 239                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 240                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 241                 if(NOT already_downloaded)
 242                         message(STATUS "Downloading ${it} ...")
 243                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 244                         list(GET status 0 status_code)
 245                         list(GET status 1 status_string)
 246                         if(NOT status_code EQUAL 0)
 247                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 248                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 249                         endif()
 250                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 251                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 252                 endif()
 253         endforeach()
 254 endif()
 255
 256
 257
 258 message(STATUS)
 259
 260 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 261 if(WIN32)
 262         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 263 else()
 264         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 265 endif()
 266
 267
 268 # Set to some meaningful default
 269 find_package(CXX11Compiler)
 270 if(NOT CXX11COMPILER_FOUND)
 271         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 272 endif()
 273 set(LYX_GCC11_MODE)
 274 if(UNIX OR MINGW)
 275         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 276           # ignore the GCC_VERSION for clang
 277           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 278           message(STATUS "Using clang")
 279           if(CXX11_STD_REGEX)
 280             set(LYX_USE_STD_REGEX 1)
 281           else()
 282             set(LYX_USE_STD_REGEX 0)
 283           endif()
 284         else()
 285           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 286           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 287           if (_err)
 288             # previous check failed, try again with _old_ parameter
 289             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 290             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 291           endif()
 292           message(STATUS "Using GCC version ${GCC_VERSION}")
 293           if(GCC_VERSION VERSION_LESS 4.6)
 294                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 295           elseif(GCC_VERSION VERSION_LESS 4.9)
 296                 # <regex> in gcc is unusable in versions less than 4.9.0
 297                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 298                 set(LYX_USE_STD_REGEX 0)
 299           else()
 300                 set(LYX_USE_STD_REGEX 1)
 301           endif()
 302         endif()
 303         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 304 else()
 305         if(MSVC_VERSION LESS 1900)
 306                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 307                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 308                 set(LYX_USE_STD_REGEX 0)
 309         else()
 310                 set(LYX_USE_STD_REGEX 1)
 311         endif()
 312 endif()
 313
 314
 315 set(VERSION_INFO "CMake Build")
 316
 317 # Try to get some informations from configure.ac
 318
 319 include(LyXPaths)
 320 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 321
 322 if(WIN32)
 323         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 324         if(MSVC)
 325                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 326         endif()
 327         set(USE_WINDOWS_PACKAGING ON)
 328 elseif(APPLE)
 329         set(USE_MACOSX_PACKAGING ON)
 330 else()
 331         set(USE_POSIX_PACKAGING ON)
 332 endif()
 333
 334 if(LYX_3RDPARTY_BUILD)
 335   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 336   # this enables the build of all 3rd_party libs
 337   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 338   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 339   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 340   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 341 endif()
 342
 343 macro(setstripped _varname)
 344         if(${ARGC} GREATER 1)
 345                 string(STRIP "${ARGV1}" _v)
 346                 if (_v MATCHES "^\\[\(.+\)\\]$")
 347                   set(_v ${CMAKE_MATCH_1})
 348                 endif()
 349                 if(USE_POSIX_PACKAGING)
 350                         string(TOLOWER ${_v} ${_varname})
 351                 else()
 352                         set(${_varname} ${_v})
 353                 endif()
 354         else()
 355                 set(${_varname})
 356         endif()
 357 endmacro(setstripped)
 358
 359 foreach(_c_l ${_config_lines} )
 360         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 361                 # Not using CMAKE_MATCH_ directly is needed, because
 362                 # its value is now changed inside macro setstripped
 363                 set(_PB ${CMAKE_MATCH_1})
 364                 set(_PV ${CMAKE_MATCH_2})
 365                 set(_PBU ${CMAKE_MATCH_3})
 366                 setstripped(PACKAGE_BASE ${_PB})
 367                 setstripped(PACKAGE_VERSION ${_PV})
 368                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 369                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 370                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 371                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 372                         set(LYX_RELEASE_VERSION ${CMAKE_MATCH_4})
 373                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 374                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 375                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 376                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 377                         else()
 378                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 379                         endif()
 380                 endif()
 381         endif()
 382         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 383                 set(LYX_DATE "${CMAKE_MATCH_1}")
 384         endif()
 385 endforeach(_c_l)
 386
 387 FIND_PROGRAM(LYX_GITVERSION git)
 388 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 389 set(LYX_REVISION_VERSION ${LYX_RELEASE_VERSION})
 390 set(LYX_PACKAGE_RELEASE "1")
 391 if(LYX_GITVERSION)
 392   if (LYX_LOCALVERSIONING)
 393     # Find the revision number and for later use
 394     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 395       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 396     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 397       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 398       # We will add offset of 40000 to get appropriate value to
 399       # previous svn.
 400       # We use this value than also to set the package-patch-value
 401       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 402       set(LYX_REVISION_VERSION "${LYX_RELEASE_VERSION}-${tmp_REVISION_VERSION}git")
 403       set(ENABLE_DIST ON)
 404     endif()
 405   endif()
 406 endif()
 407
 408 # Set the programs (lyx, tex2lyx, etc.) suffix
 409 # When building an OS X bundle, we will append
 410 # the suffix only to the bundle, not to the programs
 411 set(PROGRAM_SUFFIX "")
 412 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 413         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 414 endif()
 415 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 416 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 417 set(_convert lyxconvert${PROGRAM_SUFFIX})
 418
 419 add_custom_target(lyx_version ALL
 420   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 421   )
 422 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 423
 424 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 425 set(LYX_UTILITIES_INSTALL_PATH bin)
 426
 427 if(LYX_BUNDLE)
 428         set(LYX_CPACK ON)
 429
 430         message(STATUS)
 431         message(STATUS "Bundle creation is enabled (experimental):")
 432         message(STATUS "    make")
 433         message(STATUS "    make install/strip")
 434         message(STATUS "    make package")
 435         if(APPLE)
 436                 set(MACOSX_BUNDLE TRUE)
 437                 # This sets the bundle + executable names
 438                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 439                 # This sets the Info.plist executable name
 440                 set(osx_bundle_program_name ${_lyx})
 441                 # Bundle name
 442                 set(LYX_BUNDLE_NAME ${_lyx})
 443
 444                 # This will contain the list of files that need to be included
 445                 # in the bundle and their location within the bundle
 446                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 447                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 448
 449                 # Process Info.plist and lyxrc.dist
 450                 # See development/cmake/Install.cmake
 451                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 452
 453                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 454                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 455
 456                 # Variables used by CPack
 457                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 458                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 459                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 460
 461                 # Set the install paths
 462                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 463                 if(NOT LYX_INSTALL_PREFIX)
 464                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 465                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 466                 endif()
 467                 # Change the owner so that the install can work
 468                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 469         elseif(UNIX)
 470                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 471                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 472                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 473         elseif(WIN32)
 474                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 475         endif()
 476 endif()
 477
 478 if(LYX_INSTALL_PREFIX)
 479         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 480         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 481 endif()
 482 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 483
 484 if(UNIX)
 485   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 486 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 487   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 488 else()
 489   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 490 endif()
 491
 492 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 493   # Not a GCC compiler, programs do not have a suffix
 494   set(suffixing ${LYX_PACKAGE_SUFFIX})
 495 elseif(WIN32 AND MINGW)
 496   # We want to use a suffix for the package in this case,
 497   # even if not for the program
 498   set(suffixing ${LYX_PACKAGE_SUFFIX})
 499 else()
 500   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 501   set(suffixing ${LYX_PROGRAM_SUFFIX})
 502 endif()
 503
 504 # The define PACKAGE below allows lyx-executable to find its default configuration files
 505 # see routines
 506 #    Package::messages_file()
 507 #    get_default_user_support_dir()
 508 #    relative_system_support_dir()
 509 # in src/support/Package.cpp
 510 if(suffixing)
 511         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 512 else()
 513         set(PACKAGE ${PACKAGE_BASE})
 514 endif()
 515
 516 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 517         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 518         if (UNIX)
 519                 # use the default "/usr/local"
 520                 # but respect the user-choice on the command-line
 521                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 522         endif()
 523 endif()
 524 if(WIN32)
 525         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 526 endif()
 527 if(IS_ABSOLUTE)
 528         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 529 else()
 530         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 531 endif()
 532
 533
 534
 535 if(NOT LYX_DATA_SUBDIR)
 536         if (WIN32)
 537                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 538         else()
 539                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 540         endif()
 541 endif()
 542
 543 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 544 get_locale_destination(LYX_LOCALEDIR)
 545 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 546 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 547
 548 if(LYX_BUNDLE AND APPLE)
 549         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 550 else()
 551         if(WIN32)
 552                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 553         elseif(UNIX)
 554                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 555         else()
 556                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 557         endif()
 558 endif()
 559 mark_as_advanced(LYX_MAN_DIR)
 560
 561 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 562 # see the Readme.txt of the installer
 563 #if(LYX_INSTALL AND WIN32)
 564 #       message(STATUS "Configuring NSIS files")
 565 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 566 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 567 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 568 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 569 #endif()
 570
 571 if(NOT GROUP_CODE)
 572         #set(GROUP_CODE "The Golden Code")
 573         set(GROUP_CODE flat)
 574 endif()
 575
 576 # lyx's source files
 577 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 578 set(LYX_HPP_FILES [a-zA-Z]*.h)
 579 set(LYX_MOC_FILES moc_*.cpp)
 580
 581 include(ProjectSourceGroup)
 582
 583
 584 if(LYX_PROFILE AND NOT MSVC)
 585         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 586         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 587         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 588 else()
 589         set(LYX_PROFILE OFF)
 590 endif()
 591
 592
 593 if(LYX_NO_OPTIMIZE)
 594         set(CMAKE_BUILD_TYPE None)
 595         set(LYX_DEBUG OFF)
 596         set(LYX_RELEASE OFF)
 597         set(LYX_PROFILE OFF)
 598 elseif(LYX_RELEASE)
 599         set(CMAKE_BUILD_TYPE Release)
 600         set(LYX_DEBUG OFF)
 601         set(LYX_PROFILE OFF)
 602 elseif(LYX_PROFILE)
 603         set(CMAKE_BUILD_TYPE Profile)
 604         set(LYX_DEBUG OFF)
 605 else()
 606         set(CMAKE_BUILD_TYPE Debug)
 607         set(LYX_DEBUG ON)
 608 endif()
 609
 610
 611 # When shared libs are supported enable this option
 612 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 613 if(LYX_SHARED_LIBRARIES)
 614         set(library_type SHARED)
 615 else()
 616         set(library_type STATIC)
 617 endif()
 618
 619 if(NOT MSVC)
 620         if(NOT LYX_QUIET)
 621                 set(CMAKE_VERBOSE_MAKEFILE ON)
 622         endif()
 623         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 624         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 625           # Thanks to Brad King <brad.king@kitware.com>
 626           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 627           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 628           # and still use our own c++ extension tests
 629           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 630           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 631         endif()
 632         if(LYX_STDLIB_DEBUG)
 633                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 634         endif()
 635         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 636         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 637         if(MINGW)
 638                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 639         else()
 640                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 641         endif()
 642 endif()
 643
 644 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 645 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 646 if(LYX_CXX_FLAGS_EXTRA)
 647         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 648                 add_definitions(${_flag})
 649         endforeach()
 650 endif()
 651
 652 if(LYX_XMINGW)
 653         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 654 endif()
 655
 656 set(min_qt5_version "5.6")
 657 if(LYX_USE_QT MATCHES "AUTO")
 658         # try qt5 first
 659         find_package(Qt5Core CONFIG QUIET)
 660         if(Qt5Core_FOUND)
 661                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 662                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 663                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 664                         find_package(Qt4 "4.5.0" QUIET)
 665                         if(QT4_FOUND)
 666                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 667                         endif()
 668                 endif()
 669         else()
 670                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 671         endif()
 672 endif()
 673 if(LYX_USE_QT MATCHES "QT5")
 674         # set QPA_XCB if QT uses X11
 675         find_package(Qt5Core CONFIG REQUIRED)
 676         if (Qt5Core_FOUND)
 677                 find_package(Qt5Widgets CONFIG REQUIRED)
 678                 if(APPLE)
 679                         find_package(Qt5MacExtras CONFIG REQUIRED)
 680                 endif()
 681                 find_package(Qt5X11Extras CONFIG QUIET)
 682                 find_package(Qt5WinExtras CONFIG QUIET)
 683                 set(QTVERSION ${Qt5Core_VERSION})
 684                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 685                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 686                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 687                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 688                         # see thread in lyx-devel list
 689                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 690                         # Date 11.03.2017
 691                         # Subject: cmake compilation error
 692                         #message(FATAL_ERROR "Wrong Qt-Version")
 693                 endif()
 694                 macro (qt_use_modules lyxtarget)
 695                         foreach (_tg ${ARGN})
 696                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 697                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 698                         endforeach()
 699                 endmacro()
 700                 macro (qt_add_resources)
 701                         qt5_add_resources(${ARGN})
 702                 endmacro()
 703                 macro (qt_wrap_uifiles)
 704                         qt5_wrap_ui(${ARGN})
 705                 endmacro()
 706                 message(STATUS "Found Qt-Version ${QTVERSION}")
 707                 if(WIN32)
 708                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 709                 endif()
 710         endif()
 711 elseif(LYX_USE_QT MATCHES "QT4")
 712         if(LYX_XMINGW)
 713                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 714                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 715         endif()
 716         find_package(Qt4 "4.5.0" REQUIRED)
 717         macro (qt_use_modules)
 718         endmacro()
 719         macro (qt_add_resources)
 720                 qt4_add_resources(${ARGN})
 721         endmacro()
 722         macro (qt_wrap_uifiles)
 723                 qt4_wrap_ui(${ARGN})
 724         endmacro()
 725         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 726         if(WIN32)
 727                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 728         endif()
 729 else()
 730   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 731 endif()
 732
 733 find_package(Magic)
 734 if(Magic_FOUND)
 735   set(HAVE_MAGIC_H 1)
 736   include_directories(${Magic_INCLUDE_DIR})
 737 endif()
 738
 739 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 740
 741 set(Spelling_FOUND OFF)
 742 set(Include_used_spellchecker)   # String will be inserted into config.h
 743
 744 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 745   # try system library first
 746   find_package(MyThesLIB)
 747   if (MYTHESLIB_FOUND)
 748     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 749   else()
 750     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 751   endif()
 752 endif()
 753 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 754   find_package(MyThesLIB REQUIRED)
 755 else()
 756   add_subdirectory(3rdparty/mythes)
 757 endif()
 758 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 759
 760 if(NOT LYX_EXTERNAL_HUNSPELL)
 761     add_subdirectory(3rdparty/hunspell)
 762     add_definitions(-DHUNSPELL_STATIC)
 763     set(HUNSPELL_FOUND ON)
 764     message(STATUS "  * Hunspell:")
 765     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 766     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 767 endif()
 768
 769 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 770   string(TOUPPER ${_spell} _upspell)
 771   if (NOT ${_upspell}_FOUND)
 772     find_package(${_spell})
 773   endif()
 774   if (${_upspell}_FOUND)
 775     include_directories(${${_upspell}_INCLUDE_DIR})
 776     set(Spelling_FOUND ON)
 777     message(STATUS "Building with USE_${_upspell}")
 778     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 779   else()
 780     if(LYX_${_upspell})
 781       message(FATAL_ERROR "Required ${_spell} devel package not found")
 782     else()
 783       message(STATUS "${_upspell} not found, building without ${_spell} support")
 784     endif()
 785   endif()
 786 endforeach()
 787
 788 if(GNUWIN32_DIR)
 789         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 790 endif()
 791
 792 # Search for python default version first
 793 unset(PYTHON_EXECUTABLE CACHE)
 794 unset(LYX_PYTHON_EXECUTABLE CACHE)
 795 unset(PYTHON_VERSION_MAJOR)
 796 unset(PYTHON_VERSION_MINOR)
 797 unset(PYTHON_VERSION_STRING)
 798 find_package(PythonInterp 3.5 QUIET)
 799 if(NOT PYTHONINTERP_FOUND)
 800   unset(PYTHON_EXECUTABLE CACHE)
 801   find_package(PythonInterp 2.0 REQUIRED)
 802   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 803     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 804   endif()
 805 endif()
 806
 807 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 808
 809 if(LYX_NLS)
 810         find_package(LyXGettext)
 811         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 812                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 813         else()
 814                 # Install only supplied .gmo-files
 815                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 816                 message(STATUS "Installing provided .gmo-files only")
 817                 foreach( _gmo ${_gmofiles})
 818                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 819                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 820                 endforeach()
 821         endif()
 822 endif()
 823
 824 if(LYX_EXTERNAL_ICONV)
 825   find_package(ICONV REQUIRED)
 826 else()
 827   add_subdirectory(3rdparty/libiconv)
 828   set(HAVE_ICONV_CONST 1)
 829 endif()
 830
 831 if(LYX_EXTERNAL_Z)
 832   find_package(ZLIB REQUIRED)
 833 else()
 834   add_subdirectory(3rdparty/zlib)
 835 endif()
 836
 837 if(LYX_USE_STD_REGEX)
 838   # Set only include path.
 839   # Use internal boost, which is known to exist
 840   # we don't need any libraries
 841   set(Lyx_Boost_Libraries)
 842   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 843   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 844 else()
 845   # Using boost-regex
 846   if(LYX_EXTERNAL_BOOST)
 847     message(STATUS "Searching for external boost")
 848     find_package(Boost COMPONENTS regex)
 849     if(Boost_FOUND)
 850       message(STATUS "Boost found")
 851       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 852       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 853       if (LYX_STDLIB_DEBUG)
 854         # Comment from  Jean-Marc Lasgouttes:
 855         # In general, system boost libraries are incompatible with
 856         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 857         # details.
 858         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 859       endif()
 860     else()
 861       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 862     endif()
 863   else()
 864     # Using included boost
 865     set(Lyx_Boost_Libraries boost_regex)
 866     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 867     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 868     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 869   endif()
 870 endif()
 871
 872 if(WIN32)
 873         if(LYX_CONSOLE)
 874                 set(LYX_QTMAIN_LIBRARY)
 875         else()
 876                 set(WIN32_CONSOLE WIN32)
 877         endif()
 878         if(MSVC)
 879                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 880                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 881                 # disable checked iterators for msvc release builds to get maximum speed
 882                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 883         else()
 884                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 885                 # does not use it and always declares the vista compatible API.
 886                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 887                 add_definitions(-DWINVER=0x0500)
 888         endif()
 889 endif()
 890
 891 # Compute qt-version from ${QTVERSION}
 892
 893 message(STATUS "")
 894 foreach(_v PACKAGE PACKAGE_VERSION
 895         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 896         LYX_ABS_TOP_SRCDIR
 897         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 898         if(NOT DEFINED ${_v})
 899                 message(FATAL_ERROR "${_v} not defined")
 900         endif()
 901         string(SUBSTRING "${_v}                            " 0 28 _v1)
 902         message(STATUS "----- ${_v1}: ${${_v}}")
 903 endforeach(_v)
 904 message(STATUS "")
 905
 906
 907 if(LYX_PCH)
 908         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 909         # Not sure if it works for all non-msvc compilers
 910         include(PCHSupport_26)
 911         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 912         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 913         add_definitions(-DLYX_ENABLE_PCH)
 914
 915         if(MSVC)
 916                 macro(lyx_add_msvc_pch name_)
 917                         set_source_files_properties(${${name_}_sources} PROPERTIES
 918                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 919                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 920                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 921                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 922                                 ${TOP_BINARY_DIR}/pcheaders.h)
 923                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 924                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 925                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 926                 endmacro(lyx_add_msvc_pch)
 927                 macro(lyx_add_gcc_pch name_)
 928                 endmacro()
 929         else()
 930                 macro(lyx_add_msvc_pch name_)
 931                 endmacro()
 932                 macro(lyx_add_gcc_pch name_)
 933                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 934                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 935                 endmacro()
 936         endif()
 937 else()
 938         macro(lyx_add_msvc_pch)
 939         endmacro(lyx_add_msvc_pch)
 940         macro(lyx_add_gcc_pch name_)
 941         endmacro()
 942 endif()
 943
 944
 945 if(MSVC)
 946
 947         if(LYX_VLD)
 948                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 949                 add_subdirectory(${vld_path}/cmake)
 950                 include(${vld_path}/cmake/vld.cmake) # forced include
 951                 set(vld_dll vld)
 952         endif()
 953
 954         if(LYX_WALL)
 955                 # Use the highest warning level
 956                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
 957
 958                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 959                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 960                 else()
 961                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 962                 endif()
 963
 964                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 965                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 966                 else()
 967                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 968                 endif()
 969
 970                 # add here warnings which should produce an error /weXXXX
 971                 set(MSVC_W_ERROR   "/we4101 /we4189")
 972                 # add here warnings which should be disabled /wdXXXX
 973                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 974
 975                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 976                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 977                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 978
 979         else()
 980                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
 981
 982                 # add here warnings which should produce an error /weXXXX
 983                 set(MSVC_W_ERROR   "/we4101 /we4189")
 984                 # add here warnings which should be disabled /wdXXXX
 985                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 986
 987                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 988                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 989                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 990
 991         endif()
 992
 993         if (NOT Qt5Core_FOUND)
 994                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 995                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 996                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 997         endif()
 998
 999         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1000         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1001         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1002         message(STATUS "")
1003 endif()
1004
1005
1006 if(LYX_DEBUG_GLIBC)
1007         set(_GLIBCXX_DEBUG ON)
1008 endif()
1009
1010 if(LYX_DEBUG_GLIBC_PEDANTIC)
1011         set(_GLIBCXX_DEBUG_PEDANTIC ON)
1012 endif()
1013
1014 # Xcode compiler
1015 if (CMAKE_GENERATOR MATCHES Xcode)
1016         if (XCODE_VERSION VERSION_LESS "5.0")
1017                 # Automatically select the Xcode compiler if not set
1018                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1019                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1020                         if (XCODE_VERSION VERSION_GREATER "3.1")
1021                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1022                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1023                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1024                 # Print the selected compiler version
1025         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1026         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1027 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1028
1029 if (WIN32 AND Qt5Core_FOUND)
1030         set(Z_PREFIX 1)
1031 endif()
1032
1033 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1034 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1035 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1036
1037 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1038
1039 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1040         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1041 endif()
1042
1043 if (NOT HAVE_REGEX)
1044         set(LYX_USE_STD_REGEX 0)
1045 endif()
1046
1047
1048 set (cmd ${CMAKE_CTEST_COMMAND})
1049 if (MSVC)
1050         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1051 else ()
1052         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1053 endif ()
1054 add_custom_target (lyx_run_tests COMMAND ${cmd})
1055 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1056
1057 if(LYX_ASAN)
1058     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1059     message(STATUS)
1060     message(STATUS "Address sanitizer enabled. Usage:")
1061     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1062     message(STATUS "    chmod  +x ./asan_symbolize.py")
1063     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1064     message(STATUS)
1065 endif()
1066
1067 if(LYX_INSTALL)
1068         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1069                 message(STATUS "Python required to create doc!")
1070         else()
1071                 if(UNIX)
1072                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1073                 endif()
1074                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1075         endif()
1076 endif()
1077 include(../Install)
1078
1079 # By running the URL tests first, time can be saved when running the ctests in
1080 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1081 if(LYX_ENABLE_URLTESTS)
1082         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1083 endif()
1084 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1085 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1086 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1087 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1088 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1089 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1090 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1091
1092 message(STATUS)
1093 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1094 message(STATUS)
1095
1096 LYX_OPTION_LIST_ALL(used)
1097
1098
1099 if(LYX_NLS)
1100         message(STATUS)
1101         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1102         message(STATUS)
1103         message(STATUS "  * iconv")
1104         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1105         message(STATUS "     - library: ${ICONV_LIBRARY}")
1106         message(STATUS "  * zlib")
1107         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1108         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1109         message(STATUS)
1110 endif()
1111
1112 # Apple has builtin native spell checker,
1113 # no need to warn for missing Aspell, Hunspell or Enchant
1114 if(NOT Spelling_FOUND AND NOT APPLE)
1115   if(LYX_REQUIRE_SPELLCHECK)
1116     set(_mode "FATAL_ERROR")
1117   else()
1118     set(_mode "STATUS")
1119   endif()
1120   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1121 endif()
1122
1123 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1124
1125 if(ENABLE_DIST)
1126   # Use git to create the source package
1127   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1128   if(UNIX)
1129     set(DIST_FORMAT tgz)
1130   else()
1131     set(DIST_FORMAT zip)
1132   endif()
1133   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1134
1135   add_custom_command(
1136     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1137     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1138     WORKING_DIRECTORY ${TOP_SRC_DIR})
1139   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1140 endif()
1141
1142 # Last directory to be included so that the fixup code (OS X)
1143 # can be run last
1144 add_subdirectory(development/cmake/post_install)
1145
1146 message(STATUS)