CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43         if(POLICY CMP0020)
  44                 cmake_policy(SET CMP0020 OLD)
  45         endif()
  46         if(POLICY CMP0028)
  47                 cmake_policy(SET CMP0028 OLD)
  48         endif()
  49         if(POLICY CMP0043)
  50                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  51                 cmake_policy(SET CMP0043 NEW)
  52         endif()
  53 endif()
  54
  55 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  56
  57 # Supress regeneration
  58 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  59
  60 if(LYX_XMINGW)
  61     set(CMAKE_SYSTEM_NAME Windows)
  62     set(TOOLNAME ${LYX_XMINGW})
  63     set(TOOLCHAIN "${TOOLNAME}-")
  64     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  65     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  66     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  67
  68     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  69     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  71 endif()
  72
  73 if(NOT help AND NOT HELP)
  74   # 'project' triggers the searching for a compiler
  75   project(${LYX_PROJECT})
  76   if (CMAKE_COMPILER_IS_GNUCXX)
  77     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  78       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  79       message(STATUS "is too old, should be >= 4.0")
  80       message(FATAL_ERROR "Exiting")
  81     endif()
  82   endif()
  83 endif()
  84
  85 if(UNIX)
  86         set(ARCH_TRIPLET )
  87         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  88         if(DPKG_ARCHITECTURE_EXECUTABLE)
  89                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  90                                 OUTPUT_VARIABLE ARCH_TRIPLET
  91                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  92                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  93         endif()
  94 endif()
  95 if(ARCH_TRIPLET)
  96         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  97 else()
  98         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  99 endif()
 100
 101 include(LyXMacros)
 102
 103 # Usage LYX_OPTION
 104 # 1. parameter: option name without prefix 'LYX_'
 105 # 2. parameter: description
 106 # 3. parameter: default value, ON or OFF
 107 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 108
 109 # Usage LYX_COMBO
 110 # 1. parameter: name without prefix 'LYX_'
 111 # 2. parameter: description
 112 # 3. parameter: default value
 113 # 4-n parameter: possible other string values
 114
 115 LYX_OPTION_INIT()
 116
 117 # Options for all compilers/systems
 118 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 119 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 120 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 121 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 122 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 123 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 124 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 125 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 126 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 127 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 128 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 129 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 130 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 131 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 132 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 133 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 134 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 135 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 136 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 137 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 138 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 139 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 140 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 141
 142 # GCC specific
 143 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 144 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 145 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 146 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 147 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 148 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 149 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 150 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 151
 152 # MSVC specific
 153 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 154 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 155 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 156 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 157 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 158
 159 # APPLE specific
 160 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 161 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 162
 163
 164 if(help OR HELP)
 165         message(STATUS)
 166         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 167         message(STATUS)
 168         LYX_OPTION_LIST_ALL(help)
 169         message(STATUS)
 170         RETURN()
 171 endif()
 172
 173 # Check option dependencies
 174
 175 if(LYX_DMG)
 176         set(LYX_BUNDLE ON)
 177         set(LYX_CPACK ON)
 178 endif()
 179
 180 if(LYX_CPACK)
 181         set(LYX_INSTALL ON)
 182 endif()
 183
 184 if(LYX_INSTALL)
 185         set(LYX_NLS ON)
 186         if(WIN32 AND NOT MINGW)
 187                 set(LYX_HUNSPELL ON)
 188         endif()
 189         if(LYX_CONSOLE MATCHES "FORCE")
 190                 set(LYX_CONSOLE ON)
 191         else()
 192                 set(LYX_CONSOLE OFF)
 193         endif()
 194         set(LYX_PACKAGE_SUFFIX ON)
 195         if(NOT LYX_DEBUG)
 196                 set(LYX_RELEASE ON)
 197         endif()
 198         set(LYX_PROFILE OFF)
 199 endif()
 200
 201
 202 if(LYX_MERGE_FILES)
 203         set(LYX_PCH OFF)
 204 else()
 205         set(LYX_MERGE_REBUILD OFF)
 206 endif()
 207
 208
 209 if(LYX_DEPENDENCIES_DOWNLOAD)
 210         message(STATUS)
 211         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 212         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 213         set(deps_files lyx20-deps-msvc2010-x86.zip)
 214         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 215         foreach(it ${deps_files})
 216                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 217                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 218                 if(NOT already_downloaded)
 219                         message(STATUS "Downloading ${it} ...")
 220                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 221                         list(GET status 0 status_code)
 222                         list(GET status 1 status_string)
 223                         if(NOT status_code EQUAL 0)
 224                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 225                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 226                         endif()
 227                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 228                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 229                 endif()
 230         endforeach()
 231         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 232     if(MSVC12)
 233         # handle error in msvc12 when linking against msvc10 libs
 234         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 235     endif()
 236 endif()
 237
 238
 239
 240 message(STATUS)
 241
 242 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 243 if(WIN32)
 244         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 245 else()
 246         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 247 endif()
 248
 249
 250 set(LYX_GCC11_MODE)
 251 if(UNIX OR MINGW)
 252         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 253         message(STATUS "Using GCC version ${GCC_VERSION}")
 254         if(GCC_VERSION VERSION_LESS 4.9)
 255                 # <regex> in gcc is unusable in versions less than 4.9.0
 256                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 257                 set(LYX_USE_STD_REGEX 0)
 258         else()
 259                 if (LYX_ENABLE_CXX11)
 260                         set(LYX_USE_STD_REGEX 1)
 261                 endif()
 262         endif()
 263         if (LYX_ENABLE_CXX11)
 264                 find_package(CXX11Compiler)
 265                 if(NOT CXX11COMPILER_FOUND)
 266                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 267                 endif()
 268                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 269         endif()
 270 else()
 271         set(LYX_USE_STD_REGEX 0)
 272 #       if(MSVC10)
 273 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 274 #       endif()
 275 endif()
 276
 277
 278 set(VERSION_INFO "CMake Build")
 279
 280 # Try to get some informations from configure.ac
 281
 282 include(LyXPaths)
 283 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 284
 285 if(WIN32)
 286         set(USE_WINDOWS_PACKAGING ON)
 287 elseif(APPLE)
 288         set(USE_MACOSX_PACKAGING ON)
 289 else()
 290         set(USE_POSIX_PACKAGING ON)
 291 endif()
 292
 293 macro(setstripped _varname)
 294         if(${ARGC} GREATER 1)
 295                 string(STRIP "${ARGV1}" _v)
 296                 if(USE_POSIX_PACKAGING)
 297                         string(TOLOWER ${_v} ${_varname})
 298                 else()
 299                         set(${_varname} ${_v})
 300                 endif()
 301         else()
 302                 set(${_varname})
 303         endif()
 304 endmacro(setstripped)
 305
 306 foreach(_c_l ${_config_lines} )
 307         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 308                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 309                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 310                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 311                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 312                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 313                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 314                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 315                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 316                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 317                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 318                 endif()
 319         endif()
 320         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 321                 set(LYX_DATE "${CMAKE_MATCH_1}")
 322         endif()
 323 endforeach(_c_l)
 324
 325 FIND_PROGRAM(LYX_GITVERSION git)
 326 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 327 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 328 if(LYX_GITVERSION)
 329   if (LYX_LOCALVERSIONING)
 330     # Find the revision number and for later use
 331     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 332       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 333     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 334       # We will add offset of 40000 to get appropriate value to
 335       # previous svn.
 336       # We use this value than also to set the package-patch-value
 337       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 338       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 339       set(ENABLE_DIST ON)
 340     endif()
 341   endif()
 342 endif()
 343
 344 # Set the programs (lyx, tex2lyx, etc.) suffix
 345 # When building an OS X bundle, we will append
 346 # the suffix only to the bundle, not to the programs
 347 set(PROGRAM_SUFFIX "")
 348 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 349         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 350 endif()
 351 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 352 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 353
 354 add_custom_target(lyx_version ALL
 355   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 356   )
 357 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 358
 359 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 360 set(LYX_UTILITIES_INSTALL_PATH bin)
 361
 362 if(LYX_BUNDLE)
 363         set(LYX_CPACK ON)
 364
 365         message(STATUS)
 366         message(STATUS "Bundle creation is enabled (experimental):")
 367         message(STATUS "    make")
 368         message(STATUS "    make install/strip")
 369         message(STATUS "    make package")
 370         if(APPLE)
 371                 set(MACOSX_BUNDLE TRUE)
 372                 # This sets the bundle + executable names
 373                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 374                 # This sets the Info.plist executable name
 375                 set(osx_bundle_program_name ${_lyx})
 376                 # Bundle name
 377                 set(LYX_BUNDLE_NAME ${_lyx})
 378
 379                 # This will contain the list of files that need to be included
 380                 # in the bundle and their location within the bundle
 381                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 382                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 383
 384                 # Process Info.plist and lyxrc.dist
 385                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 386                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 387
 388                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 389                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 390
 391                 # Variables used by CPack
 392                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 393                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 394                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 395
 396                 # Set the install paths
 397                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 398                 if(NOT LYX_INSTALL_PREFIX)
 399                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 400                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 401                 endif()
 402                 # Change the owner so that the install can work
 403                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 404         elseif(UNIX)
 405                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 406                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 407                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 408         elseif(WIN32)
 409                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 410         endif()
 411 endif()
 412
 413 if(LYX_INSTALL_PREFIX)
 414         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 415         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 416 endif()
 417 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 418
 419 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 420
 421 if(LYX_PACKAGE_SUFFIX)
 422         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 423 else()
 424         set(PACKAGE ${PACKAGE_BASE})
 425 endif()
 426
 427 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 428         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 429         if (UNIX)
 430                 # don't use the default "/usr/local"
 431                 # but respect the user-choice on the command-line
 432                 if(LYX_INSTALL_SUFFIX)
 433                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 434                 else()
 435                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 436                 endif()
 437         endif()
 438         if(WIN32)
 439                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 440         endif()
 441 endif()
 442 if(IS_ABSOLUTE)
 443         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 444 else()
 445         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 446 endif()
 447
 448
 449
 450 if(NOT LYX_DATA_SUBDIR)
 451         if (WIN32)
 452                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 453         else()
 454                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 455         endif()
 456 endif()
 457
 458 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 459 set(LYX_LOCALEDIR "locale")
 460 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 461 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 462
 463 if(LYX_BUNDLE AND APPLE)
 464         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 465 else()
 466         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 467 endif()
 468 mark_as_advanced(LYX_MAN_DIR)
 469
 470 if(LYX_INSTALL AND WIN32)
 471         message(STATUS "Configuring NSIS files")
 472         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 473         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 474         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 475         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 476 endif()
 477
 478 if(NOT GROUP_CODE)
 479         #set(GROUP_CODE "The Golden Code")
 480         set(GROUP_CODE flat)
 481 endif()
 482
 483 # lyx's source files
 484 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 485 set(LYX_HPP_FILES [a-zA-Z]*.h)
 486 set(LYX_MOC_FILES moc_*.cpp)
 487
 488 include(ProjectSourceGroup)
 489
 490
 491 if(LYX_PROFILE AND NOT MSVC)
 492         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 493         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 494         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 495 else()
 496         set(LYX_PROFILE OFF)
 497 endif()
 498
 499
 500 if(LYX_NO_OPTIMIZE)
 501         set(CMAKE_BUILD_TYPE None)
 502         set(LYX_DEBUG OFF)
 503         set(LYX_RELEASE OFF)
 504         set(LYX_PROFILE OFF)
 505 elseif(LYX_RELEASE)
 506         set(CMAKE_BUILD_TYPE Release)
 507         set(LYX_DEBUG OFF)
 508         set(LYX_PROFILE OFF)
 509 elseif(LYX_PROFILE)
 510         set(CMAKE_BUILD_TYPE Profile)
 511         set(LYX_DEBUG OFF)
 512 else()
 513         set(CMAKE_BUILD_TYPE Debug)
 514         set(LYX_DEBUG ON)
 515 endif()
 516
 517
 518 # When shared libs are supported enable this option
 519 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 520 if(LYX_SHARED_LIBRARIES)
 521         set(library_type SHARED)
 522 else()
 523         set(library_type STATIC)
 524 endif()
 525
 526 if(NOT MSVC)
 527         if(NOT LYX_QUIET)
 528                 set(CMAKE_VERBOSE_MAKEFILE ON)
 529         endif()
 530     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 531         if(LYX_STDLIB_DEBUG)
 532                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 533         endif()
 534         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 535         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 536         if(MINGW)
 537                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 538         else()
 539                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 540         endif()
 541 endif()
 542
 543 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 544 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 545 if(LYX_CXX_FLAGS_EXTRA)
 546         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 547                 add_definitions(${_flag})
 548         endforeach()
 549 endif()
 550
 551 if(LYX_XMINGW)
 552         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 553 endif()
 554
 555 if(LYX_USE_QT MATCHES "QT5")
 556         find_package(Qt5Core REQUIRED)
 557         if (Qt5Core_FOUND)
 558                 find_package(Qt5Widgets REQUIRED)
 559                 if(APPLE)
 560                         find_package(Qt5MacExtras REQUIRED)
 561                 endif()
 562                 find_package(Qt5X11Extras QUIET)
 563                 find_package(Qt5WinExtras QUIET)
 564                 set(QTVERSION ${Qt5Core_VERSION})
 565                 macro (qt_use_modules)
 566                         qt5_use_modules(${ARGN})
 567                 endmacro()
 568                 macro (qt_add_resources)
 569                         qt5_add_resources(${ARGN})
 570                 endmacro()
 571                 macro (qt_wrap_uifiles)
 572                         qt5_wrap_ui(${ARGN})
 573                 endmacro()
 574                 message(STATUS "Found Qt-Version ${QTVERSION}")
 575         if(WIN32)
 576             set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 577         endif()
 578         endif()
 579 elseif(LYX_USE_QT MATCHES "QT4")
 580         if(LYX_XMINGW)
 581                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 582                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 583         endif()
 584         find_package(Qt4 "4.5.0" REQUIRED)
 585         macro (qt_use_modules)
 586         endmacro()
 587         macro (qt_add_resources)
 588                 qt4_add_resources(${ARGN})
 589         endmacro()
 590         macro (qt_wrap_uifiles)
 591                 qt4_wrap_ui(${ARGN})
 592         endmacro()
 593     if(WIN32)
 594         set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 595     endif()
 596 else()
 597   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 598 endif()
 599
 600 find_package(Magic)
 601 if(Magic_FOUND)
 602         set(HAVE_MAGIC_H 1)
 603 endif()
 604
 605 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 606
 607 set(Spelling_FOUND OFF)
 608 set(Include_used_spellchecker)   # String will be inserted into config.h
 609
 610 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 611   string(TOUPPER ${_spell} _upspell)
 612   find_package(${_spell})
 613   if (${_upspell}_FOUND)
 614     include_directories(${${_upspell}_INCLUDE_DIR})
 615     set(Spelling_FOUND ON)
 616     message(STATUS "Building with USE_${_upspell}")
 617     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 618   else()
 619     if(LYX_${_upspell})
 620       message(FATAL_ERROR "Required ${_spell} devel package not found")
 621     else()
 622       message(STATUS "${_upspell} not found, building without ${_spell} support")
 623     endif()
 624   endif()
 625 endforeach()
 626
 627 find_package(PythonInterp 2.7 QUIET)
 628 if(PYTHONINTERP_FOUND)
 629   if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 630     unset(PYTHONINTERP_FOUND)
 631   endif()
 632 endif()
 633
 634 if (NOT PYTHONINTERP_FOUND)
 635   unset(PYTHON_EXECUTABLE CACHE)
 636   unset(PYTHON_VERSION_MAJOR)
 637   unset(PYTHON_VERSION_MINOR)
 638   unset(PYTHON_VERSION_STRING)
 639   find_package(PythonInterp 3.3 REQUIRED)
 640 endif()
 641
 642 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 643
 644 if(LYX_NLS)
 645         find_package(LyXGettext)
 646         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 647                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 648         else()
 649                 # Install only supplied .gmo-files
 650                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 651                 message(STATUS "Installing provided .gmo-files only")
 652                 foreach( _gmo ${_gmofiles})
 653                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 654                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 655                 endforeach()
 656         endif()
 657 endif()
 658
 659
 660 find_package(ICONV REQUIRED)
 661 find_package(ZLIB REQUIRED)
 662
 663 if(LYX_EXTERNAL_BOOST)
 664         message(STATUS "Searching for boost")
 665         if(LYX_USE_STD_REGEX)
 666                 find_package(Boost COMPONENTS signals)
 667         else()
 668                 find_package(Boost COMPONENTS signals regex)
 669         endif()
 670         if(Boost_FOUND)
 671                 message(STATUS "Boost found")
 672                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 673                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 674                 if (LYX_STDLIB_DEBUG)
 675                         # Comment from  Jean-Marc Lasgouttes:
 676                         # In general, system boost libraries are incompatible with
 677                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 678                         # details.
 679                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 680                 endif()
 681         else()
 682                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 683         endif()
 684 else()
 685         if(LYX_USE_STD_REGEX)
 686                 set(Lyx_Boost_Libraries boost_signals)
 687         else()
 688                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 689         endif()
 690         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 691         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 692         include_directories(${TOP_SRC_DIR}/boost)
 693         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 694 endif()
 695
 696
 697
 698
 699 if(WIN32)
 700         if(LYX_CONSOLE)
 701         set(LYX_QTMAIN_LIBRARY)
 702     else()
 703                 set(WIN32_CONSOLE WIN32)
 704         endif()
 705         if(MSVC)
 706                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 707                 # disable checked iterators for msvc release builds to get maximum speed
 708                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 709         else()
 710                 add_definitions(-DWINVER=0x0500)
 711         endif()
 712 endif()
 713
 714 # Compute qt4-version from ${QTVERSION}
 715
 716 message(STATUS "")
 717 foreach(_v PACKAGE PACKAGE_VERSION
 718         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 719         LYX_ABS_TOP_SRCDIR
 720         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 721         if(NOT DEFINED ${_v})
 722                 message(FATAL_ERROR "${_v} not defined")
 723         endif()
 724         string(SUBSTRING "${_v}                            " 0 28 _v1)
 725         message(STATUS "----- ${_v1}: ${${_v}}")
 726 endforeach(_v)
 727 message(STATUS "")
 728
 729
 730 if(LYX_PCH)
 731         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 732         # Not sure if it works for all non-msvc compilers
 733         include(PCHSupport_26)
 734         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 735         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 736         add_definitions(-DLYX_ENABLE_PCH)
 737
 738         if(MSVC)
 739                 macro(lyx_add_msvc_pch name_)
 740                         set_source_files_properties(${${name_}_sources} PROPERTIES
 741                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 742                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 743                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 744                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 745                                 ${TOP_BINARY_DIR}/pcheaders.h)
 746                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 747                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 748                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 749                 endmacro(lyx_add_msvc_pch)
 750                 macro(lyx_add_gcc_pch name_)
 751                 endmacro()
 752         else()
 753                 macro(lyx_add_msvc_pch name_)
 754                 endmacro()
 755                 macro(lyx_add_gcc_pch name_)
 756                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 757                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 758                 endmacro()
 759         endif()
 760 else()
 761         macro(lyx_add_msvc_pch)
 762         endmacro(lyx_add_msvc_pch)
 763         macro(lyx_add_gcc_pch name_)
 764         endmacro()
 765 endif()
 766
 767
 768 if(MSVC)
 769
 770         if(LYX_VLD)
 771                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 772                 add_subdirectory(${vld_path}/cmake)
 773                 include(${vld_path}/cmake/vld.cmake) # forced include
 774                 set(vld_dll vld)
 775         endif()
 776
 777         if(LYX_WALL)
 778                 # Use the highest warning level
 779                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 780
 781                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 782                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 783                 else()
 784                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 785                 endif()
 786
 787                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 788                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 789                 else()
 790                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 791                 endif()
 792
 793                 # add here warnings which should produce an error /weXXXX
 794                 set(MSVC_W_ERROR   "/we4101 /we4189")
 795                 # add here warnings which should be disabled /wdXXXX
 796                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 797
 798                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 799                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 800                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 801
 802         else()
 803                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 804
 805                 # add here warnings which should produce an error /weXXXX
 806                 set(MSVC_W_ERROR   "/we4101 /we4189")
 807                 # add here warnings which should be disabled /wdXXXX
 808                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 809
 810                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 811                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 812                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 813
 814         endif()
 815
 816         if (NOT Qt5Core_FOUND)
 817                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 818                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 819                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 820         endif()
 821
 822         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 823         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 824         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 825         message(STATUS "")
 826 endif()
 827
 828
 829 if(LYX_DEBUG_GLIBC)
 830         set(_GLIBCXX_DEBUG ON)
 831 endif()
 832
 833 if(LYX_DEBUG_GLIBC_PEDANTIC)
 834         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 835 endif()
 836
 837 # Xcode compiler
 838 if (CMAKE_GENERATOR MATCHES Xcode)
 839         if (XCODE_VERSION VERSION_LESS "5.0")
 840                 # Automatically select the Xcode compiler if not set
 841                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 842                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 843                         if (XCODE_VERSION VERSION_GREATER "3.1")
 844                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 845                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 846                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 847                 # Print the selected compiler version
 848         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 849         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 850 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 851
 852 if (WIN32 AND Qt5Core_FOUND)
 853         set(Z_PREFIX 1)
 854 endif()
 855
 856 # compiler tests, config.h generation
 857 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 858         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 859 else()
 860         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 861         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 862 endif()
 863
 864 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 865
 866 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 867         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 868 endif()
 869
 870 if (NOT HAVE_REGEX)
 871         set(LYX_USE_STD_REGEX 0)
 872 endif()
 873
 874
 875 set (cmd ${CMAKE_CTEST_COMMAND})
 876 if (MSVC)
 877         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 878 else ()
 879         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 880 endif ()
 881 add_custom_target (lyx_run_tests COMMAND ${cmd})
 882 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 883
 884 if(LYX_ASAN)
 885     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 886     message(STATUS)
 887     message(STATUS "Address sanitizer enabled. Usage:")
 888     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 889     message(STATUS "    chmod  +x ./asan_symbolize.py")
 890     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 891     message(STATUS)
 892 endif()
 893
 894 if(LYX_INSTALL)
 895         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 896                 message(STATUS "Python required to create doc!")
 897         else()
 898                 if(UNIX)
 899                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 900                 endif()
 901                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 902         endif()
 903         include(../Install)
 904 endif()
 905
 906 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 907 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 908 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 909 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 910 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 911 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 912 if(LYX_ENABLE_URLTESTS)
 913         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 914 endif()
 915
 916 message(STATUS)
 917 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 918 message(STATUS)
 919
 920 LYX_OPTION_LIST_ALL(used)
 921
 922
 923 if(LYX_NLS)
 924         message(STATUS)
 925         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 926         message(STATUS)
 927         message(STATUS "  * iconv")
 928         message(STATUS "     - header : ${ICONV_HEADER}")
 929         message(STATUS "     - library: ${ICONV_LIBRARY}")
 930         message(STATUS "  * zlib")
 931         message(STATUS "     - header : ${ZLIB_HEADER}")
 932         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 933         message(STATUS)
 934 endif()
 935
 936 # Apple has builtin native spell checker,
 937 # no need to warn for missing Aspell, Hunspell or Enchant
 938 if(NOT Spelling_FOUND AND NOT APPLE)
 939   if(LYX_REQUIRE_SPELLCHECK)
 940     set(_mode "FATAL_ERROR")
 941   else()
 942     set(_mode "STATUS")
 943   endif()
 944   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 945 endif()
 946
 947 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 948
 949 if(ENABLE_DIST)
 950   # Use git to create the source package
 951   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 952   if(UNIX)
 953     set(DIST_FORMAT tgz)
 954   else()
 955     set(DIST_FORMAT zip)
 956   endif()
 957   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 958
 959   add_custom_command(
 960     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 961     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 962     WORKING_DIRECTORY ${TOP_SRC_DIR})
 963   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 964 endif()
 965
 966 # Last directory to be included so that the fixup code (OS X)
 967 # can be run last
 968 add_subdirectory(development/cmake/post_install)
 969
 970 message(STATUS)