CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 OLD)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84   # Enable LTO if supported
  85   if (POLICY CMP0069)
  86     cmake_policy(SET CMP0069 NEW)
  87     include(CheckIPOSupported)
  88     check_ipo_supported(RESULT result OUTPUT reason LANGUAGES CXX)
  89     if(result)
  90       message(STATUS "Setting IPO True")
  91       set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
  92     else()
  93       message(STATUS "Not setting IPO , result = ${result}, reason = ${reason}")
  94     endif()
  95   endif()
  96 endif()
  97
  98 if(UNIX)
  99         set(ARCH_TRIPLET )
 100         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
 101         if(DPKG_ARCHITECTURE_EXECUTABLE)
 102                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
 103                                 OUTPUT_VARIABLE ARCH_TRIPLET
 104                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
 105                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
 106         endif()
 107 endif()
 108 if(ARCH_TRIPLET)
 109         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 110 else()
 111         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 112 endif()
 113
 114 include(LyXMacros)
 115 include(LyXDestinations)
 116
 117 # Usage LYX_OPTION
 118 # 1. parameter: option name without prefix 'LYX_'
 119 # 2. parameter: description
 120 # 3. parameter: default value, ON or OFF
 121 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 122
 123 # Usage LYX_COMBO
 124 # 1. parameter: name without prefix 'LYX_'
 125 # 2. parameter: description
 126 # 3. parameter: default value
 127 # 4-n parameter: possible other string values
 128
 129 LYX_OPTION_INIT()
 130
 131 # Options for all compilers/systems
 132 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 133 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 134 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 135 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 136 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 137 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 138 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 139 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 140 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 141 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 142 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 143 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 144 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 145 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 146 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 147 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 148 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 149 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 150 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 151 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 152 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 153 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 154 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 155 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 156 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 157 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 158 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 159 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 160 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 161 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 162 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 163
 164 # GCC specific
 165 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 166 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 167 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 168 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 169 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 170 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 171 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 172
 173 # MSVC specific
 174 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 175 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 176 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 177 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 178
 179 # APPLE specific
 180 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 181 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 182
 183
 184 if(help OR HELP)
 185         message(STATUS)
 186         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 187         message(STATUS)
 188         LYX_OPTION_LIST_ALL(help)
 189         message(STATUS)
 190         RETURN()
 191 endif()
 192
 193 # Check option dependencies
 194
 195 if(LYX_DMG)
 196         set(LYX_BUNDLE ON)
 197         set(LYX_CPACK ON)
 198 endif()
 199
 200 if(LYX_CPACK)
 201         set(LYX_INSTALL ON)
 202 endif()
 203
 204 if(LYX_INSTALL)
 205         set(LYX_NLS ON)
 206         if(WIN32 AND NOT MINGW)
 207                 set(LYX_HUNSPELL ON)
 208         endif()
 209         set(LYX_PACKAGE_SUFFIX ON)
 210         if(NOT LYX_DEBUG)
 211                 set(LYX_RELEASE ON)
 212         endif()
 213         set(LYX_PROFILE OFF)
 214 endif()
 215
 216
 217 if(LYX_MERGE_FILES)
 218         set(LYX_PCH OFF)
 219 else()
 220         set(LYX_MERGE_REBUILD OFF)
 221 endif()
 222
 223 if(LYX_DEPENDENCIES_DOWNLOAD)
 224         message(STATUS)
 225         if(MSVC14)
 226                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 227                 set(deps_files lyx-windows-deps-msvc2015.zip)
 228                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 229                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 230         elseif(MSVC10)
 231                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 232                 set(deps_files lyx-windows-deps-msvc2010.zip)
 233                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 234                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 235         else()
 236                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 237         endif()
 238     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 239         foreach(it ${deps_files})
 240                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 241                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 242                 if(NOT already_downloaded)
 243                         message(STATUS "Downloading ${it} ...")
 244                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 245                         list(GET status 0 status_code)
 246                         list(GET status 1 status_string)
 247                         if(NOT status_code EQUAL 0)
 248                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 249                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 250                         endif()
 251                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 252                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 253                 endif()
 254         endforeach()
 255 endif()
 256
 257
 258
 259 message(STATUS)
 260
 261 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 262 if(WIN32)
 263         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 264 else()
 265         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 266 endif()
 267
 268
 269 # Set to some meaningful default
 270 find_package(CXX11Compiler)
 271 if(NOT CXX11COMPILER_FOUND)
 272         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 273 endif()
 274 set(LYX_GCC11_MODE)
 275 if(UNIX OR MINGW)
 276         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 277           # ignore the GCC_VERSION for clang
 278           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 279           message(STATUS "Using clang")
 280           if(CXX11_STD_REGEX)
 281             set(LYX_USE_STD_REGEX 1)
 282           else()
 283             set(LYX_USE_STD_REGEX 0)
 284           endif()
 285         else()
 286           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 287           message(STATUS "Using GCC version ${GCC_VERSION}")
 288           if(GCC_VERSION VERSION_LESS 4.9)
 289                   if(GCC_VERSION VERSION_LESS 4.6)
 290                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 291                   endif()
 292                   # <regex> in gcc is unusable in versions less than 4.9.0
 293                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 294                   set(LYX_USE_STD_REGEX 0)
 295           else()
 296                   set(LYX_USE_STD_REGEX 1)
 297           endif()
 298         endif()
 299         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 300 else()
 301         if(MSVC_VERSION LESS 1915)
 302                 set(LYX_USE_STD_REGEX 0)
 303         else()
 304                 set(LYX_USE_STD_REGEX 1)
 305         endif()
 306 endif()
 307
 308
 309 set(VERSION_INFO "CMake Build")
 310
 311 # Try to get some informations from configure.ac
 312
 313 include(LyXPaths)
 314 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 315
 316 if(WIN32)
 317         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 318         if(MSVC)
 319                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 320         endif()
 321         set(USE_WINDOWS_PACKAGING ON)
 322 elseif(APPLE)
 323         set(USE_MACOSX_PACKAGING ON)
 324 else()
 325         set(USE_POSIX_PACKAGING ON)
 326 endif()
 327
 328 if(LYX_3RDPARTY_BUILD)
 329   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 330   # this enables the build of all 3rd_party libs
 331   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 332   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 333   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 334   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 335 endif()
 336
 337 macro(setstripped _varname)
 338         if(${ARGC} GREATER 1)
 339                 string(STRIP "${ARGV1}" _v)
 340                 message(STATUS "1. _v = ${_varname} ${_v}")
 341                 if (_v MATCHES "^\\[\(.+\)\\]$")
 342                   set(_v ${CMAKE_MATCH_1})
 343                 endif()
 344                 message(STATUS "2. _v = ${_v}")
 345                 if(USE_POSIX_PACKAGING)
 346                         string(TOLOWER ${_v} ${_varname})
 347                 else()
 348                         set(${_varname} ${_v})
 349                 endif()
 350         else()
 351                 set(${_varname})
 352         endif()
 353 endmacro(setstripped)
 354
 355 foreach(_c_l ${_config_lines} )
 356         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 357                 set(_PB ${CMAKE_MATCH_1})
 358                 set(_PV ${CMAKE_MATCH_2})
 359                 set(_PBU ${CMAKE_MATCH_3})
 360                 setstripped(PACKAGE_BASE ${_PB})
 361                 setstripped(PACKAGE_VERSION ${_PV})
 362                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 363                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 364                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 365                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 366                         set(LYX_RELEASE_VERSION ${CMAKE_MATCH_4})
 367                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 368                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 369                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 370                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 371                         else()
 372                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 373                         endif()
 374                 endif()
 375         endif()
 376         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 377                 set(LYX_DATE "${CMAKE_MATCH_1}")
 378         endif()
 379 endforeach(_c_l)
 380
 381 FIND_PROGRAM(LYX_GITVERSION git)
 382 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 383 set(LYX_REVISION_VERSION ${LYX_RELEASE_VERSION})
 384 set(LYX_PACKAGE_RELEASE "1")
 385 if(LYX_GITVERSION)
 386   if (LYX_LOCALVERSIONING)
 387     # Find the revision number and for later use
 388     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 389       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 390     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 391       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 392       # We will add offset of 40000 to get appropriate value to
 393       # previous svn.
 394       # We use this value than also to set the package-patch-value
 395       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 396       set(LYX_REVISION_VERSION "${LYX_RELEASE_VERSION}-${tmp_REVISION_VERSION}git")
 397       set(ENABLE_DIST ON)
 398     endif()
 399   endif()
 400 endif()
 401
 402 # Set the programs (lyx, tex2lyx, etc.) suffix
 403 # When building an OS X bundle, we will append
 404 # the suffix only to the bundle, not to the programs
 405 set(PROGRAM_SUFFIX "")
 406 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 407         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 408 endif()
 409 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 410 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 411 set(_convert lyxconvert${PROGRAM_SUFFIX})
 412
 413 add_custom_target(lyx_version ALL
 414   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 415   )
 416 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 417
 418 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 419 set(LYX_UTILITIES_INSTALL_PATH bin)
 420
 421 if(LYX_BUNDLE)
 422         set(LYX_CPACK ON)
 423
 424         message(STATUS)
 425         message(STATUS "Bundle creation is enabled (experimental):")
 426         message(STATUS "    make")
 427         message(STATUS "    make install/strip")
 428         message(STATUS "    make package")
 429         if(APPLE)
 430                 set(MACOSX_BUNDLE TRUE)
 431                 # This sets the bundle + executable names
 432                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 433                 # This sets the Info.plist executable name
 434                 set(osx_bundle_program_name ${_lyx})
 435                 # Bundle name
 436                 set(LYX_BUNDLE_NAME ${_lyx})
 437
 438                 # This will contain the list of files that need to be included
 439                 # in the bundle and their location within the bundle
 440                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 441                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 442
 443                 # Process Info.plist and lyxrc.dist
 444                 # See development/cmake/Install.cmake
 445                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 446
 447                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 448                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 449
 450                 # Variables used by CPack
 451                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 452                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 453                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 454
 455                 # Set the install paths
 456                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 457                 if(NOT LYX_INSTALL_PREFIX)
 458                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 459                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 460                 endif()
 461                 # Change the owner so that the install can work
 462                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 463         elseif(UNIX)
 464                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 465                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 466                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 467         elseif(WIN32)
 468                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 469         endif()
 470 endif()
 471
 472 if(LYX_INSTALL_PREFIX)
 473         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 474         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 475 endif()
 476 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 477
 478 if(UNIX)
 479   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 480 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 481   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 482 else()
 483   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 484 endif()
 485
 486 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 487   # Not a GCC compiler, programs do not have a suffix
 488   set(suffixing ${LYX_PACKAGE_SUFFIX})
 489 elseif(WIN32 AND MINGW)
 490   # We want to use a suffix for the package in this case,
 491   # even if not for the program
 492   set(suffixing ${LYX_PACKAGE_SUFFIX})
 493 else()
 494   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 495   set(suffixing ${LYX_PROGRAM_SUFFIX})
 496 endif()
 497
 498 # The define PACKAGE below allows lyx-executable to find its default configuration files
 499 # see routines
 500 #    Package::messages_file()
 501 #    get_default_user_support_dir()
 502 #    relative_system_support_dir()
 503 # in src/support/Package.cpp
 504 if(suffixing)
 505         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 506 else()
 507         set(PACKAGE ${PACKAGE_BASE})
 508 endif()
 509
 510 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 511         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 512         if (UNIX)
 513                 # use the default "/usr/local"
 514                 # but respect the user-choice on the command-line
 515                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 516         endif()
 517 endif()
 518 if(WIN32)
 519         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 520 endif()
 521 if(IS_ABSOLUTE)
 522         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 523 else()
 524         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 525 endif()
 526
 527
 528
 529 if(NOT LYX_DATA_SUBDIR)
 530         if (WIN32)
 531                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 532         else()
 533                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 534         endif()
 535 endif()
 536
 537 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 538 get_locale_destination(LYX_LOCALEDIR)
 539 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 540 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 541
 542 if(LYX_BUNDLE AND APPLE)
 543         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 544 else()
 545         if(WIN32)
 546                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 547         elseif(UNIX)
 548                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 549         else()
 550                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 551         endif()
 552 endif()
 553 mark_as_advanced(LYX_MAN_DIR)
 554
 555 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 556 # see the Readme.txt of the installer
 557 #if(LYX_INSTALL AND WIN32)
 558 #       message(STATUS "Configuring NSIS files")
 559 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 560 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 561 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 562 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 563 #endif()
 564
 565 if(NOT GROUP_CODE)
 566         #set(GROUP_CODE "The Golden Code")
 567         set(GROUP_CODE flat)
 568 endif()
 569
 570 # lyx's source files
 571 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 572 set(LYX_HPP_FILES [a-zA-Z]*.h)
 573 set(LYX_MOC_FILES moc_*.cpp)
 574
 575 include(ProjectSourceGroup)
 576
 577
 578 if(LYX_PROFILE AND NOT MSVC)
 579         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 580         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 581         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 582 else()
 583         set(LYX_PROFILE OFF)
 584 endif()
 585
 586
 587 if(LYX_NO_OPTIMIZE)
 588         set(CMAKE_BUILD_TYPE None)
 589         set(LYX_DEBUG OFF)
 590         set(LYX_RELEASE OFF)
 591         set(LYX_PROFILE OFF)
 592 elseif(LYX_RELEASE)
 593         set(CMAKE_BUILD_TYPE Release)
 594         set(LYX_DEBUG OFF)
 595         set(LYX_PROFILE OFF)
 596 elseif(LYX_PROFILE)
 597         set(CMAKE_BUILD_TYPE Profile)
 598         set(LYX_DEBUG OFF)
 599 else()
 600         set(CMAKE_BUILD_TYPE Debug)
 601         set(LYX_DEBUG ON)
 602 endif()
 603
 604
 605 # When shared libs are supported enable this option
 606 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 607 if(LYX_SHARED_LIBRARIES)
 608         set(library_type SHARED)
 609 else()
 610         set(library_type STATIC)
 611 endif()
 612
 613 if(NOT MSVC)
 614         if(NOT LYX_QUIET)
 615                 set(CMAKE_VERBOSE_MAKEFILE ON)
 616         endif()
 617         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 618         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 619           # Thanks to Brad King <brad.king@kitware.com>
 620           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 621           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 622           # and still use our own c++ extension tests
 623           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 624           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 625         endif()
 626         if(LYX_STDLIB_DEBUG)
 627                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 628         endif()
 629         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 630         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 631         if(MINGW)
 632                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 633         else()
 634                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 635         endif()
 636 endif()
 637
 638 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 639 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 640 if(LYX_CXX_FLAGS_EXTRA)
 641         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 642                 add_definitions(${_flag})
 643         endforeach()
 644 endif()
 645
 646 if(LYX_XMINGW)
 647         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 648 endif()
 649
 650 set(min_qt5_version "5.6")
 651 if(LYX_USE_QT MATCHES "AUTO")
 652         # try qt5 first
 653         find_package(Qt5Core CONFIG QUIET)
 654         if(Qt5Core_FOUND)
 655                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 656                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 657                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 658                         find_package(Qt4 "4.5.0" QUIET)
 659                         if(QT4_FOUND)
 660                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 661                         endif()
 662                 endif()
 663         else()
 664                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 665         endif()
 666 endif()
 667 if(LYX_USE_QT MATCHES "QT5")
 668         # set QPA_XCB if QT uses X11
 669         find_package(Qt5Core CONFIG REQUIRED)
 670         if (Qt5Core_FOUND)
 671                 find_package(Qt5Widgets CONFIG REQUIRED)
 672                 if(APPLE)
 673                         find_package(Qt5MacExtras CONFIG REQUIRED)
 674                 endif()
 675                 find_package(Qt5X11Extras CONFIG QUIET)
 676                 find_package(Qt5WinExtras CONFIG QUIET)
 677                 set(QTVERSION ${Qt5Core_VERSION})
 678                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 679                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 680                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 681                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 682                         # see thread in lyx-devel list
 683                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 684                         # Date 11.03.2017
 685                         # Subject: cmake compilation error
 686                         #message(FATAL_ERROR "Wrong Qt-Version")
 687                 endif()
 688                 macro (qt_use_modules lyxtarget)
 689                         foreach (_tg ${ARGN})
 690                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 691                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 692                         endforeach()
 693                 endmacro()
 694                 macro (qt_add_resources)
 695                         qt5_add_resources(${ARGN})
 696                 endmacro()
 697                 macro (qt_wrap_uifiles)
 698                         qt5_wrap_ui(${ARGN})
 699                 endmacro()
 700                 message(STATUS "Found Qt-Version ${QTVERSION}")
 701                 if(WIN32)
 702                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 703                 endif()
 704         endif()
 705 elseif(LYX_USE_QT MATCHES "QT4")
 706         if(LYX_XMINGW)
 707                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 708                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 709         endif()
 710         find_package(Qt4 "4.5.0" REQUIRED)
 711         macro (qt_use_modules)
 712         endmacro()
 713         macro (qt_add_resources)
 714                 qt4_add_resources(${ARGN})
 715         endmacro()
 716         macro (qt_wrap_uifiles)
 717                 qt4_wrap_ui(${ARGN})
 718         endmacro()
 719         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 720         if(WIN32)
 721                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 722         endif()
 723 else()
 724   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 725 endif()
 726
 727 find_package(Magic)
 728 if(Magic_FOUND)
 729   set(HAVE_MAGIC_H 1)
 730   include_directories(${Magic_INCLUDE_DIR})
 731 endif()
 732
 733 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 734
 735 set(Spelling_FOUND OFF)
 736 set(Include_used_spellchecker)   # String will be inserted into config.h
 737
 738 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 739   # try system library first
 740   find_package(MyThesLIB)
 741   if (MYTHESLIB_FOUND)
 742     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 743   else()
 744     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 745   endif()
 746 endif()
 747 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 748   find_package(MyThesLIB REQUIRED)
 749 else()
 750   add_subdirectory(3rdparty/mythes)
 751 endif()
 752 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 753
 754 if(NOT LYX_EXTERNAL_HUNSPELL)
 755     add_subdirectory(3rdparty/hunspell)
 756     add_definitions(-DHUNSPELL_STATIC)
 757     set(HUNSPELL_FOUND ON)
 758     message(STATUS "  * Hunspell:")
 759     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 760     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 761 endif()
 762
 763 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 764   string(TOUPPER ${_spell} _upspell)
 765   if (NOT ${_upspell}_FOUND)
 766     find_package(${_spell})
 767   endif()
 768   if (${_upspell}_FOUND)
 769     include_directories(${${_upspell}_INCLUDE_DIR})
 770     set(Spelling_FOUND ON)
 771     message(STATUS "Building with USE_${_upspell}")
 772     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 773   else()
 774     if(LYX_${_upspell})
 775       message(FATAL_ERROR "Required ${_spell} devel package not found")
 776     else()
 777       message(STATUS "${_upspell} not found, building without ${_spell} support")
 778     endif()
 779   endif()
 780 endforeach()
 781
 782 if(GNUWIN32_DIR)
 783         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 784 endif()
 785
 786 # Search for python default version first
 787 unset(PYTHON_EXECUTABLE CACHE)
 788 unset(LYX_PYTHON_EXECUTABLE CACHE)
 789 unset(PYTHON_VERSION_MAJOR)
 790 unset(PYTHON_VERSION_MINOR)
 791 unset(PYTHON_VERSION_STRING)
 792 find_package(PythonInterp 3.3 QUIET)
 793 if(NOT PYTHONINTERP_FOUND)
 794   unset(PYTHON_EXECUTABLE CACHE)
 795   find_package(PythonInterp 2.0 REQUIRED)
 796   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 797     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 798   endif()
 799 endif()
 800
 801 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 802
 803 if(LYX_NLS)
 804         find_package(LyXGettext)
 805         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 806                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 807         else()
 808                 # Install only supplied .gmo-files
 809                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 810                 message(STATUS "Installing provided .gmo-files only")
 811                 foreach( _gmo ${_gmofiles})
 812                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 813                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 814                 endforeach()
 815         endif()
 816 endif()
 817
 818 if(LYX_EXTERNAL_ICONV)
 819   find_package(ICONV REQUIRED)
 820 else()
 821   add_subdirectory(3rdparty/libiconv)
 822   set(HAVE_ICONV_CONST 1)
 823 endif()
 824
 825 if(LYX_EXTERNAL_Z)
 826   find_package(ZLIB REQUIRED)
 827 else()
 828   add_subdirectory(3rdparty/zlib)
 829 endif()
 830
 831 if(LYX_USE_STD_REGEX)
 832   # Set only include path.
 833   # Use internal boost, which is known to exist
 834   # we don't need any libraries
 835   set(Lyx_Boost_Libraries)
 836   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 837   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 838 else()
 839   # Using boost-regex
 840   if(LYX_EXTERNAL_BOOST)
 841     message(STATUS "Searching for external boost")
 842     find_package(Boost COMPONENTS regex)
 843     if(Boost_FOUND)
 844       message(STATUS "Boost found")
 845       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 846       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 847       if (LYX_STDLIB_DEBUG)
 848         # Comment from  Jean-Marc Lasgouttes:
 849         # In general, system boost libraries are incompatible with
 850         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 851         # details.
 852         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 853       endif()
 854     else()
 855       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 856     endif()
 857   else()
 858     # Using included boost
 859     set(Lyx_Boost_Libraries boost_regex)
 860     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 861     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 862     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 863   endif()
 864 endif()
 865
 866 if(WIN32)
 867         if(LYX_CONSOLE)
 868                 set(LYX_QTMAIN_LIBRARY)
 869         else()
 870                 set(WIN32_CONSOLE WIN32)
 871         endif()
 872         if(MSVC)
 873                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 874                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 875                 # disable checked iterators for msvc release builds to get maximum speed
 876                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 877         else()
 878                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 879                 # does not use it and always declares the vista compatible API.
 880                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 881                 add_definitions(-DWINVER=0x0500)
 882         endif()
 883 endif()
 884
 885 # Compute qt-version from ${QTVERSION}
 886
 887 message(STATUS "")
 888 foreach(_v PACKAGE PACKAGE_VERSION
 889         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 890         LYX_ABS_TOP_SRCDIR
 891         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 892         if(NOT DEFINED ${_v})
 893                 message(FATAL_ERROR "${_v} not defined")
 894         endif()
 895         string(SUBSTRING "${_v}                            " 0 28 _v1)
 896         message(STATUS "----- ${_v1}: ${${_v}}")
 897 endforeach(_v)
 898 message(STATUS "")
 899
 900
 901 if(LYX_PCH)
 902         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 903         # Not sure if it works for all non-msvc compilers
 904         include(PCHSupport_26)
 905         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 906         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 907         add_definitions(-DLYX_ENABLE_PCH)
 908
 909         if(MSVC)
 910                 macro(lyx_add_msvc_pch name_)
 911                         set_source_files_properties(${${name_}_sources} PROPERTIES
 912                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 913                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 914                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 915                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 916                                 ${TOP_BINARY_DIR}/pcheaders.h)
 917                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 918                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 919                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 920                 endmacro(lyx_add_msvc_pch)
 921                 macro(lyx_add_gcc_pch name_)
 922                 endmacro()
 923         else()
 924                 macro(lyx_add_msvc_pch name_)
 925                 endmacro()
 926                 macro(lyx_add_gcc_pch name_)
 927                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 928                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 929                 endmacro()
 930         endif()
 931 else()
 932         macro(lyx_add_msvc_pch)
 933         endmacro(lyx_add_msvc_pch)
 934         macro(lyx_add_gcc_pch name_)
 935         endmacro()
 936 endif()
 937
 938
 939 if(MSVC)
 940
 941         if(LYX_VLD)
 942                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 943                 add_subdirectory(${vld_path}/cmake)
 944                 include(${vld_path}/cmake/vld.cmake) # forced include
 945                 set(vld_dll vld)
 946         endif()
 947
 948         if(LYX_WALL)
 949                 # Use the highest warning level
 950                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
 951
 952                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 953                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 954                 else()
 955                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 956                 endif()
 957
 958                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 959                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 960                 else()
 961                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 962                 endif()
 963
 964                 # add here warnings which should produce an error /weXXXX
 965                 set(MSVC_W_ERROR   "/we4101 /we4189")
 966                 # add here warnings which should be disabled /wdXXXX
 967                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 968
 969                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 970                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 971                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 972
 973         else()
 974                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
 975
 976                 # add here warnings which should produce an error /weXXXX
 977                 set(MSVC_W_ERROR   "/we4101 /we4189")
 978                 # add here warnings which should be disabled /wdXXXX
 979                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 980
 981                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 982                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 983                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 984
 985         endif()
 986
 987         if (NOT Qt5Core_FOUND)
 988                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 989                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 990                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 991         endif()
 992
 993         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 994         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 995         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 996         message(STATUS "")
 997 endif()
 998
 999
1000 if(LYX_DEBUG_GLIBC)
1001         set(_GLIBCXX_DEBUG ON)
1002 endif()
1003
1004 if(LYX_DEBUG_GLIBC_PEDANTIC)
1005         set(_GLIBCXX_DEBUG_PEDANTIC ON)
1006 endif()
1007
1008 # Xcode compiler
1009 if (CMAKE_GENERATOR MATCHES Xcode)
1010         if (XCODE_VERSION VERSION_LESS "5.0")
1011                 # Automatically select the Xcode compiler if not set
1012                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1013                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1014                         if (XCODE_VERSION VERSION_GREATER "3.1")
1015                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1016                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1017                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1018                 # Print the selected compiler version
1019         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1020         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1021 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1022
1023 if (WIN32 AND Qt5Core_FOUND)
1024         set(Z_PREFIX 1)
1025 endif()
1026
1027 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1028 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1029 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1030
1031 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1032
1033 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1034         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1035 endif()
1036
1037 if (NOT HAVE_REGEX)
1038         set(LYX_USE_STD_REGEX 0)
1039 endif()
1040
1041
1042 set (cmd ${CMAKE_CTEST_COMMAND})
1043 if (MSVC)
1044         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1045 else ()
1046         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1047 endif ()
1048 add_custom_target (lyx_run_tests COMMAND ${cmd})
1049 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1050
1051 if(LYX_ASAN)
1052     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1053     message(STATUS)
1054     message(STATUS "Address sanitizer enabled. Usage:")
1055     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1056     message(STATUS "    chmod  +x ./asan_symbolize.py")
1057     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1058     message(STATUS)
1059 endif()
1060
1061 if(LYX_INSTALL)
1062         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1063                 message(STATUS "Python required to create doc!")
1064         else()
1065                 if(UNIX)
1066                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1067                 endif()
1068                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1069         endif()
1070 endif()
1071 include(../Install)
1072
1073 # By running the URL tests first, time can be saved when running the ctests in
1074 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1075 if(LYX_ENABLE_URLTESTS)
1076         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1077 endif()
1078 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1079 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1080 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1081 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1082 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1083 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1084 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1085
1086 message(STATUS)
1087 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1088 message(STATUS)
1089
1090 LYX_OPTION_LIST_ALL(used)
1091
1092
1093 if(LYX_NLS)
1094         message(STATUS)
1095         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1096         message(STATUS)
1097         message(STATUS "  * iconv")
1098         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1099         message(STATUS "     - library: ${ICONV_LIBRARY}")
1100         message(STATUS "  * zlib")
1101         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1102         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1103         message(STATUS)
1104 endif()
1105
1106 # Apple has builtin native spell checker,
1107 # no need to warn for missing Aspell, Hunspell or Enchant
1108 if(NOT Spelling_FOUND AND NOT APPLE)
1109   if(LYX_REQUIRE_SPELLCHECK)
1110     set(_mode "FATAL_ERROR")
1111   else()
1112     set(_mode "STATUS")
1113   endif()
1114   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1115 endif()
1116
1117 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1118
1119 if(ENABLE_DIST)
1120   # Use git to create the source package
1121   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1122   if(UNIX)
1123     set(DIST_FORMAT tgz)
1124   else()
1125     set(DIST_FORMAT zip)
1126   endif()
1127   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1128
1129   add_custom_command(
1130     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1131     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1132     WORKING_DIRECTORY ${TOP_SRC_DIR})
1133   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1134 endif()
1135
1136 # Last directory to be included so that the fixup code (OS X)
1137 # can be run last
1138 add_subdirectory(development/cmake/post_install)
1139
1140 message(STATUS)