CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 OLD)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84   # Enable LTO if supported
  85   if (POLICY CMP0069)
  86     cmake_policy(SET CMP0069 NEW)
  87     include(CheckIPOSupported)
  88     check_ipo_supported(RESULT result OUTPUT reason LANGUAGES CXX)
  89     if(result)
  90       message(STATUS "Setting IPO True")
  91       set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
  92     else()
  93       message(STATUS "Not setting IPO , result = ${result}, reason = ${reason}")
  94     endif()
  95   endif()
  96 endif()
  97
  98 if(UNIX)
  99         set(ARCH_TRIPLET )
 100         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
 101         if(DPKG_ARCHITECTURE_EXECUTABLE)
 102                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
 103                                 OUTPUT_VARIABLE ARCH_TRIPLET
 104                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
 105                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
 106         endif()
 107 endif()
 108 if(ARCH_TRIPLET)
 109         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 110 else()
 111         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 112 endif()
 113
 114 include(LyXMacros)
 115 include(LyXDestinations)
 116
 117 # Usage LYX_OPTION
 118 # 1. parameter: option name without prefix 'LYX_'
 119 # 2. parameter: description
 120 # 3. parameter: default value, ON or OFF
 121 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 122
 123 # Usage LYX_COMBO
 124 # 1. parameter: name without prefix 'LYX_'
 125 # 2. parameter: description
 126 # 3. parameter: default value
 127 # 4-n parameter: possible other string values
 128
 129 LYX_OPTION_INIT()
 130
 131 # Options for all compilers/systems
 132 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 133 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 134 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 135 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 136 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 137 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 138 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 139 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 140 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 141 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 142 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 143 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 144 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 145 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 146 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 147 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 148 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 149 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 150 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 151 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 152 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 153 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 154 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 155 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 156 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 157 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 158 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 159 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 160 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 161 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 162 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 163
 164 # GCC specific
 165 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 166 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 167 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 168 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 169 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 170 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 171 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 172
 173 # MSVC specific
 174 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 175 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 176 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 177 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 178
 179 # APPLE specific
 180 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 181 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 182
 183
 184 if(help OR HELP)
 185         message(STATUS)
 186         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 187         message(STATUS)
 188         LYX_OPTION_LIST_ALL(help)
 189         message(STATUS)
 190         RETURN()
 191 endif()
 192
 193 # Check option dependencies
 194
 195 if(LYX_DMG)
 196         set(LYX_BUNDLE ON)
 197         set(LYX_CPACK ON)
 198 endif()
 199
 200 if(LYX_CPACK)
 201         set(LYX_INSTALL ON)
 202 endif()
 203
 204 if(LYX_INSTALL)
 205         set(LYX_NLS ON)
 206         if(WIN32 AND NOT MINGW)
 207                 set(LYX_HUNSPELL ON)
 208         endif()
 209         set(LYX_PACKAGE_SUFFIX ON)
 210         if(NOT LYX_DEBUG)
 211                 set(LYX_RELEASE ON)
 212         endif()
 213         set(LYX_PROFILE OFF)
 214 endif()
 215
 216
 217 if(LYX_MERGE_FILES)
 218         set(LYX_PCH OFF)
 219 else()
 220         set(LYX_MERGE_REBUILD OFF)
 221 endif()
 222
 223 if(LYX_DEPENDENCIES_DOWNLOAD)
 224         message(STATUS)
 225         if(MSVC14)
 226                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 227                 set(deps_files lyx-windows-deps-msvc2015.zip)
 228                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 229                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 230         elseif(MSVC10)
 231                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 232                 set(deps_files lyx-windows-deps-msvc2010.zip)
 233                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 234                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 235         else()
 236                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 237         endif()
 238     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 239         foreach(it ${deps_files})
 240                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 241                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 242                 if(NOT already_downloaded)
 243                         message(STATUS "Downloading ${it} ...")
 244                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 245                         list(GET status 0 status_code)
 246                         list(GET status 1 status_string)
 247                         if(NOT status_code EQUAL 0)
 248                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 249                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 250                         endif()
 251                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 252                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 253                 endif()
 254         endforeach()
 255 endif()
 256
 257
 258
 259 message(STATUS)
 260
 261 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 262 if(WIN32)
 263         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 264 else()
 265         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 266 endif()
 267
 268
 269 # Set to some meaningful default
 270 find_package(CXX11Compiler)
 271 if(NOT CXX11COMPILER_FOUND)
 272         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 273 endif()
 274 set(LYX_GCC11_MODE)
 275 if(UNIX OR MINGW)
 276         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 277           # ignore the GCC_VERSION for clang
 278           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 279           message(STATUS "Using clang")
 280           if(CXX11_STD_REGEX)
 281             set(LYX_USE_STD_REGEX 1)
 282           else()
 283             set(LYX_USE_STD_REGEX 0)
 284           endif()
 285         else()
 286           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 287           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 288           if (_err)
 289             # previous check failed, try again with _old_ parameter
 290             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 291             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 292           endif()
 293           message(STATUS "Using GCC version ${GCC_VERSION}")
 294           if(GCC_VERSION VERSION_LESS 4.6)
 295                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 296           elseif(GCC_VERSION VERSION_LESS 4.9)
 297                 # <regex> in gcc is unusable in versions less than 4.9.0
 298                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 299                 set(LYX_USE_STD_REGEX 0)
 300           else()
 301                 set(LYX_USE_STD_REGEX 1)
 302           endif()
 303         endif()
 304         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 305 else()
 306         if(MSVC_VERSION LESS 1900)
 307                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 308                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 309                 set(LYX_USE_STD_REGEX 0)
 310         else()
 311                 set(LYX_USE_STD_REGEX 1)
 312         endif()
 313 endif()
 314
 315
 316 set(VERSION_INFO "CMake Build")
 317
 318 # Try to get some informations from configure.ac
 319
 320 include(LyXPaths)
 321 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 322
 323 if(WIN32)
 324         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 325         if(MSVC)
 326                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 327         endif()
 328         set(USE_WINDOWS_PACKAGING ON)
 329 elseif(APPLE)
 330         set(USE_MACOSX_PACKAGING ON)
 331 else()
 332         set(USE_POSIX_PACKAGING ON)
 333 endif()
 334
 335 if(LYX_3RDPARTY_BUILD)
 336   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 337   # this enables the build of all 3rd_party libs
 338   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 339   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 340   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 341   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 342 endif()
 343
 344 macro(setstripped _varname)
 345         if(${ARGC} GREATER 1)
 346                 string(STRIP "${ARGV1}" _v)
 347                 if (_v MATCHES "^\\[\(.+\)\\]$")
 348                   set(_v ${CMAKE_MATCH_1})
 349                 endif()
 350                 if(USE_POSIX_PACKAGING)
 351                         string(TOLOWER ${_v} ${_varname})
 352                 else()
 353                         set(${_varname} ${_v})
 354                 endif()
 355         else()
 356                 set(${_varname})
 357         endif()
 358 endmacro(setstripped)
 359
 360 foreach(_c_l ${_config_lines} )
 361         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 362                 # Not using CMAKE_MATCH_ directly is needed, because
 363                 # its value is now changed inside macro setstripped
 364                 set(_PB ${CMAKE_MATCH_1})
 365                 set(_PV ${CMAKE_MATCH_2})
 366                 set(_PBU ${CMAKE_MATCH_3})
 367                 setstripped(PACKAGE_BASE ${_PB})
 368                 setstripped(PACKAGE_VERSION ${_PV})
 369                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 370                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 371                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 372                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 373                         set(LYX_RELEASE_VERSION ${CMAKE_MATCH_4})
 374                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 375                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 376                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 377                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 378                         else()
 379                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 380                         endif()
 381                 endif()
 382         endif()
 383         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 384                 set(LYX_DATE "${CMAKE_MATCH_1}")
 385         endif()
 386 endforeach(_c_l)
 387
 388 FIND_PROGRAM(LYX_GITVERSION git)
 389 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 390 set(LYX_REVISION_VERSION ${LYX_RELEASE_VERSION})
 391 set(LYX_PACKAGE_RELEASE "1")
 392 if(LYX_GITVERSION)
 393   if (LYX_LOCALVERSIONING)
 394     # Find the revision number and for later use
 395     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 396       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 397     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 398       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 399       # We will add offset of 40000 to get appropriate value to
 400       # previous svn.
 401       # We use this value than also to set the package-patch-value
 402       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 403       set(LYX_REVISION_VERSION "${LYX_RELEASE_VERSION}-${tmp_REVISION_VERSION}git")
 404       set(ENABLE_DIST ON)
 405     endif()
 406   endif()
 407 endif()
 408
 409 # Set the programs (lyx, tex2lyx, etc.) suffix
 410 # When building an OS X bundle, we will append
 411 # the suffix only to the bundle, not to the programs
 412 set(PROGRAM_SUFFIX "")
 413 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 414         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 415 endif()
 416 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 417 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 418 set(_convert lyxconvert${PROGRAM_SUFFIX})
 419
 420 add_custom_target(lyx_version ALL
 421   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 422   )
 423 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 424
 425 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 426 set(LYX_UTILITIES_INSTALL_PATH bin)
 427
 428 if(LYX_BUNDLE)
 429         set(LYX_CPACK ON)
 430
 431         message(STATUS)
 432         message(STATUS "Bundle creation is enabled (experimental):")
 433         message(STATUS "    make")
 434         message(STATUS "    make install/strip")
 435         message(STATUS "    make package")
 436         if(APPLE)
 437                 set(MACOSX_BUNDLE TRUE)
 438                 # This sets the bundle + executable names
 439                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 440                 # This sets the Info.plist executable name
 441                 set(osx_bundle_program_name ${_lyx})
 442                 # Bundle name
 443                 set(LYX_BUNDLE_NAME ${_lyx})
 444
 445                 # This will contain the list of files that need to be included
 446                 # in the bundle and their location within the bundle
 447                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 448                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 449
 450                 # Process Info.plist and lyxrc.dist
 451                 # See development/cmake/Install.cmake
 452                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 453
 454                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 455                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 456
 457                 # Variables used by CPack
 458                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 459                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 460                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 461
 462                 # Set the install paths
 463                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 464                 if(NOT LYX_INSTALL_PREFIX)
 465                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 466                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 467                 endif()
 468                 # Change the owner so that the install can work
 469                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 470         elseif(UNIX)
 471                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 472                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 473                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 474         elseif(WIN32)
 475                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 476         endif()
 477 endif()
 478
 479 if(LYX_INSTALL_PREFIX)
 480         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 481         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 482 endif()
 483 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 484
 485 if(UNIX)
 486   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 487 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 488   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 489 else()
 490   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 491 endif()
 492
 493 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 494   # Not a GCC compiler, programs do not have a suffix
 495   set(suffixing ${LYX_PACKAGE_SUFFIX})
 496 elseif(WIN32 AND MINGW)
 497   # We want to use a suffix for the package in this case,
 498   # even if not for the program
 499   set(suffixing ${LYX_PACKAGE_SUFFIX})
 500 else()
 501   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 502   set(suffixing ${LYX_PROGRAM_SUFFIX})
 503 endif()
 504
 505 # The define PACKAGE below allows lyx-executable to find its default configuration files
 506 # see routines
 507 #    Package::messages_file()
 508 #    get_default_user_support_dir()
 509 #    relative_system_support_dir()
 510 # in src/support/Package.cpp
 511 if(suffixing)
 512         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 513 else()
 514         set(PACKAGE ${PACKAGE_BASE})
 515 endif()
 516
 517 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 518         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 519         if (UNIX)
 520                 # use the default "/usr/local"
 521                 # but respect the user-choice on the command-line
 522                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 523         endif()
 524 endif()
 525 if(WIN32)
 526         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 527 endif()
 528 if(IS_ABSOLUTE)
 529         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 530 else()
 531         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 532 endif()
 533
 534
 535
 536 if(NOT LYX_DATA_SUBDIR)
 537         if (WIN32)
 538                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 539         else()
 540                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 541         endif()
 542 endif()
 543
 544 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 545 get_locale_destination(LYX_LOCALEDIR)
 546 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 547 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 548
 549 if(LYX_BUNDLE AND APPLE)
 550         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 551 else()
 552         if(WIN32)
 553                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 554         elseif(UNIX)
 555                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 556         else()
 557                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 558         endif()
 559 endif()
 560 mark_as_advanced(LYX_MAN_DIR)
 561
 562 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 563 # see the Readme.txt of the installer
 564 #if(LYX_INSTALL AND WIN32)
 565 #       message(STATUS "Configuring NSIS files")
 566 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 567 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 568 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 569 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 570 #endif()
 571
 572 if(NOT GROUP_CODE)
 573         #set(GROUP_CODE "The Golden Code")
 574         set(GROUP_CODE flat)
 575 endif()
 576
 577 # lyx's source files
 578 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 579 set(LYX_HPP_FILES [a-zA-Z]*.h)
 580 set(LYX_MOC_FILES moc_*.cpp)
 581
 582 include(ProjectSourceGroup)
 583
 584
 585 if(LYX_PROFILE AND NOT MSVC)
 586         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 587         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 588         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 589 else()
 590         set(LYX_PROFILE OFF)
 591 endif()
 592
 593
 594 if(LYX_NO_OPTIMIZE)
 595         set(CMAKE_BUILD_TYPE None)
 596         set(LYX_DEBUG OFF)
 597         set(LYX_RELEASE OFF)
 598         set(LYX_PROFILE OFF)
 599 elseif(LYX_RELEASE)
 600         set(CMAKE_BUILD_TYPE Release)
 601         set(LYX_DEBUG OFF)
 602         set(LYX_PROFILE OFF)
 603 elseif(LYX_PROFILE)
 604         set(CMAKE_BUILD_TYPE Profile)
 605         set(LYX_DEBUG OFF)
 606 else()
 607         set(CMAKE_BUILD_TYPE Debug)
 608         set(LYX_DEBUG ON)
 609 endif()
 610
 611
 612 # When shared libs are supported enable this option
 613 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 614 if(LYX_SHARED_LIBRARIES)
 615         set(library_type SHARED)
 616 else()
 617         set(library_type STATIC)
 618 endif()
 619
 620 if(NOT MSVC)
 621         if(NOT LYX_QUIET)
 622                 set(CMAKE_VERBOSE_MAKEFILE ON)
 623         endif()
 624         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 625         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 626           # Thanks to Brad King <brad.king@kitware.com>
 627           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 628           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 629           # and still use our own c++ extension tests
 630           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 631           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 632         endif()
 633         if(LYX_STDLIB_DEBUG)
 634                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 635         endif()
 636         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 637         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 638         if(MINGW)
 639                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 640         else()
 641                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 642         endif()
 643 endif()
 644
 645 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 646 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 647 if(LYX_CXX_FLAGS_EXTRA)
 648         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 649                 add_definitions(${_flag})
 650         endforeach()
 651 endif()
 652
 653 if(LYX_XMINGW)
 654         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 655 endif()
 656
 657 set(min_qt5_version "5.6")
 658 if(LYX_USE_QT MATCHES "AUTO")
 659         # try qt5 first
 660         find_package(Qt5Core CONFIG QUIET)
 661         if(Qt5Core_FOUND)
 662                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 663                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 664                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 665                         find_package(Qt4 "4.5.0" QUIET)
 666                         if(QT4_FOUND)
 667                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 668                         endif()
 669                 endif()
 670         else()
 671                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 672         endif()
 673 endif()
 674 if(LYX_USE_QT MATCHES "QT5")
 675         # set QPA_XCB if QT uses X11
 676         find_package(Qt5Core CONFIG REQUIRED)
 677         if (Qt5Core_FOUND)
 678                 find_package(Qt5Widgets CONFIG REQUIRED)
 679                 if(APPLE)
 680                         find_package(Qt5MacExtras CONFIG REQUIRED)
 681                 endif()
 682                 find_package(Qt5X11Extras CONFIG QUIET)
 683                 find_package(Qt5WinExtras CONFIG QUIET)
 684                 set(QTVERSION ${Qt5Core_VERSION})
 685                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 686                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 687                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 688                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 689                         # see thread in lyx-devel list
 690                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 691                         # Date 11.03.2017
 692                         # Subject: cmake compilation error
 693                         #message(FATAL_ERROR "Wrong Qt-Version")
 694                 endif()
 695                 macro (qt_use_modules lyxtarget)
 696                         foreach (_tg ${ARGN})
 697                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 698                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 699                         endforeach()
 700                 endmacro()
 701                 macro (qt_add_resources)
 702                         qt5_add_resources(${ARGN})
 703                 endmacro()
 704                 macro (qt_wrap_uifiles)
 705                         qt5_wrap_ui(${ARGN})
 706                 endmacro()
 707                 message(STATUS "Found Qt-Version ${QTVERSION}")
 708                 if(WIN32)
 709                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 710                 endif()
 711         endif()
 712 elseif(LYX_USE_QT MATCHES "QT4")
 713         if(LYX_XMINGW)
 714                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 715                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 716         endif()
 717         find_package(Qt4 "4.5.0" REQUIRED)
 718         macro (qt_use_modules)
 719         endmacro()
 720         macro (qt_add_resources)
 721                 qt4_add_resources(${ARGN})
 722         endmacro()
 723         macro (qt_wrap_uifiles)
 724                 qt4_wrap_ui(${ARGN})
 725         endmacro()
 726         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 727         if(WIN32)
 728                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 729         endif()
 730 else()
 731   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 732 endif()
 733
 734 find_package(Magic)
 735 if(Magic_FOUND)
 736   set(HAVE_MAGIC_H 1)
 737   include_directories(${Magic_INCLUDE_DIR})
 738 endif()
 739
 740 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 741
 742 set(Spelling_FOUND OFF)
 743 set(Include_used_spellchecker)   # String will be inserted into config.h
 744
 745 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 746   # try system library first
 747   find_package(MyThesLIB)
 748   if (MYTHESLIB_FOUND)
 749     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 750   else()
 751     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 752   endif()
 753 endif()
 754 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 755   find_package(MyThesLIB REQUIRED)
 756 else()
 757   add_subdirectory(3rdparty/mythes)
 758 endif()
 759 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 760
 761 if(NOT LYX_EXTERNAL_HUNSPELL)
 762     add_subdirectory(3rdparty/hunspell)
 763     add_definitions(-DHUNSPELL_STATIC)
 764     set(HUNSPELL_FOUND ON)
 765     message(STATUS "  * Hunspell:")
 766     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 767     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 768 endif()
 769
 770 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 771   string(TOUPPER ${_spell} _upspell)
 772   if (NOT ${_upspell}_FOUND)
 773     find_package(${_spell})
 774   endif()
 775   if (${_upspell}_FOUND)
 776     include_directories(${${_upspell}_INCLUDE_DIR})
 777     set(Spelling_FOUND ON)
 778     message(STATUS "Building with USE_${_upspell}")
 779     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 780   else()
 781     if(LYX_${_upspell})
 782       message(FATAL_ERROR "Required ${_spell} devel package not found")
 783     else()
 784       message(STATUS "${_upspell} not found, building without ${_spell} support")
 785     endif()
 786   endif()
 787 endforeach()
 788
 789 if(GNUWIN32_DIR)
 790         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 791 endif()
 792
 793 # Search for python default version first
 794 unset(PYTHON_EXECUTABLE CACHE)
 795 unset(LYX_PYTHON_EXECUTABLE CACHE)
 796 unset(PYTHON_VERSION_MAJOR)
 797 unset(PYTHON_VERSION_MINOR)
 798 unset(PYTHON_VERSION_STRING)
 799 find_package(PythonInterp 3.5 QUIET)
 800 if(NOT PYTHONINTERP_FOUND)
 801   unset(PYTHON_EXECUTABLE CACHE)
 802   find_package(PythonInterp 2.0 REQUIRED)
 803   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 804     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 805   endif()
 806 endif()
 807
 808 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 809
 810 if(LYX_NLS)
 811         find_package(LyXGettext)
 812         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 813                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 814         else()
 815                 # Install only supplied .gmo-files
 816                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 817                 message(STATUS "Installing provided .gmo-files only")
 818                 foreach( _gmo ${_gmofiles})
 819                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 820                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 821                 endforeach()
 822         endif()
 823 endif()
 824
 825 if(LYX_EXTERNAL_ICONV)
 826   find_package(ICONV REQUIRED)
 827 else()
 828   add_subdirectory(3rdparty/libiconv)
 829   set(HAVE_ICONV_CONST 1)
 830 endif()
 831
 832 if(LYX_EXTERNAL_Z)
 833   find_package(ZLIB REQUIRED)
 834 else()
 835   add_subdirectory(3rdparty/zlib)
 836 endif()
 837
 838 if(LYX_USE_STD_REGEX)
 839   # Set only include path.
 840   # Use internal boost, which is known to exist
 841   # we don't need any libraries
 842   set(Lyx_Boost_Libraries)
 843   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 844   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 845 else()
 846   # Using boost-regex
 847   if(LYX_EXTERNAL_BOOST)
 848     message(STATUS "Searching for external boost")
 849     find_package(Boost COMPONENTS regex)
 850     if(Boost_FOUND)
 851       message(STATUS "Boost found")
 852       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 853       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 854       if (LYX_STDLIB_DEBUG)
 855         # Comment from  Jean-Marc Lasgouttes:
 856         # In general, system boost libraries are incompatible with
 857         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 858         # details.
 859         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 860       endif()
 861     else()
 862       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 863     endif()
 864   else()
 865     # Using included boost
 866     set(Lyx_Boost_Libraries boost_regex)
 867     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 868     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 869     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 870   endif()
 871 endif()
 872
 873 if(WIN32)
 874         if(LYX_CONSOLE)
 875                 set(LYX_QTMAIN_LIBRARY)
 876         else()
 877                 set(WIN32_CONSOLE WIN32)
 878         endif()
 879         if(MSVC)
 880                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 881                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 882                 # disable checked iterators for msvc release builds to get maximum speed
 883                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 884         else()
 885                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 886                 # does not use it and always declares the vista compatible API.
 887                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 888                 add_definitions(-DWINVER=0x0500)
 889         endif()
 890 endif()
 891
 892 # Compute qt-version from ${QTVERSION}
 893
 894 message(STATUS "")
 895 foreach(_v PACKAGE PACKAGE_VERSION
 896         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 897         LYX_ABS_TOP_SRCDIR
 898         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 899         if(NOT DEFINED ${_v})
 900                 message(FATAL_ERROR "${_v} not defined")
 901         endif()
 902         string(SUBSTRING "${_v}                            " 0 28 _v1)
 903         message(STATUS "----- ${_v1}: ${${_v}}")
 904 endforeach(_v)
 905 message(STATUS "")
 906
 907
 908 if(LYX_PCH)
 909         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 910         # Not sure if it works for all non-msvc compilers
 911         include(PCHSupport_26)
 912         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 913         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 914         add_definitions(-DLYX_ENABLE_PCH)
 915
 916         if(MSVC)
 917                 macro(lyx_add_msvc_pch name_)
 918                         set_source_files_properties(${${name_}_sources} PROPERTIES
 919                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 920                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 921                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 922                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 923                                 ${TOP_BINARY_DIR}/pcheaders.h)
 924                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 925                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 926                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 927                 endmacro(lyx_add_msvc_pch)
 928                 macro(lyx_add_gcc_pch name_)
 929                 endmacro()
 930         else()
 931                 macro(lyx_add_msvc_pch name_)
 932                 endmacro()
 933                 macro(lyx_add_gcc_pch name_)
 934                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 935                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 936                 endmacro()
 937         endif()
 938 else()
 939         macro(lyx_add_msvc_pch)
 940         endmacro(lyx_add_msvc_pch)
 941         macro(lyx_add_gcc_pch name_)
 942         endmacro()
 943 endif()
 944
 945
 946 if(MSVC)
 947
 948         if(LYX_VLD)
 949                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 950                 add_subdirectory(${vld_path}/cmake)
 951                 include(${vld_path}/cmake/vld.cmake) # forced include
 952                 set(vld_dll vld)
 953         endif()
 954
 955         if(LYX_WALL)
 956                 # Use the highest warning level
 957                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
 958
 959                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 960                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 961                 else()
 962                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 963                 endif()
 964
 965                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 966                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 967                 else()
 968                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 969                 endif()
 970
 971                 # add here warnings which should produce an error /weXXXX
 972                 set(MSVC_W_ERROR   "/we4101 /we4189")
 973                 # add here warnings which should be disabled /wdXXXX
 974                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 975
 976                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 977                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 978                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 979
 980         else()
 981                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
 982
 983                 # add here warnings which should produce an error /weXXXX
 984                 set(MSVC_W_ERROR   "/we4101 /we4189")
 985                 # add here warnings which should be disabled /wdXXXX
 986                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 987
 988                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 989                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 990                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 991
 992         endif()
 993
 994         if (NOT Qt5Core_FOUND)
 995                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 996                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 997                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 998         endif()
 999
1000         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1001         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1002         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1003         message(STATUS "")
1004 endif()
1005
1006
1007 if(LYX_DEBUG_GLIBC)
1008         set(_GLIBCXX_DEBUG ON)
1009 endif()
1010
1011 if(LYX_DEBUG_GLIBC_PEDANTIC)
1012         set(_GLIBCXX_DEBUG_PEDANTIC ON)
1013 endif()
1014
1015 # Xcode compiler
1016 if (CMAKE_GENERATOR MATCHES Xcode)
1017         if (XCODE_VERSION VERSION_LESS "5.0")
1018                 # Automatically select the Xcode compiler if not set
1019                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1020                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1021                         if (XCODE_VERSION VERSION_GREATER "3.1")
1022                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1023                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1024                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1025                 # Print the selected compiler version
1026         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1027         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1028 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1029
1030 if (WIN32 AND Qt5Core_FOUND)
1031         set(Z_PREFIX 1)
1032 endif()
1033
1034 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1035 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1036 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1037
1038 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1039
1040 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1041         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1042 endif()
1043
1044 if (NOT HAVE_REGEX)
1045         set(LYX_USE_STD_REGEX 0)
1046 endif()
1047
1048
1049 set (cmd ${CMAKE_CTEST_COMMAND})
1050 if (MSVC)
1051         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1052 else ()
1053         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1054 endif ()
1055 add_custom_target (lyx_run_tests COMMAND ${cmd})
1056 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1057
1058 if(LYX_ASAN)
1059     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1060     message(STATUS)
1061     message(STATUS "Address sanitizer enabled. Usage:")
1062     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1063     message(STATUS "    chmod  +x ./asan_symbolize.py")
1064     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1065     message(STATUS)
1066 endif()
1067
1068 if(LYX_INSTALL)
1069         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1070                 message(STATUS "Python required to create doc!")
1071         else()
1072                 if(UNIX)
1073                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1074                 endif()
1075                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1076         endif()
1077 endif()
1078 include(../Install)
1079
1080 # By running the URL tests first, time can be saved when running the ctests in
1081 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1082 if(LYX_ENABLE_URLTESTS)
1083         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1084 endif()
1085 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1086 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1087 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1088 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1089 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1090 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1091 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1092
1093 message(STATUS)
1094 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1095 message(STATUS)
1096
1097 LYX_OPTION_LIST_ALL(used)
1098
1099
1100 if(LYX_NLS)
1101         message(STATUS)
1102         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1103         message(STATUS)
1104         message(STATUS "  * iconv")
1105         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1106         message(STATUS "     - library: ${ICONV_LIBRARY}")
1107         message(STATUS "  * zlib")
1108         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1109         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1110         message(STATUS)
1111 endif()
1112
1113 # Apple has builtin native spell checker,
1114 # no need to warn for missing Aspell, Hunspell or Enchant
1115 if(NOT Spelling_FOUND AND NOT APPLE)
1116   if(LYX_REQUIRE_SPELLCHECK)
1117     set(_mode "FATAL_ERROR")
1118   else()
1119     set(_mode "STATUS")
1120   endif()
1121   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1122 endif()
1123
1124 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1125
1126 if(ENABLE_DIST)
1127   # Use git to create the source package
1128   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1129   if(UNIX)
1130     set(DIST_FORMAT tgz)
1131   else()
1132     set(DIST_FORMAT zip)
1133   endif()
1134   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1135
1136   add_custom_command(
1137     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1138     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1139     WORKING_DIRECTORY ${TOP_SRC_DIR})
1140   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1141 endif()
1142
1143 # Last directory to be included so that the fixup code (OS X)
1144 # can be run last
1145 add_subdirectory(development/cmake/post_install)
1146
1147 message(STATUS)