CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 129 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 130 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 131 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 132 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 133 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 134 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 135 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 136 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 137 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 138 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 139 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 140 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 141 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 144 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 145
 146 # GCC specific
 147 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 148 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 149 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 150 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 151 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 152 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 153 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 154
 155 # MSVC specific
 156 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 157 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 158 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160
 161 # APPLE specific
 162 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 163 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 164
 165
 166 if(help OR HELP)
 167         message(STATUS)
 168         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 169         message(STATUS)
 170         LYX_OPTION_LIST_ALL(help)
 171         message(STATUS)
 172         RETURN()
 173 endif()
 174
 175 # Check option dependencies
 176
 177 if(LYX_DMG)
 178         set(LYX_BUNDLE ON)
 179         set(LYX_CPACK ON)
 180 endif()
 181
 182 if(LYX_CPACK)
 183         set(LYX_INSTALL ON)
 184 endif()
 185
 186 if(LYX_INSTALL)
 187         set(LYX_NLS ON)
 188         if(WIN32 AND NOT MINGW)
 189                 set(LYX_HUNSPELL ON)
 190         endif()
 191         if(LYX_CONSOLE MATCHES "FORCE")
 192                 set(LYX_CONSOLE ON)
 193         else()
 194                 set(LYX_CONSOLE OFF)
 195         endif()
 196         set(LYX_PACKAGE_SUFFIX ON)
 197         if(NOT LYX_DEBUG)
 198                 set(LYX_RELEASE ON)
 199         endif()
 200         set(LYX_PROFILE OFF)
 201 endif()
 202
 203
 204 if(LYX_MERGE_FILES)
 205         set(LYX_PCH OFF)
 206 else()
 207         set(LYX_MERGE_REBUILD OFF)
 208 endif()
 209
 210
 211 if(LYX_DEPENDENCIES_DOWNLOAD)
 212         message(STATUS)
 213         if(MSVC14)
 214                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 215                 set(deps_files lyx-windows-deps-msvc2015.zip)
 216                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 218         elseif(MSVC10)
 219                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 220                 set(deps_files lyx-windows-deps-msvc2010.zip)
 221                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 222                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 223         else()
 224                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 225         endif()
 226     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 227         foreach(it ${deps_files})
 228                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 229                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 230                 if(NOT already_downloaded)
 231                         message(STATUS "Downloading ${it} ...")
 232                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 233                         list(GET status 0 status_code)
 234                         list(GET status 1 status_string)
 235                         if(NOT status_code EQUAL 0)
 236                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 237                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 238                         endif()
 239                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 240                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 241                 endif()
 242         endforeach()
 243 endif()
 244
 245
 246
 247 message(STATUS)
 248
 249 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 250 if(WIN32)
 251         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 252 else()
 253         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 254 endif()
 255
 256
 257 # Set to some meaningful default
 258 find_package(CXX11Compiler)
 259 if(NOT CXX11COMPILER_FOUND)
 260         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 261 endif()
 262 set(LYX_GCC11_MODE)
 263 if(UNIX OR MINGW)
 264         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 265           # ignore the GCC_VERSION for clang
 266           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 267           message(STATUS "Using clang")
 268           if(CXX11_STD_REGEX)
 269             set(LYX_USE_STD_REGEX 1)
 270           else()
 271             set(LYX_USE_STD_REGEX 0)
 272           endif()
 273         else()
 274           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 275           message(STATUS "Using GCC version ${GCC_VERSION}")
 276           if(GCC_VERSION VERSION_LESS 4.9)
 277                   if(GCC_VERSION VERSION_LESS 4.6)
 278                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 279                   endif()
 280                   # <regex> in gcc is unusable in versions less than 4.9.0
 281                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 282                   set(LYX_USE_STD_REGEX 0)
 283           else()
 284                   set(LYX_USE_STD_REGEX 1)
 285           endif()
 286         endif()
 287         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 288 else()
 289         set(LYX_USE_STD_REGEX 0)
 290 #       if(MSVC10)
 291 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 292 #       endif()
 293 endif()
 294
 295
 296 set(VERSION_INFO "CMake Build")
 297
 298 # Try to get some informations from configure.ac
 299
 300 include(LyXPaths)
 301 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 302
 303 if(WIN32)
 304         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 305         if(MSVC)
 306                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 307         endif()
 308         set(USE_WINDOWS_PACKAGING ON)
 309 elseif(APPLE)
 310         set(USE_MACOSX_PACKAGING ON)
 311 else()
 312         set(USE_POSIX_PACKAGING ON)
 313 endif()
 314
 315 macro(setstripped _varname)
 316         if(${ARGC} GREATER 1)
 317                 string(STRIP "${ARGV1}" _v)
 318                 if(USE_POSIX_PACKAGING)
 319                         string(TOLOWER ${_v} ${_varname})
 320                 else()
 321                         set(${_varname} ${_v})
 322                 endif()
 323         else()
 324                 set(${_varname})
 325         endif()
 326 endmacro(setstripped)
 327
 328 foreach(_c_l ${_config_lines} )
 329         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 330                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 331                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 332                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 333                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 334                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 335                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 336                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 337                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 338                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 339                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 340                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 341                         else()
 342                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 343                         endif()
 344                 endif()
 345         endif()
 346         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 347                 set(LYX_DATE "${CMAKE_MATCH_1}")
 348         endif()
 349 endforeach(_c_l)
 350
 351 FIND_PROGRAM(LYX_GITVERSION git)
 352 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 353 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 354 if(LYX_GITVERSION)
 355   if (LYX_LOCALVERSIONING)
 356     # Find the revision number and for later use
 357     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 358       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 359     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 360       # We will add offset of 40000 to get appropriate value to
 361       # previous svn.
 362       # We use this value than also to set the package-patch-value
 363       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 364       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 365       set(ENABLE_DIST ON)
 366     endif()
 367   endif()
 368 endif()
 369
 370 # Set the programs (lyx, tex2lyx, etc.) suffix
 371 # When building an OS X bundle, we will append
 372 # the suffix only to the bundle, not to the programs
 373 set(PROGRAM_SUFFIX "")
 374 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 375         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 376 endif()
 377 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 378 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 379
 380 add_custom_target(lyx_version ALL
 381   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 382   )
 383 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 384
 385 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 386 set(LYX_UTILITIES_INSTALL_PATH bin)
 387
 388 if(LYX_BUNDLE)
 389         set(LYX_CPACK ON)
 390
 391         message(STATUS)
 392         message(STATUS "Bundle creation is enabled (experimental):")
 393         message(STATUS "    make")
 394         message(STATUS "    make install/strip")
 395         message(STATUS "    make package")
 396         if(APPLE)
 397                 set(MACOSX_BUNDLE TRUE)
 398                 # This sets the bundle + executable names
 399                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 400                 # This sets the Info.plist executable name
 401                 set(osx_bundle_program_name ${_lyx})
 402                 # Bundle name
 403                 set(LYX_BUNDLE_NAME ${_lyx})
 404
 405                 # This will contain the list of files that need to be included
 406                 # in the bundle and their location within the bundle
 407                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 408                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 409
 410                 # Process Info.plist and lyxrc.dist
 411                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 412                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 413
 414                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 415                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 416
 417                 # Variables used by CPack
 418                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 419                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 420                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 421
 422                 # Set the install paths
 423                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 424                 if(NOT LYX_INSTALL_PREFIX)
 425                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 426                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 427                 endif()
 428                 # Change the owner so that the install can work
 429                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 430         elseif(UNIX)
 431                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 432                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 433                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 434         elseif(WIN32)
 435                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 436         endif()
 437 endif()
 438
 439 if(LYX_INSTALL_PREFIX)
 440         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 441         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 442 endif()
 443 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 444
 445 if(UNIX)
 446   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 447 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 448   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 449 else()
 450   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 451 endif()
 452
 453 if(LYX_PACKAGE_SUFFIX)
 454         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 455 else()
 456         set(PACKAGE ${PACKAGE_BASE})
 457 endif()
 458
 459 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 460         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 461         if (UNIX)
 462                 # use the default "/usr/local"
 463                 # but respect the user-choice on the command-line
 464                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 465         endif()
 466 endif()
 467 if(WIN32)
 468         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 469 endif()
 470 if(IS_ABSOLUTE)
 471         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 472 else()
 473         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 474 endif()
 475
 476
 477
 478 if(NOT LYX_DATA_SUBDIR)
 479         if (WIN32)
 480                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 481         else()
 482                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 483         endif()
 484 endif()
 485
 486 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 487 get_locale_destination(LYX_LOCALEDIR)
 488 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 489 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 490
 491 if(LYX_BUNDLE AND APPLE)
 492         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 493 else()
 494         if(WIN32)
 495                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 496         elseif(UNIX)
 497                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 498         else()
 499                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 500         endif()
 501 endif()
 502 mark_as_advanced(LYX_MAN_DIR)
 503
 504 if(LYX_INSTALL AND WIN32)
 505         message(STATUS "Configuring NSIS files")
 506         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 507         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 508         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 509         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 510 endif()
 511
 512 if(NOT GROUP_CODE)
 513         #set(GROUP_CODE "The Golden Code")
 514         set(GROUP_CODE flat)
 515 endif()
 516
 517 # lyx's source files
 518 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 519 set(LYX_HPP_FILES [a-zA-Z]*.h)
 520 set(LYX_MOC_FILES moc_*.cpp)
 521
 522 include(ProjectSourceGroup)
 523
 524
 525 if(LYX_PROFILE AND NOT MSVC)
 526         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 527         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 528         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 529 else()
 530         set(LYX_PROFILE OFF)
 531 endif()
 532
 533
 534 if(LYX_NO_OPTIMIZE)
 535         set(CMAKE_BUILD_TYPE None)
 536         set(LYX_DEBUG OFF)
 537         set(LYX_RELEASE OFF)
 538         set(LYX_PROFILE OFF)
 539 elseif(LYX_RELEASE)
 540         set(CMAKE_BUILD_TYPE Release)
 541         set(LYX_DEBUG OFF)
 542         set(LYX_PROFILE OFF)
 543 elseif(LYX_PROFILE)
 544         set(CMAKE_BUILD_TYPE Profile)
 545         set(LYX_DEBUG OFF)
 546 else()
 547         set(CMAKE_BUILD_TYPE Debug)
 548         set(LYX_DEBUG ON)
 549 endif()
 550
 551
 552 # When shared libs are supported enable this option
 553 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 554 if(LYX_SHARED_LIBRARIES)
 555         set(library_type SHARED)
 556 else()
 557         set(library_type STATIC)
 558 endif()
 559
 560 if(NOT MSVC)
 561         if(NOT LYX_QUIET)
 562                 set(CMAKE_VERBOSE_MAKEFILE ON)
 563         endif()
 564     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 565         if(LYX_STDLIB_DEBUG)
 566                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 567         endif()
 568         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 569         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 570         if(MINGW)
 571                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 572         else()
 573                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 574         endif()
 575 endif()
 576
 577 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 578 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 579 if(LYX_CXX_FLAGS_EXTRA)
 580         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 581                 add_definitions(${_flag})
 582         endforeach()
 583 endif()
 584
 585 if(LYX_XMINGW)
 586         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 587 endif()
 588
 589 if(LYX_USE_QT MATCHES "QT5")
 590         # set QPA_XCB if QT uses X11
 591         find_package(Qt5Core REQUIRED)
 592         if (Qt5Core_FOUND)
 593                 find_package(Qt5Widgets REQUIRED)
 594                 if(APPLE)
 595                         find_package(Qt5MacExtras REQUIRED)
 596                 endif()
 597                 find_package(Qt5X11Extras QUIET)
 598                 find_package(Qt5WinExtras QUIET)
 599                 set(QTVERSION ${Qt5Core_VERSION})
 600                 macro (qt_use_modules)
 601                         qt5_use_modules(${ARGN})
 602                 endmacro()
 603                 macro (qt_add_resources)
 604                         qt5_add_resources(${ARGN})
 605                 endmacro()
 606                 macro (qt_wrap_uifiles)
 607                         qt5_wrap_ui(${ARGN})
 608                 endmacro()
 609                 message(STATUS "Found Qt-Version ${QTVERSION}")
 610                 if(WIN32)
 611                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 612                 endif()
 613         endif()
 614 elseif(LYX_USE_QT MATCHES "QT4")
 615         if(LYX_XMINGW)
 616                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 617                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 618         endif()
 619         find_package(Qt4 "4.5.0" REQUIRED)
 620         macro (qt_use_modules)
 621         endmacro()
 622         macro (qt_add_resources)
 623                 qt4_add_resources(${ARGN})
 624         endmacro()
 625         macro (qt_wrap_uifiles)
 626                 qt4_wrap_ui(${ARGN})
 627         endmacro()
 628         if(WIN32)
 629                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 630         endif()
 631 else()
 632   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 633 endif()
 634
 635 find_package(Magic)
 636 if(Magic_FOUND)
 637         set(HAVE_MAGIC_H 1)
 638 endif()
 639
 640 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 641
 642 set(Spelling_FOUND OFF)
 643 set(Include_used_spellchecker)   # String will be inserted into config.h
 644
 645 if(LYX_3RDPARTY_BUILD)
 646     add_subdirectory(3rdparty/hunspell)
 647     add_definitions(-DHUNSPELL_STATIC)
 648     set(HUNSPELL_FOUND ON)
 649     message(STATUS "  * Hunspell:")
 650     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 651     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 652 endif()
 653
 654 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 655   string(TOUPPER ${_spell} _upspell)
 656   if (NOT ${_upspell}_FOUND)
 657     find_package(${_spell})
 658   endif()
 659   if (${_upspell}_FOUND)
 660     include_directories(${${_upspell}_INCLUDE_DIR})
 661     set(Spelling_FOUND ON)
 662     message(STATUS "Building with USE_${_upspell}")
 663     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 664   else()
 665     if(LYX_${_upspell})
 666       message(FATAL_ERROR "Required ${_spell} devel package not found")
 667     else()
 668       message(STATUS "${_upspell} not found, building without ${_spell} support")
 669     endif()
 670   endif()
 671 endforeach()
 672
 673 if(GNUWIN32_DIR)
 674         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 675 endif()
 676
 677 find_package(PythonInterp 2.7 QUIET)
 678 if(PYTHONINTERP_FOUND)
 679         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 680         unset(PYTHONINTERP_FOUND)
 681         endif()
 682 endif()
 683
 684 if(NOT PYTHONINTERP_FOUND)
 685   unset(PYTHON_EXECUTABLE CACHE)
 686   unset(PYTHON_VERSION_MAJOR)
 687   unset(PYTHON_VERSION_MINOR)
 688   unset(PYTHON_VERSION_STRING)
 689   find_package(PythonInterp 3.3 REQUIRED)
 690 endif()
 691
 692 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 693
 694 if(LYX_NLS)
 695         find_package(LyXGettext)
 696         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 697                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 698         else()
 699                 # Install only supplied .gmo-files
 700                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 701                 message(STATUS "Installing provided .gmo-files only")
 702                 foreach( _gmo ${_gmofiles})
 703                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 704                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 705                 endforeach()
 706         endif()
 707 endif()
 708
 709 if(UNIX)
 710     find_package(ICONV REQUIRED)
 711     find_package(ZLIB REQUIRED)
 712 else()
 713     if(LYX_3RDPARTY_BUILD)
 714         add_subdirectory(3rdparty/libiconv)
 715         set(HAVE_ICONV_CONST 1)
 716         add_subdirectory(3rdparty/zlib)
 717     endif()
 718 endif()
 719
 720 if(LYX_EXTERNAL_BOOST)
 721         message(STATUS "Searching for boost")
 722         if(NOT LYX_USE_STD_REGEX)
 723                 find_package(Boost COMPONENTS regex)
 724         endif()
 725         if(Boost_FOUND)
 726                 message(STATUS "Boost found")
 727                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 728                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 729                 if (LYX_STDLIB_DEBUG)
 730                         # Comment from  Jean-Marc Lasgouttes:
 731                         # In general, system boost libraries are incompatible with
 732                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 733                         # details.
 734                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 735                 endif()
 736         else()
 737                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 738         endif()
 739 else()
 740         if(NOT LYX_USE_STD_REGEX)
 741                 set(Lyx_Boost_Libraries boost_regex)
 742         endif()
 743         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 744         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 745         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 746 endif()
 747
 748
 749
 750
 751 if(WIN32)
 752         if(LYX_CONSOLE)
 753                 set(LYX_QTMAIN_LIBRARY)
 754         else()
 755                 set(WIN32_CONSOLE WIN32)
 756         endif()
 757         if(MSVC)
 758                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 759                 # disable checked iterators for msvc release builds to get maximum speed
 760                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 761         else()
 762                 add_definitions(-DWINVER=0x0500)
 763         endif()
 764 endif()
 765
 766 # Compute qt4-version from ${QTVERSION}
 767
 768 message(STATUS "")
 769 foreach(_v PACKAGE PACKAGE_VERSION
 770         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 771         LYX_ABS_TOP_SRCDIR
 772         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 773         if(NOT DEFINED ${_v})
 774                 message(FATAL_ERROR "${_v} not defined")
 775         endif()
 776         string(SUBSTRING "${_v}                            " 0 28 _v1)
 777         message(STATUS "----- ${_v1}: ${${_v}}")
 778 endforeach(_v)
 779 message(STATUS "")
 780
 781
 782 if(LYX_PCH)
 783         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 784         # Not sure if it works for all non-msvc compilers
 785         include(PCHSupport_26)
 786         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 787         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 788         add_definitions(-DLYX_ENABLE_PCH)
 789
 790         if(MSVC)
 791                 macro(lyx_add_msvc_pch name_)
 792                         set_source_files_properties(${${name_}_sources} PROPERTIES
 793                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 794                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 795                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 796                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 797                                 ${TOP_BINARY_DIR}/pcheaders.h)
 798                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 799                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 800                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 801                 endmacro(lyx_add_msvc_pch)
 802                 macro(lyx_add_gcc_pch name_)
 803                 endmacro()
 804         else()
 805                 macro(lyx_add_msvc_pch name_)
 806                 endmacro()
 807                 macro(lyx_add_gcc_pch name_)
 808                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 809                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 810                 endmacro()
 811         endif()
 812 else()
 813         macro(lyx_add_msvc_pch)
 814         endmacro(lyx_add_msvc_pch)
 815         macro(lyx_add_gcc_pch name_)
 816         endmacro()
 817 endif()
 818
 819
 820 if(MSVC)
 821
 822         if(LYX_VLD)
 823                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 824                 add_subdirectory(${vld_path}/cmake)
 825                 include(${vld_path}/cmake/vld.cmake) # forced include
 826                 set(vld_dll vld)
 827         endif()
 828
 829         if(LYX_WALL)
 830                 # Use the highest warning level
 831                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 832
 833                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 834                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 835                 else()
 836                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 837                 endif()
 838
 839                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 840                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 841                 else()
 842                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 843                 endif()
 844
 845                 # add here warnings which should produce an error /weXXXX
 846                 set(MSVC_W_ERROR   "/we4101 /we4189")
 847                 # add here warnings which should be disabled /wdXXXX
 848                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 849
 850                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 851                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 852                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 853
 854         else()
 855                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 856
 857                 # add here warnings which should produce an error /weXXXX
 858                 set(MSVC_W_ERROR   "/we4101 /we4189")
 859                 # add here warnings which should be disabled /wdXXXX
 860                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 861
 862                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 863                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 864                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 865
 866         endif()
 867
 868         if (NOT Qt5Core_FOUND)
 869                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 870                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 871                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 872         endif()
 873
 874         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 875         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 876         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 877         message(STATUS "")
 878 endif()
 879
 880
 881 if(LYX_DEBUG_GLIBC)
 882         set(_GLIBCXX_DEBUG ON)
 883 endif()
 884
 885 if(LYX_DEBUG_GLIBC_PEDANTIC)
 886         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 887 endif()
 888
 889 # Xcode compiler
 890 if (CMAKE_GENERATOR MATCHES Xcode)
 891         if (XCODE_VERSION VERSION_LESS "5.0")
 892                 # Automatically select the Xcode compiler if not set
 893                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 894                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 895                         if (XCODE_VERSION VERSION_GREATER "3.1")
 896                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 897                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 898                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 899                 # Print the selected compiler version
 900         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 901         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 902 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 903
 904 if (WIN32 AND Qt5Core_FOUND)
 905         set(Z_PREFIX 1)
 906 endif()
 907
 908 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 909 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 910 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 911
 912 set(QPA_XCB)
 913 if(Qt5X11Extras_FOUND AND QT_USES_X11)
 914   # QPA_XCB is only valid if QT5+X11
 915   set(QPA_XCB 1)
 916 endif()
 917 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 918
 919 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 920         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 921 endif()
 922
 923 if (NOT HAVE_REGEX)
 924         set(LYX_USE_STD_REGEX 0)
 925 endif()
 926
 927
 928 set (cmd ${CMAKE_CTEST_COMMAND})
 929 if (MSVC)
 930         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 931 else ()
 932         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 933 endif ()
 934 add_custom_target (lyx_run_tests COMMAND ${cmd})
 935 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 936
 937 if(LYX_ASAN)
 938     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 939     message(STATUS)
 940     message(STATUS "Address sanitizer enabled. Usage:")
 941     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 942     message(STATUS "    chmod  +x ./asan_symbolize.py")
 943     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 944     message(STATUS)
 945 endif()
 946
 947 if(LYX_INSTALL)
 948         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 949                 message(STATUS "Python required to create doc!")
 950         else()
 951                 if(UNIX)
 952                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 953                 endif()
 954                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 955         endif()
 956         include(../Install)
 957 endif()
 958
 959 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 960 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 961 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 962 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 963 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 964 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 965 if(LYX_ENABLE_URLTESTS)
 966         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 967 endif()
 968
 969 message(STATUS)
 970 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 971 message(STATUS)
 972
 973 LYX_OPTION_LIST_ALL(used)
 974
 975
 976 if(LYX_NLS)
 977         message(STATUS)
 978         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 979         message(STATUS)
 980         message(STATUS "  * iconv")
 981         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 982         message(STATUS "     - library: ${ICONV_LIBRARY}")
 983         message(STATUS "  * zlib")
 984         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 985         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 986         message(STATUS)
 987 endif()
 988
 989 # Apple has builtin native spell checker,
 990 # no need to warn for missing Aspell, Hunspell or Enchant
 991 if(NOT Spelling_FOUND AND NOT APPLE)
 992   if(LYX_REQUIRE_SPELLCHECK)
 993     set(_mode "FATAL_ERROR")
 994   else()
 995     set(_mode "STATUS")
 996   endif()
 997   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 998 endif()
 999
1000 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1001
1002 if(ENABLE_DIST)
1003   # Use git to create the source package
1004   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1005   if(UNIX)
1006     set(DIST_FORMAT tgz)
1007   else()
1008     set(DIST_FORMAT zip)
1009   endif()
1010   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1011
1012   add_custom_command(
1013     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1014     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1015     WORKING_DIRECTORY ${TOP_SRC_DIR})
1016   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1017 endif()
1018
1019 # Last directory to be included so that the fixup code (OS X)
1020 # can be run last
1021 add_subdirectory(development/cmake/post_install)
1022
1023 message(STATUS)