CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50 endif()
  51
  52 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  53
  54 # Supress regeneration
  55 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  56
  57 if(LYX_XMINGW)
  58     set(CMAKE_SYSTEM_NAME Windows)
  59     set(TOOLNAME ${LYX_XMINGW})
  60     set(TOOLCHAIN "${TOOLNAME}-")
  61     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  62     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  63     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  64
  65     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  66     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  68 endif()
  69
  70 if(NOT help AND NOT HELP)
  71   # 'project' triggers the searching for a compiler
  72   project(${LYX_PROJECT})
  73   if (CMAKE_COMPILER_IS_GNUCXX)
  74     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  75       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  76       message(STATUS "is too old, should be >= 4.0")
  77       message(FATAL_ERROR "Exiting")
  78     endif()
  79   endif()
  80 endif()
  81
  82 if(UNIX)
  83         set(ARCH_TRIPLET )
  84         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  85         if(DPKG_ARCHITECTURE_EXECUTABLE)
  86                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  87                                 OUTPUT_VARIABLE ARCH_TRIPLET
  88                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  89                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  90         endif()
  91 endif()
  92 if(ARCH_TRIPLET)
  93         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  94 else()
  95         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  96 endif()
  97
  98 include(LyXMacros)
  99 include(LyXDestinations)
 100
 101 # Usage LYX_OPTION
 102 # 1. parameter: option name without prefix 'LYX_'
 103 # 2. parameter: description
 104 # 3. parameter: default value, ON or OFF
 105 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 106
 107 # Usage LYX_COMBO
 108 # 1. parameter: name without prefix 'LYX_'
 109 # 2. parameter: description
 110 # 3. parameter: default value
 111 # 4-n parameter: possible other string values
 112
 113 LYX_OPTION_INIT()
 114
 115 # Options for all compilers/systems
 116 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 117 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 118 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 119 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 120 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 121 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 122 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 123 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 124 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 125 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 126 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 127 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 128 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 129 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 130 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 131 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 132 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 133 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 134 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 135 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 136 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 137 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 138 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 139 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 140 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 141 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 142 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 143 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 144 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 145
 146 # GCC specific
 147 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 148 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 149 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 150 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 151 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 152 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 153 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 154
 155 # MSVC specific
 156 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 157 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 158 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160
 161 # APPLE specific
 162 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 163 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 164
 165
 166 if(help OR HELP)
 167         message(STATUS)
 168         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 169         message(STATUS)
 170         LYX_OPTION_LIST_ALL(help)
 171         message(STATUS)
 172         RETURN()
 173 endif()
 174
 175 # Check option dependencies
 176
 177 if(LYX_DMG)
 178         set(LYX_BUNDLE ON)
 179         set(LYX_CPACK ON)
 180 endif()
 181
 182 if(LYX_CPACK)
 183         set(LYX_INSTALL ON)
 184 endif()
 185
 186 if(LYX_INSTALL)
 187         set(LYX_NLS ON)
 188         if(WIN32 AND NOT MINGW)
 189                 set(LYX_HUNSPELL ON)
 190         endif()
 191         if(LYX_CONSOLE MATCHES "FORCE")
 192                 set(LYX_CONSOLE ON)
 193         else()
 194                 set(LYX_CONSOLE OFF)
 195         endif()
 196         set(LYX_PACKAGE_SUFFIX ON)
 197         if(NOT LYX_DEBUG)
 198                 set(LYX_RELEASE ON)
 199         endif()
 200         set(LYX_PROFILE OFF)
 201 endif()
 202
 203
 204 if(LYX_MERGE_FILES)
 205         set(LYX_PCH OFF)
 206 else()
 207         set(LYX_MERGE_REBUILD OFF)
 208 endif()
 209
 210 if(LYX_DEPENDENCIES_DOWNLOAD)
 211         message(STATUS)
 212         if(MSVC14)
 213                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 214                 set(deps_files lyx-windows-deps-msvc2015.zip)
 215                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 216                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 217         elseif(MSVC10)
 218                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 219                 set(deps_files lyx-windows-deps-msvc2010.zip)
 220                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 221                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 222         else()
 223                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 224         endif()
 225     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 226         foreach(it ${deps_files})
 227                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 228                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 229                 if(NOT already_downloaded)
 230                         message(STATUS "Downloading ${it} ...")
 231                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 232                         list(GET status 0 status_code)
 233                         list(GET status 1 status_string)
 234                         if(NOT status_code EQUAL 0)
 235                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 236                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 237                         endif()
 238                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 239                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 240                 endif()
 241         endforeach()
 242 endif()
 243
 244
 245
 246 message(STATUS)
 247
 248 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 249 if(WIN32)
 250         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 251 else()
 252         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 253 endif()
 254
 255
 256 # Set to some meaningful default
 257 find_package(CXX11Compiler)
 258 if(NOT CXX11COMPILER_FOUND)
 259         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 260 endif()
 261 set(LYX_GCC11_MODE)
 262 if(UNIX OR MINGW)
 263         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 264           # ignore the GCC_VERSION for clang
 265           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 266           message(STATUS "Using clang")
 267           if(CXX11_STD_REGEX)
 268             set(LYX_USE_STD_REGEX 1)
 269           else()
 270             set(LYX_USE_STD_REGEX 0)
 271           endif()
 272         else()
 273           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 274           message(STATUS "Using GCC version ${GCC_VERSION}")
 275           if(GCC_VERSION VERSION_LESS 4.9)
 276                   if(GCC_VERSION VERSION_LESS 4.6)
 277                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 278                   endif()
 279                   # <regex> in gcc is unusable in versions less than 4.9.0
 280                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 281                   set(LYX_USE_STD_REGEX 0)
 282           else()
 283                   set(LYX_USE_STD_REGEX 1)
 284           endif()
 285         endif()
 286         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 287 else()
 288         set(LYX_USE_STD_REGEX 0)
 289 #       if(MSVC10)
 290 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 291 #       endif()
 292 endif()
 293
 294
 295 set(VERSION_INFO "CMake Build")
 296
 297 # Try to get some informations from configure.ac
 298
 299 include(LyXPaths)
 300 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 301
 302 if(WIN32)
 303         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 304         if(MSVC)
 305                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 306         endif()
 307         set(USE_WINDOWS_PACKAGING ON)
 308 elseif(APPLE)
 309         set(USE_MACOSX_PACKAGING ON)
 310 else()
 311         set(USE_POSIX_PACKAGING ON)
 312 endif()
 313
 314 if(LYX_3RDPARTY_BUILD)
 315   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 316   # this enables the build of all 3rd_party libs
 317   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 318   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 319   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 320   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 321 endif()
 322
 323 macro(setstripped _varname)
 324         if(${ARGC} GREATER 1)
 325                 string(STRIP "${ARGV1}" _v)
 326                 if(USE_POSIX_PACKAGING)
 327                         string(TOLOWER ${_v} ${_varname})
 328                 else()
 329                         set(${_varname} ${_v})
 330                 endif()
 331         else()
 332                 set(${_varname})
 333         endif()
 334 endmacro(setstripped)
 335
 336 foreach(_c_l ${_config_lines} )
 337         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 338                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 339                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 340                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 341                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 342                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 343                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 344                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 345                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 346                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 347                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 348                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 349                         else()
 350                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 351                         endif()
 352                 endif()
 353         endif()
 354         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 355                 set(LYX_DATE "${CMAKE_MATCH_1}")
 356         endif()
 357 endforeach(_c_l)
 358
 359 FIND_PROGRAM(LYX_GITVERSION git)
 360 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 361 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 362 set(LYX_PACKAGE_RELEASE "1")
 363 if(LYX_GITVERSION)
 364   if (LYX_LOCALVERSIONING)
 365     # Find the revision number and for later use
 366     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 367       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 368     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 369       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 370       # We will add offset of 40000 to get appropriate value to
 371       # previous svn.
 372       # We use this value than also to set the package-patch-value
 373       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 374       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 375       set(ENABLE_DIST ON)
 376     endif()
 377   endif()
 378 endif()
 379
 380 # Set the programs (lyx, tex2lyx, etc.) suffix
 381 # When building an OS X bundle, we will append
 382 # the suffix only to the bundle, not to the programs
 383 set(PROGRAM_SUFFIX "")
 384 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 385         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 386 endif()
 387 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 388 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 389 set(_convert lyxconvert${PROGRAM_SUFFIX})
 390
 391 add_custom_target(lyx_version ALL
 392   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 393   )
 394 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 395
 396 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 397 set(LYX_UTILITIES_INSTALL_PATH bin)
 398
 399 if(LYX_BUNDLE)
 400         set(LYX_CPACK ON)
 401
 402         message(STATUS)
 403         message(STATUS "Bundle creation is enabled (experimental):")
 404         message(STATUS "    make")
 405         message(STATUS "    make install/strip")
 406         message(STATUS "    make package")
 407         if(APPLE)
 408                 set(MACOSX_BUNDLE TRUE)
 409                 # This sets the bundle + executable names
 410                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 411                 # This sets the Info.plist executable name
 412                 set(osx_bundle_program_name ${_lyx})
 413                 # Bundle name
 414                 set(LYX_BUNDLE_NAME ${_lyx})
 415
 416                 # This will contain the list of files that need to be included
 417                 # in the bundle and their location within the bundle
 418                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 419                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 420
 421                 # Process Info.plist and lyxrc.dist
 422                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 423                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 424
 425                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 426                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 427
 428                 # Variables used by CPack
 429                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 430                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 431                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 432
 433                 # Set the install paths
 434                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 435                 if(NOT LYX_INSTALL_PREFIX)
 436                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 437                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 438                 endif()
 439                 # Change the owner so that the install can work
 440                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 441         elseif(UNIX)
 442                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 443                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 444                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 445         elseif(WIN32)
 446                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 447         endif()
 448 endif()
 449
 450 if(LYX_INSTALL_PREFIX)
 451         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 452         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 453 endif()
 454 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 455
 456 if(UNIX)
 457   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 458 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 459   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 460 else()
 461   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 462 endif()
 463
 464 if(CMAKE_COMPILER_IS_GNUCXX)
 465   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 466   set(suffixing ${LYX_PROGRAM_SUFFIX})
 467 else()
 468   # Not a GCC compiler, programs do not have a suffix
 469   set(suffixing ${LYX_PACKAGE_SUFFIX})
 470 endif()
 471
 472 # The define PACKAGE below allows lyx-executable to find its default configuration files
 473 # see routines
 474 #    Package::messages_file()
 475 #    get_default_user_support_dir()
 476 #    relative_system_support_dir()
 477 # in src/support/Package.cpp
 478 #
 479 if(suffixing)
 480         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 481 else()
 482         set(PACKAGE ${PACKAGE_BASE})
 483 endif()
 484
 485 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 486         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 487         if (UNIX)
 488                 # use the default "/usr/local"
 489                 # but respect the user-choice on the command-line
 490                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 491         endif()
 492 endif()
 493 if(WIN32)
 494         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 495 endif()
 496 if(IS_ABSOLUTE)
 497         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 498 else()
 499         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 500 endif()
 501
 502
 503
 504 if(NOT LYX_DATA_SUBDIR)
 505         if (WIN32)
 506                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 507         else()
 508                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 509         endif()
 510 endif()
 511
 512 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 513 get_locale_destination(LYX_LOCALEDIR)
 514 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 515 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 516
 517 if(LYX_BUNDLE AND APPLE)
 518         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 519 else()
 520         if(WIN32)
 521                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 522         elseif(UNIX)
 523                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 524         else()
 525                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 526         endif()
 527 endif()
 528 mark_as_advanced(LYX_MAN_DIR)
 529
 530 # The Win installer cannot be built by Cmake because one needs to install plugins for NSIS
 531 # see the Readme.txt of the installer
 532 #if(LYX_INSTALL AND WIN32)
 533 #       message(STATUS "Configuring NSIS files")
 534 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 535 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 536 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 537 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 538 #endif()
 539
 540 if(NOT GROUP_CODE)
 541         #set(GROUP_CODE "The Golden Code")
 542         set(GROUP_CODE flat)
 543 endif()
 544
 545 # lyx's source files
 546 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 547 set(LYX_HPP_FILES [a-zA-Z]*.h)
 548 set(LYX_MOC_FILES moc_*.cpp)
 549
 550 include(ProjectSourceGroup)
 551
 552
 553 if(LYX_PROFILE AND NOT MSVC)
 554         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 555         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 556         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 557 else()
 558         set(LYX_PROFILE OFF)
 559 endif()
 560
 561
 562 if(LYX_NO_OPTIMIZE)
 563         set(CMAKE_BUILD_TYPE None)
 564         set(LYX_DEBUG OFF)
 565         set(LYX_RELEASE OFF)
 566         set(LYX_PROFILE OFF)
 567 elseif(LYX_RELEASE)
 568         set(CMAKE_BUILD_TYPE Release)
 569         set(LYX_DEBUG OFF)
 570         set(LYX_PROFILE OFF)
 571 elseif(LYX_PROFILE)
 572         set(CMAKE_BUILD_TYPE Profile)
 573         set(LYX_DEBUG OFF)
 574 else()
 575         set(CMAKE_BUILD_TYPE Debug)
 576         set(LYX_DEBUG ON)
 577 endif()
 578
 579
 580 # When shared libs are supported enable this option
 581 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 582 if(LYX_SHARED_LIBRARIES)
 583         set(library_type SHARED)
 584 else()
 585         set(library_type STATIC)
 586 endif()
 587
 588 if(NOT MSVC)
 589         if(NOT LYX_QUIET)
 590                 set(CMAKE_VERBOSE_MAKEFILE ON)
 591         endif()
 592         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 593         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 594           # Thanks to Brad King <brad.king@kitware.com>
 595           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 596           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 597           # and still use our own c++ extension tests
 598           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 599           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 600         endif()
 601         if(LYX_STDLIB_DEBUG)
 602                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 603         endif()
 604         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 605         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 606         if(MINGW)
 607                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 608         else()
 609                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 610         endif()
 611 endif()
 612
 613 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 614 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 615 if(LYX_CXX_FLAGS_EXTRA)
 616         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 617                 add_definitions(${_flag})
 618         endforeach()
 619 endif()
 620
 621 if(LYX_XMINGW)
 622         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 623 endif()
 624
 625 set(min_qt5_version "5.6")
 626 if(LYX_USE_QT MATCHES "AUTO")
 627         # try qt5 first
 628         find_package(Qt5Core QUIET)
 629         if(Qt5Core_FOUND)
 630                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 631                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 632                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 633                         find_package(Qt4 "4.5.0" QUIET)
 634                         if(QT4_FOUND)
 635                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 636                         endif()
 637                 endif()
 638         else()
 639                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 640         endif()
 641 endif()
 642 if(LYX_USE_QT MATCHES "QT5")
 643         # set QPA_XCB if QT uses X11
 644         find_package(Qt5Core REQUIRED)
 645         if (Qt5Core_FOUND)
 646                 find_package(Qt5Widgets REQUIRED)
 647                 if(APPLE)
 648                         find_package(Qt5MacExtras REQUIRED)
 649                 endif()
 650                 find_package(Qt5X11Extras QUIET)
 651                 find_package(Qt5WinExtras QUIET)
 652                 set(QTVERSION ${Qt5Core_VERSION})
 653                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 654                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 655                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 656                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 657                         # see thread in lyx-devel list
 658                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 659                         # Date 11.03.2017
 660                         # Subject: cmake compilation error
 661                         #message(FATAL_ERROR "Wrong Qt-Version")
 662                 endif()
 663                 macro (qt_use_modules)
 664                         qt5_use_modules(${ARGN})
 665                 endmacro()
 666                 macro (qt_add_resources)
 667                         qt5_add_resources(${ARGN})
 668                 endmacro()
 669                 macro (qt_wrap_uifiles)
 670                         qt5_wrap_ui(${ARGN})
 671                 endmacro()
 672                 message(STATUS "Found Qt-Version ${QTVERSION}")
 673                 if(WIN32)
 674                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 675                 endif()
 676         endif()
 677 elseif(LYX_USE_QT MATCHES "QT4")
 678         if(LYX_XMINGW)
 679                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 680                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 681         endif()
 682         find_package(Qt4 "4.5.0" REQUIRED)
 683         macro (qt_use_modules)
 684         endmacro()
 685         macro (qt_add_resources)
 686                 qt4_add_resources(${ARGN})
 687         endmacro()
 688         macro (qt_wrap_uifiles)
 689                 qt4_wrap_ui(${ARGN})
 690         endmacro()
 691         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 692         if(WIN32)
 693                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 694         endif()
 695 else()
 696   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 697 endif()
 698
 699 find_package(Magic)
 700 if(Magic_FOUND)
 701         set(HAVE_MAGIC_H 1)
 702 endif()
 703
 704 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 705
 706 set(Spelling_FOUND OFF)
 707 set(Include_used_spellchecker)   # String will be inserted into config.h
 708
 709 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 710   # try system library first
 711   find_package(MyThesLIB)
 712   if (MYTHESLIB_FOUND)
 713     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 714   else()
 715     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 716   endif()
 717 endif()
 718 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 719   find_package(MyThesLIB REQUIRED)
 720 else()
 721   add_subdirectory(3rdparty/mythes)
 722 endif()
 723 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 724
 725 if(NOT LYX_EXTERNAL_HUNSPELL)
 726     add_subdirectory(3rdparty/hunspell)
 727     add_definitions(-DHUNSPELL_STATIC)
 728     set(HUNSPELL_FOUND ON)
 729     message(STATUS "  * Hunspell:")
 730     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 731     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 732 endif()
 733
 734 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 735   string(TOUPPER ${_spell} _upspell)
 736   if (NOT ${_upspell}_FOUND)
 737     find_package(${_spell})
 738   endif()
 739   if (${_upspell}_FOUND)
 740     include_directories(${${_upspell}_INCLUDE_DIR})
 741     set(Spelling_FOUND ON)
 742     message(STATUS "Building with USE_${_upspell}")
 743     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 744   else()
 745     if(LYX_${_upspell})
 746       message(FATAL_ERROR "Required ${_spell} devel package not found")
 747     else()
 748       message(STATUS "${_upspell} not found, building without ${_spell} support")
 749     endif()
 750   endif()
 751 endforeach()
 752
 753 if(GNUWIN32_DIR)
 754         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 755 endif()
 756
 757 # Search for python default version first
 758 unset(PYTHON_EXECUTABLE CACHE)
 759 unset(LYX_PYTHON_EXECUTABLE CACHE)
 760 unset(PYTHON_VERSION_MAJOR)
 761 unset(PYTHON_VERSION_MINOR)
 762 unset(PYTHON_VERSION_STRING)
 763 find_package(PythonInterp 3.3 QUIET)
 764 if(NOT PYTHONINTERP_FOUND)
 765   unset(PYTHON_EXECUTABLE CACHE)
 766   find_package(PythonInterp 2.0 REQUIRED)
 767   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 768     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 769   endif()
 770 endif()
 771
 772 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 773
 774 if(LYX_NLS)
 775         find_package(LyXGettext)
 776         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 777                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 778         else()
 779                 # Install only supplied .gmo-files
 780                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 781                 message(STATUS "Installing provided .gmo-files only")
 782                 foreach( _gmo ${_gmofiles})
 783                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 784                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 785                 endforeach()
 786         endif()
 787 endif()
 788
 789 if(LYX_EXTERNAL_ICONV)
 790   find_package(ICONV REQUIRED)
 791 else()
 792   add_subdirectory(3rdparty/libiconv)
 793   set(HAVE_ICONV_CONST 1)
 794 endif()
 795
 796 if(LYX_EXTERNAL_Z)
 797   find_package(ZLIB REQUIRED)
 798 else()
 799   add_subdirectory(3rdparty/zlib)
 800 endif()
 801
 802 if(LYX_USE_STD_REGEX)
 803   # Set only include path.
 804   # Use internal boost, which is known to exist
 805   # we don't need any libraries
 806   set(Lyx_Boost_Libraries)
 807   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 808   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 809 else()
 810   # Using boost-regex
 811   if(LYX_EXTERNAL_BOOST)
 812     message(STATUS "Searching for external boost")
 813     find_package(Boost COMPONENTS regex)
 814     if(Boost_FOUND)
 815       message(STATUS "Boost found")
 816       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 817       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 818       if (LYX_STDLIB_DEBUG)
 819         # Comment from  Jean-Marc Lasgouttes:
 820         # In general, system boost libraries are incompatible with
 821         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 822         # details.
 823         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 824       endif()
 825     else()
 826       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 827     endif()
 828   else()
 829     # Using included boost
 830     set(Lyx_Boost_Libraries boost_regex)
 831     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 832     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 833     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 834   endif()
 835 endif()
 836
 837 if(WIN32)
 838         if(LYX_CONSOLE)
 839                 set(LYX_QTMAIN_LIBRARY)
 840         else()
 841                 set(WIN32_CONSOLE WIN32)
 842         endif()
 843         if(MSVC)
 844                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 845                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 846                 # disable checked iterators for msvc release builds to get maximum speed
 847                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 848         else()
 849                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 850                 # does not use it and always declares the vista compatible API.
 851                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 852                 add_definitions(-DWINVER=0x0500)
 853         endif()
 854 endif()
 855
 856 # Compute qt-version from ${QTVERSION}
 857
 858 message(STATUS "")
 859 foreach(_v PACKAGE PACKAGE_VERSION
 860         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 861         LYX_ABS_TOP_SRCDIR
 862         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 863         if(NOT DEFINED ${_v})
 864                 message(FATAL_ERROR "${_v} not defined")
 865         endif()
 866         string(SUBSTRING "${_v}                            " 0 28 _v1)
 867         message(STATUS "----- ${_v1}: ${${_v}}")
 868 endforeach(_v)
 869 message(STATUS "")
 870
 871
 872 if(LYX_PCH)
 873         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 874         # Not sure if it works for all non-msvc compilers
 875         include(PCHSupport_26)
 876         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 877         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 878         add_definitions(-DLYX_ENABLE_PCH)
 879
 880         if(MSVC)
 881                 macro(lyx_add_msvc_pch name_)
 882                         set_source_files_properties(${${name_}_sources} PROPERTIES
 883                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 884                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 885                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 886                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 887                                 ${TOP_BINARY_DIR}/pcheaders.h)
 888                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 889                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 890                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 891                 endmacro(lyx_add_msvc_pch)
 892                 macro(lyx_add_gcc_pch name_)
 893                 endmacro()
 894         else()
 895                 macro(lyx_add_msvc_pch name_)
 896                 endmacro()
 897                 macro(lyx_add_gcc_pch name_)
 898                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 899                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 900                 endmacro()
 901         endif()
 902 else()
 903         macro(lyx_add_msvc_pch)
 904         endmacro(lyx_add_msvc_pch)
 905         macro(lyx_add_gcc_pch name_)
 906         endmacro()
 907 endif()
 908
 909
 910 if(MSVC)
 911
 912         if(LYX_VLD)
 913                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 914                 add_subdirectory(${vld_path}/cmake)
 915                 include(${vld_path}/cmake/vld.cmake) # forced include
 916                 set(vld_dll vld)
 917         endif()
 918
 919         if(LYX_WALL)
 920                 # Use the highest warning level
 921                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 922
 923                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 924                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 925                 else()
 926                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 927                 endif()
 928
 929                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 930                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 931                 else()
 932                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 933                 endif()
 934
 935                 # add here warnings which should produce an error /weXXXX
 936                 set(MSVC_W_ERROR   "/we4101 /we4189")
 937                 # add here warnings which should be disabled /wdXXXX
 938                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 939
 940                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 941                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 942                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 943
 944         else()
 945                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 946
 947                 # add here warnings which should produce an error /weXXXX
 948                 set(MSVC_W_ERROR   "/we4101 /we4189")
 949                 # add here warnings which should be disabled /wdXXXX
 950                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 951
 952                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 953                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 954                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 955
 956         endif()
 957
 958         if (NOT Qt5Core_FOUND)
 959                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 960                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 961                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 962         endif()
 963
 964         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 965         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 966         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 967         message(STATUS "")
 968 endif()
 969
 970
 971 if(LYX_DEBUG_GLIBC)
 972         set(_GLIBCXX_DEBUG ON)
 973 endif()
 974
 975 if(LYX_DEBUG_GLIBC_PEDANTIC)
 976         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 977 endif()
 978
 979 # Xcode compiler
 980 if (CMAKE_GENERATOR MATCHES Xcode)
 981         if (XCODE_VERSION VERSION_LESS "5.0")
 982                 # Automatically select the Xcode compiler if not set
 983                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 984                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 985                         if (XCODE_VERSION VERSION_GREATER "3.1")
 986                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 987                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 988                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 989                 # Print the selected compiler version
 990         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 991         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 992 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 993
 994 if (WIN32 AND Qt5Core_FOUND)
 995         set(Z_PREFIX 1)
 996 endif()
 997
 998 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 999 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1000 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1001
1002 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1003
1004 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1005         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1006 endif()
1007
1008 if (NOT HAVE_REGEX)
1009         set(LYX_USE_STD_REGEX 0)
1010 endif()
1011
1012
1013 set (cmd ${CMAKE_CTEST_COMMAND})
1014 if (MSVC)
1015         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1016 else ()
1017         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1018 endif ()
1019 add_custom_target (lyx_run_tests COMMAND ${cmd})
1020 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1021
1022 if(LYX_ASAN)
1023     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1024     message(STATUS)
1025     message(STATUS "Address sanitizer enabled. Usage:")
1026     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1027     message(STATUS "    chmod  +x ./asan_symbolize.py")
1028     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1029     message(STATUS)
1030 endif()
1031
1032 if(LYX_INSTALL)
1033         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1034                 message(STATUS "Python required to create doc!")
1035         else()
1036                 if(UNIX)
1037                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1038                 endif()
1039                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1040         endif()
1041 endif()
1042 include(../Install)
1043
1044 # By running the URL tests first, time can be saved when running the ctests in
1045 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1046 if(LYX_ENABLE_URLTESTS)
1047         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1048 endif()
1049 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1050 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1051 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1052 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1053 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1054 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1055
1056 message(STATUS)
1057 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1058 message(STATUS)
1059
1060 LYX_OPTION_LIST_ALL(used)
1061
1062
1063 if(LYX_NLS)
1064         message(STATUS)
1065         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1066         message(STATUS)
1067         message(STATUS "  * iconv")
1068         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1069         message(STATUS "     - library: ${ICONV_LIBRARY}")
1070         message(STATUS "  * zlib")
1071         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1072         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1073         message(STATUS)
1074 endif()
1075
1076 # Apple has builtin native spell checker,
1077 # no need to warn for missing Aspell, Hunspell or Enchant
1078 if(NOT Spelling_FOUND AND NOT APPLE)
1079   if(LYX_REQUIRE_SPELLCHECK)
1080     set(_mode "FATAL_ERROR")
1081   else()
1082     set(_mode "STATUS")
1083   endif()
1084   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1085 endif()
1086
1087 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1088
1089 if(ENABLE_DIST)
1090   # Use git to create the source package
1091   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1092   if(UNIX)
1093     set(DIST_FORMAT tgz)
1094   else()
1095     set(DIST_FORMAT zip)
1096   endif()
1097   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1098
1099   add_custom_command(
1100     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1101     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1102     WORKING_DIRECTORY ${TOP_SRC_DIR})
1103   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1104 endif()
1105
1106 # Last directory to be included so that the fixup code (OS X)
1107 # can be run last
1108 add_subdirectory(development/cmake/post_install)
1109
1110 message(STATUS)