CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 if(UNIX)
  46         set(ARCH_TRIPLET )
  47         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  48         if(DPKG_ARCHITECTURE_EXECUTABLE)
  49                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  50                                 OUTPUT_VARIABLE ARCH_TRIPLET
  51                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  52                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  53         endif()
  54 endif()
  55 if(ARCH_TRIPLET)
  56         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  57 else()
  58         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  59 endif()
  60
  61 include(LyXMacros)
  62
  63 # Usage LYX_OPTION
  64 # 1. parameter: option name without prefix 'LYX_'
  65 # 2. parameter: description
  66 # 3. parameter: default value, ON or OFF
  67 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  68
  69
  70 LYX_OPTION_INIT()
  71
  72 # Options for all compilers/systems
  73 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  74 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  75 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  76 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  77 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  78 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  79 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  80 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  81 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  82 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  83 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  84 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  85 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  86 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  87 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  88 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  89 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  90 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  91
  92 # GCC specific
  93 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  94 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  95 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  96 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  97 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  98 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  99 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 100
 101 # MSVC specific
 102 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 103 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 104 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 105 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 106 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 107
 108 # APPLE specific
 109 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 110 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 111
 112
 113 if(help OR HELP)
 114         message(STATUS)
 115         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 116         message(STATUS)
 117         LYX_OPTION_LIST_ALL(help)
 118         message(STATUS)
 119         RETURN()
 120 endif()
 121
 122 # Check option dependencies
 123
 124 if(LYX_CPACK)
 125         set(LYX_INSTALL ON)
 126 endif()
 127
 128 if(LYX_DMG)
 129         set(LYX_BUNDLE ON)
 130         set(LYX_CPACK ON)
 131 endif()
 132
 133 if(LYX_INSTALL)
 134         set(LYX_NLS ON)
 135         if (WIN32)
 136                 set(LYX_HUNSPELL ON)
 137         endif()
 138         set(LYX_CONSOLE OFF)
 139         set(LYX_PACKAGE_SUFFIX ON)
 140         set(LYX_RELEASE ON)
 141         set(LYX_PROFILE OFF)
 142 endif()
 143
 144
 145 if(LYX_MERGE_FILES)
 146         set(LYX_PCH OFF)
 147 else()
 148         set(LYX_MERGE_REBUILD OFF)
 149 endif()
 150
 151 if(LYX_DEPENDENCIES_DOWNLOAD)
 152         message(STATUS)
 153         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 154         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 155         set(deps_files lyx20-deps-msvc2010-x86.zip)
 156         foreach(it ${deps_files})
 157                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 158                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 159                 if(NOT already_downloaded)
 160                         message(STATUS "Downloading ${it} ...")
 161                         file(DOWNLOAD http://sourceforge.net/projects/scusi/files/${it} ${LYX_DEPENDENCIES_DIR}/download/${it}
 162                                       SHOW_PROGRESS STATUS status LOG log)
 163                         list(GET status 0 status_code)
 164                         list(GET status 1 status_string)
 165                         if(NOT status_code EQUAL 0)
 166                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 167                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 168                         endif()
 169                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 170                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 171                 endif()
 172         endforeach()
 173         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 174 endif()
 175
 176
 177
 178 message(STATUS)
 179
 180 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 181 if(WIN32)
 182         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 183 else()
 184         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 185 endif()
 186
 187
 188 if(UNIX OR MINGW)
 189         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 190         message(STATUS "Using GCC version ${GCC_VERSION}")
 191         if(NOT GCC_VERSION VERSION_LESS 4.4)
 192                 set(LYX_USE_TR1 1)
 193                 # GCC <= 4.5 does not support regex: there are linker errors
 194                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 195                 set(LYX_USE_TR1_REGEX 0)
 196         endif()
 197 else()
 198         if(MSVC10)
 199                 set(LYX_USE_TR1 1)
 200                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 201         endif()
 202 endif()
 203
 204
 205 set(VERSION_INFO "CMake Build")
 206
 207 # Try to get some informations from configure.ac
 208
 209 include(LyXPaths)
 210 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 211
 212 if(WIN32)
 213         set(USE_WINDOWS_PACKAGING ON)
 214 elseif(APPLE)
 215         set(USE_MACOSX_PACKAGING ON)
 216 else()
 217         set(USE_POSIX_PACKAGING ON)
 218 endif()
 219
 220 macro(setstripped _varname _value)
 221         string(STRIP ${_value} _v)
 222         if(USE_POSIX_PACKAGING)
 223                 string(TOLOWER ${_v} ${_varname})
 224         else()
 225                 set(${_varname} ${_v})
 226         endif()
 227 endmacro(setstripped)
 228
 229 foreach(_c_l ${_config_lines} )
 230         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 231                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 232                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 233                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 234                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 235                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 236                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 237                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 238                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 239                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 240                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 241                 endif()
 242         endif()
 243         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 244                 set(LYX_DATE "${CMAKE_MATCH_1}")
 245         endif()
 246 endforeach(_c_l)
 247
 248 # Find the revision number and for later use
 249 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 250 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 251 if(LYX_SVNVERSION)
 252         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 253         # We use this value also to set the package-patch-value
 254         if(LYX_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 255                 set(LYX_REVISION_VERSION ${CMAKE_MATCH_1})
 256         endif()
 257 else()
 258         set(LYX_REVISION_VERSION svn) #TODO use date
 259 endif()
 260
 261
 262 if(LYX_PROGRAM_SUFFIX)
 263         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 264 else()
 265         set(PROGRAM_SUFFIX "")
 266 endif()
 267
 268
 269 if(LYX_BUNDLE)
 270         set(LYX_CPACK ON)
 271         message(STATUS)
 272         message(STATUS "Bundle creation is enabled (experimental):")
 273         message(STATUS "    make")
 274         message(STATUS "    make install/strip")
 275         message(STATUS "    make package")
 276         if(APPLE)
 277                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 278                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 279                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 280                 if(NOT LYX_INSTALL_PREFIX)
 281                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 282                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 283                 endif()
 284         elseif(UNIX)
 285                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 286                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 287                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 288         elseif(WIN32)
 289                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 290         endif()
 291 endif()
 292
 293 if(LYX_INSTALL_PREFIX)
 294         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 295         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 296 endif()
 297 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 298
 299 if(LYX_PACKAGE_SUFFIX)
 300         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 301 else()
 302         set(PACKAGE ${PACKAGE_BASE})
 303 endif()
 304
 305
 306 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 307         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 308         if (UNIX)
 309                 # don't use the default "/usr/local"
 310                 # but respect the user-choice on the command-line
 311                 if(LYX_INSTALL_SUFFIX)
 312                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 313                 else()
 314                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 315                 endif()
 316         endif()
 317         if(WIN32)
 318                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 319         endif()
 320 endif()
 321 if(IS_ABSOLUTE)
 322         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 323 else()
 324         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 325 endif()
 326
 327
 328
 329 if(NOT LYX_DATA_SUBDIR)
 330         if (WIN32)
 331                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 332         else()
 333                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 334         endif()
 335 endif()
 336
 337 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 338 set(LYX_LOCALEDIR "locale")
 339 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 340 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 341
 342
 343 if(LYX_INSTALL AND WIN32)
 344         message(STATUS "Configuring NSIS files")
 345         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 346         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 347         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 348         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 349 endif()
 350
 351 if(NOT GROUP_CODE)
 352         #set(GROUP_CODE "The Golden Code")
 353         set(GROUP_CODE flat)
 354 endif()
 355
 356 # lyx's source files
 357 set(LYX_CPP_FILES *.cpp)
 358 set(LYX_HPP_FILES *.h)
 359 set(LYX_MOC_FILES moc_*.cpp)
 360
 361 include(ProjectSourceGroup)
 362
 363
 364 if(NOT MSVC)
 365         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 366         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 367         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg" CACHE TYPE STRING FORCE)
 368 else()
 369         set(LYX_PROFILE OFF)
 370 endif()
 371
 372
 373 if(LYX_NO_OPTIMIZE)
 374         set(CMAKE_BUILD_TYPE None)
 375         set(LYX_DEBUG OFF)
 376         set(LYX_RELEASE OFF)
 377         set(LYX_PROFILE OFF)
 378 elseif(LYX_RELEASE)
 379         set(CMAKE_BUILD_TYPE Release)
 380         set(LYX_DEBUG OFF)
 381         set(LYX_PROFILE OFF)
 382 elseif(LYX_PROFILE)
 383         set(CMAKE_BUILD_TYPE Profile)
 384         set(LYX_DEBUG OFF)
 385 else()
 386         set(CMAKE_BUILD_TYPE Debug)
 387         set(LYX_DEBUG ON)
 388 endif()
 389
 390
 391 # When shared libs are supported enable this option
 392 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 393 if(LYX_SHARED_LIBRARIES)
 394         set(library_type SHARED)
 395 else()
 396         set(library_type STATIC)
 397 endif()
 398
 399 if(NOT MSVC)
 400         if(NOT LYX_QUIET)
 401                 set(CMAKE_VERBOSE_MAKEFILE ON)
 402         endif()
 403         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 404         if(LYX_STDLIB_DEBUG)
 405                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 406         endif()
 407         if(LYX_CONCEPT_CHECKS)
 408                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 409         endif()
 410         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 411         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 412         if(MINGW)
 413                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 414         else()
 415                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 416         endif()
 417 endif()
 418
 419
 420 find_package(Qt4 REQUIRED)
 421
 422
 423 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 424
 425 if(LYX_ASPELL)
 426         find_package(ASPELL)
 427         include_directories(${ASPELL_INCLUDE_DIR})
 428 endif()
 429
 430 if(LYX_ENCHANT)
 431         find_package(Enchant REQUIRED)
 432         include_directories(${ENCHANT_INCLUDE_DIR})
 433 endif()
 434
 435 if(LYX_HUNSPELL)
 436         find_package(Hunspell REQUIRED)
 437         include_directories(${HUNSPELL_INCLUDE_DIR})
 438 endif()
 439
 440 if(LYX_NLS)
 441         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 442         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 443                 message(FATAL_ERROR "Python 2.6 needed!")
 444         endif()
 445         find_package(LyXGettext REQUIRED)
 446         include_directories(${TOP_SRC_DIR}/po)
 447         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 448 endif()
 449
 450 if(LYX_NLS)
 451         if(LYX_EXTERNAL_LIBINTL)
 452                 find_package(Libintl REQUIRED)
 453                 if(DEFINED LIBINTL_LIBRARIES)
 454                         # find getext when configuring
 455                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 456                         # on mac use iconv also form ports
 457                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 458                 endif()
 459         else()
 460                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 461         endif()
 462 endif()
 463
 464 find_package(ICONV REQUIRED)
 465 find_package(ZLIB REQUIRED)
 466
 467 if(LYX_EXTERNAL_BOOST)
 468         message(STATUS "Searching for boost")
 469         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 470         if(Boost_FOUND)
 471                 message(STATUS "Boost found")
 472                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 473                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 474         else()
 475                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 476         endif()
 477 else()
 478         if(LYX_USE_TR1_REGEX)
 479                 set(Lyx_Boost_Libraries boost_signals)
 480         else()
 481                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 482         endif()
 483         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 484         include_directories(${TOP_SRC_DIR}/boost)
 485         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 486 endif()
 487
 488
 489
 490
 491 if(WIN32)
 492         if(NOT LYX_CONSOLE)
 493                 set(WIN32_CONSOLE WIN32)
 494                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 495         endif()
 496         if(MSVC)
 497                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 498                 # disable checked iterators for msvc release builds to get maximum speed
 499                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 500         else()
 501                 add_definitions(-DWINVER=0x0500)
 502         endif()
 503 endif()
 504
 505 message(STATUS "")
 506 foreach(_v PACKAGE PACKAGE_VERSION
 507         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 508         LYX_ABS_TOP_SRCDIR
 509         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 510         if(NOT DEFINED ${_v})
 511                 message(FATAL_ERROR "${_v} not defined")
 512         endif()
 513         string(SUBSTRING "${_v}                            " 0 28 _v1)
 514         message(STATUS "----- ${_v1}: ${${_v}}")
 515 endforeach(_v)
 516 message(STATUS "")
 517
 518
 519 if(LYX_PCH)
 520         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 521         # Not sure if it works for all non-msvc compilers
 522         include(PCHSupport_26)
 523         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 524         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 525         add_definitions(-DLYX_ENABLE_PCH)
 526
 527         if(MSVC)
 528                 macro(lyx_add_msvc_pch name_)
 529                         set_source_files_properties(${${name_}_sources} PROPERTIES
 530                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 531                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 532                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 533                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 534                                 ${TOP_BINARY_DIR}/pcheaders.h)
 535                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 536                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 537                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 538                 endmacro(lyx_add_msvc_pch)
 539                 macro(lyx_add_gcc_pch name_)
 540                 endmacro()
 541         else()
 542                 macro(lyx_add_msvc_pch name_)
 543                 endmacro()
 544                 macro(lyx_add_gcc_pch name_)
 545                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 546                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 547                 endmacro()
 548         endif()
 549 else()
 550         macro(lyx_add_msvc_pch)
 551         endmacro(lyx_add_msvc_pch)
 552         macro(lyx_add_gcc_pch name_)
 553         endmacro()
 554 endif()
 555
 556
 557 if(MSVC)
 558
 559         if(LYX_VLD)
 560                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 561                 add_subdirectory(${vld_path}/cmake)
 562                 include(${vld_path}/cmake/vld.cmake) # forced include
 563                 set(vld_dll vld)
 564         endif()
 565
 566         if(LYX_WALL)
 567                 # Use the highest warning level
 568                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 569
 570                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 571                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 572                 else()
 573                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 574                 endif()
 575
 576                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 577                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 578                 else()
 579                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 580                 endif()
 581
 582                 # add here warnings which should produce an error /weXXXX
 583                 set(MSVC_W_ERROR   "/we4101 /we4189")
 584                 # add here warnings which should be disabled /wdXXXX
 585                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 586
 587                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 588                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 589                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 590
 591         else()
 592                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 593
 594                 # add here warnings which should produce an error /weXXXX
 595                 set(MSVC_W_ERROR   "/we4101 /we4189")
 596                 # add here warnings which should be disabled /wdXXXX
 597                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 598
 599                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 600                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 601                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 602
 603         endif()
 604         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 605         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 606         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 607
 608         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 609         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 610         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 611         message(STATUS "")
 612 endif()
 613
 614
 615 if(LYX_DEBUG_GLIBC)
 616         set(_GLIBCXX_DEBUG ON)
 617 endif()
 618
 619 if(LYX_DEBUG_GLIBC_PEDANTIC)
 620         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 621 endif()
 622
 623 # compiler tests, config.h generation
 624 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 625         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 626 else()
 627         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 628         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 629 endif()
 630
 631 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 632
 633 # Compute qt4-version from ${QTVERSION}
 634 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 635         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 636 endif()
 637
 638 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 639 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 640 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 641
 642
 643 if(LYX_INSTALL)
 644         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 645                 message(STATUS "Python required to create doc!")
 646         else()
 647                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 648                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 649         endif()
 650         include(../Install)
 651 endif()
 652
 653 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 654
 655 message(STATUS)
 656 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 657 message(STATUS)
 658 LYX_OPTION_LIST_ALL(used)
 659
 660
 661 if(LYX_NLS)
 662         message(STATUS)
 663         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 664         message(STATUS)
 665         message(STATUS "  * intl")
 666         message(STATUS "     - header : ${LIBINTL_HEADER}")
 667         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 668         message(STATUS "  * iconv")
 669         message(STATUS "     - header : ${ICONV_HEADER}")
 670         message(STATUS "     - library: ${ICONV_LIBRARY}")
 671         message(STATUS "  * zlib")
 672         message(STATUS "     - header : ${ZLIB_HEADER}")
 673         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 674         message(STATUS)
 675 endif()
 676
 677 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 678
 679 message(STATUS)