CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2020 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10 # Instruct cmake to not use gnu extensions,
  11 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  12 set(CMAKE_CXX_EXTENSIONS OFF)
  13
  14 enable_testing()
  15
  16 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  17 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  18 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  19
  20 set(LYX_CMAKE_DIR "development/cmake")
  21 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  22 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  23 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  24
  25 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  26
  27 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  28
  29 message(STATUS)
  30 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  31         message(STATUS "Building in-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  33 else()
  34         message(STATUS "Building out-of-source")
  35         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  36 endif()
  37
  38 # This directory should be used if some test uses lyx-executable
  39 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  40 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  41
  42 if(COMMAND cmake_policy)
  43         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  44         cmake_policy(SET CMP0006 NEW)
  45         if(POLICY CMP0043)
  46                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  47                 cmake_policy(SET CMP0043 NEW)
  48         endif()
  49         cmake_policy(SET CMP0020 NEW)
  50         if(POLICY CMP0075)
  51                 cmake_policy(SET CMP0075 NEW)
  52         endif()
  53         if(POLICY CMP0077)
  54                 cmake_policy(SET CMP0077 NEW)
  55         endif()
  56 endif()
  57
  58 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  59
  60 # Supress regeneration
  61 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  62
  63 if(LYX_XMINGW)
  64     set(CMAKE_SYSTEM_NAME Windows)
  65     set(TOOLNAME ${LYX_XMINGW})
  66     set(TOOLCHAIN "${TOOLNAME}-")
  67     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  68     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  69     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  70
  71     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  72     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  73     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  74 endif()
  75
  76 if(NOT help AND NOT HELP)
  77   # 'project' triggers the searching for a compiler
  78   project(${LYX_PROJECT})
  79   if (CMAKE_COMPILER_IS_GNUCXX)
  80     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.9")
  81       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  82       message(STATUS "is too old, should be >= 4.9")
  83       message(FATAL_ERROR "Exiting")
  84     endif()
  85   endif()
  86 endif()
  87
  88 if(UNIX)
  89         set(ARCH_TRIPLET )
  90         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  91         if(DPKG_ARCHITECTURE_EXECUTABLE)
  92                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  93                                 OUTPUT_VARIABLE ARCH_TRIPLET
  94                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  95                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  96         endif()
  97 endif()
  98 if(ARCH_TRIPLET)
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
 100 else()
 101         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 102 endif()
 103
 104 include(LyXMacros)
 105 include(LyXDestinations)
 106
 107 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 108 if(WIN32)
 109         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 110         if(MSVC)
 111                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 112         endif()
 113         set(USE_WINDOWS_PACKAGING ON)
 114 elseif(APPLE)
 115         set(USE_MACOSX_PACKAGING ON)
 116 else()
 117         set(USE_POSIX_PACKAGING ON)
 118 endif()
 119
 120 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 121 list(GET _package_list 0 PACKAGE_BASE)
 122 list(GET _package_list 1 PACKAGE_VERSION)
 123 list(GET _package_list 2 PACKAGE_BUGREPORT)
 124 list(GET _envlist 0 LYX_DIR_VER)
 125 list(GET _envlist 1 LYX_USERDIR_VER)
 126 list(GET _version_list 0 LYX_VERSION)
 127 list(GET _version_list 1 LYX_MAJOR_VERSION)
 128 list(GET _version_list 2 LYX_MINOR_VERSION)
 129 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 130 list(GET _version_list 4 LYX_RELEASE_PATCH)
 131
 132 # Usage LYX_OPTION
 133 # 1. parameter: option name without prefix 'LYX_'
 134 # 2. parameter: description
 135 # 3. parameter: default value, ON or OFF
 136 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 137
 138 # Usage LYX_COMBO
 139 # 1. parameter: name without prefix 'LYX_'
 140 # 2. parameter: description
 141 # 3. parameter: default value
 142 # 4-n parameter: possible other string values
 143
 144 LYX_OPTION_INIT()
 145 LYX_COMBO(ENABLE_BUILD_TYPE  "Allows to tweak the compiled code" AUTO release prerelease development gprof)
 146
 147 if(LYX_ENABLE_BUILD_TYPE MATCHES "AUTO")
 148   message(STATUS "Selecting build type defaults from configure.ac")
 149 else()
 150   set(LYX_BUILD_TYPE "${LYX_ENABLE_BUILD_TYPE}")
 151   message(STATUS "Selecting build type defaults from LYX_ENABLE_BUILD_TYPE")
 152 endif()
 153
 154 # Select some defaults depending on LYX_BUILD_TYPE
 155 # they can always be overwritten by the respective command line settings
 156 # These settings are only effective on fresh(==empty) CMakeCache.txt
 157 if(LYX_BUILD_TYPE STREQUAL "development")
 158   set(DefaultLyxDebug ON)
 159   set(DefaultLyxRelease OFF)
 160   set(DefaultLyxStdlibDebug ON)
 161   set(DefaultLyxEnableAssertions ON)
 162   set(DefaultLyxProfile OFF)
 163   set(DefaultExternalLibs OFF)
 164 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 165   set(DefaultLyxDebug OFF)
 166   set(DefaultLyxRelease OFF)
 167   set(DefaultLyxStdlibDebug OFF)
 168   set(DefaultLyxEnableAssertions OFF)
 169   set(DefaultLyxProfile OFF)
 170   set(DefaultExternalLibs ON)
 171 elseif(LYX_BUILD_TYPE STREQUAL "release")
 172   set(DefaultLyxDebug OFF)
 173   set(DefaultLyxRelease ON)
 174   set(DefaultLyxStdlibDebug OFF)
 175   set(DefaultLyxEnableAssertions OFF)
 176   set(DefaultLyxProfile OFF)
 177   set(DefaultExternalLibs ON)
 178 elseif(LYX_BUILD_TYPE STREQUAL "gprof")
 179   set(DefaultLyxDebug ON)
 180   set(DefaultLyxRelease OFF)
 181   set(DefaultLyxStdlibDebug OFF)
 182   set(DefaultLyxEnableAssertions OFF)
 183   set(DefaultLyxProfile ON)
 184   set(DefaultExternalLibs OFF)
 185 else()
 186   message(FATAL_ERROR "Invalid build type (${LYX_BUILD_TYPE}) encountered")
 187 endif()
 188
 189 # Options for all compilers/systems
 190 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 191 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 192 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 193 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 194 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 195 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 196 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 197 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 198 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 199 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 200 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 201 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 202 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 203 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 204 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 205 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 206 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 207 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 208 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 209 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 210 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 211 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 212 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 213 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 214   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 215 else()
 216   if (LYX_ENABLE_VALGRIND_TESTS)
 217     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 218   endif()
 219 endif()
 220 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 221 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 222 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 223 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 224 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 225 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 226 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ${DefaultExternalLibs} ALL)
 227 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ${DefaultExternalLibs} ALL)
 228 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ${DefaultExternalLibs} ALL)
 229 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ${DefaultExternalLibs} ALL)
 230 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 231
 232 # GCC specific
 233 LYX_OPTION(PROFILE              "Build with options for gprof" ${DefaultLyxProfile} GCC)
 234 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" ${DefaultExternalLibs} GCC)
 235 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 236 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 237 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 238 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 239
 240 # MSVC specific
 241 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 242 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 243 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 244 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 245
 246 # APPLE specific
 247 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 248 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 249
 250 # Try to get some informations from configure.ac
 251 include(LyXPaths)
 252
 253
 254 if(help OR HELP)
 255         message(STATUS)
 256         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 257         message(STATUS)
 258         LYX_OPTION_LIST_ALL(help)
 259         message(STATUS)
 260         unset(help CACHE)
 261         unset(HELP CACHE)
 262         RETURN()
 263 endif()
 264
 265 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 266   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 267 else()
 268   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 269 endif()
 270
 271 # Check option dependencies
 272 if (LYX_ENABLE_VALGRIND_TESTS)
 273         find_program(VALGRIND_EXECUTABLE "valgrind")
 274         if (NOT VALGRIND_EXECUTABLE)
 275                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 276         endif()
 277 endif()
 278 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 279   if (LYX_EXTERNAL_BOOST)
 280     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 281   endif()
 282 endif()
 283
 284 if(LYX_DMG)
 285         set(LYX_BUNDLE ON)
 286         set(LYX_CPACK ON)
 287 endif()
 288
 289 if(LYX_CPACK)
 290         set(LYX_INSTALL ON)
 291 endif()
 292
 293 if(LYX_INSTALL)
 294         set(LYX_NLS ON)
 295         if(WIN32 AND NOT MINGW)
 296                 set(LYX_HUNSPELL ON)
 297         endif()
 298         set(LYX_PACKAGE_SUFFIX ON)
 299         if(NOT LYX_DEBUG)
 300                 set(LYX_RELEASE ON)
 301         endif()
 302         set(LYX_PROFILE OFF)
 303 endif()
 304
 305
 306 if(LYX_MERGE_FILES)
 307         set(LYX_PCH OFF)
 308 else()
 309         set(LYX_MERGE_REBUILD OFF)
 310 endif()
 311
 312 if(LYX_DEPENDENCIES_DOWNLOAD)
 313         message(STATUS)
 314         if(MSVC14)
 315                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 316                 set(deps_files lyx-windows-deps-msvc2015.zip)
 317                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 318                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 319         elseif(MSVC10)
 320                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 321                 set(deps_files lyx-windows-deps-msvc2010.zip)
 322                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 323                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 324         else()
 325                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 326         endif()
 327     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 328         foreach(it ${deps_files})
 329                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 330                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 331                 if(NOT already_downloaded)
 332                         message(STATUS "Downloading ${it} ...")
 333                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 334                         list(GET status 0 status_code)
 335                         list(GET status 1 status_string)
 336                         if(NOT status_code EQUAL 0)
 337                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 338                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 339                         endif()
 340                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 341                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 342                 endif()
 343         endforeach()
 344 endif()
 345
 346 message(STATUS)
 347
 348 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 349 if(WIN32)
 350         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 351 else()
 352         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 353 endif()
 354
 355 set(LYX_IPO_SUPPORTED OFF)
 356 if (POLICY CMP0069)
 357   cmake_policy(SET CMP0069 NEW)
 358   if(LYX_USE_IPO MATCHES "AUTO")
 359     # Enable LTO if supported and not debugging
 360     if (NOT LYX_DEBUG)
 361       include(CheckIPOSupported)
 362       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 363     endif()
 364   else()
 365     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 366   endif()
 367 endif()
 368 if (LYX_IPO_SUPPORTED)
 369   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 370 else()
 371   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 372 endif()
 373
 374 # Set to some meaningful default
 375 find_package(CXX11Compiler)
 376 if(NOT CXX11COMPILER_FOUND)
 377         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 378 endif()
 379 unset(LYX_GCC11_MODE)
 380 if(UNIX OR MINGW)
 381         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 382           # ignore the GCC_VERSION for clang
 383           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 384           message(STATUS "Using clang")
 385           if(CXX11_STD_REGEX)
 386             set(LYX_USE_STD_REGEX 1)
 387           else()
 388             set(LYX_USE_STD_REGEX 0)
 389           endif()
 390         else()
 391           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 392           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 393           if (_err)
 394             # previous check failed, try again with _old_ parameter
 395             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 396             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 397           endif()
 398           message(STATUS "Using GCC version ${GCC_VERSION}")
 399           if(GCC_VERSION VERSION_LESS 4.9)
 400                 message(FATAL_ERROR "gcc >= 4.9 is required.")
 401           endif()
 402           set(LYX_USE_STD_REGEX 1)
 403         endif()
 404         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 405 else()
 406         if(MSVC_VERSION LESS 1900)
 407                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 408                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 409         endif()
 410         set(LYX_USE_STD_REGEX 1)
 411 endif()
 412
 413 if(LYX_3RDPARTY_BUILD)
 414   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 415   # this enables the build of all 3rd_party libs
 416   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 417   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 418   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 419   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 420 endif()
 421
 422 FIND_PROGRAM(LYX_GITVERSION git)
 423 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 424 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 425 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 426 if(LYX_GITVERSION)
 427   if (LYX_LOCALVERSIONING)
 428     # Find the revision number for later use
 429     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 430       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 431       RESULT_VARIABLE tmp_GIT_RESULT
 432       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 433       ERROR_VARIABLE tmp_GIT_ERROR
 434       OUTPUT_STRIP_TRAILING_WHITESPACE)
 435     if (tmp_GIT_RESULT EQUAL 0)
 436       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 437         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 438         # We will add offset of 40000 to get appropriate value to
 439         # previous svn.
 440         # We use this value than also to set the package-patch-value
 441         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 442         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 443         set(ENABLE_DIST ON)
 444       endif()
 445     endif()
 446   endif()
 447 endif()
 448 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 449   set(LYX_PACKAGE_RELEASE  "1")
 450   if (LYX_RELEASE_PATCH GREATER 0)
 451     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 452   endif()
 453 endif()
 454
 455 # Set the programs (lyx, tex2lyx, etc.) suffix
 456 # When building an OS X bundle, we will append
 457 # the suffix only to the bundle, not to the programs
 458 set(PROGRAM_SUFFIX "")
 459 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 460         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 461 endif()
 462 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 463 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 464 set(_convert lyxconvert${PROGRAM_SUFFIX})
 465
 466 add_custom_target(lyx_version ALL
 467   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 468   )
 469 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 470
 471 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 472 set(LYX_UTILITIES_INSTALL_PATH bin)
 473
 474 if(LYX_BUNDLE)
 475         set(LYX_CPACK ON)
 476
 477         message(STATUS)
 478         message(STATUS "Bundle creation is enabled (experimental):")
 479         message(STATUS "    make")
 480         message(STATUS "    make install/strip")
 481         message(STATUS "    make package")
 482         if(APPLE)
 483                 set(MACOSX_BUNDLE TRUE)
 484                 # This sets the bundle + executable names
 485                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 486                 # This sets the Info.plist executable name
 487                 set(osx_bundle_program_name ${_lyx})
 488                 # Bundle name
 489                 set(LYX_BUNDLE_NAME ${_lyx})
 490
 491                 # This will contain the list of files that need to be included
 492                 # in the bundle and their location within the bundle
 493                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 494                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 495
 496                 # Process Info.plist and lyxrc.dist
 497                 # See development/cmake/Install.cmake
 498                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 499
 500                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 501                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 502
 503                 # Variables used by CPack
 504                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 505                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 506                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 507
 508                 # Set the install paths
 509                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 510                 if(NOT LYX_INSTALL_PREFIX)
 511                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 512                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 513                 endif()
 514                 # Change the owner so that the install can work
 515                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 516         elseif(UNIX)
 517                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 518                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 519                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 520         elseif(WIN32)
 521                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 522         endif()
 523 endif()
 524
 525 if(LYX_INSTALL_PREFIX)
 526         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 527         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 528 endif()
 529 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 530
 531 if(UNIX)
 532   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 533 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 534   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 535 else()
 536   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 537 endif()
 538
 539 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 540   # Not a GCC compiler, programs do not have a suffix
 541   set(suffixing ${LYX_PACKAGE_SUFFIX})
 542 elseif(WIN32 AND MINGW)
 543   # We want to use a suffix for the package in this case,
 544   # even if not for the program
 545   set(suffixing ${LYX_PACKAGE_SUFFIX})
 546 else()
 547   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 548   set(suffixing ${LYX_PROGRAM_SUFFIX})
 549 endif()
 550
 551 # The define PACKAGE below allows lyx-executable to find its default configuration files
 552 # see routines
 553 #    Package::messages_file()
 554 #    get_default_user_support_dir()
 555 #    relative_system_support_dir()
 556 # in src/support/Package.cpp
 557 if(suffixing)
 558         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 559 else()
 560         set(PACKAGE ${PACKAGE_BASE})
 561 endif()
 562
 563 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 564         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 565         if (UNIX)
 566                 # use the default "/usr/local"
 567                 # but respect the user-choice on the command-line
 568                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 569         endif()
 570 endif()
 571 if(WIN32)
 572         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 573 endif()
 574 if(IS_ABSOLUTE)
 575         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 576 else()
 577         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 578 endif()
 579
 580
 581
 582 if(NOT LYX_DATA_SUBDIR)
 583         if (WIN32)
 584                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 585         else()
 586                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 587         endif()
 588 endif()
 589
 590 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 591 get_locale_destination(LYX_LOCALEDIR)
 592 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 593 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 594
 595 if(LYX_BUNDLE AND APPLE)
 596         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 597 else()
 598         if(WIN32)
 599                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 600         elseif(UNIX)
 601                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 602         else()
 603                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 604         endif()
 605 endif()
 606 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 607         unset(LYX_MAN_DIR CACHE)
 608         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 609 endif()
 610 unset(LYX_MAN_DIR_tmp)
 611 mark_as_advanced(LYX_MAN_DIR)
 612
 613 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 614 # see the Readme.txt of the installer
 615 #if(LYX_INSTALL AND WIN32)
 616 #       message(STATUS "Configuring NSIS files")
 617 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 618 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 619 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 620 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 621 #endif()
 622
 623 if(NOT GROUP_CODE)
 624         #set(GROUP_CODE "The Golden Code")
 625         set(GROUP_CODE flat)
 626 endif()
 627
 628 # lyx's source files
 629 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 630 set(LYX_HPP_FILES [a-zA-Z]*.h)
 631 set(LYX_MOC_FILES moc_*.cpp)
 632
 633 include(ProjectSourceGroup)
 634
 635
 636 if(LYX_PROFILE AND NOT MSVC)
 637         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 638         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 639         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 640 else()
 641         set(LYX_PROFILE OFF)
 642 endif()
 643
 644
 645 if(LYX_NO_OPTIMIZE)
 646         set(CMAKE_BUILD_TYPE None)
 647         set(LYX_DEBUG OFF)
 648         set(LYX_RELEASE OFF)
 649         set(LYX_PROFILE OFF)
 650 elseif(LYX_RELEASE)
 651         set(CMAKE_BUILD_TYPE Release)
 652         set(LYX_DEBUG OFF)
 653         set(LYX_PROFILE OFF)
 654 elseif(LYX_PROFILE)
 655         set(CMAKE_BUILD_TYPE Profile)
 656         set(LYX_DEBUG OFF)
 657 else()
 658         set(CMAKE_BUILD_TYPE Debug)
 659         set(LYX_DEBUG ON)
 660 endif()
 661
 662
 663 # When shared libs are supported enable this option
 664 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 665 if(LYX_SHARED_LIBRARIES)
 666         set(library_type SHARED)
 667 else()
 668         set(library_type STATIC)
 669 endif()
 670
 671 if(LYX_ENABLE_ASSERTIONS)
 672   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 673 else()
 674   set(LYX_CXX_FLAGS "")
 675 endif()
 676
 677 if(MSVC)
 678   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 679     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 680     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 681   endif()
 682   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 683 else()
 684         if(NOT LYX_QUIET)
 685                 set(CMAKE_VERBOSE_MAKEFILE ON)
 686         endif()
 687         if(LYX_GCC11_MODE MATCHES "\\+\\+([0-9][0-9])")
 688           # Thanks to Brad King <brad.king@kitware.com>
 689           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 690           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 691           # and still use our own c++ extension tests
 692           set(std_num ${CMAKE_MATCH_1})
 693           set(CMAKE_CXX_STANDARD ${std_num})
 694         else()
 695           message(STATUS "Setting CMAKE_CXX_STANDARD 11 as fallback")
 696           set(CMAKE_CXX_STANDARD 11)
 697           set(LYX_GCC11_MODE "--std=c++11")
 698         endif()
 699         # The following setting with LYX_GCC11_MODE is needed because cmake does not honor
 700         # CMAKE_CXX_STANDARD while performing tests like
 701         # check_cxx_source_compiles("..." HAVE_DEF_MAKE_UNIQUE)
 702         set(LYX_CXX_FLAGS "-Wall -Wextra -Wno-deprecated-copy ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 703         if(LYX_STDLIB_DEBUG)
 704           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 705         else()
 706           if(LYX_DEBUG_GLIBC)
 707             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 708           endif()
 709           if(LYX_DEBUG_GLIBC_PEDANTIC)
 710             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 711           endif()
 712         endif()
 713         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 714         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 715         if(MINGW)
 716                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 717         else()
 718                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 719         endif()
 720 endif()
 721
 722 if(LYX_ASAN)
 723     set(CMAKE_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g ${CMAKE_CXX_FLAGS}")
 724     message(STATUS)
 725     message(STATUS "Address sanitizer enabled. Usage:")
 726     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 727     message(STATUS "    chmod  +x ./asan_symbolize.py")
 728     message(STATUS "    ./bin/${_lyx} 2>&1 | ./asan_symbolize.py  | c++filt ")
 729     message(STATUS)
 730 endif()
 731
 732 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 733 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 734 if(LYX_CXX_FLAGS_EXTRA)
 735         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 736                 add_definitions(${_flag})
 737         endforeach()
 738 endif()
 739
 740 if(LYX_XMINGW)
 741         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 742 endif()
 743
 744 set(min_qt5_version "5.6")
 745 if(LYX_USE_QT MATCHES "AUTO")
 746         # try qt5 first
 747         find_package(Qt5Core CONFIG QUIET)
 748         if(Qt5Core_FOUND)
 749                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 750                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 751                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 752                         find_package(Qt4 "4.5.0" QUIET)
 753                         if(QT4_FOUND)
 754                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 755                         endif()
 756                 endif()
 757         else()
 758                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 759         endif()
 760 endif()
 761 if(LYX_USE_QT MATCHES "QT5")
 762         # set QPA_XCB if QT uses X11
 763         find_package(Qt5Core CONFIG REQUIRED)
 764         if (Qt5Core_FOUND)
 765                 find_package(Qt5Widgets CONFIG REQUIRED)
 766                 if(APPLE)
 767                         find_package(Qt5MacExtras CONFIG REQUIRED)
 768                 endif()
 769                 find_package(Qt5X11Extras CONFIG QUIET)
 770                 find_package(Qt5WinExtras CONFIG QUIET)
 771                 set(QTVERSION ${Qt5Core_VERSION})
 772                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 773                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 774                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 775                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 776                         # see thread in lyx-devel list
 777                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 778                         # Date 11.03.2017
 779                         # Subject: cmake compilation error
 780                         #message(FATAL_ERROR "Wrong Qt-Version")
 781                 endif()
 782                 macro (qt_use_modules lyxtarget)
 783                         foreach (_tg ${ARGN})
 784                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 785                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 786                         endforeach()
 787                 endmacro()
 788                 macro (qt_add_resources)
 789                         qt5_add_resources(${ARGN})
 790                 endmacro()
 791                 macro (qt_wrap_uifiles)
 792                         qt5_wrap_ui(${ARGN})
 793                 endmacro()
 794                 message(STATUS "Found Qt-Version ${QTVERSION}")
 795                 if(WIN32)
 796                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 797                 endif()
 798         endif()
 799 elseif(LYX_USE_QT MATCHES "QT4")
 800         if(LYX_XMINGW)
 801                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 802                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 803         endif()
 804         find_package(Qt4 "4.5.0" REQUIRED)
 805         macro (qt_use_modules)
 806         endmacro()
 807         macro (qt_add_resources)
 808                 qt4_add_resources(${ARGN})
 809         endmacro()
 810         macro (qt_wrap_uifiles)
 811                 qt4_wrap_ui(${ARGN})
 812         endmacro()
 813         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 814         if(WIN32)
 815                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 816         endif()
 817 else()
 818   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 819 endif()
 820
 821 find_package(Magic)
 822 if(Magic_FOUND)
 823   set(HAVE_MAGIC_H 1)
 824   include_directories(${Magic_INCLUDE_DIR})
 825 endif()
 826
 827 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 828
 829 set(Spelling_FOUND OFF)
 830 set(Include_used_spellchecker)   # String will be inserted into config.h
 831
 832 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 833   # try system library first
 834   find_package(MYTHESLIB)
 835   if (MYTHESLIB_FOUND)
 836     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 837   else()
 838     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 839   endif()
 840 endif()
 841 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 842   find_package(MYTHESLIB REQUIRED)
 843 else()
 844   add_subdirectory(3rdparty/mythes)
 845 endif()
 846 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 847
 848 if(NOT LYX_EXTERNAL_HUNSPELL)
 849     add_subdirectory(3rdparty/hunspell)
 850     add_definitions(-DHUNSPELL_STATIC)
 851     set(HUNSPELL_FOUND ON)
 852     message(STATUS "  * Hunspell:")
 853     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 854     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 855 endif()
 856
 857 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 858   string(TOUPPER ${_spell} _upspell)
 859   if (NOT ${_upspell}_FOUND)
 860     find_package(${_spell})
 861   endif()
 862   if (${_upspell}_FOUND)
 863     include_directories(${${_upspell}_INCLUDE_DIR})
 864     set(Spelling_FOUND ON)
 865     message(STATUS "Building with USE_${_upspell}")
 866     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 867   else()
 868     if(LYX_${_upspell})
 869       message(FATAL_ERROR "Required ${_spell} devel package not found")
 870     else()
 871       message(STATUS "${_upspell} not found, building without ${_spell} support")
 872     endif()
 873   endif()
 874 endforeach()
 875
 876 if(GNUWIN32_DIR)
 877         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 878         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Perl/bin" )
 879 endif()
 880
 881 # Search for python default version first
 882 unset(PYTHON_EXECUTABLE CACHE)
 883 unset(LYX_PYTHON_EXECUTABLE CACHE)
 884 unset(PYTHON_VERSION_MAJOR)
 885 unset(PYTHON_VERSION_MINOR)
 886 unset(PYTHON_VERSION_STRING)
 887 if (CMAKE_VERSION VERSION_LESS "3.13")
 888   find_package(PythonInterp 3.5 QUIET)
 889   if(NOT PYTHONINTERP_FOUND)
 890     find_package(PythonInterp 2.0 REQUIRED)
 891     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 892       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 893     endif()
 894   endif()
 895   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 896 else()
 897   find_package(Python3 3.5 QUIET)
 898   if(NOT Python3_Interpreter_FOUND)
 899     unset(PYTHON_EXECUTABLE CACHE)
 900     find_package(Python2 2.0 REQUIRED)
 901     if(NOT Python2_VERSION VERSION_LESS 2.8)
 902       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 903     endif()
 904     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 905   else()
 906     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 907   endif()
 908 endif()
 909
 910 if(LYX_NLS)
 911         find_package(LyXGettext)
 912         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 913                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 914         else()
 915                 # Install only supplied .gmo-files
 916                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 917                 message(STATUS "Installing provided .gmo-files only")
 918                 foreach( _gmo ${_gmofiles})
 919                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 920                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 921                 endforeach()
 922         endif()
 923 endif()
 924
 925 if(LYX_EXTERNAL_ICONV)
 926   # Possible remnants of previous run without external iconv
 927   file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/libiconv" "${CMAKE_BINARY_DIR}/3rdparty/libiconv")
 928   find_package(ICONV REQUIRED)
 929 else()
 930   add_subdirectory(3rdparty/libiconv)
 931   set(HAVE_ICONV_CONST 1)
 932 endif()
 933
 934 if(LYX_EXTERNAL_Z)
 935   find_package(ZLIB REQUIRED)
 936 else()
 937   add_subdirectory(3rdparty/zlib)
 938 endif()
 939
 940 if(NOT LYX_EXTERNAL_DTL)
 941   add_subdirectory(3rdparty/dtl)
 942 endif()
 943
 944 if(LYX_USE_STD_REGEX)
 945   # Set only include path.
 946   # Use internal boost, which is known to exist
 947   # we don't need any libraries
 948   set(Lyx_Boost_Libraries)
 949   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 950   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 951 else()
 952   # Using boost-regex
 953   if(LYX_EXTERNAL_BOOST)
 954     message(STATUS "Searching for external boost")
 955     find_package(Boost COMPONENTS regex)
 956     if(Boost_FOUND)
 957       message(STATUS "Boost found")
 958       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 959       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 960       if (LYX_STDLIB_DEBUG OR LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC)
 961         # Comment from  Jean-Marc Lasgouttes:
 962         # In general, system boost libraries are incompatible with
 963         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 964         # details.
 965         message(FATAL_ERROR "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF -DLYX_DEBUG_GLIBC=OFF -DLYX_DEBUG_GLIBC_PEDANTIC=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 966       endif()
 967     else()
 968       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 969     endif()
 970   else()
 971     # Using included boost
 972     set(Lyx_Boost_Libraries boost_regex)
 973     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 974     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 975     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 976   endif()
 977 endif()
 978
 979 if(WIN32)
 980         if(LYX_CONSOLE)
 981                 set(LYX_QTMAIN_LIBRARY)
 982         else()
 983                 set(WIN32_CONSOLE WIN32)
 984         endif()
 985         if(MSVC)
 986                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 987                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 988                 # disable checked iterators for msvc release builds to get maximum speed
 989                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 990         else()
 991                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 992                 # does not use it and always declares the vista compatible API.
 993                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 994                 add_definitions(-DWINVER=0x0500)
 995         endif()
 996 endif()
 997
 998 # Compute qt-version from ${QTVERSION}
 999
1000 message(STATUS "")
1001 foreach(_v PACKAGE PACKAGE_VERSION
1002         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
1003         LYX_ABS_TOP_SRCDIR
1004         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
1005         if(NOT DEFINED ${_v})
1006                 message(FATAL_ERROR "${_v} not defined")
1007         endif()
1008         string(SUBSTRING "${_v}                            " 0 28 _v1)
1009         message(STATUS "----- ${_v1}: ${${_v}}")
1010 endforeach(_v)
1011 message(STATUS "")
1012
1013
1014 if(LYX_PCH)
1015         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
1016         # Not sure if it works for all non-msvc compilers
1017         include(PCHSupport_26)
1018         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
1019         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
1020         add_definitions(-DLYX_ENABLE_PCH)
1021
1022         if(MSVC)
1023                 macro(lyx_add_msvc_pch name_)
1024                         set_source_files_properties(${${name_}_sources} PROPERTIES
1025                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
1026                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
1027                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
1028                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
1029                                 ${TOP_BINARY_DIR}/pcheaders.h)
1030                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1031                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1032                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
1033                 endmacro(lyx_add_msvc_pch)
1034                 macro(lyx_add_gcc_pch name_)
1035                 endmacro()
1036         else()
1037                 macro(lyx_add_msvc_pch name_)
1038                 endmacro()
1039                 macro(lyx_add_gcc_pch name_)
1040                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1041                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1042                 endmacro()
1043         endif()
1044 else()
1045         macro(lyx_add_msvc_pch)
1046         endmacro(lyx_add_msvc_pch)
1047         macro(lyx_add_gcc_pch name_)
1048         endmacro()
1049 endif()
1050
1051
1052 if(MSVC)
1053
1054         if(LYX_VLD)
1055                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1056                 add_subdirectory(${vld_path}/cmake)
1057                 include(${vld_path}/cmake/vld.cmake) # forced include
1058                 set(vld_dll vld)
1059         endif()
1060
1061         if(LYX_WALL)
1062                 # Use the highest warning level
1063                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1064
1065                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1066                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1067                 else()
1068                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1069                 endif()
1070
1071                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1072                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1073                 else()
1074                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1075                 endif()
1076
1077                 # add here warnings which should produce an error /weXXXX
1078                 set(MSVC_W_ERROR   "/we4101 /we4189")
1079                 # add here warnings which should be disabled /wdXXXX
1080                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1081
1082                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1083                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1084                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /W4 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1085
1086         else()
1087                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1088
1089                 # add here warnings which should produce an error /weXXXX
1090                 set(MSVC_W_ERROR   "/we4101 /we4189")
1091                 # add here warnings which should be disabled /wdXXXX
1092                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1093
1094                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1095                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1096                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1097
1098         endif()
1099
1100         if (NOT Qt5Core_FOUND)
1101                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1102                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1103                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1104         endif()
1105
1106         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1107         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1108         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1109         message(STATUS "")
1110 endif()
1111
1112
1113 # Xcode compiler
1114 if (CMAKE_GENERATOR MATCHES Xcode)
1115         if (XCODE_VERSION VERSION_LESS "5.0")
1116                 # Automatically select the Xcode compiler if not set
1117                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1118                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1119                         if (XCODE_VERSION VERSION_GREATER "3.1")
1120                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1121                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1122                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1123                 # Print the selected compiler version
1124         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1125         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1126 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1127
1128 if (WIN32 AND Qt5Core_FOUND)
1129         set(Z_PREFIX 1)
1130 endif()
1131
1132 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1133 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1134 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1135
1136 unset(opts)
1137 foreach(_option ${LYX_OPTIONS})
1138   if(${_option}_show_message)
1139     string(SUBSTRING "${_option}                            " 0 31 _var)
1140     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1141     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1142     if (${_index} GREATER -1)
1143       set(_isset ${${_option}})
1144     elseif(${_option})
1145       set(_isset ON)
1146     else()
1147       set(_isset OFF)
1148     endif()
1149     string(SUBSTRING "${_isset}           " 0 10 _val)
1150     set(opts "${opts} ${_option}(${${_option}})")
1151   endif()
1152 endforeach()
1153 set(tmp_vi "CMake Build")
1154 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1155 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1156 list(APPEND tmp_vi "  Build flags:             ${opts}")
1157 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1158 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1159 if (LYX_DEBUG)
1160 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1161 else()
1162 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1163 endif()
1164 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1165 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1166 get_data_destination(dest_data)
1167 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1168 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1169
1170 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1171 unset(opts)
1172 unset(tmp_vi)
1173
1174 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1175         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1176 endif()
1177
1178 if (NOT HAVE_REGEX)
1179         set(LYX_USE_STD_REGEX 0)
1180 endif()
1181
1182
1183 set (cmd ${CMAKE_CTEST_COMMAND})
1184 if (MSVC)
1185         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1186 else ()
1187         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1188 endif ()
1189 add_custom_target (lyx_run_tests COMMAND ${cmd})
1190 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1191
1192 if(LYX_INSTALL)
1193         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1194                 message(STATUS "Python required to create doc!")
1195         else()
1196                 if(UNIX)
1197                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1198                 endif()
1199                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1200         endif()
1201 endif()
1202 include(../Install)
1203
1204 # By running the URL tests first, time can be saved when running the ctests in
1205 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1206
1207 # Needed, because of perl scripts in checkurls autotests and batchtests
1208 find_package(Perl REQUIRED)
1209
1210 if(LYX_ENABLE_URLTESTS)
1211         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1212 endif()
1213 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1214 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1215 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1216 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1217 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1218 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1219 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1220
1221 message(STATUS)
1222 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1223 message(STATUS)
1224
1225 LYX_OPTION_LIST_ALL(used)
1226
1227
1228 if(LYX_NLS)
1229         message(STATUS)
1230         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1231         message(STATUS)
1232         message(STATUS "  * iconv")
1233         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1234         message(STATUS "     - library: ${ICONV_LIBRARY}")
1235         message(STATUS "  * zlib")
1236         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1237         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1238         message(STATUS)
1239 endif()
1240
1241 # Apple has builtin native spell checker,
1242 # no need to warn for missing Aspell, Hunspell or Enchant
1243 if(NOT Spelling_FOUND AND NOT APPLE)
1244   if(LYX_REQUIRE_SPELLCHECK)
1245     set(_mode "FATAL_ERROR")
1246   else()
1247     set(_mode "STATUS")
1248   endif()
1249   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1250 endif()
1251
1252 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1253
1254 if(ENABLE_DIST)
1255   # Use git to create the source package
1256   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1257   if(UNIX)
1258     set(DIST_FORMAT tgz)
1259   else()
1260     set(DIST_FORMAT zip)
1261   endif()
1262   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1263
1264   add_custom_command(
1265     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1266     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1267     WORKING_DIRECTORY ${TOP_SRC_DIR})
1268   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1269 endif()
1270
1271 # Last directory to be included so that the fixup code (OS X)
1272 # can be run last
1273 add_subdirectory(development/cmake/post_install)
1274
1275 string(TIMESTAMP current_date "%Y-%m-%d %H:%M")
1276 execute_process(COMMAND ${LYX_GITVERSION} describe --tags
1277         WORKING_DIRECTORY "${TOP_SRC_DIR}"
1278         OUTPUT_VARIABLE current_version
1279         OUTPUT_STRIP_TRAILING_WHITESPACE)
1280 file(APPEND "${TOP_BINARY_DIR}/Testing/IgnoredCount" "${current_date} ${current_version} Ignored tests = ${LYX_ignored_count}\n")
1281 message(STATUS)