CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 133 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 134 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 135 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 136 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 137 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 138 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 139 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 140 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 141 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 142 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 143 LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 144 else()
 145 unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 146 endif()
 147 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 148 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 149 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 150 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 151 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 152 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 153 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 154 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ON ALL)
 155 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 156 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 157 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 158
 159 # GCC specific
 160 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 161 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 162 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 163 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 164 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 165 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 166
 167 # MSVC specific
 168 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 169 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 170 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 171 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 172
 173 # APPLE specific
 174 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 175 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 176
 177
 178 if(help OR HELP)
 179         message(STATUS)
 180         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 181         message(STATUS)
 182         LYX_OPTION_LIST_ALL(help)
 183         message(STATUS)
 184         RETURN()
 185 endif()
 186
 187 # Check option dependencies
 188 if (LYX_ENABLE_VALGRIND_TESTS)
 189         find_program(VALGRIND_EXECUTABLE "valgrind")
 190         if (NOT VALGRIND_EXECUTABLE)
 191                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 192         endif()
 193 endif()
 194
 195 if(LYX_DMG)
 196         set(LYX_BUNDLE ON)
 197         set(LYX_CPACK ON)
 198 endif()
 199
 200 if(LYX_CPACK)
 201         set(LYX_INSTALL ON)
 202 endif()
 203
 204 if(LYX_INSTALL)
 205         set(LYX_NLS ON)
 206         if(WIN32 AND NOT MINGW)
 207                 set(LYX_HUNSPELL ON)
 208         endif()
 209         set(LYX_PACKAGE_SUFFIX ON)
 210         if(NOT LYX_DEBUG)
 211                 set(LYX_RELEASE ON)
 212         endif()
 213         set(LYX_PROFILE OFF)
 214 endif()
 215
 216
 217 if(LYX_MERGE_FILES)
 218         set(LYX_PCH OFF)
 219 else()
 220         set(LYX_MERGE_REBUILD OFF)
 221 endif()
 222
 223 if(LYX_DEPENDENCIES_DOWNLOAD)
 224         message(STATUS)
 225         if(MSVC14)
 226                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 227                 set(deps_files lyx-windows-deps-msvc2015.zip)
 228                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 229                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 230         elseif(MSVC10)
 231                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 232                 set(deps_files lyx-windows-deps-msvc2010.zip)
 233                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 234                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 235         else()
 236                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 237         endif()
 238     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 239         foreach(it ${deps_files})
 240                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 241                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 242                 if(NOT already_downloaded)
 243                         message(STATUS "Downloading ${it} ...")
 244                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 245                         list(GET status 0 status_code)
 246                         list(GET status 1 status_string)
 247                         if(NOT status_code EQUAL 0)
 248                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 249                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 250                         endif()
 251                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 252                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 253                 endif()
 254         endforeach()
 255 endif()
 256
 257 message(STATUS)
 258
 259 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 260 if(WIN32)
 261         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 262 else()
 263         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 264 endif()
 265
 266 set(LYX_IPO_SUPPORTED OFF)
 267 if (POLICY CMP0069)
 268   cmake_policy(SET CMP0069 NEW)
 269   if(LYX_USE_IPO MATCHES "AUTO")
 270     # Enable LTO if supported and not debugging
 271     if (NOT LYX_DEBUG)
 272       include(CheckIPOSupported)
 273       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 274     endif()
 275   else()
 276     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 277   endif()
 278 endif()
 279 if (LYX_IPO_SUPPORTED)
 280   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 281 else()
 282   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 283 endif()
 284
 285 # Set to some meaningful default
 286 find_package(CXX11Compiler)
 287 if(NOT CXX11COMPILER_FOUND)
 288         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 289 endif()
 290 unset(LYX_GCC11_MODE)
 291 if(UNIX OR MINGW)
 292         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 293           # ignore the GCC_VERSION for clang
 294           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 295           message(STATUS "Using clang")
 296           if(CXX11_STD_REGEX)
 297             set(LYX_USE_STD_REGEX 1)
 298           else()
 299             set(LYX_USE_STD_REGEX 0)
 300           endif()
 301         else()
 302           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 303           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 304           if (_err)
 305             # previous check failed, try again with _old_ parameter
 306             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 307             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 308           endif()
 309           message(STATUS "Using GCC version ${GCC_VERSION}")
 310           if(GCC_VERSION VERSION_LESS 4.6)
 311                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 312           elseif(GCC_VERSION VERSION_LESS 4.9)
 313                 # <regex> in gcc is unusable in versions less than 4.9.0
 314                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 315                 set(LYX_USE_STD_REGEX 0)
 316           else()
 317                 set(LYX_USE_STD_REGEX 1)
 318           endif()
 319         endif()
 320         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 321 else()
 322         if(MSVC_VERSION LESS 1900)
 323                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 324                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 325                 set(LYX_USE_STD_REGEX 0)
 326         else()
 327                 set(LYX_USE_STD_REGEX 1)
 328         endif()
 329 endif()
 330
 331
 332 # Try to get some informations from configure.ac
 333
 334 include(LyXPaths)
 335 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 336
 337 if(WIN32)
 338         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 339         if(MSVC)
 340                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 341         endif()
 342         set(USE_WINDOWS_PACKAGING ON)
 343 elseif(APPLE)
 344         set(USE_MACOSX_PACKAGING ON)
 345 else()
 346         set(USE_POSIX_PACKAGING ON)
 347 endif()
 348
 349 if(LYX_3RDPARTY_BUILD)
 350   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 351   # this enables the build of all 3rd_party libs
 352   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 353   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 354   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 355   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 356 endif()
 357
 358 macro(setstripped _varname)
 359         if(${ARGC} GREATER 1)
 360                 string(STRIP "${ARGV1}" _v)
 361                 if (_v MATCHES "^\\[\(.+\)\\]$")
 362                   set(_v ${CMAKE_MATCH_1})
 363                 endif()
 364                 if(USE_POSIX_PACKAGING)
 365                         string(TOLOWER ${_v} ${_varname})
 366                 else()
 367                         set(${_varname} ${_v})
 368                 endif()
 369         else()
 370                 set(${_varname})
 371         endif()
 372 endmacro(setstripped)
 373
 374 foreach(_c_l ${_config_lines} )
 375         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 376                 # Not using CMAKE_MATCH_ directly is needed, because
 377                 # its value is now changed inside macro setstripped
 378                 set(_PB ${CMAKE_MATCH_1})
 379                 set(_PV ${CMAKE_MATCH_2})
 380                 set(_PBU ${CMAKE_MATCH_3})
 381                 setstripped(PACKAGE_BASE ${_PB})
 382                 setstripped(PACKAGE_VERSION ${_PV})
 383                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 384                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\(\\.\([0-9]+\)\)?\)?.*$")
 385                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 386                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 387                         set(LYX_RELEASE_LEVEL ${CMAKE_MATCH_4})
 388                         set(LYX_RELEASE_PATCH ${CMAKE_MATCH_6})
 389                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 390                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 391                         if (NOT LYX_RELEASE_LEVEL)
 392                                 set(LYX_RELEASE_LEVEL 0)
 393                         endif()
 394                         if (NOT LYX_RELEASE_PATCH)
 395                                 set(LYX_RELEASE_PATCH 0)
 396                         endif()
 397                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 398                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 399                         else()
 400                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 401                         endif()
 402                 endif()
 403         endif()
 404         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 405                 set(LYX_DATE "${CMAKE_MATCH_1}")
 406         endif()
 407 endforeach(_c_l)
 408 unset(_config_lines)
 409
 410 FIND_PROGRAM(LYX_GITVERSION git)
 411 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 412 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 413 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 414 if(LYX_GITVERSION)
 415   if (LYX_LOCALVERSIONING)
 416     # Find the revision number for later use
 417     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 418       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 419       RESULT_VARIABLE tmp_GIT_RESULT
 420       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 421       ERROR_VARIABLE tmp_GIT_ERROR
 422       OUTPUT_STRIP_TRAILING_WHITESPACE)
 423     if (tmp_GIT_RESULT EQUAL 0)
 424       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 425         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 426         # We will add offset of 40000 to get appropriate value to
 427         # previous svn.
 428         # We use this value than also to set the package-patch-value
 429         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 430         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 431         set(ENABLE_DIST ON)
 432       endif()
 433     endif()
 434   endif()
 435 endif()
 436 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 437   set(LYX_PACKAGE_RELEASE  "1")
 438   if (LYX_RELEASE_PATCH GREATER 0)
 439     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 440   endif()
 441 endif()
 442
 443 # Set the programs (lyx, tex2lyx, etc.) suffix
 444 # When building an OS X bundle, we will append
 445 # the suffix only to the bundle, not to the programs
 446 set(PROGRAM_SUFFIX "")
 447 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 448         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 449 endif()
 450 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 451 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 452 set(_convert lyxconvert${PROGRAM_SUFFIX})
 453
 454 add_custom_target(lyx_version ALL
 455   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 456   )
 457 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 458
 459 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 460 set(LYX_UTILITIES_INSTALL_PATH bin)
 461
 462 if(LYX_BUNDLE)
 463         set(LYX_CPACK ON)
 464
 465         message(STATUS)
 466         message(STATUS "Bundle creation is enabled (experimental):")
 467         message(STATUS "    make")
 468         message(STATUS "    make install/strip")
 469         message(STATUS "    make package")
 470         if(APPLE)
 471                 set(MACOSX_BUNDLE TRUE)
 472                 # This sets the bundle + executable names
 473                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 474                 # This sets the Info.plist executable name
 475                 set(osx_bundle_program_name ${_lyx})
 476                 # Bundle name
 477                 set(LYX_BUNDLE_NAME ${_lyx})
 478
 479                 # This will contain the list of files that need to be included
 480                 # in the bundle and their location within the bundle
 481                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 482                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 483
 484                 # Process Info.plist and lyxrc.dist
 485                 # See development/cmake/Install.cmake
 486                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 487
 488                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 489                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 490
 491                 # Variables used by CPack
 492                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 493                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 494                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 495
 496                 # Set the install paths
 497                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 498                 if(NOT LYX_INSTALL_PREFIX)
 499                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 500                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 501                 endif()
 502                 # Change the owner so that the install can work
 503                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 504         elseif(UNIX)
 505                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 506                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 507                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 508         elseif(WIN32)
 509                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 510         endif()
 511 endif()
 512
 513 if(LYX_INSTALL_PREFIX)
 514         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 515         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 516 endif()
 517 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 518
 519 if(UNIX)
 520   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 521 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 522   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 523 else()
 524   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 525 endif()
 526
 527 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 528   # Not a GCC compiler, programs do not have a suffix
 529   set(suffixing ${LYX_PACKAGE_SUFFIX})
 530 elseif(WIN32 AND MINGW)
 531   # We want to use a suffix for the package in this case,
 532   # even if not for the program
 533   set(suffixing ${LYX_PACKAGE_SUFFIX})
 534 else()
 535   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 536   set(suffixing ${LYX_PROGRAM_SUFFIX})
 537 endif()
 538
 539 # The define PACKAGE below allows lyx-executable to find its default configuration files
 540 # see routines
 541 #    Package::messages_file()
 542 #    get_default_user_support_dir()
 543 #    relative_system_support_dir()
 544 # in src/support/Package.cpp
 545 if(suffixing)
 546         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 547 else()
 548         set(PACKAGE ${PACKAGE_BASE})
 549 endif()
 550
 551 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 552         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 553         if (UNIX)
 554                 # use the default "/usr/local"
 555                 # but respect the user-choice on the command-line
 556                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 557         endif()
 558 endif()
 559 if(WIN32)
 560         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 561 endif()
 562 if(IS_ABSOLUTE)
 563         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 564 else()
 565         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 566 endif()
 567
 568
 569
 570 if(NOT LYX_DATA_SUBDIR)
 571         if (WIN32)
 572                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 573         else()
 574                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 575         endif()
 576 endif()
 577
 578 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 579 get_locale_destination(LYX_LOCALEDIR)
 580 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 581 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 582
 583 if(LYX_BUNDLE AND APPLE)
 584         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 585 else()
 586         if(WIN32)
 587                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 588         elseif(UNIX)
 589                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 590         else()
 591                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 592         endif()
 593 endif()
 594 mark_as_advanced(LYX_MAN_DIR)
 595
 596 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 597 # see the Readme.txt of the installer
 598 #if(LYX_INSTALL AND WIN32)
 599 #       message(STATUS "Configuring NSIS files")
 600 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 601 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 602 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 603 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 604 #endif()
 605
 606 if(NOT GROUP_CODE)
 607         #set(GROUP_CODE "The Golden Code")
 608         set(GROUP_CODE flat)
 609 endif()
 610
 611 # lyx's source files
 612 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 613 set(LYX_HPP_FILES [a-zA-Z]*.h)
 614 set(LYX_MOC_FILES moc_*.cpp)
 615
 616 include(ProjectSourceGroup)
 617
 618
 619 if(LYX_PROFILE AND NOT MSVC)
 620         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 621         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 622         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 623 else()
 624         set(LYX_PROFILE OFF)
 625 endif()
 626
 627
 628 if(LYX_NO_OPTIMIZE)
 629         set(CMAKE_BUILD_TYPE None)
 630         set(LYX_DEBUG OFF)
 631         set(LYX_RELEASE OFF)
 632         set(LYX_PROFILE OFF)
 633 elseif(LYX_RELEASE)
 634         set(CMAKE_BUILD_TYPE Release)
 635         set(LYX_DEBUG OFF)
 636         set(LYX_PROFILE OFF)
 637 elseif(LYX_PROFILE)
 638         set(CMAKE_BUILD_TYPE Profile)
 639         set(LYX_DEBUG OFF)
 640 else()
 641         set(CMAKE_BUILD_TYPE Debug)
 642         set(LYX_DEBUG ON)
 643 endif()
 644
 645
 646 # When shared libs are supported enable this option
 647 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 648 if(LYX_SHARED_LIBRARIES)
 649         set(library_type SHARED)
 650 else()
 651         set(library_type STATIC)
 652 endif()
 653
 654 if(NOT MSVC)
 655         if(NOT LYX_QUIET)
 656                 set(CMAKE_VERBOSE_MAKEFILE ON)
 657         endif()
 658         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 659         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 660           # Thanks to Brad King <brad.king@kitware.com>
 661           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 662           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 663           # and still use our own c++ extension tests
 664           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 665           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 666         endif()
 667         if(LYX_STDLIB_DEBUG)
 668                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 669         endif()
 670         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 671         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 672         if(MINGW)
 673                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 674         else()
 675                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 676         endif()
 677 endif()
 678
 679 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 680 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 681 if(LYX_CXX_FLAGS_EXTRA)
 682         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 683                 add_definitions(${_flag})
 684         endforeach()
 685 endif()
 686
 687 if(LYX_XMINGW)
 688         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 689 endif()
 690
 691 set(min_qt5_version "5.6")
 692 if(LYX_USE_QT MATCHES "AUTO")
 693         # try qt5 first
 694         find_package(Qt5Core CONFIG QUIET)
 695         if(Qt5Core_FOUND)
 696                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 697                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 698                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 699                         find_package(Qt4 "4.5.0" QUIET)
 700                         if(QT4_FOUND)
 701                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 702                         endif()
 703                 endif()
 704         else()
 705                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 706         endif()
 707 endif()
 708 if(LYX_USE_QT MATCHES "QT5")
 709         # set QPA_XCB if QT uses X11
 710         find_package(Qt5Core CONFIG REQUIRED)
 711         if (Qt5Core_FOUND)
 712                 find_package(Qt5Widgets CONFIG REQUIRED)
 713                 if(APPLE)
 714                         find_package(Qt5MacExtras CONFIG REQUIRED)
 715                 endif()
 716                 find_package(Qt5X11Extras CONFIG QUIET)
 717                 find_package(Qt5WinExtras CONFIG QUIET)
 718                 set(QTVERSION ${Qt5Core_VERSION})
 719                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 720                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 721                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 722                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 723                         # see thread in lyx-devel list
 724                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 725                         # Date 11.03.2017
 726                         # Subject: cmake compilation error
 727                         #message(FATAL_ERROR "Wrong Qt-Version")
 728                 endif()
 729                 macro (qt_use_modules lyxtarget)
 730                         foreach (_tg ${ARGN})
 731                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 732                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 733                         endforeach()
 734                 endmacro()
 735                 macro (qt_add_resources)
 736                         qt5_add_resources(${ARGN})
 737                 endmacro()
 738                 macro (qt_wrap_uifiles)
 739                         qt5_wrap_ui(${ARGN})
 740                 endmacro()
 741                 message(STATUS "Found Qt-Version ${QTVERSION}")
 742                 if(WIN32)
 743                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 744                 endif()
 745         endif()
 746 elseif(LYX_USE_QT MATCHES "QT4")
 747         if(LYX_XMINGW)
 748                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 749                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 750         endif()
 751         find_package(Qt4 "4.5.0" REQUIRED)
 752         macro (qt_use_modules)
 753         endmacro()
 754         macro (qt_add_resources)
 755                 qt4_add_resources(${ARGN})
 756         endmacro()
 757         macro (qt_wrap_uifiles)
 758                 qt4_wrap_ui(${ARGN})
 759         endmacro()
 760         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 761         if(WIN32)
 762                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 763         endif()
 764 else()
 765   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 766 endif()
 767
 768 find_package(Magic)
 769 if(Magic_FOUND)
 770   set(HAVE_MAGIC_H 1)
 771   include_directories(${Magic_INCLUDE_DIR})
 772 endif()
 773
 774 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 775
 776 set(Spelling_FOUND OFF)
 777 set(Include_used_spellchecker)   # String will be inserted into config.h
 778
 779 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 780   # try system library first
 781   find_package(MyThesLIB)
 782   if (MYTHESLIB_FOUND)
 783     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 784   else()
 785     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 786   endif()
 787 endif()
 788 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 789   find_package(MyThesLIB REQUIRED)
 790 else()
 791   add_subdirectory(3rdparty/mythes)
 792 endif()
 793 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 794
 795 if(NOT LYX_EXTERNAL_HUNSPELL)
 796     add_subdirectory(3rdparty/hunspell)
 797     add_definitions(-DHUNSPELL_STATIC)
 798     set(HUNSPELL_FOUND ON)
 799     message(STATUS "  * Hunspell:")
 800     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 801     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 802 endif()
 803
 804 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 805   string(TOUPPER ${_spell} _upspell)
 806   if (NOT ${_upspell}_FOUND)
 807     find_package(${_spell})
 808   endif()
 809   if (${_upspell}_FOUND)
 810     include_directories(${${_upspell}_INCLUDE_DIR})
 811     set(Spelling_FOUND ON)
 812     message(STATUS "Building with USE_${_upspell}")
 813     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 814   else()
 815     if(LYX_${_upspell})
 816       message(FATAL_ERROR "Required ${_spell} devel package not found")
 817     else()
 818       message(STATUS "${_upspell} not found, building without ${_spell} support")
 819     endif()
 820   endif()
 821 endforeach()
 822
 823 if(GNUWIN32_DIR)
 824         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 825 endif()
 826
 827 # Search for python default version first
 828 unset(PYTHON_EXECUTABLE CACHE)
 829 unset(LYX_PYTHON_EXECUTABLE CACHE)
 830 unset(PYTHON_VERSION_MAJOR)
 831 unset(PYTHON_VERSION_MINOR)
 832 unset(PYTHON_VERSION_STRING)
 833 if (CMAKE_VERSION VERSION_LESS "3.13")
 834   find_package(PythonInterp 3.5 QUIET)
 835   if(NOT PYTHONINTERP_FOUND)
 836     find_package(PythonInterp 2.0 REQUIRED)
 837     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 838       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 839     endif()
 840   endif()
 841   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 842 else()
 843   find_package(Python3 3.5 QUIET)
 844   if(NOT Python3_Interpreter_FOUND)
 845     unset(PYTHON_EXECUTABLE CACHE)
 846     find_package(Python2 2.0 REQUIRED)
 847     if(NOT Python2_VERSION VERSION_LESS 2.8)
 848       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 849     endif()
 850     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 851   else()
 852     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 853   endif()
 854 endif()
 855
 856 if(LYX_NLS)
 857         find_package(LyXGettext)
 858         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 859                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 860         else()
 861                 # Install only supplied .gmo-files
 862                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 863                 message(STATUS "Installing provided .gmo-files only")
 864                 foreach( _gmo ${_gmofiles})
 865                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 866                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 867                 endforeach()
 868         endif()
 869 endif()
 870
 871 if(LYX_EXTERNAL_ICONV)
 872   find_package(ICONV REQUIRED)
 873 else()
 874   add_subdirectory(3rdparty/libiconv)
 875   set(HAVE_ICONV_CONST 1)
 876 endif()
 877
 878 if(LYX_EXTERNAL_Z)
 879   find_package(ZLIB REQUIRED)
 880 else()
 881   add_subdirectory(3rdparty/zlib)
 882 endif()
 883
 884 if(NOT LYX_EXTERNAL_DTL)
 885   add_subdirectory(3rdparty/dtl)
 886 endif()
 887
 888 if(LYX_USE_STD_REGEX)
 889   # Set only include path.
 890   # Use internal boost, which is known to exist
 891   # we don't need any libraries
 892   set(Lyx_Boost_Libraries)
 893   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 894   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 895 else()
 896   # Using boost-regex
 897   if(LYX_EXTERNAL_BOOST)
 898     message(STATUS "Searching for external boost")
 899     find_package(Boost COMPONENTS regex)
 900     if(Boost_FOUND)
 901       message(STATUS "Boost found")
 902       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 903       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 904       if (LYX_STDLIB_DEBUG)
 905         # Comment from  Jean-Marc Lasgouttes:
 906         # In general, system boost libraries are incompatible with
 907         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 908         # details.
 909         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 910       endif()
 911     else()
 912       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 913     endif()
 914   else()
 915     # Using included boost
 916     set(Lyx_Boost_Libraries boost_regex)
 917     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 918     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 919     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 920   endif()
 921 endif()
 922
 923 if(WIN32)
 924         if(LYX_CONSOLE)
 925                 set(LYX_QTMAIN_LIBRARY)
 926         else()
 927                 set(WIN32_CONSOLE WIN32)
 928         endif()
 929         if(MSVC)
 930                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 931                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 932                 # disable checked iterators for msvc release builds to get maximum speed
 933                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 934         else()
 935                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 936                 # does not use it and always declares the vista compatible API.
 937                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 938                 add_definitions(-DWINVER=0x0500)
 939         endif()
 940 endif()
 941
 942 # Compute qt-version from ${QTVERSION}
 943
 944 message(STATUS "")
 945 foreach(_v PACKAGE PACKAGE_VERSION
 946         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 947         LYX_ABS_TOP_SRCDIR
 948         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 949         if(NOT DEFINED ${_v})
 950                 message(FATAL_ERROR "${_v} not defined")
 951         endif()
 952         string(SUBSTRING "${_v}                            " 0 28 _v1)
 953         message(STATUS "----- ${_v1}: ${${_v}}")
 954 endforeach(_v)
 955 message(STATUS "")
 956
 957
 958 if(LYX_PCH)
 959         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 960         # Not sure if it works for all non-msvc compilers
 961         include(PCHSupport_26)
 962         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 963         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 964         add_definitions(-DLYX_ENABLE_PCH)
 965
 966         if(MSVC)
 967                 macro(lyx_add_msvc_pch name_)
 968                         set_source_files_properties(${${name_}_sources} PROPERTIES
 969                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 970                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 971                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 972                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 973                                 ${TOP_BINARY_DIR}/pcheaders.h)
 974                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 975                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 976                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 977                 endmacro(lyx_add_msvc_pch)
 978                 macro(lyx_add_gcc_pch name_)
 979                 endmacro()
 980         else()
 981                 macro(lyx_add_msvc_pch name_)
 982                 endmacro()
 983                 macro(lyx_add_gcc_pch name_)
 984                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 985                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 986                 endmacro()
 987         endif()
 988 else()
 989         macro(lyx_add_msvc_pch)
 990         endmacro(lyx_add_msvc_pch)
 991         macro(lyx_add_gcc_pch name_)
 992         endmacro()
 993 endif()
 994
 995
 996 if(MSVC)
 997
 998         if(LYX_VLD)
 999                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1000                 add_subdirectory(${vld_path}/cmake)
1001                 include(${vld_path}/cmake/vld.cmake) # forced include
1002                 set(vld_dll vld)
1003         endif()
1004
1005         if(LYX_WALL)
1006                 # Use the highest warning level
1007                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1008
1009                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1010                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1011                 else()
1012                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1013                 endif()
1014
1015                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1016                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1017                 else()
1018                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1019                 endif()
1020
1021                 # add here warnings which should produce an error /weXXXX
1022                 set(MSVC_W_ERROR   "/we4101 /we4189")
1023                 # add here warnings which should be disabled /wdXXXX
1024                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1025
1026                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1027                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1028                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1029
1030         else()
1031                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1032
1033                 # add here warnings which should produce an error /weXXXX
1034                 set(MSVC_W_ERROR   "/we4101 /we4189")
1035                 # add here warnings which should be disabled /wdXXXX
1036                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1037
1038                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1039                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1040                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1041
1042         endif()
1043
1044         if (NOT Qt5Core_FOUND)
1045                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1046                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1047                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1048         endif()
1049
1050         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1051         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1052         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1053         message(STATUS "")
1054 endif()
1055
1056
1057 if(LYX_DEBUG_GLIBC)
1058         set(_GLIBCXX_DEBUG ON)
1059 endif()
1060
1061 if(LYX_DEBUG_GLIBC_PEDANTIC)
1062         set(_GLIBCXX_DEBUG_PEDANTIC ON)
1063 endif()
1064
1065 # Xcode compiler
1066 if (CMAKE_GENERATOR MATCHES Xcode)
1067         if (XCODE_VERSION VERSION_LESS "5.0")
1068                 # Automatically select the Xcode compiler if not set
1069                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1070                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1071                         if (XCODE_VERSION VERSION_GREATER "3.1")
1072                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1073                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1074                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1075                 # Print the selected compiler version
1076         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1077         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1078 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1079
1080 if (WIN32 AND Qt5Core_FOUND)
1081         set(Z_PREFIX 1)
1082 endif()
1083
1084 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1085 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1086 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1087
1088 unset(opts)
1089 foreach(_option ${LYX_OPTIONS})
1090   if(${_option}_show_message)
1091     string(SUBSTRING "${_option}                            " 0 31 _var)
1092     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1093     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1094     if (${_index} GREATER -1)
1095       set(_isset ${${_option}})
1096     elseif(${_option})
1097       set(_isset ON)
1098     else()
1099       set(_isset OFF)
1100     endif()
1101     string(SUBSTRING "${_isset}           " 0 10 _val)
1102     set(opts "${opts} ${_option}(${${_option}})")
1103   endif()
1104 endforeach()
1105 set(tmp_vi "CMake Build")
1106 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1107 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1108 list(APPEND tmp_vi "  Build flags:             ${opts}")
1109 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1110 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1111 if (LYX_DEBUG)
1112 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1113 else()
1114 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1115 endif()
1116 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1117 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1118 get_data_destination(dest_data)
1119 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1120 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1121
1122 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1123 unset(opts)
1124 unset(tmp_vi)
1125
1126 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1127         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1128 endif()
1129
1130 if (NOT HAVE_REGEX)
1131         set(LYX_USE_STD_REGEX 0)
1132 endif()
1133
1134
1135 set (cmd ${CMAKE_CTEST_COMMAND})
1136 if (MSVC)
1137         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1138 else ()
1139         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1140 endif ()
1141 add_custom_target (lyx_run_tests COMMAND ${cmd})
1142 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1143
1144 if(LYX_ASAN)
1145     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1146     message(STATUS)
1147     message(STATUS "Address sanitizer enabled. Usage:")
1148     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1149     message(STATUS "    chmod  +x ./asan_symbolize.py")
1150     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1151     message(STATUS)
1152 endif()
1153
1154 if(LYX_INSTALL)
1155         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1156                 message(STATUS "Python required to create doc!")
1157         else()
1158                 if(UNIX)
1159                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1160                 endif()
1161                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1162         endif()
1163 endif()
1164 include(../Install)
1165
1166 # By running the URL tests first, time can be saved when running the ctests in
1167 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1168 if(LYX_ENABLE_URLTESTS)
1169         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1170 endif()
1171 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1172 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1173 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1174 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1175 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1176 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1177 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1178
1179 message(STATUS)
1180 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1181 message(STATUS)
1182
1183 LYX_OPTION_LIST_ALL(used)
1184
1185
1186 if(LYX_NLS)
1187         message(STATUS)
1188         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1189         message(STATUS)
1190         message(STATUS "  * iconv")
1191         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1192         message(STATUS "     - library: ${ICONV_LIBRARY}")
1193         message(STATUS "  * zlib")
1194         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1195         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1196         message(STATUS)
1197 endif()
1198
1199 # Apple has builtin native spell checker,
1200 # no need to warn for missing Aspell, Hunspell or Enchant
1201 if(NOT Spelling_FOUND AND NOT APPLE)
1202   if(LYX_REQUIRE_SPELLCHECK)
1203     set(_mode "FATAL_ERROR")
1204   else()
1205     set(_mode "STATUS")
1206   endif()
1207   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1208 endif()
1209
1210 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1211
1212 if(ENABLE_DIST)
1213   # Use git to create the source package
1214   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1215   if(UNIX)
1216     set(DIST_FORMAT tgz)
1217   else()
1218     set(DIST_FORMAT zip)
1219   endif()
1220   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1221
1222   add_custom_command(
1223     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1224     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1225     WORKING_DIRECTORY ${TOP_SRC_DIR})
1226   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1227 endif()
1228
1229 # Last directory to be included so that the fixup code (OS X)
1230 # can be run last
1231 add_subdirectory(development/cmake/post_install)
1232
1233 message(STATUS)