CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34 # This directory should be used if some test uses lyx-executable
  35 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  36 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  37
  38 if(COMMAND cmake_policy)
  39         cmake_policy(SET CMP0003 OLD)
  40         cmake_policy(SET CMP0005 OLD)
  41         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  42         cmake_policy(SET CMP0006 NEW)
  43 endif()
  44
  45 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  46
  47 # Supress regeneration
  48 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  49
  50 if(LYX_XMINGW)
  51     set(CMAKE_SYSTEM_NAME Windows)
  52     set(TOOLNAME ${LYX_XMINGW})
  53     set(TOOLCHAIN "${TOOLNAME}-")
  54     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  55     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  56     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  57
  58     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  59     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  60     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  61 endif()
  62
  63 if(NOT help AND NOT HELP)
  64         # 'project' triggers the searching for a compiler
  65         project(${LYX_PROJECT})
  66 endif()
  67
  68 if(UNIX)
  69         set(ARCH_TRIPLET )
  70         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  71         if(DPKG_ARCHITECTURE_EXECUTABLE)
  72                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  73                                 OUTPUT_VARIABLE ARCH_TRIPLET
  74                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  75                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  76         endif()
  77 endif()
  78 if(ARCH_TRIPLET)
  79         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  80 else()
  81         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  82 endif()
  83
  84 include(LyXMacros)
  85
  86 # Usage LYX_OPTION
  87 # 1. parameter: option name without prefix 'LYX_'
  88 # 2. parameter: description
  89 # 3. parameter: default value, ON or OFF
  90 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  91
  92 # Usage LYX_COMBO
  93 # 1. parameter: name without prefix 'LYX_'
  94 # 2. parameter: description
  95 # 3. parameter: default value
  96 # 4-n parameter: possible other string values
  97
  98 LYX_OPTION_INIT()
  99
 100 # Options for all compilers/systems
 101 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 102 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 103 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 104 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 105 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 106 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 107 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 108 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 109 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 110 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 111 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 112 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 113 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 114 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 115 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 116 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 117 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 118 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 119 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 120 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 121 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 122
 123 # GCC specific
 124 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 125 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 126 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 127 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 128 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 129 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 130 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 131 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 132 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 133
 134 # MSVC specific
 135 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 136 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 137 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 138 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 139 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 140
 141 # APPLE specific
 142 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 143 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 144 if(LYX_XMINGW)
 145   LYX_COMBO(USE_QT               "Use Qt version as frontend for MINGW" QT4)
 146 else()
 147   LYX_COMBO(USE_QT               "Use Qt version as frontend" QT4 QT5)
 148 endif()
 149
 150
 151 if(help OR HELP)
 152         message(STATUS)
 153         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 154         message(STATUS)
 155         LYX_OPTION_LIST_ALL(help)
 156         message(STATUS)
 157         RETURN()
 158 endif()
 159
 160 # Check option dependencies
 161
 162 if(LYX_DMG)
 163         set(LYX_BUNDLE ON)
 164         set(LYX_CPACK ON)
 165 endif()
 166
 167 if(LYX_CPACK)
 168         set(LYX_INSTALL ON)
 169 endif()
 170
 171 if(LYX_INSTALL)
 172         set(LYX_NLS ON)
 173         if(WIN32 AND NOT MINGW)
 174                 set(LYX_HUNSPELL ON)
 175         endif()
 176         if(LYX_CONSOLE MATCHES "FORCE")
 177                 set(LYX_CONSOLE ON)
 178         else()
 179                 set(LYX_CONSOLE OFF)
 180         endif()
 181         set(LYX_PACKAGE_SUFFIX ON)
 182         if(NOT LYX_DEBUG)
 183                 set(LYX_RELEASE ON)
 184         endif()
 185         set(LYX_PROFILE OFF)
 186 endif()
 187
 188
 189 if(LYX_MERGE_FILES)
 190         set(LYX_PCH OFF)
 191 else()
 192         set(LYX_MERGE_REBUILD OFF)
 193 endif()
 194
 195
 196 if(LYX_DEPENDENCIES_DOWNLOAD)
 197         message(STATUS)
 198         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 199         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 200         set(deps_files lyx20-deps-msvc2010-x86.zip)
 201         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 202         foreach(it ${deps_files})
 203                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 204                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 205                 if(NOT already_downloaded)
 206                         message(STATUS "Downloading ${it} ...")
 207                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 208                         list(GET status 0 status_code)
 209                         list(GET status 1 status_string)
 210                         if(NOT status_code EQUAL 0)
 211                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 212                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 213                         endif()
 214                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 215                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 216                 endif()
 217         endforeach()
 218         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 219     if(MSVC12)
 220         # handle error in msvc12 when linking against msvc10 libs
 221         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /vd2")
 222     endif()
 223 endif()
 224
 225
 226
 227 message(STATUS)
 228
 229 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 230 if(WIN32)
 231         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 232 else()
 233         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 234 endif()
 235
 236
 237 set(LYX_GCC11_MODE)
 238 if(UNIX OR MINGW)
 239         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 240         message(STATUS "Using GCC version ${GCC_VERSION}")
 241         if(NOT GCC_VERSION VERSION_LESS 4.4)
 242                 set(LYX_USE_TR1 1)
 243                 # GCC <= 4.5 does not support regex: there are linker errors
 244                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 245                 set(LYX_USE_TR1_REGEX 0)
 246         endif()
 247         if (LYX_ENABLE_CXX11)
 248                 find_package(CXX11Compiler)
 249                 if(NOT CXX11COMPILER_FOUND)
 250                         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 251                 endif()
 252                 set(LYX_GCC11_MODE "${CXX11_FLAG}")
 253         endif()
 254 else()
 255         if(MSVC10)
 256                 set(LYX_USE_TR1 1)
 257                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 258         endif()
 259 endif()
 260
 261
 262 set(VERSION_INFO "CMake Build")
 263
 264 # Try to get some informations from configure.ac
 265
 266 include(LyXPaths)
 267 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 268
 269 if(WIN32)
 270         set(USE_WINDOWS_PACKAGING ON)
 271 elseif(APPLE)
 272         set(USE_MACOSX_PACKAGING ON)
 273 else()
 274         set(USE_POSIX_PACKAGING ON)
 275 endif()
 276
 277 macro(setstripped _varname)
 278         if(${ARGC} GREATER 1)
 279                 string(STRIP "${ARGV1}" _v)
 280                 if(USE_POSIX_PACKAGING)
 281                         string(TOLOWER ${_v} ${_varname})
 282                 else()
 283                         set(${_varname} ${_v})
 284                 endif()
 285         else()
 286                 set(${_varname})
 287         endif()
 288 endmacro(setstripped)
 289
 290 foreach(_c_l ${_config_lines} )
 291         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 292                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 293                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 294                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 295                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 296                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 297                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 298                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 299                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 300                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 301                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 302                 endif()
 303         endif()
 304         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 305                 set(LYX_DATE "${CMAKE_MATCH_1}")
 306         endif()
 307 endforeach(_c_l)
 308
 309 if (LYX_LOCALVERSIONING)
 310         # Find the revision number and for later use
 311         FIND_PROGRAM(LYX_GITVERSION git)
 312         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 313         if(LYX_GITVERSION)
 314                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 315                 WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 316                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 317                   # We will add offset of 40000 to get appropriate value to
 318                   # previous svn.
 319                   # We use this value than also to set the package-patch-value
 320                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 321                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 322                   set(ENABLE_DIST ON)
 323                 endif()
 324         else()
 325                 set(LYX_REVISION_VERSION git) #TODO use date
 326         endif()
 327 else()
 328         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 329 endif()
 330
 331 # Set the programs (lyx, tex2lyx, etc.) suffix
 332 # When building an OS X bundle, we will append
 333 # the suffix only to the bundle, not to the programs
 334 set(PROGRAM_SUFFIX "")
 335 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 336         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 337 endif()
 338 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 339 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 340
 341 add_custom_target(lyx_version ALL
 342   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 343   )
 344 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 345
 346 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 347 set(LYX_UTILITIES_INSTALL_PATH bin)
 348
 349 if(LYX_BUNDLE)
 350         set(LYX_CPACK ON)
 351
 352         message(STATUS)
 353         message(STATUS "Bundle creation is enabled (experimental):")
 354         message(STATUS "    make")
 355         message(STATUS "    make install/strip")
 356         message(STATUS "    make package")
 357         if(APPLE)
 358                 set(MACOSX_BUNDLE TRUE)
 359                 # This sets the bundle + executable names
 360                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 361                 # This sets the Info.plist executable name
 362                 set(osx_bundle_program_name ${_lyx})
 363                 # Bundle name
 364                 set(LYX_BUNDLE_NAME ${_lyx})
 365
 366                 # This will contain the list of files that need to be included
 367                 # in the bundle and their location within the bundle
 368                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 369                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 370
 371                 # Process Info.plist and lyxrc.dist
 372                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 373                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 374
 375                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 376                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 377
 378                 # Variables used by CPack
 379                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 380                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 381                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 382
 383                 # Set the install paths
 384                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 385                 if(NOT LYX_INSTALL_PREFIX)
 386                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 387                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 388                 endif()
 389                 # Change the owner so that the install can work
 390                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 391         elseif(UNIX)
 392                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 393                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 394                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 395         elseif(WIN32)
 396                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 397         endif()
 398 endif()
 399
 400 if(LYX_INSTALL_PREFIX)
 401         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 402         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 403 endif()
 404 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 405
 406 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 407
 408 if(LYX_PACKAGE_SUFFIX)
 409         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 410 else()
 411         set(PACKAGE ${PACKAGE_BASE})
 412 endif()
 413
 414 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 415         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 416         if (UNIX)
 417                 # don't use the default "/usr/local"
 418                 # but respect the user-choice on the command-line
 419                 if(LYX_INSTALL_SUFFIX)
 420                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 421                 else()
 422                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 423                 endif()
 424         endif()
 425         if(WIN32)
 426                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 427         endif()
 428 endif()
 429 if(IS_ABSOLUTE)
 430         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 431 else()
 432         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 433 endif()
 434
 435
 436
 437 if(NOT LYX_DATA_SUBDIR)
 438         if (WIN32)
 439                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 440         else()
 441                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 442         endif()
 443 endif()
 444
 445 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 446 set(LYX_LOCALEDIR "locale")
 447 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 448 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 449
 450 if(LYX_BUNDLE AND APPLE)
 451         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 452 else()
 453         set(LYX_MAN_DIR "/usr/local/man/man1" CACHE STRING "Install location for man pages.")
 454 endif()
 455 mark_as_advanced(LYX_MAN_DIR)
 456
 457 if(LYX_INSTALL AND WIN32)
 458         message(STATUS "Configuring NSIS files")
 459         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 460         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 461         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 462         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 463 endif()
 464
 465 if(NOT GROUP_CODE)
 466         #set(GROUP_CODE "The Golden Code")
 467         set(GROUP_CODE flat)
 468 endif()
 469
 470 # lyx's source files
 471 set(LYX_CPP_FILES *.cpp)
 472 set(LYX_HPP_FILES *.h)
 473 set(LYX_MOC_FILES moc_*.cpp)
 474
 475 include(ProjectSourceGroup)
 476
 477
 478 if(LYX_PROFILE AND NOT MSVC)
 479         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 480         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 481         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 482 else()
 483         set(LYX_PROFILE OFF)
 484 endif()
 485
 486
 487 if(LYX_NO_OPTIMIZE)
 488         set(CMAKE_BUILD_TYPE None)
 489         set(LYX_DEBUG OFF)
 490         set(LYX_RELEASE OFF)
 491         set(LYX_PROFILE OFF)
 492 elseif(LYX_RELEASE)
 493         set(CMAKE_BUILD_TYPE Release)
 494         set(LYX_DEBUG OFF)
 495         set(LYX_PROFILE OFF)
 496 elseif(LYX_PROFILE)
 497         set(CMAKE_BUILD_TYPE Profile)
 498         set(LYX_DEBUG OFF)
 499 else()
 500         set(CMAKE_BUILD_TYPE Debug)
 501         set(LYX_DEBUG ON)
 502 endif()
 503
 504
 505 # When shared libs are supported enable this option
 506 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 507 if(LYX_SHARED_LIBRARIES)
 508         set(library_type SHARED)
 509 else()
 510         set(library_type STATIC)
 511 endif()
 512
 513 if(NOT MSVC)
 514         if(NOT LYX_QUIET)
 515                 set(CMAKE_VERBOSE_MAKEFILE ON)
 516         endif()
 517         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 518         if(LYX_STDLIB_DEBUG)
 519                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 520         endif()
 521         if(LYX_CONCEPT_CHECKS)
 522                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 523         endif()
 524         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 525         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 526         if(MINGW)
 527                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 528         else()
 529                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 530         endif()
 531 endif()
 532
 533 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 534 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 535 if(LYX_CXX_FLAGS_EXTRA)
 536         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 537                 add_definitions(${_flag})
 538         endforeach()
 539 endif()
 540
 541 if(LYX_XMINGW)
 542     set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 543     list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 544 endif()
 545 if(LYX_USE_QT MATCHES "QT5")
 546   find_package(Qt5Core REQUIRED)
 547   if (Qt5Core_FOUND)
 548         find_package(Qt5Widgets REQUIRED)
 549         find_package(Qt5X11Extras)
 550         set(QTVERSION ${Qt5Core_VERSION})
 551         macro (qt_use_modules)
 552                 qt5_use_modules(${ARGN})
 553         endmacro()
 554         macro (qt_add_resources)
 555                 qt5_add_resources(${ARGN})
 556         endmacro()
 557         macro (qt_wrap_uifiles)
 558                 qt5_wrap_ui(${ARGN})
 559         endmacro()
 560   endif()
 561 elseif(LYX_USE_QT MATCHES "QT4")
 562         find_package(Qt4 "4.5.0" REQUIRED)
 563         macro (qt_use_modules)
 564         endmacro()
 565         macro (qt_add_resources)
 566                 qt4_add_resources(${ARGN})
 567         endmacro()
 568         macro (qt_wrap_uifiles)
 569                 qt4_wrap_ui(${ARGN})
 570         endmacro()
 571 else()
 572   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 573 endif()
 574
 575 find_package(Magic)
 576 if(Magic_FOUND)
 577         set(HAVE_MAGIC_H 1)
 578 endif()
 579
 580 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 581
 582 set(Spelling_FOUND OFF)
 583 set(Include_used_spellchecker)   # String will be inserted into config.h
 584
 585 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 586   string(TOUPPER ${_spell} _upspell)
 587   find_package(${_spell})
 588   if (${_upspell}_FOUND)
 589     include_directories(${${_upspell}_INCLUDE_DIR})
 590     set(Spelling_FOUND ON)
 591     message(STATUS "Building with USE_${_upspell}")
 592     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 593   else()
 594     if(LYX_${_upspell})
 595       message(FATAL_ERROR "Required ${_spell} devel package not found")
 596     else()
 597       message(STATUS "${_upspell} not found, building without ${_spell} support")
 598     endif()
 599   endif()
 600 endforeach()
 601
 602 if(LYX_NLS)
 603         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 604         find_package(LyXGettext)
 605         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 606                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 607         else()
 608                 # Install only supplied .gmo-files
 609                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 610                 message(STATUS "Installing provided .gmo-files only")
 611                 foreach( _gmo ${_gmofiles})
 612                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 613                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 614                 endforeach()
 615         endif()
 616 endif()
 617
 618
 619 find_package(ICONV REQUIRED)
 620 find_package(ZLIB REQUIRED)
 621
 622 if(LYX_EXTERNAL_BOOST)
 623         message(STATUS "Searching for boost")
 624         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 625         if(Boost_FOUND)
 626                 message(STATUS "Boost found")
 627                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 628                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 629         else()
 630                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 631         endif()
 632 else()
 633         if(LYX_USE_TR1_REGEX)
 634                 set(Lyx_Boost_Libraries boost_signals)
 635         else()
 636                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 637         endif()
 638         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 639         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 640         include_directories(${TOP_SRC_DIR}/boost)
 641         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 642 endif()
 643
 644
 645
 646
 647 if(WIN32)
 648         if(NOT LYX_CONSOLE)
 649                 set(WIN32_CONSOLE WIN32)
 650                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 651         endif()
 652         if(MSVC)
 653                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 654                 # disable checked iterators for msvc release builds to get maximum speed
 655                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 656         else()
 657                 add_definitions(-DWINVER=0x0500)
 658         endif()
 659 endif()
 660
 661 # Compute qt4-version from ${QTVERSION}
 662
 663 message(STATUS "")
 664 foreach(_v PACKAGE PACKAGE_VERSION
 665         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 666         LYX_ABS_TOP_SRCDIR
 667         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 668         if(NOT DEFINED ${_v})
 669                 message(FATAL_ERROR "${_v} not defined")
 670         endif()
 671         string(SUBSTRING "${_v}                            " 0 28 _v1)
 672         message(STATUS "----- ${_v1}: ${${_v}}")
 673 endforeach(_v)
 674 message(STATUS "")
 675
 676
 677 if(LYX_PCH)
 678         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 679         # Not sure if it works for all non-msvc compilers
 680         include(PCHSupport_26)
 681         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 682         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 683         add_definitions(-DLYX_ENABLE_PCH)
 684
 685         if(MSVC)
 686                 macro(lyx_add_msvc_pch name_)
 687                         set_source_files_properties(${${name_}_sources} PROPERTIES
 688                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 689                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 690                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 691                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 692                                 ${TOP_BINARY_DIR}/pcheaders.h)
 693                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 694                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 695                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 696                 endmacro(lyx_add_msvc_pch)
 697                 macro(lyx_add_gcc_pch name_)
 698                 endmacro()
 699         else()
 700                 macro(lyx_add_msvc_pch name_)
 701                 endmacro()
 702                 macro(lyx_add_gcc_pch name_)
 703                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 704                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 705                 endmacro()
 706         endif()
 707 else()
 708         macro(lyx_add_msvc_pch)
 709         endmacro(lyx_add_msvc_pch)
 710         macro(lyx_add_gcc_pch name_)
 711         endmacro()
 712 endif()
 713
 714
 715 if(MSVC)
 716
 717         if(LYX_VLD)
 718                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 719                 add_subdirectory(${vld_path}/cmake)
 720                 include(${vld_path}/cmake/vld.cmake) # forced include
 721                 set(vld_dll vld)
 722         endif()
 723
 724         if(LYX_WALL)
 725                 # Use the highest warning level
 726                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 727
 728                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 729                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 730                 else()
 731                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 732                 endif()
 733
 734                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 735                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 736                 else()
 737                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 738                 endif()
 739
 740                 # add here warnings which should produce an error /weXXXX
 741                 set(MSVC_W_ERROR   "/we4101 /we4189")
 742                 # add here warnings which should be disabled /wdXXXX
 743                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 744
 745                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 746                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 747                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 748
 749         else()
 750                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 751
 752                 # add here warnings which should produce an error /weXXXX
 753                 set(MSVC_W_ERROR   "/we4101 /we4189")
 754                 # add here warnings which should be disabled /wdXXXX
 755                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 756
 757                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 758                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 759                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 760
 761         endif()
 762
 763         if (NOT Qt5Core_FOUND)
 764                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 765                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 766                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 767         endif()
 768
 769         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 770         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 771         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 772         message(STATUS "")
 773 endif()
 774
 775
 776 if(LYX_DEBUG_GLIBC)
 777         set(_GLIBCXX_DEBUG ON)
 778 endif()
 779
 780 if(LYX_DEBUG_GLIBC_PEDANTIC)
 781         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 782 endif()
 783
 784 # Xcode compiler
 785 if (CMAKE_GENERATOR MATCHES Xcode)
 786         if (XCODE_VERSION VERSION_LESS "5.0")
 787                 # Automatically select the Xcode compiler if not set
 788                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 789                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 790                         if (XCODE_VERSION VERSION_GREATER "3.1")
 791                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 792                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 793                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 794                 # Print the selected compiler version
 795         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 796         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 797 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 798
 799 if (WIN32 AND Qt5Core_FOUND)
 800         set(Z_PREFIX 1)
 801 endif()
 802
 803 # compiler tests, config.h generation
 804 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 805         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 806 else()
 807         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 808         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 809 endif()
 810
 811 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 812
 813 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 814         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 815 endif()
 816
 817
 818 set (cmd ${CMAKE_CTEST_COMMAND})
 819 if (MSVC)
 820         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 821 else ()
 822         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 823 endif ()
 824 add_custom_target (lyx_run_tests COMMAND ${cmd})
 825 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 826
 827
 828 if(LYX_INSTALL)
 829         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 830                 message(STATUS "Python required to create doc!")
 831         else()
 832                 if(UNIX)
 833                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 834                 endif()
 835                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 836         endif()
 837         include(../Install)
 838 endif()
 839
 840 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 841 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 842 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 843 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 844 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 845 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 846 if(LYX_ENABLE_URLTESTS)
 847         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 848 endif()
 849
 850 message(STATUS)
 851 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 852 message(STATUS)
 853
 854 LYX_OPTION_LIST_ALL(used)
 855
 856
 857 if(LYX_NLS)
 858         message(STATUS)
 859         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 860         message(STATUS)
 861         message(STATUS "  * iconv")
 862         message(STATUS "     - header : ${ICONV_HEADER}")
 863         message(STATUS "     - library: ${ICONV_LIBRARY}")
 864         message(STATUS "  * zlib")
 865         message(STATUS "     - header : ${ZLIB_HEADER}")
 866         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 867         message(STATUS)
 868 endif()
 869
 870 # Apple has builtin native spell checker,
 871 # no need to warn for missing Aspell, Hunspell or Enchant
 872 if(NOT Spelling_FOUND AND NOT APPLE)
 873   if(LYX_REQUIRE_SPELLCHECK)
 874     set(_mode "FATAL_ERROR")
 875   else()
 876     set(_mode "STATUS")
 877   endif()
 878   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 879 endif()
 880
 881 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 882
 883 if(ENABLE_DIST)
 884   # Use git to create the source package
 885   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 886   if(UNIX)
 887     set(DIST_FORMAT tgz)
 888   else()
 889     set(DIST_FORMAT zip)
 890   endif()
 891   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 892
 893   add_custom_command(
 894     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 895     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 896     WORKING_DIRECTORY ${TOP_SRC_DIR})
 897   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 898 endif()
 899
 900 # Last directory to be included so that the fixup code (OS X)
 901 # can be run last
 902 add_subdirectory(development/cmake/post_install)
 903
 904 message(STATUS)