CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 129 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 130 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 131 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 132 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 133 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 134 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 135 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 136 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 137 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 138 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 139 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 140 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 141 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 144 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 145
 146 # GCC specific
 147 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 148 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 149 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 150 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 151 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 152 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 153 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 154
 155 # MSVC specific
 156 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 157 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 158 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 159 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 160
 161 # APPLE specific
 162 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 163 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 164
 165
 166 if(help OR HELP)
 167         message(STATUS)
 168         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 169         message(STATUS)
 170         LYX_OPTION_LIST_ALL(help)
 171         message(STATUS)
 172         RETURN()
 173 endif()
 174
 175 # Check option dependencies
 176
 177 if(LYX_DMG)
 178         set(LYX_BUNDLE ON)
 179         set(LYX_CPACK ON)
 180 endif()
 181
 182 if(LYX_CPACK)
 183         set(LYX_INSTALL ON)
 184 endif()
 185
 186 if(LYX_INSTALL)
 187         set(LYX_NLS ON)
 188         if(WIN32 AND NOT MINGW)
 189                 set(LYX_HUNSPELL ON)
 190         endif()
 191         if(LYX_CONSOLE MATCHES "FORCE")
 192                 set(LYX_CONSOLE ON)
 193         else()
 194                 set(LYX_CONSOLE OFF)
 195         endif()
 196         set(LYX_PACKAGE_SUFFIX ON)
 197         if(NOT LYX_DEBUG)
 198                 set(LYX_RELEASE ON)
 199         endif()
 200         set(LYX_PROFILE OFF)
 201 endif()
 202
 203
 204 if(LYX_MERGE_FILES)
 205         set(LYX_PCH OFF)
 206 else()
 207         set(LYX_MERGE_REBUILD OFF)
 208 endif()
 209
 210
 211 if(LYX_DEPENDENCIES_DOWNLOAD)
 212         message(STATUS)
 213     if(MSVC12)
 214         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 215         set(deps_files lyx-windows-deps-msvc2013.zip)
 216         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 218     else()
 219         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 220             set(deps_files lyx20-deps-msvc2010-x86.zip)
 221             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 222         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 223     endif()
 224     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 225         foreach(it ${deps_files})
 226                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 227                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 228                 if(NOT already_downloaded)
 229                         message(STATUS "Downloading ${it} ...")
 230                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 231                         list(GET status 0 status_code)
 232                         list(GET status 1 status_string)
 233                         if(NOT status_code EQUAL 0)
 234                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 235                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 236                         endif()
 237                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 238                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 239                 endif()
 240         endforeach()
 241 endif()
 242
 243
 244
 245 message(STATUS)
 246
 247 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 248 if(WIN32)
 249         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 250 else()
 251         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 252 endif()
 253
 254
 255 # Set to some meaningful default
 256 find_package(CXX11Compiler)
 257 if(NOT CXX11COMPILER_FOUND)
 258         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 259 endif()
 260 set(LYX_GCC11_MODE)
 261 if(UNIX OR MINGW)
 262         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 263           # ignore the GCC_VERSION for clang
 264           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 265           message(STATUS "Using clang")
 266           if(CXX11_STD_REGEX)
 267             set(LYX_USE_STD_REGEX 1)
 268           else()
 269             set(LYX_USE_STD_REGEX 0)
 270           endif()
 271         else()
 272           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 273           message(STATUS "Using GCC version ${GCC_VERSION}")
 274           if(GCC_VERSION VERSION_LESS 4.9)
 275                   if(GCC_VERSION VERSION_LESS 4.6)
 276                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 277                   endif()
 278                   # <regex> in gcc is unusable in versions less than 4.9.0
 279                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 280                   set(LYX_USE_STD_REGEX 0)
 281           else()
 282                   set(LYX_USE_STD_REGEX 1)
 283           endif()
 284         endif()
 285         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 286 else()
 287         set(LYX_USE_STD_REGEX 0)
 288 #       if(MSVC10)
 289 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 290 #       endif()
 291 endif()
 292
 293
 294 set(VERSION_INFO "CMake Build")
 295
 296 # Try to get some informations from configure.ac
 297
 298 include(LyXPaths)
 299 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 300
 301 if(WIN32)
 302         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 303         if(MSVC)
 304                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 305         endif()
 306         set(USE_WINDOWS_PACKAGING ON)
 307 elseif(APPLE)
 308         set(USE_MACOSX_PACKAGING ON)
 309 else()
 310         set(USE_POSIX_PACKAGING ON)
 311 endif()
 312
 313 macro(setstripped _varname)
 314         if(${ARGC} GREATER 1)
 315                 string(STRIP "${ARGV1}" _v)
 316                 if(USE_POSIX_PACKAGING)
 317                         string(TOLOWER ${_v} ${_varname})
 318                 else()
 319                         set(${_varname} ${_v})
 320                 endif()
 321         else()
 322                 set(${_varname})
 323         endif()
 324 endmacro(setstripped)
 325
 326 foreach(_c_l ${_config_lines} )
 327         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 328                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 329                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 330                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 331                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 332                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 333                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 334                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 335                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 336                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 337                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 338                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 339                         else()
 340                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 341                         endif()
 342                 endif()
 343         endif()
 344         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 345                 set(LYX_DATE "${CMAKE_MATCH_1}")
 346         endif()
 347 endforeach(_c_l)
 348
 349 FIND_PROGRAM(LYX_GITVERSION git)
 350 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 351 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 352 if(LYX_GITVERSION)
 353   if (LYX_LOCALVERSIONING)
 354     # Find the revision number and for later use
 355     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 356       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 357     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 358       # We will add offset of 40000 to get appropriate value to
 359       # previous svn.
 360       # We use this value than also to set the package-patch-value
 361       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 362       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 363       set(ENABLE_DIST ON)
 364     endif()
 365   endif()
 366 endif()
 367
 368 # Set the programs (lyx, tex2lyx, etc.) suffix
 369 # When building an OS X bundle, we will append
 370 # the suffix only to the bundle, not to the programs
 371 set(PROGRAM_SUFFIX "")
 372 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 373         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 374 endif()
 375 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 376 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 377
 378 add_custom_target(lyx_version ALL
 379   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 380   )
 381 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 382
 383 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 384 set(LYX_UTILITIES_INSTALL_PATH bin)
 385
 386 if(LYX_BUNDLE)
 387         set(LYX_CPACK ON)
 388
 389         message(STATUS)
 390         message(STATUS "Bundle creation is enabled (experimental):")
 391         message(STATUS "    make")
 392         message(STATUS "    make install/strip")
 393         message(STATUS "    make package")
 394         if(APPLE)
 395                 set(MACOSX_BUNDLE TRUE)
 396                 # This sets the bundle + executable names
 397                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 398                 # This sets the Info.plist executable name
 399                 set(osx_bundle_program_name ${_lyx})
 400                 # Bundle name
 401                 set(LYX_BUNDLE_NAME ${_lyx})
 402
 403                 # This will contain the list of files that need to be included
 404                 # in the bundle and their location within the bundle
 405                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 406                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 407
 408                 # Process Info.plist and lyxrc.dist
 409                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 410                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 411
 412                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 413                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 414
 415                 # Variables used by CPack
 416                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 417                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 418                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 419
 420                 # Set the install paths
 421                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 422                 if(NOT LYX_INSTALL_PREFIX)
 423                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 424                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 425                 endif()
 426                 # Change the owner so that the install can work
 427                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 428         elseif(UNIX)
 429                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 430                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 431                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 432         elseif(WIN32)
 433                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 434         endif()
 435 endif()
 436
 437 if(LYX_INSTALL_PREFIX)
 438         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 439         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 440 endif()
 441 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 442
 443 if(UNIX)
 444   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 445 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 446   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 447 else()
 448   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 449 endif()
 450
 451 if(LYX_PACKAGE_SUFFIX)
 452         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 453 else()
 454         set(PACKAGE ${PACKAGE_BASE})
 455 endif()
 456
 457 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 458         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 459         if (UNIX)
 460                 # use the default "/usr/local"
 461                 # but respect the user-choice on the command-line
 462                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 463         endif()
 464 endif()
 465 if(WIN32)
 466         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 467 endif()
 468 if(IS_ABSOLUTE)
 469         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 470 else()
 471         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 472 endif()
 473
 474
 475
 476 if(NOT LYX_DATA_SUBDIR)
 477         if (WIN32)
 478                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 479         else()
 480                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 481         endif()
 482 endif()
 483
 484 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 485 get_locale_destination(LYX_LOCALEDIR)
 486 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 487 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 488
 489 if(LYX_BUNDLE AND APPLE)
 490         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 491 else()
 492         if(WIN32)
 493                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 494         elseif(UNIX)
 495                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 496         else()
 497                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 498         endif()
 499 endif()
 500 mark_as_advanced(LYX_MAN_DIR)
 501
 502 if(LYX_INSTALL AND WIN32)
 503         message(STATUS "Configuring NSIS files")
 504         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 505         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 506         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 507         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 508 endif()
 509
 510 if(NOT GROUP_CODE)
 511         #set(GROUP_CODE "The Golden Code")
 512         set(GROUP_CODE flat)
 513 endif()
 514
 515 # lyx's source files
 516 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 517 set(LYX_HPP_FILES [a-zA-Z]*.h)
 518 set(LYX_MOC_FILES moc_*.cpp)
 519
 520 include(ProjectSourceGroup)
 521
 522
 523 if(LYX_PROFILE AND NOT MSVC)
 524         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 525         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 526         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 527 else()
 528         set(LYX_PROFILE OFF)
 529 endif()
 530
 531
 532 if(LYX_NO_OPTIMIZE)
 533         set(CMAKE_BUILD_TYPE None)
 534         set(LYX_DEBUG OFF)
 535         set(LYX_RELEASE OFF)
 536         set(LYX_PROFILE OFF)
 537 elseif(LYX_RELEASE)
 538         set(CMAKE_BUILD_TYPE Release)
 539         set(LYX_DEBUG OFF)
 540         set(LYX_PROFILE OFF)
 541 elseif(LYX_PROFILE)
 542         set(CMAKE_BUILD_TYPE Profile)
 543         set(LYX_DEBUG OFF)
 544 else()
 545         set(CMAKE_BUILD_TYPE Debug)
 546         set(LYX_DEBUG ON)
 547 endif()
 548
 549
 550 # When shared libs are supported enable this option
 551 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 552 if(LYX_SHARED_LIBRARIES)
 553         set(library_type SHARED)
 554 else()
 555         set(library_type STATIC)
 556 endif()
 557
 558 if(NOT MSVC)
 559         if(NOT LYX_QUIET)
 560                 set(CMAKE_VERBOSE_MAKEFILE ON)
 561         endif()
 562     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 563         if(LYX_STDLIB_DEBUG)
 564                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 565         endif()
 566         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 567         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 568         if(MINGW)
 569                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 570         else()
 571                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 572         endif()
 573 endif()
 574
 575 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 576 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 577 if(LYX_CXX_FLAGS_EXTRA)
 578         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 579                 add_definitions(${_flag})
 580         endforeach()
 581 endif()
 582
 583 if(LYX_XMINGW)
 584         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 585 endif()
 586
 587 if(LYX_USE_QT MATCHES "QT5")
 588         # set QPA_XCB if QT uses X11
 589         find_package(Qt5Core REQUIRED)
 590         if (Qt5Core_FOUND)
 591                 find_package(Qt5Widgets REQUIRED)
 592                 if(APPLE)
 593                         find_package(Qt5MacExtras REQUIRED)
 594                 endif()
 595                 find_package(Qt5X11Extras QUIET)
 596                 find_package(Qt5WinExtras QUIET)
 597                 set(QTVERSION ${Qt5Core_VERSION})
 598                 macro (qt_use_modules)
 599                         qt5_use_modules(${ARGN})
 600                 endmacro()
 601                 macro (qt_add_resources)
 602                         qt5_add_resources(${ARGN})
 603                 endmacro()
 604                 macro (qt_wrap_uifiles)
 605                         qt5_wrap_ui(${ARGN})
 606                 endmacro()
 607                 message(STATUS "Found Qt-Version ${QTVERSION}")
 608                 if(WIN32)
 609                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 610                 endif()
 611         endif()
 612 elseif(LYX_USE_QT MATCHES "QT4")
 613         if(LYX_XMINGW)
 614                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 615                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 616         endif()
 617         find_package(Qt4 "4.5.0" REQUIRED)
 618         macro (qt_use_modules)
 619         endmacro()
 620         macro (qt_add_resources)
 621                 qt4_add_resources(${ARGN})
 622         endmacro()
 623         macro (qt_wrap_uifiles)
 624                 qt4_wrap_ui(${ARGN})
 625         endmacro()
 626         if(WIN32)
 627                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 628         endif()
 629 else()
 630   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 631 endif()
 632
 633 find_package(Magic)
 634 if(Magic_FOUND)
 635         set(HAVE_MAGIC_H 1)
 636 endif()
 637
 638 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 639
 640 set(Spelling_FOUND OFF)
 641 set(Include_used_spellchecker)   # String will be inserted into config.h
 642
 643 if(LYX_3RDPARTY_BUILD)
 644     add_subdirectory(3rdparty/hunspell)
 645     add_definitions(-DHUNSPELL_STATIC)
 646     set(HUNSPELL_FOUND ON)
 647     message(STATUS "  * Hunspell:")
 648     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 649     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 650 endif()
 651
 652 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 653   string(TOUPPER ${_spell} _upspell)
 654   if (NOT ${_upspell}_FOUND)
 655     find_package(${_spell})
 656   endif()
 657   if (${_upspell}_FOUND)
 658     include_directories(${${_upspell}_INCLUDE_DIR})
 659     set(Spelling_FOUND ON)
 660     message(STATUS "Building with USE_${_upspell}")
 661     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 662   else()
 663     if(LYX_${_upspell})
 664       message(FATAL_ERROR "Required ${_spell} devel package not found")
 665     else()
 666       message(STATUS "${_upspell} not found, building without ${_spell} support")
 667     endif()
 668   endif()
 669 endforeach()
 670
 671 if(GNUWIN32_DIR)
 672         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 673 endif()
 674
 675 find_package(PythonInterp 2.7 QUIET)
 676 if(PYTHONINTERP_FOUND)
 677         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 678         unset(PYTHONINTERP_FOUND)
 679         endif()
 680 endif()
 681
 682 if(NOT PYTHONINTERP_FOUND)
 683   unset(PYTHON_EXECUTABLE CACHE)
 684   unset(PYTHON_VERSION_MAJOR)
 685   unset(PYTHON_VERSION_MINOR)
 686   unset(PYTHON_VERSION_STRING)
 687   find_package(PythonInterp 3.3 REQUIRED)
 688 endif()
 689
 690 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 691
 692 if(LYX_NLS)
 693         find_package(LyXGettext)
 694         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 695                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 696         else()
 697                 # Install only supplied .gmo-files
 698                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 699                 message(STATUS "Installing provided .gmo-files only")
 700                 foreach( _gmo ${_gmofiles})
 701                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 702                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 703                 endforeach()
 704         endif()
 705 endif()
 706
 707 if(UNIX)
 708     find_package(ICONV REQUIRED)
 709     find_package(ZLIB REQUIRED)
 710 else()
 711     if(LYX_3RDPARTY_BUILD)
 712         add_subdirectory(3rdparty/libiconv)
 713         set(HAVE_ICONV_CONST 1)
 714         add_subdirectory(3rdparty/zlib)
 715     endif()
 716 endif()
 717
 718 if(LYX_EXTERNAL_BOOST)
 719         message(STATUS "Searching for boost")
 720         if(NOT LYX_USE_STD_REGEX)
 721                 find_package(Boost COMPONENTS regex)
 722         endif()
 723         if(Boost_FOUND)
 724                 message(STATUS "Boost found")
 725                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 726                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 727                 if (LYX_STDLIB_DEBUG)
 728                         # Comment from  Jean-Marc Lasgouttes:
 729                         # In general, system boost libraries are incompatible with
 730                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 731                         # details.
 732                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 733                 endif()
 734         else()
 735                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 736         endif()
 737 else()
 738         if(NOT LYX_USE_STD_REGEX)
 739                 set(Lyx_Boost_Libraries boost_regex)
 740         endif()
 741         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 742         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 743         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 744 endif()
 745
 746
 747
 748
 749 if(WIN32)
 750         if(LYX_CONSOLE)
 751                 set(LYX_QTMAIN_LIBRARY)
 752         else()
 753                 set(WIN32_CONSOLE WIN32)
 754         endif()
 755         if(MSVC)
 756                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 757                 # disable checked iterators for msvc release builds to get maximum speed
 758                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 759         else()
 760                 add_definitions(-DWINVER=0x0500)
 761         endif()
 762 endif()
 763
 764 # Compute qt4-version from ${QTVERSION}
 765
 766 message(STATUS "")
 767 foreach(_v PACKAGE PACKAGE_VERSION
 768         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 769         LYX_ABS_TOP_SRCDIR
 770         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 771         if(NOT DEFINED ${_v})
 772                 message(FATAL_ERROR "${_v} not defined")
 773         endif()
 774         string(SUBSTRING "${_v}                            " 0 28 _v1)
 775         message(STATUS "----- ${_v1}: ${${_v}}")
 776 endforeach(_v)
 777 message(STATUS "")
 778
 779
 780 if(LYX_PCH)
 781         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 782         # Not sure if it works for all non-msvc compilers
 783         include(PCHSupport_26)
 784         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 785         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 786         add_definitions(-DLYX_ENABLE_PCH)
 787
 788         if(MSVC)
 789                 macro(lyx_add_msvc_pch name_)
 790                         set_source_files_properties(${${name_}_sources} PROPERTIES
 791                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 792                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 793                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 794                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 795                                 ${TOP_BINARY_DIR}/pcheaders.h)
 796                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 797                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 798                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 799                 endmacro(lyx_add_msvc_pch)
 800                 macro(lyx_add_gcc_pch name_)
 801                 endmacro()
 802         else()
 803                 macro(lyx_add_msvc_pch name_)
 804                 endmacro()
 805                 macro(lyx_add_gcc_pch name_)
 806                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 807                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 808                 endmacro()
 809         endif()
 810 else()
 811         macro(lyx_add_msvc_pch)
 812         endmacro(lyx_add_msvc_pch)
 813         macro(lyx_add_gcc_pch name_)
 814         endmacro()
 815 endif()
 816
 817
 818 if(MSVC)
 819
 820         if(LYX_VLD)
 821                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 822                 add_subdirectory(${vld_path}/cmake)
 823                 include(${vld_path}/cmake/vld.cmake) # forced include
 824                 set(vld_dll vld)
 825         endif()
 826
 827         if(LYX_WALL)
 828                 # Use the highest warning level
 829                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 830
 831                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 832                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 833                 else()
 834                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 835                 endif()
 836
 837                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 838                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 839                 else()
 840                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 841                 endif()
 842
 843                 # add here warnings which should produce an error /weXXXX
 844                 set(MSVC_W_ERROR   "/we4101 /we4189")
 845                 # add here warnings which should be disabled /wdXXXX
 846                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 847
 848                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 849                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 850                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 851
 852         else()
 853                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 854
 855                 # add here warnings which should produce an error /weXXXX
 856                 set(MSVC_W_ERROR   "/we4101 /we4189")
 857                 # add here warnings which should be disabled /wdXXXX
 858                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 859
 860                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 861                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 862                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 863
 864         endif()
 865
 866         if (NOT Qt5Core_FOUND)
 867                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 868                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 869                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 870         endif()
 871
 872         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 873         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 874         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 875         message(STATUS "")
 876 endif()
 877
 878
 879 if(LYX_DEBUG_GLIBC)
 880         set(_GLIBCXX_DEBUG ON)
 881 endif()
 882
 883 if(LYX_DEBUG_GLIBC_PEDANTIC)
 884         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 885 endif()
 886
 887 # Xcode compiler
 888 if (CMAKE_GENERATOR MATCHES Xcode)
 889         if (XCODE_VERSION VERSION_LESS "5.0")
 890                 # Automatically select the Xcode compiler if not set
 891                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 892                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 893                         if (XCODE_VERSION VERSION_GREATER "3.1")
 894                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 895                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 896                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 897                 # Print the selected compiler version
 898         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 899         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 900 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 901
 902 if (WIN32 AND Qt5Core_FOUND)
 903         set(Z_PREFIX 1)
 904 endif()
 905
 906 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 907 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 908 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 909
 910 set(QPA_XCB)
 911 if(Qt5X11Extras_FOUND AND QT_USES_X11)
 912   # QPA_XCB is only valid if QT5+X11
 913   set(QPA_XCB 1)
 914 endif()
 915 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 916
 917 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 918         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 919 endif()
 920
 921 if (NOT HAVE_REGEX)
 922         set(LYX_USE_STD_REGEX 0)
 923 endif()
 924
 925
 926 set (cmd ${CMAKE_CTEST_COMMAND})
 927 if (MSVC)
 928         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 929 else ()
 930         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 931 endif ()
 932 add_custom_target (lyx_run_tests COMMAND ${cmd})
 933 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 934
 935 if(LYX_ASAN)
 936     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 937     message(STATUS)
 938     message(STATUS "Address sanitizer enabled. Usage:")
 939     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 940     message(STATUS "    chmod  +x ./asan_symbolize.py")
 941     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 942     message(STATUS)
 943 endif()
 944
 945 if(LYX_INSTALL)
 946         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 947                 message(STATUS "Python required to create doc!")
 948         else()
 949                 if(UNIX)
 950                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 951                 endif()
 952                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 953         endif()
 954         include(../Install)
 955 endif()
 956
 957 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 958 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 959 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 960 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 961 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 962 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 963 if(LYX_ENABLE_URLTESTS)
 964         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 965 endif()
 966
 967 message(STATUS)
 968 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 969 message(STATUS)
 970
 971 LYX_OPTION_LIST_ALL(used)
 972
 973
 974 if(LYX_NLS)
 975         message(STATUS)
 976         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 977         message(STATUS)
 978         message(STATUS "  * iconv")
 979         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 980         message(STATUS "     - library: ${ICONV_LIBRARY}")
 981         message(STATUS "  * zlib")
 982         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 983         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 984         message(STATUS)
 985 endif()
 986
 987 # Apple has builtin native spell checker,
 988 # no need to warn for missing Aspell, Hunspell or Enchant
 989 if(NOT Spelling_FOUND AND NOT APPLE)
 990   if(LYX_REQUIRE_SPELLCHECK)
 991     set(_mode "FATAL_ERROR")
 992   else()
 993     set(_mode "STATUS")
 994   endif()
 995   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 996 endif()
 997
 998 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 999
1000 if(ENABLE_DIST)
1001   # Use git to create the source package
1002   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1003   if(UNIX)
1004     set(DIST_FORMAT tgz)
1005   else()
1006     set(DIST_FORMAT zip)
1007   endif()
1008   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1009
1010   add_custom_command(
1011     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1012     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1013     WORKING_DIRECTORY ${TOP_SRC_DIR})
1014   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1015 endif()
1016
1017 # Last directory to be included so that the fixup code (OS X)
1018 # can be run last
1019 add_subdirectory(development/cmake/post_install)
1020
1021 message(STATUS)