CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34
  35 if(COMMAND cmake_policy)
  36         cmake_policy(SET CMP0003 OLD)
  37         cmake_policy(SET CMP0005 OLD)
  38 endif()
  39
  40 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  41
  42 # Supress regeneration
  43 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  44
  45 if(NOT help AND NOT HELP)
  46         # 'project' triggers the searching for a compiler
  47         project(${LYX_PROJECT})
  48 endif()
  49
  50 if(UNIX)
  51         set(ARCH_TRIPLET )
  52         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  53         if(DPKG_ARCHITECTURE_EXECUTABLE)
  54                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  55                                 OUTPUT_VARIABLE ARCH_TRIPLET
  56                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  57                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  58         endif()
  59 endif()
  60 if(ARCH_TRIPLET)
  61         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  62 else()
  63         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  64 endif()
  65
  66 include(LyXMacros)
  67
  68 # Usage LYX_OPTION
  69 # 1. parameter: option name without prefix 'LYX_'
  70 # 2. parameter: description
  71 # 3. parameter: default value, ON or OFF
  72 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  73
  74
  75 LYX_OPTION_INIT()
  76
  77 # Options for all compilers/systems
  78 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  79 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  80 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  81 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  82 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  83 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  84 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  85 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  86 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  87 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  88 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  89 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  90 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  91 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  92 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  93 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  94 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  95 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  96 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  97
  98 # GCC specific
  99 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 100 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 101 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 102 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 103 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
 104 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 105 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 106 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 107 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 108
 109 # MSVC specific
 110 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 111 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 112 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 113 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 114 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 115
 116 # APPLE specific
 117 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 118 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 119
 120
 121 if(help OR HELP)
 122         message(STATUS)
 123         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 124         message(STATUS)
 125         LYX_OPTION_LIST_ALL(help)
 126         message(STATUS)
 127         RETURN()
 128 endif()
 129
 130 # Check option dependencies
 131
 132 if(LYX_CPACK)
 133         set(LYX_INSTALL ON)
 134 endif()
 135
 136 if(LYX_DMG)
 137         set(LYX_BUNDLE ON)
 138         set(LYX_CPACK ON)
 139 endif()
 140
 141 if(LYX_INSTALL)
 142         set(LYX_NLS ON)
 143         if (WIN32)
 144                 set(LYX_HUNSPELL ON)
 145         endif()
 146         if(LYX_CONSOLE MATCHES "FORCE")
 147                 set(LYX_CONSOLE ON)
 148         else()
 149                 set(LYX_CONSOLE OFF)
 150         endif()
 151         set(LYX_PACKAGE_SUFFIX ON)
 152         set(LYX_RELEASE ON)
 153         set(LYX_PROFILE OFF)
 154 endif()
 155
 156
 157 if(LYX_MERGE_FILES)
 158         set(LYX_PCH OFF)
 159 else()
 160         set(LYX_MERGE_REBUILD OFF)
 161 endif()
 162
 163 if(LYX_DEPENDENCIES_DOWNLOAD)
 164         message(STATUS)
 165         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 166         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 167         set(deps_files lyx20-deps-msvc2010-x86.zip)
 168         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 169         foreach(it ${deps_files})
 170                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 171                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 172                 if(NOT already_downloaded)
 173                         message(STATUS "Downloading ${it} ...")
 174                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 175                         list(GET status 0 status_code)
 176                         list(GET status 1 status_string)
 177                         if(NOT status_code EQUAL 0)
 178                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 179                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 180                         endif()
 181                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 182                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 183                 endif()
 184         endforeach()
 185         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 186 endif()
 187
 188
 189
 190 message(STATUS)
 191
 192 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 193 if(WIN32)
 194         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 195 else()
 196         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 197 endif()
 198
 199
 200 set(LYX_GCC11_MODE)
 201 if(UNIX OR MINGW)
 202         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 203         message(STATUS "Using GCC version ${GCC_VERSION}")
 204         if(NOT GCC_VERSION VERSION_LESS 4.4)
 205                 set(LYX_USE_TR1 1)
 206                 # GCC <= 4.5 does not support regex: there are linker errors
 207                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 208                 set(LYX_USE_TR1_REGEX 0)
 209         endif()
 210         if (LYX_ENABLE_CXX11)
 211                 if(GCC_VERSION VERSION_GREATER 4.7)
 212                         set(LYX_GCC11_MODE "-std=gnu++11")
 213                 elseif(GCC_VERSION VERSION_GREATER 4.2)
 214                         set(LYX_GCC11_MODE "-std=gnu++0x")
 215                 endif()
 216         endif()
 217 else()
 218         if(MSVC10)
 219                 set(LYX_USE_TR1 1)
 220                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 221         endif()
 222 endif()
 223
 224
 225 set(VERSION_INFO "CMake Build")
 226
 227 # Try to get some informations from configure.ac
 228
 229 include(LyXPaths)
 230 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 231
 232 if(WIN32)
 233         set(USE_WINDOWS_PACKAGING ON)
 234 elseif(APPLE)
 235         set(USE_MACOSX_PACKAGING ON)
 236 else()
 237         set(USE_POSIX_PACKAGING ON)
 238 endif()
 239
 240 macro(setstripped _varname _value)
 241         string(STRIP ${_value} _v)
 242         if(USE_POSIX_PACKAGING)
 243                 string(TOLOWER ${_v} ${_varname})
 244         else()
 245                 set(${_varname} ${_v})
 246         endif()
 247 endmacro(setstripped)
 248
 249 foreach(_c_l ${_config_lines} )
 250         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 251                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 252                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 253                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 254                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 255                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 256                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 257                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 258                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 259                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 260                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 261                 endif()
 262         endif()
 263         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 264                 set(LYX_DATE "${CMAKE_MATCH_1}")
 265         endif()
 266 endforeach(_c_l)
 267
 268 if (LYX_LOCALVERSIONING)
 269         # Find the revision number and for later use
 270         FIND_PROGRAM(LYX_GITVERSION git)
 271         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 272         if(LYX_GITVERSION)
 273                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "describe" WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 274                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 275                   # We will add offset of 40000 to get appropriate value to
 276                   # previous svn.
 277                   # We use this value than also to set the package-patch-value
 278                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 279                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 280                   set(ENABLE_DIST ON)
 281                 endif()
 282         else()
 283                 set(LYX_REVISION_VERSION git) #TODO use date
 284         endif()
 285 else()
 286         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 287 endif()
 288
 289 if(LYX_PROGRAM_SUFFIX)
 290         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 291 else()
 292         set(PROGRAM_SUFFIX "")
 293 endif()
 294
 295 add_custom_target(lyx_version ALL
 296   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 297   )
 298 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 299
 300 if(APPLE)
 301         set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 302         configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 303 endif()
 304
 305 if(LYX_BUNDLE)
 306         set(LYX_CPACK ON)
 307         message(STATUS)
 308         message(STATUS "Bundle creation is enabled (experimental):")
 309         message(STATUS "    make")
 310         message(STATUS "    make install/strip")
 311         message(STATUS "    make package")
 312         if(APPLE)
 313                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 314                 set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 315                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 316                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 317                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 318                 if(NOT LYX_INSTALL_PREFIX)
 319                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 320                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 321                 endif()
 322                 # Change the owner so that the install can work
 323                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
 324         elseif(UNIX)
 325                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 326                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 327                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 328         elseif(WIN32)
 329                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 330         endif()
 331 endif()
 332
 333 if(LYX_INSTALL_PREFIX)
 334         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 335         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 336 endif()
 337 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 338
 339 if(LYX_PACKAGE_SUFFIX)
 340         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 341 else()
 342         set(PACKAGE ${PACKAGE_BASE})
 343 endif()
 344
 345
 346 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 347         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 348         if (UNIX)
 349                 # don't use the default "/usr/local"
 350                 # but respect the user-choice on the command-line
 351                 if(LYX_INSTALL_SUFFIX)
 352                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 353                 else()
 354                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 355                 endif()
 356         endif()
 357         if(WIN32)
 358                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 359         endif()
 360 endif()
 361 if(IS_ABSOLUTE)
 362         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 363 else()
 364         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 365 endif()
 366
 367
 368
 369 if(NOT LYX_DATA_SUBDIR)
 370         if (WIN32)
 371                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 372         else()
 373                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 374         endif()
 375 endif()
 376
 377 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 378 set(LYX_LOCALEDIR "locale")
 379 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 380 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 381
 382
 383 if(LYX_INSTALL AND WIN32)
 384         message(STATUS "Configuring NSIS files")
 385         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 386         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 387         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 388         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 389 endif()
 390
 391 if(NOT GROUP_CODE)
 392         #set(GROUP_CODE "The Golden Code")
 393         set(GROUP_CODE flat)
 394 endif()
 395
 396 # lyx's source files
 397 set(LYX_CPP_FILES *.cpp)
 398 set(LYX_HPP_FILES *.h)
 399 set(LYX_MOC_FILES moc_*.cpp)
 400
 401 include(ProjectSourceGroup)
 402
 403
 404 if(LYX_PROFILE AND NOT MSVC)
 405         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 406         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 407         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 408 else()
 409         set(LYX_PROFILE OFF)
 410 endif()
 411
 412
 413 if(LYX_NO_OPTIMIZE)
 414         set(CMAKE_BUILD_TYPE None)
 415         set(LYX_DEBUG OFF)
 416         set(LYX_RELEASE OFF)
 417         set(LYX_PROFILE OFF)
 418 elseif(LYX_RELEASE)
 419         set(CMAKE_BUILD_TYPE Release)
 420         set(LYX_DEBUG OFF)
 421         set(LYX_PROFILE OFF)
 422 elseif(LYX_PROFILE)
 423         set(CMAKE_BUILD_TYPE Profile)
 424         set(LYX_DEBUG OFF)
 425 else()
 426         set(CMAKE_BUILD_TYPE Debug)
 427         set(LYX_DEBUG ON)
 428 endif()
 429
 430
 431 # When shared libs are supported enable this option
 432 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 433 if(LYX_SHARED_LIBRARIES)
 434         set(library_type SHARED)
 435 else()
 436         set(library_type STATIC)
 437 endif()
 438
 439 if(NOT MSVC)
 440         if(NOT LYX_QUIET)
 441                 set(CMAKE_VERBOSE_MAKEFILE ON)
 442         endif()
 443         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 444         if(LYX_STDLIB_DEBUG)
 445                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 446         endif()
 447         if(LYX_CONCEPT_CHECKS)
 448                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 449         endif()
 450         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 451         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 452         if(MINGW)
 453                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 454         else()
 455                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 456         endif()
 457 endif()
 458
 459
 460 find_package(Qt4 REQUIRED)
 461 find_package(Magic)
 462 if(Magic_FOUND)
 463         set(HAVE_MAGIC_H 1)
 464 endif()
 465
 466 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 467
 468 if(LYX_ASPELL)
 469         find_package(ASPELL)
 470         include_directories(${ASPELL_INCLUDE_DIR})
 471 endif()
 472
 473 if(LYX_ENCHANT)
 474         find_package(Enchant REQUIRED)
 475         include_directories(${ENCHANT_INCLUDE_DIR})
 476 endif()
 477
 478 if(LYX_HUNSPELL)
 479         find_package(Hunspell REQUIRED)
 480         include_directories(${HUNSPELL_INCLUDE_DIR})
 481 endif()
 482
 483 if(LYX_NLS)
 484         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 485         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 486                 message(FATAL_ERROR "Python 2.6 needed!")
 487         endif()
 488         find_package(LyXGettext REQUIRED)
 489         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 490 endif()
 491
 492 if(LYX_NLS)
 493         if(LYX_EXTERNAL_LIBINTL)
 494                 find_package(Libintl REQUIRED)
 495                 if(DEFINED LIBINTL_LIBRARIES)
 496                         # find getext when configuring
 497                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 498                         # on mac use iconv also form ports
 499                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 500                 endif()
 501         else()
 502                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 503         endif()
 504 endif()
 505
 506 if(LYX_EXTERNAL_LIBINTL)
 507         set(intl_link ${LIBINTL_LIBRARIES})
 508 else()
 509         set(intl_link intl)
 510 endif()
 511
 512 find_package(ICONV REQUIRED)
 513 find_package(ZLIB REQUIRED)
 514
 515 if(LYX_EXTERNAL_BOOST)
 516         message(STATUS "Searching for boost")
 517         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 518         if(Boost_FOUND)
 519                 message(STATUS "Boost found")
 520                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 521                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 522         else()
 523                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 524         endif()
 525 else()
 526         if(LYX_USE_TR1_REGEX)
 527                 set(Lyx_Boost_Libraries boost_signals)
 528         else()
 529                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 530         endif()
 531         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 532         include_directories(${TOP_SRC_DIR}/boost)
 533         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 534 endif()
 535
 536
 537
 538
 539 if(WIN32)
 540         if(NOT LYX_CONSOLE)
 541                 set(WIN32_CONSOLE WIN32)
 542                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 543         endif()
 544         if(MSVC)
 545                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 546                 # disable checked iterators for msvc release builds to get maximum speed
 547                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 548         else()
 549                 add_definitions(-DWINVER=0x0500)
 550         endif()
 551 endif()
 552
 553 # Compute qt4-version from ${QTVERSION}
 554
 555 message(STATUS "")
 556 foreach(_v PACKAGE PACKAGE_VERSION
 557         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 558         LYX_ABS_TOP_SRCDIR
 559         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 560         if(NOT DEFINED ${_v})
 561                 message(FATAL_ERROR "${_v} not defined")
 562         endif()
 563         string(SUBSTRING "${_v}                            " 0 28 _v1)
 564         message(STATUS "----- ${_v1}: ${${_v}}")
 565 endforeach(_v)
 566 message(STATUS "")
 567
 568
 569 if(LYX_PCH)
 570         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 571         # Not sure if it works for all non-msvc compilers
 572         include(PCHSupport_26)
 573         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 574         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 575         add_definitions(-DLYX_ENABLE_PCH)
 576
 577         if(MSVC)
 578                 macro(lyx_add_msvc_pch name_)
 579                         set_source_files_properties(${${name_}_sources} PROPERTIES
 580                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 581                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 582                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 583                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 584                                 ${TOP_BINARY_DIR}/pcheaders.h)
 585                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 586                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 587                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 588                 endmacro(lyx_add_msvc_pch)
 589                 macro(lyx_add_gcc_pch name_)
 590                 endmacro()
 591         else()
 592                 macro(lyx_add_msvc_pch name_)
 593                 endmacro()
 594                 macro(lyx_add_gcc_pch name_)
 595                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 596                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 597                 endmacro()
 598         endif()
 599 else()
 600         macro(lyx_add_msvc_pch)
 601         endmacro(lyx_add_msvc_pch)
 602         macro(lyx_add_gcc_pch name_)
 603         endmacro()
 604 endif()
 605
 606
 607 if(MSVC)
 608
 609         if(LYX_VLD)
 610                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 611                 add_subdirectory(${vld_path}/cmake)
 612                 include(${vld_path}/cmake/vld.cmake) # forced include
 613                 set(vld_dll vld)
 614         endif()
 615
 616         if(LYX_WALL)
 617                 # Use the highest warning level
 618                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 619
 620                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 621                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 622                 else()
 623                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 624                 endif()
 625
 626                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 627                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 628                 else()
 629                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 630                 endif()
 631
 632                 # add here warnings which should produce an error /weXXXX
 633                 set(MSVC_W_ERROR   "/we4101 /we4189")
 634                 # add here warnings which should be disabled /wdXXXX
 635                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 636
 637                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 638                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 639                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 640
 641         else()
 642                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 643
 644                 # add here warnings which should produce an error /weXXXX
 645                 set(MSVC_W_ERROR   "/we4101 /we4189")
 646                 # add here warnings which should be disabled /wdXXXX
 647                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 648
 649                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 650                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 651                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 652
 653         endif()
 654         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 655         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 656         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 657
 658         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 659         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 660         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 661         message(STATUS "")
 662 endif()
 663
 664
 665 if(LYX_DEBUG_GLIBC)
 666         set(_GLIBCXX_DEBUG ON)
 667 endif()
 668
 669 if(LYX_DEBUG_GLIBC_PEDANTIC)
 670         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 671 endif()
 672
 673 # Xcode compiler
 674 if (CMAKE_GENERATOR MATCHES Xcode)
 675         # Automatically select the Xcode compiler if not set
 676         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 677                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 678                 if (XCODE_VERSION VERSION_GREATER "3.1")
 679                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 680                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 681         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 682
 683         # Print the selected compiler version
 684     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 685 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 686
 687
 688 # compiler tests, config.h generation
 689 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 690         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 691 else()
 692         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 693         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 694 endif()
 695
 696 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 697
 698 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 699         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 700 endif()
 701
 702 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 703 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 704
 705 set (cmd ${CMAKE_CTEST_COMMAND})
 706 if (MSVC)
 707         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 708 else ()
 709         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 710 endif ()
 711 add_custom_target (lyx_run_tests COMMAND ${cmd})
 712 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 713
 714
 715 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 716 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 717 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 718 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 719
 720
 721 if(LYX_INSTALL)
 722         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 723                 message(STATUS "Python required to create doc!")
 724         else()
 725                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 726                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 727         endif()
 728         if(NOT(LYX_BUNDLE AND APPLE))
 729                 include(../Install)
 730         endif()
 731 endif()
 732
 733 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 734 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 735
 736 message(STATUS)
 737 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 738 message(STATUS)
 739 LYX_OPTION_LIST_ALL(used)
 740
 741
 742 if(LYX_NLS)
 743         message(STATUS)
 744         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 745         message(STATUS)
 746         message(STATUS "  * intl")
 747         message(STATUS "     - header : ${LIBINTL_HEADER}")
 748         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 749         message(STATUS "  * iconv")
 750         message(STATUS "     - header : ${ICONV_HEADER}")
 751         message(STATUS "     - library: ${ICONV_LIBRARY}")
 752         message(STATUS "  * zlib")
 753         message(STATUS "     - header : ${ZLIB_HEADER}")
 754         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 755         message(STATUS)
 756 endif()
 757
 758 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 759
 760 if(ENABLE_DIST)
 761   # Use git to create the source package
 762   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 763   if(UNIX)
 764     set(DIST_FORMAT tgz)
 765   else()
 766     set(DIST_FORMAT zip)
 767   endif()
 768   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 769
 770   add_custom_command(
 771     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 772     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 773     WORKING_DIRECTORY ${TOP_SRC_DIR})
 774   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 775 endif()
 776
 777 message(STATUS)