CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT LyX)
  11
  12 enable_testing()
  13
  14 set(LYX_CMAKE_DIR "development/cmake")
  15 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19
  20 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  21
  22 message(STATUS)
  23 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  24         message(STATUS "Building in-source")
  25         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  26 else()
  27         message(STATUS "Building out-of-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  29 endif()
  30
  31
  32 if(COMMAND cmake_policy)
  33         cmake_policy(SET CMP0003 OLD)
  34         cmake_policy(SET CMP0005 OLD)
  35 endif()
  36
  37 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  38
  39 # Supress regeneration
  40 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  41
  42 if(NOT help AND NOT HELP)
  43         # 'project' triggers the searching for a compiler
  44         project(${LYX_PROJECT})
  45 endif()
  46
  47 if(UNIX)
  48         set(ARCH_TRIPLET )
  49         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  50         if(DPKG_ARCHITECTURE_EXECUTABLE)
  51                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  52                                 OUTPUT_VARIABLE ARCH_TRIPLET
  53                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  54                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  55         endif()
  56 endif()
  57 if(ARCH_TRIPLET)
  58         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  59 else()
  60         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  61 endif()
  62
  63 include(LyXMacros)
  64
  65 # Usage LYX_OPTION
  66 # 1. parameter: option name without prefix 'LYX_'
  67 # 2. parameter: description
  68 # 3. parameter: default value, ON or OFF
  69 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  70
  71
  72 LYX_OPTION_INIT()
  73
  74 # Options for all compilers/systems
  75 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  76 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  77 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  78 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  79 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  80 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  81 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  82 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  83 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  84 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  85 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  86 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  87 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  88 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  89 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  90 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  91 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  92 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  93 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  94
  95 # GCC specific
  96 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  97 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  98 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  99 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 100 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
 101 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 102 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 103 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 104
 105 # MSVC specific
 106 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 107 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 108 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 109 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 110 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 111
 112 # APPLE specific
 113 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 114 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 115
 116
 117 if(help OR HELP)
 118         message(STATUS)
 119         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 120         message(STATUS)
 121         LYX_OPTION_LIST_ALL(help)
 122         message(STATUS)
 123         RETURN()
 124 endif()
 125
 126 # Check option dependencies
 127
 128 if(LYX_CPACK)
 129         set(LYX_INSTALL ON)
 130 endif()
 131
 132 if(LYX_DMG)
 133         set(LYX_BUNDLE ON)
 134         set(LYX_CPACK ON)
 135 endif()
 136
 137 if(LYX_INSTALL)
 138         set(LYX_NLS ON)
 139         if (WIN32)
 140                 set(LYX_HUNSPELL ON)
 141         endif()
 142         if(LYX_CONSOLE MATCHES "FORCE")
 143                 set(LYX_CONSOLE ON)
 144         else()
 145                 set(LYX_CONSOLE OFF)
 146         endif()
 147         set(LYX_PACKAGE_SUFFIX ON)
 148         set(LYX_RELEASE ON)
 149         set(LYX_PROFILE OFF)
 150 endif()
 151
 152
 153 if(LYX_MERGE_FILES)
 154         set(LYX_PCH OFF)
 155 else()
 156         set(LYX_MERGE_REBUILD OFF)
 157 endif()
 158
 159 if(LYX_DEPENDENCIES_DOWNLOAD)
 160         message(STATUS)
 161         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 162         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 163         set(deps_files lyx20-deps-msvc2010-x86.zip)
 164         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 165         foreach(it ${deps_files})
 166                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 167                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 168                 if(NOT already_downloaded)
 169                         message(STATUS "Downloading ${it} ...")
 170                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 171                         list(GET status 0 status_code)
 172                         list(GET status 1 status_string)
 173                         if(NOT status_code EQUAL 0)
 174                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 175                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 176                         endif()
 177                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 178                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 179                 endif()
 180         endforeach()
 181         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 182 endif()
 183
 184
 185
 186 message(STATUS)
 187
 188 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 189 if(WIN32)
 190         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 191 else()
 192         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 193 endif()
 194
 195
 196 if(UNIX OR MINGW)
 197         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 198         message(STATUS "Using GCC version ${GCC_VERSION}")
 199         if(NOT GCC_VERSION VERSION_LESS 4.4)
 200                 set(LYX_USE_TR1 1)
 201                 # GCC <= 4.5 does not support regex: there are linker errors
 202                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 203                 set(LYX_USE_TR1_REGEX 0)
 204         endif()
 205 else()
 206         if(MSVC10)
 207                 set(LYX_USE_TR1 1)
 208                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 209         endif()
 210 endif()
 211
 212
 213 set(VERSION_INFO "CMake Build")
 214
 215 # Try to get some informations from configure.ac
 216
 217 include(LyXPaths)
 218 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 219
 220 if(WIN32)
 221         set(USE_WINDOWS_PACKAGING ON)
 222 elseif(APPLE)
 223         set(USE_MACOSX_PACKAGING ON)
 224 else()
 225         set(USE_POSIX_PACKAGING ON)
 226 endif()
 227
 228 macro(setstripped _varname _value)
 229         string(STRIP ${_value} _v)
 230         if(USE_POSIX_PACKAGING)
 231                 string(TOLOWER ${_v} ${_varname})
 232         else()
 233                 set(${_varname} ${_v})
 234         endif()
 235 endmacro(setstripped)
 236
 237 foreach(_c_l ${_config_lines} )
 238         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 239                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 240                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 241                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 242                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 243                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 244                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 245                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 246                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 247                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 248                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 249                 endif()
 250         endif()
 251         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 252                 set(LYX_DATE "${CMAKE_MATCH_1}")
 253         endif()
 254 endforeach(_c_l)
 255
 256 if (LYX_LOCALVERSIONING)
 257         # Find the revision number and for later use
 258         FIND_PROGRAM(LYX_GITVERSION git)
 259         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 260         if(LYX_GITVERSION)
 261                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "describe" WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 262                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 263                   # We will add offset of 40000 to get appropriate value to
 264                   # previous svn.
 265                   # We use this value than also to set the package-patch-value
 266                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 267                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 268                 endif()
 269                 # Override the value from configure.ac, if possible
 270                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "log" "-1" "--format=%ci"
 271                         WORKING_DIRECTORY "${TOP_SRC_DIR}"
 272                         OUTPUT_VARIABLE LYX_DATEtmp OUTPUT_STRIP_TRAILING_WHITESPACE)
 273
 274                 string(REGEX MATCH "([0-9]+-[0-9]+-[0-9]+)" LYX_DATE ${LYX_DATEtmp})
 275         else()
 276                 set(LYX_REVISION_VERSION git) #TODO use date
 277         endif()
 278 else()
 279         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 280 endif()
 281
 282 if(LYX_PROGRAM_SUFFIX)
 283         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 284 else()
 285         set(PROGRAM_SUFFIX "")
 286 endif()
 287
 288
 289 if(APPLE)
 290         set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 291         configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 292 endif()
 293
 294 if(LYX_BUNDLE)
 295         set(LYX_CPACK ON)
 296         message(STATUS)
 297         message(STATUS "Bundle creation is enabled (experimental):")
 298         message(STATUS "    make")
 299         message(STATUS "    make install/strip")
 300         message(STATUS "    make package")
 301         if(APPLE)
 302                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 303                 set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 304                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 305                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 306                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 307                 if(NOT LYX_INSTALL_PREFIX)
 308                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 309                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 310                 endif()
 311                 # Change the owner so that the install can work
 312                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
 313         elseif(UNIX)
 314                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 315                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 316                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 317         elseif(WIN32)
 318                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 319         endif()
 320 endif()
 321
 322 if(LYX_INSTALL_PREFIX)
 323         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 324         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 325 endif()
 326 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 327
 328 if(LYX_PACKAGE_SUFFIX)
 329         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 330 else()
 331         set(PACKAGE ${PACKAGE_BASE})
 332 endif()
 333
 334
 335 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 336         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 337         if (UNIX)
 338                 # don't use the default "/usr/local"
 339                 # but respect the user-choice on the command-line
 340                 if(LYX_INSTALL_SUFFIX)
 341                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 342                 else()
 343                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 344                 endif()
 345         endif()
 346         if(WIN32)
 347                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 348         endif()
 349 endif()
 350 if(IS_ABSOLUTE)
 351         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 352 else()
 353         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 354 endif()
 355
 356
 357
 358 if(NOT LYX_DATA_SUBDIR)
 359         if (WIN32)
 360                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 361         else()
 362                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 363         endif()
 364 endif()
 365
 366 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 367 set(LYX_LOCALEDIR "locale")
 368 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 369 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 370
 371
 372 if(LYX_INSTALL AND WIN32)
 373         message(STATUS "Configuring NSIS files")
 374         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 375         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 376         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 377         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 378 endif()
 379
 380 if(NOT GROUP_CODE)
 381         #set(GROUP_CODE "The Golden Code")
 382         set(GROUP_CODE flat)
 383 endif()
 384
 385 # lyx's source files
 386 set(LYX_CPP_FILES *.cpp)
 387 set(LYX_HPP_FILES *.h)
 388 set(LYX_MOC_FILES moc_*.cpp)
 389
 390 include(ProjectSourceGroup)
 391
 392
 393 if(LYX_PROFILE AND NOT MSVC)
 394         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 395         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 396         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 397 else()
 398         set(LYX_PROFILE OFF)
 399 endif()
 400
 401
 402 if(LYX_NO_OPTIMIZE)
 403         set(CMAKE_BUILD_TYPE None)
 404         set(LYX_DEBUG OFF)
 405         set(LYX_RELEASE OFF)
 406         set(LYX_PROFILE OFF)
 407 elseif(LYX_RELEASE)
 408         set(CMAKE_BUILD_TYPE Release)
 409         set(LYX_DEBUG OFF)
 410         set(LYX_PROFILE OFF)
 411 elseif(LYX_PROFILE)
 412         set(CMAKE_BUILD_TYPE Profile)
 413         set(LYX_DEBUG OFF)
 414 else()
 415         set(CMAKE_BUILD_TYPE Debug)
 416         set(LYX_DEBUG ON)
 417 endif()
 418
 419
 420 # When shared libs are supported enable this option
 421 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 422 if(LYX_SHARED_LIBRARIES)
 423         set(library_type SHARED)
 424 else()
 425         set(library_type STATIC)
 426 endif()
 427
 428 if(NOT MSVC)
 429         if(NOT LYX_QUIET)
 430                 set(CMAKE_VERBOSE_MAKEFILE ON)
 431         endif()
 432         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 433         if(LYX_STDLIB_DEBUG)
 434                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 435         endif()
 436         if(LYX_CONCEPT_CHECKS)
 437                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 438         endif()
 439         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 440         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 441         if(MINGW)
 442                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 443         else()
 444                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 445         endif()
 446 endif()
 447
 448
 449 find_package(Qt4 REQUIRED)
 450 find_package(Magic)
 451 if(Magic_FOUND)
 452         set(HAVE_MAGIC_H 1)
 453 endif()
 454
 455 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 456
 457 if(LYX_ASPELL)
 458         find_package(ASPELL)
 459         include_directories(${ASPELL_INCLUDE_DIR})
 460 endif()
 461
 462 if(LYX_ENCHANT)
 463         find_package(Enchant REQUIRED)
 464         include_directories(${ENCHANT_INCLUDE_DIR})
 465 endif()
 466
 467 if(LYX_HUNSPELL)
 468         find_package(Hunspell REQUIRED)
 469         include_directories(${HUNSPELL_INCLUDE_DIR})
 470 endif()
 471
 472 if(LYX_NLS)
 473         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 474         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 475                 message(FATAL_ERROR "Python 2.6 needed!")
 476         endif()
 477         find_package(LyXGettext REQUIRED)
 478         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 479 endif()
 480
 481 if(LYX_NLS)
 482         if(LYX_EXTERNAL_LIBINTL)
 483                 find_package(Libintl REQUIRED)
 484                 if(DEFINED LIBINTL_LIBRARIES)
 485                         # find getext when configuring
 486                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 487                         # on mac use iconv also form ports
 488                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 489                 endif()
 490         else()
 491                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 492         endif()
 493 endif()
 494
 495 find_package(ICONV REQUIRED)
 496 find_package(ZLIB REQUIRED)
 497
 498 if(LYX_EXTERNAL_BOOST)
 499         message(STATUS "Searching for boost")
 500         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 501         if(Boost_FOUND)
 502                 message(STATUS "Boost found")
 503                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 504                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 505         else()
 506                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 507         endif()
 508 else()
 509         if(LYX_USE_TR1_REGEX)
 510                 set(Lyx_Boost_Libraries boost_signals)
 511         else()
 512                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 513         endif()
 514         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 515         include_directories(${TOP_SRC_DIR}/boost)
 516         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 517 endif()
 518
 519
 520
 521
 522 if(WIN32)
 523         if(NOT LYX_CONSOLE)
 524                 set(WIN32_CONSOLE WIN32)
 525                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 526         endif()
 527         if(MSVC)
 528                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 529                 # disable checked iterators for msvc release builds to get maximum speed
 530                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 531         else()
 532                 add_definitions(-DWINVER=0x0500)
 533         endif()
 534 endif()
 535
 536 message(STATUS "")
 537 foreach(_v PACKAGE PACKAGE_VERSION
 538         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 539         LYX_ABS_TOP_SRCDIR
 540         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 541         if(NOT DEFINED ${_v})
 542                 message(FATAL_ERROR "${_v} not defined")
 543         endif()
 544         string(SUBSTRING "${_v}                            " 0 28 _v1)
 545         message(STATUS "----- ${_v1}: ${${_v}}")
 546 endforeach(_v)
 547 message(STATUS "")
 548
 549
 550 if(LYX_PCH)
 551         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 552         # Not sure if it works for all non-msvc compilers
 553         include(PCHSupport_26)
 554         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 555         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 556         add_definitions(-DLYX_ENABLE_PCH)
 557
 558         if(MSVC)
 559                 macro(lyx_add_msvc_pch name_)
 560                         set_source_files_properties(${${name_}_sources} PROPERTIES
 561                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 562                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 563                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 564                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 565                                 ${TOP_BINARY_DIR}/pcheaders.h)
 566                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 567                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 568                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 569                 endmacro(lyx_add_msvc_pch)
 570                 macro(lyx_add_gcc_pch name_)
 571                 endmacro()
 572         else()
 573                 macro(lyx_add_msvc_pch name_)
 574                 endmacro()
 575                 macro(lyx_add_gcc_pch name_)
 576                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 577                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 578                 endmacro()
 579         endif()
 580 else()
 581         macro(lyx_add_msvc_pch)
 582         endmacro(lyx_add_msvc_pch)
 583         macro(lyx_add_gcc_pch name_)
 584         endmacro()
 585 endif()
 586
 587
 588 if(MSVC)
 589
 590         if(LYX_VLD)
 591                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 592                 add_subdirectory(${vld_path}/cmake)
 593                 include(${vld_path}/cmake/vld.cmake) # forced include
 594                 set(vld_dll vld)
 595         endif()
 596
 597         if(LYX_WALL)
 598                 # Use the highest warning level
 599                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 600
 601                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 602                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 603                 else()
 604                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 605                 endif()
 606
 607                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 608                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 609                 else()
 610                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 611                 endif()
 612
 613                 # add here warnings which should produce an error /weXXXX
 614                 set(MSVC_W_ERROR   "/we4101 /we4189")
 615                 # add here warnings which should be disabled /wdXXXX
 616                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 617
 618                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 619                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 620                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 621
 622         else()
 623                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 624
 625                 # add here warnings which should produce an error /weXXXX
 626                 set(MSVC_W_ERROR   "/we4101 /we4189")
 627                 # add here warnings which should be disabled /wdXXXX
 628                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 629
 630                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 631                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 632                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 633
 634         endif()
 635         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 636         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 637         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 638
 639         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 640         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 641         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 642         message(STATUS "")
 643 endif()
 644
 645
 646 if(LYX_DEBUG_GLIBC)
 647         set(_GLIBCXX_DEBUG ON)
 648 endif()
 649
 650 if(LYX_DEBUG_GLIBC_PEDANTIC)
 651         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 652 endif()
 653
 654 # Xcode compiler
 655 if (CMAKE_GENERATOR MATCHES Xcode)
 656         # Automatically select the Xcode compiler if not set
 657         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 658                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 659                 if (XCODE_VERSION VERSION_GREATER "3.1")
 660                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 661                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 662         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 663
 664         # Print the selected compiler version
 665     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 666 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 667
 668
 669 # compiler tests, config.h generation
 670 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 671         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 672 else()
 673         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 674         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 675 endif()
 676
 677 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 678 configure_file(${LYX_CMAKE_DIR}/lyx_date.h.cmake ${TOP_BINARY_DIR}/lyx_date.h)
 679
 680 # Compute qt4-version from ${QTVERSION}
 681 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 682         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 683 endif()
 684
 685 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 686 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 687 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 688 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 689
 690
 691 if(LYX_INSTALL)
 692         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 693                 message(STATUS "Python required to create doc!")
 694         else()
 695                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 696                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 697         endif()
 698         if(NOT(LYX_BUNDLE AND APPLE))
 699                 include(../Install)
 700         endif()
 701 endif()
 702
 703 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 704
 705 message(STATUS)
 706 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 707 message(STATUS)
 708 LYX_OPTION_LIST_ALL(used)
 709
 710
 711 if(LYX_NLS)
 712         message(STATUS)
 713         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 714         message(STATUS)
 715         message(STATUS "  * intl")
 716         message(STATUS "     - header : ${LIBINTL_HEADER}")
 717         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 718         message(STATUS "  * iconv")
 719         message(STATUS "     - header : ${ICONV_HEADER}")
 720         message(STATUS "     - library: ${ICONV_LIBRARY}")
 721         message(STATUS "  * zlib")
 722         message(STATUS "     - header : ${ZLIB_HEADER}")
 723         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 724         message(STATUS)
 725 endif()
 726
 727 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 728
 729 message(STATUS)