CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Try to get some informations from configure.ac
 106 include(LyXPaths)
 107
 108 # Value of USE_POSIX_PACKAGING is needed in determineversionandbuildtype()
 109 if(WIN32)
 110         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 111         if(MSVC)
 112                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 113         endif()
 114         set(USE_WINDOWS_PACKAGING ON)
 115 elseif(APPLE)
 116         set(USE_MACOSX_PACKAGING ON)
 117 else()
 118         set(USE_POSIX_PACKAGING ON)
 119 endif()
 120
 121 determineversionandbuildtype("${TOP_SRC_DIR}/configure.ac" _package_list _version_list _envlist LYX_DATE LYX_BUILD_TYPE)
 122 list(GET _package_list 0 PACKAGE_BASE)
 123 list(GET _package_list 1 PACKAGE_VERSION)
 124 list(GET _package_list 2 PACKAGE_BUGREPORT)
 125 list(GET _envlist 0 LYX_DIR_VER)
 126 list(GET _envlist 1 LYX_USERDIR_VER)
 127 list(GET _version_list 0 LYX_VERSION)
 128 list(GET _version_list 1 LYX_MAJOR_VERSION)
 129 list(GET _version_list 2 LYX_MINOR_VERSION)
 130 list(GET _version_list 3 LYX_RELEASE_LEVEL)
 131 list(GET _version_list 4 LYX_RELEASE_PATCH)
 132
 133 # Usage LYX_OPTION
 134 # 1. parameter: option name without prefix 'LYX_'
 135 # 2. parameter: description
 136 # 3. parameter: default value, ON or OFF
 137 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 138
 139 # Usage LYX_COMBO
 140 # 1. parameter: name without prefix 'LYX_'
 141 # 2. parameter: description
 142 # 3. parameter: default value
 143 # 4-n parameter: possible other string values
 144
 145 LYX_OPTION_INIT()
 146 LYX_COMBO(ENABLE_BUILD_TYPE  "Allows to tweak the compiled code" AUTO release prerelease development gprof)
 147
 148 if(LYX_ENABLE_BUILD_TYPE MATCHES "AUTO")
 149   message(STATUS "Selecting build type defaults from configure.ac")
 150 else()
 151   set(LYX_BUILD_TYPE "${LYX_ENABLE_BUILD_TYPE}")
 152   message(STATUS "Selecting build type defaults from LYX_ENABLE_BUILD_TYPE")
 153 endif()
 154
 155 # Select some defaults depending on LYX_BUILD_TYPE
 156 # they can always be overwritten by the respective command line settings
 157 # These settings are only effective on fresh(==empty) CMakeCache.txt
 158 if(LYX_BUILD_TYPE STREQUAL "development")
 159   set(DefaultLyxDebug ON)
 160   set(DefaultLyxRelease OFF)
 161   set(DefaultLyxStdlibDebug ON)
 162   set(DefaultLyxEnableAssertions ON)
 163   set(DefaultLyxProfile OFF)
 164 elseif(LYX_BUILD_TYPE STREQUAL "prerelease")
 165   set(DefaultLyxDebug OFF)
 166   set(DefaultLyxRelease OFF)
 167   set(DefaultLyxStdlibDebug OFF)
 168   set(DefaultLyxEnableAssertions OFF)
 169   set(DefaultLyxProfile OFF)
 170 elseif(LYX_BUILD_TYPE STREQUAL "release")
 171   set(DefaultLyxDebug OFF)
 172   set(DefaultLyxRelease ON)
 173   set(DefaultLyxStdlibDebug OFF)
 174   set(DefaultLyxEnableAssertions OFF)
 175   set(DefaultLyxProfile OFF)
 176 elseif(LYX_BUILD_TYPE STREQUAL "gprof")
 177   set(DefaultLyxDebug ON)
 178   set(DefaultLyxRelease OFF)
 179   set(DefaultLyxStdlibDebug OFF)
 180   set(DefaultLyxEnableAssertions OFF)
 181   set(DefaultLyxProfile ON)
 182 else()
 183   message(FATAL_ERROR "Invalid build type (${LYX_BUILD_TYPE}) encountered")
 184 endif()
 185
 186 # Options for all compilers/systems
 187 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 188 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 189 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 190 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 191 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 192 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 193 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 194 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 195 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" ${DefaultLyxRelease} ALL)
 196 LYX_OPTION(DEBUG            "Enforce debug build"  ${DefaultLyxDebug} ALL)
 197 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 198 LYX_OPTION(ENABLE_ASSERTIONS "Run sanity checks in the program"  ${DefaultLyxEnableAssertions} ALL)
 199 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 200 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 201 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 202 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 203 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 204 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 205 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 206 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 207 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 208 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 209 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 210 if (NOT CMAKE_VERSION VERSION_LESS "3.17")
 211   LYX_OPTION(ENABLE_VALGRIND_TESTS  "Enable for tests involving valgrind" OFF ALL)
 212 else()
 213   if (LYX_ENABLE_VALGRIND_TESTS)
 214     unset(LYX_ENABLE_VALGRIND_TESTS CACHE)
 215   endif()
 216 endif()
 217 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 218 #LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 219 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 220 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 221 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 222 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 223 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 224 LYX_OPTION(EXTERNAL_DTL     "OFF := Build 3rdparty commands dt2dv and dv2dt" ON ALL)
 225 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 226 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 227 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 228
 229 # GCC specific
 230 LYX_OPTION(PROFILE              "Build with options for gprof" ${DefaultLyxProfile} GCC)
 231 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 232 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 233 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 234 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 235 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" ${DefaultLyxStdlibDebug} GCC)
 236
 237 # MSVC specific
 238 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 239 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 240 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 241 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 242
 243 # APPLE specific
 244 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 245 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 246
 247
 248 if(help OR HELP)
 249         message(STATUS)
 250         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 251         message(STATUS)
 252         LYX_OPTION_LIST_ALL(help)
 253         message(STATUS)
 254         RETURN()
 255 endif()
 256
 257 if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 258   set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 259 else()
 260   set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 261 endif()
 262
 263 # Check option dependencies
 264 if (LYX_ENABLE_VALGRIND_TESTS)
 265         find_program(VALGRIND_EXECUTABLE "valgrind")
 266         if (NOT VALGRIND_EXECUTABLE)
 267                 message(FATAL_ERROR "Cannot use valgrind tests, executable valgrind is missing. Please disable LYX_ENABLE_VALGRIND_TESTS")
 268         endif()
 269 endif()
 270 if (LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC OR LYX_STDLIB_DEBUG)
 271   if (LYX_EXTERNAL_BOOST)
 272     message(FATAL_ERROR "Using external boost not compatible with debug mode for stdlib")
 273   endif()
 274 endif()
 275
 276 if(LYX_DMG)
 277         set(LYX_BUNDLE ON)
 278         set(LYX_CPACK ON)
 279 endif()
 280
 281 if(LYX_CPACK)
 282         set(LYX_INSTALL ON)
 283 endif()
 284
 285 if(LYX_INSTALL)
 286         set(LYX_NLS ON)
 287         if(WIN32 AND NOT MINGW)
 288                 set(LYX_HUNSPELL ON)
 289         endif()
 290         set(LYX_PACKAGE_SUFFIX ON)
 291         if(NOT LYX_DEBUG)
 292                 set(LYX_RELEASE ON)
 293         endif()
 294         set(LYX_PROFILE OFF)
 295 endif()
 296
 297
 298 if(LYX_MERGE_FILES)
 299         set(LYX_PCH OFF)
 300 else()
 301         set(LYX_MERGE_REBUILD OFF)
 302 endif()
 303
 304 if(LYX_DEPENDENCIES_DOWNLOAD)
 305         message(STATUS)
 306         if(MSVC14)
 307                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 308                 set(deps_files lyx-windows-deps-msvc2015.zip)
 309                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 310                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 311         elseif(MSVC10)
 312                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 313                 set(deps_files lyx-windows-deps-msvc2010.zip)
 314                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 315                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 316         else()
 317                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 318         endif()
 319     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 320         foreach(it ${deps_files})
 321                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 322                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 323                 if(NOT already_downloaded)
 324                         message(STATUS "Downloading ${it} ...")
 325                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 326                         list(GET status 0 status_code)
 327                         list(GET status 1 status_string)
 328                         if(NOT status_code EQUAL 0)
 329                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 330                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 331                         endif()
 332                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 333                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 334                 endif()
 335         endforeach()
 336 endif()
 337
 338 message(STATUS)
 339
 340 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 341 if(WIN32)
 342         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 343 else()
 344         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 345 endif()
 346
 347 set(LYX_IPO_SUPPORTED OFF)
 348 if (POLICY CMP0069)
 349   cmake_policy(SET CMP0069 NEW)
 350   if(LYX_USE_IPO MATCHES "AUTO")
 351     # Enable LTO if supported and not debugging
 352     if (NOT LYX_DEBUG)
 353       include(CheckIPOSupported)
 354       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 355     endif()
 356   else()
 357     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 358   endif()
 359 endif()
 360 if (LYX_IPO_SUPPORTED)
 361   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 362 else()
 363   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 364 endif()
 365
 366 # Set to some meaningful default
 367 find_package(CXX11Compiler)
 368 if(NOT CXX11COMPILER_FOUND)
 369         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 370 endif()
 371 unset(LYX_GCC11_MODE)
 372 if(UNIX OR MINGW)
 373         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 374           # ignore the GCC_VERSION for clang
 375           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 376           message(STATUS "Using clang")
 377           if(CXX11_STD_REGEX)
 378             set(LYX_USE_STD_REGEX 1)
 379           else()
 380             set(LYX_USE_STD_REGEX 0)
 381           endif()
 382         else()
 383           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 384           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 385           if (_err)
 386             # previous check failed, try again with _old_ parameter
 387             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 388             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 389           endif()
 390           message(STATUS "Using GCC version ${GCC_VERSION}")
 391           if(GCC_VERSION VERSION_LESS 4.6)
 392                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 393           elseif(GCC_VERSION VERSION_LESS 4.9)
 394                 # <regex> in gcc is unusable in versions less than 4.9.0
 395                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 396                 set(LYX_USE_STD_REGEX 0)
 397           else()
 398                 set(LYX_USE_STD_REGEX 1)
 399           endif()
 400         endif()
 401         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 402 else()
 403         if(MSVC_VERSION LESS 1900)
 404                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 405                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 406                 set(LYX_USE_STD_REGEX 0)
 407         else()
 408                 set(LYX_USE_STD_REGEX 1)
 409         endif()
 410 endif()
 411
 412 if(LYX_3RDPARTY_BUILD)
 413   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 414   # this enables the build of all 3rd_party libs
 415   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 416   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 417   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 418   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 419 endif()
 420
 421 FIND_PROGRAM(LYX_GITVERSION git)
 422 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 423 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 424 set(LYX_PACKAGE_RELEASE "UNDEFINED")
 425 if(LYX_GITVERSION)
 426   if (LYX_LOCALVERSIONING)
 427     # Find the revision number for later use
 428     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 429       WORKING_DIRECTORY "${TOP_SRC_DIR}"
 430       RESULT_VARIABLE tmp_GIT_RESULT
 431       OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE
 432       ERROR_VARIABLE tmp_GIT_ERROR
 433       OUTPUT_STRIP_TRAILING_WHITESPACE)
 434     if (tmp_GIT_RESULT EQUAL 0)
 435       if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 436         set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 437         # We will add offset of 40000 to get appropriate value to
 438         # previous svn.
 439         # We use this value than also to set the package-patch-value
 440         MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 441         set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 442         set(ENABLE_DIST ON)
 443       endif()
 444     endif()
 445   endif()
 446 endif()
 447 if (LYX_PACKAGE_RELEASE MATCHES "UNDEFINED")
 448   set(LYX_PACKAGE_RELEASE  "1")
 449   if (LYX_RELEASE_PATCH GREATER 0)
 450     set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}.${LYX_RELEASE_PATCH}")
 451   endif()
 452 endif()
 453
 454 # Set the programs (lyx, tex2lyx, etc.) suffix
 455 # When building an OS X bundle, we will append
 456 # the suffix only to the bundle, not to the programs
 457 set(PROGRAM_SUFFIX "")
 458 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 459         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 460 endif()
 461 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 462 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 463 set(_convert lyxconvert${PROGRAM_SUFFIX})
 464
 465 add_custom_target(lyx_version ALL
 466   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 467   )
 468 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 469
 470 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 471 set(LYX_UTILITIES_INSTALL_PATH bin)
 472
 473 if(LYX_BUNDLE)
 474         set(LYX_CPACK ON)
 475
 476         message(STATUS)
 477         message(STATUS "Bundle creation is enabled (experimental):")
 478         message(STATUS "    make")
 479         message(STATUS "    make install/strip")
 480         message(STATUS "    make package")
 481         if(APPLE)
 482                 set(MACOSX_BUNDLE TRUE)
 483                 # This sets the bundle + executable names
 484                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 485                 # This sets the Info.plist executable name
 486                 set(osx_bundle_program_name ${_lyx})
 487                 # Bundle name
 488                 set(LYX_BUNDLE_NAME ${_lyx})
 489
 490                 # This will contain the list of files that need to be included
 491                 # in the bundle and their location within the bundle
 492                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 493                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 494
 495                 # Process Info.plist and lyxrc.dist
 496                 # See development/cmake/Install.cmake
 497                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 498
 499                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 500                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 501
 502                 # Variables used by CPack
 503                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 504                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 505                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 506
 507                 # Set the install paths
 508                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 509                 if(NOT LYX_INSTALL_PREFIX)
 510                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 511                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 512                 endif()
 513                 # Change the owner so that the install can work
 514                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 515         elseif(UNIX)
 516                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 517                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 518                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 519         elseif(WIN32)
 520                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 521         endif()
 522 endif()
 523
 524 if(LYX_INSTALL_PREFIX)
 525         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 526         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 527 endif()
 528 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 529
 530 if(UNIX)
 531   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 532 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 533   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 534 else()
 535   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 536 endif()
 537
 538 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 539   # Not a GCC compiler, programs do not have a suffix
 540   set(suffixing ${LYX_PACKAGE_SUFFIX})
 541 elseif(WIN32 AND MINGW)
 542   # We want to use a suffix for the package in this case,
 543   # even if not for the program
 544   set(suffixing ${LYX_PACKAGE_SUFFIX})
 545 else()
 546   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 547   set(suffixing ${LYX_PROGRAM_SUFFIX})
 548 endif()
 549
 550 # The define PACKAGE below allows lyx-executable to find its default configuration files
 551 # see routines
 552 #    Package::messages_file()
 553 #    get_default_user_support_dir()
 554 #    relative_system_support_dir()
 555 # in src/support/Package.cpp
 556 if(suffixing)
 557         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 558 else()
 559         set(PACKAGE ${PACKAGE_BASE})
 560 endif()
 561
 562 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 563         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 564         if (UNIX)
 565                 # use the default "/usr/local"
 566                 # but respect the user-choice on the command-line
 567                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 568         endif()
 569 endif()
 570 if(WIN32)
 571         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 572 endif()
 573 if(IS_ABSOLUTE)
 574         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 575 else()
 576         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 577 endif()
 578
 579
 580
 581 if(NOT LYX_DATA_SUBDIR)
 582         if (WIN32)
 583                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 584         else()
 585                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 586         endif()
 587 endif()
 588
 589 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}/${LYX_DATA_SUBDIR}")
 590 get_locale_destination(LYX_LOCALEDIR)
 591 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 592 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 593
 594 if(LYX_BUNDLE AND APPLE)
 595         set(LYX_MAN_DIR_tmp "${LYX_DATA_SUBDIR}")
 596 else()
 597         if(WIN32)
 598                 set(LYX_MAN_DIR_tmp "${CMAKE_BINARY_DIR}/usr/local/man/")
 599         elseif(UNIX)
 600                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/share/man/")
 601         else()
 602                 set(LYX_MAN_DIR_tmp "${CMAKE_INSTALL_PREFIX}/man/")
 603         endif()
 604 endif()
 605 if (NOT LYX_MAN_DIR_tmp EQUAL "${LYX_MAN_DIR}")
 606         unset(LYX_MAN_DIR CACHE)
 607         set(LYX_MAN_DIR "${LYX_MAN_DIR_tmp}" CACHE STRING "Install location for man pages.")
 608 endif()
 609 unset(LYX_MAN_DIR_tmp)
 610 mark_as_advanced(LYX_MAN_DIR)
 611
 612 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 613 # see the Readme.txt of the installer
 614 #if(LYX_INSTALL AND WIN32)
 615 #       message(STATUS "Configuring NSIS files")
 616 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 617 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 618 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 619 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 620 #endif()
 621
 622 if(NOT GROUP_CODE)
 623         #set(GROUP_CODE "The Golden Code")
 624         set(GROUP_CODE flat)
 625 endif()
 626
 627 # lyx's source files
 628 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 629 set(LYX_HPP_FILES [a-zA-Z]*.h)
 630 set(LYX_MOC_FILES moc_*.cpp)
 631
 632 include(ProjectSourceGroup)
 633
 634
 635 if(LYX_PROFILE AND NOT MSVC)
 636         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 637         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 638         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 639 else()
 640         set(LYX_PROFILE OFF)
 641 endif()
 642
 643
 644 if(LYX_NO_OPTIMIZE)
 645         set(CMAKE_BUILD_TYPE None)
 646         set(LYX_DEBUG OFF)
 647         set(LYX_RELEASE OFF)
 648         set(LYX_PROFILE OFF)
 649 elseif(LYX_RELEASE)
 650         set(CMAKE_BUILD_TYPE Release)
 651         set(LYX_DEBUG OFF)
 652         set(LYX_PROFILE OFF)
 653 elseif(LYX_PROFILE)
 654         set(CMAKE_BUILD_TYPE Profile)
 655         set(LYX_DEBUG OFF)
 656 else()
 657         set(CMAKE_BUILD_TYPE Debug)
 658         set(LYX_DEBUG ON)
 659 endif()
 660
 661
 662 # When shared libs are supported enable this option
 663 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 664 if(LYX_SHARED_LIBRARIES)
 665         set(library_type SHARED)
 666 else()
 667         set(library_type STATIC)
 668 endif()
 669
 670 if(LYX_ENABLE_ASSERTIONS)
 671   set(LYX_CXX_FLAGS " -DENABLE_ASSERTIONS=1")
 672 else()
 673   set(LYX_CXX_FLAGS "")
 674 endif()
 675
 676 if(MSVC)
 677   if (CXX11_FLAG MATCHES "\\+\\+([0-9]+)")
 678     set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 679     message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 680   endif()
 681   set(CMAKE_CXX_FLAGS       "${CMAKE_CXX_FLAGS}${LYX_CXX_FLAGS}")
 682 else()
 683         if(NOT LYX_QUIET)
 684                 set(CMAKE_VERBOSE_MAKEFILE ON)
 685         endif()
 686         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}${LYX_CXX_FLAGS}")
 687         if(LYX_GCC11_MODE MATCHES "\\+\\+(14|11|98)")
 688           # Thanks to Brad King <brad.king@kitware.com>
 689           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 690           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 691           # and still use our own c++ extension tests
 692           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 693           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 694         endif()
 695         if(LYX_STDLIB_DEBUG)
 696           set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 697         else()
 698           if(LYX_DEBUG_GLIBC)
 699             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG")
 700           endif()
 701           if(LYX_DEBUG_GLIBC_PEDANTIC)
 702             set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG_PEDANTIC")
 703           endif()
 704         endif()
 705         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 706         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 707         if(MINGW)
 708                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 709         else()
 710                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 711         endif()
 712 endif()
 713
 714 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 715 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 716 if(LYX_CXX_FLAGS_EXTRA)
 717         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 718                 add_definitions(${_flag})
 719         endforeach()
 720 endif()
 721
 722 if(LYX_XMINGW)
 723         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 724 endif()
 725
 726 set(min_qt5_version "5.6")
 727 if(LYX_USE_QT MATCHES "AUTO")
 728         # try qt5 first
 729         find_package(Qt5Core CONFIG QUIET)
 730         if(Qt5Core_FOUND)
 731                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 732                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 733                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 734                         find_package(Qt4 "4.5.0" QUIET)
 735                         if(QT4_FOUND)
 736                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 737                         endif()
 738                 endif()
 739         else()
 740                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 741         endif()
 742 endif()
 743 if(LYX_USE_QT MATCHES "QT5")
 744         # set QPA_XCB if QT uses X11
 745         find_package(Qt5Core CONFIG REQUIRED)
 746         if (Qt5Core_FOUND)
 747                 find_package(Qt5Widgets CONFIG REQUIRED)
 748                 if(APPLE)
 749                         find_package(Qt5MacExtras CONFIG REQUIRED)
 750                 endif()
 751                 find_package(Qt5X11Extras CONFIG QUIET)
 752                 find_package(Qt5WinExtras CONFIG QUIET)
 753                 set(QTVERSION ${Qt5Core_VERSION})
 754                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 755                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 756                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 757                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 758                         # see thread in lyx-devel list
 759                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 760                         # Date 11.03.2017
 761                         # Subject: cmake compilation error
 762                         #message(FATAL_ERROR "Wrong Qt-Version")
 763                 endif()
 764                 macro (qt_use_modules lyxtarget)
 765                         foreach (_tg ${ARGN})
 766                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 767                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 768                         endforeach()
 769                 endmacro()
 770                 macro (qt_add_resources)
 771                         qt5_add_resources(${ARGN})
 772                 endmacro()
 773                 macro (qt_wrap_uifiles)
 774                         qt5_wrap_ui(${ARGN})
 775                 endmacro()
 776                 message(STATUS "Found Qt-Version ${QTVERSION}")
 777                 if(WIN32)
 778                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 779                 endif()
 780         endif()
 781 elseif(LYX_USE_QT MATCHES "QT4")
 782         if(LYX_XMINGW)
 783                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 784                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 785         endif()
 786         find_package(Qt4 "4.5.0" REQUIRED)
 787         macro (qt_use_modules)
 788         endmacro()
 789         macro (qt_add_resources)
 790                 qt4_add_resources(${ARGN})
 791         endmacro()
 792         macro (qt_wrap_uifiles)
 793                 qt4_wrap_ui(${ARGN})
 794         endmacro()
 795         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 796         if(WIN32)
 797                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 798         endif()
 799 else()
 800   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 801 endif()
 802
 803 find_package(Magic)
 804 if(Magic_FOUND)
 805   set(HAVE_MAGIC_H 1)
 806   include_directories(${Magic_INCLUDE_DIR})
 807 endif()
 808
 809 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 810
 811 set(Spelling_FOUND OFF)
 812 set(Include_used_spellchecker)   # String will be inserted into config.h
 813
 814 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 815   # try system library first
 816   find_package(MyThesLIB)
 817   if (MYTHESLIB_FOUND)
 818     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 819   else()
 820     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 821   endif()
 822 endif()
 823 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 824   find_package(MyThesLIB REQUIRED)
 825 else()
 826   add_subdirectory(3rdparty/mythes)
 827 endif()
 828 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 829
 830 if(NOT LYX_EXTERNAL_HUNSPELL)
 831     add_subdirectory(3rdparty/hunspell)
 832     add_definitions(-DHUNSPELL_STATIC)
 833     set(HUNSPELL_FOUND ON)
 834     message(STATUS "  * Hunspell:")
 835     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 836     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 837 endif()
 838
 839 foreach(_spell "ASPELL" "ENCHANT" "HUNSPELL")
 840   string(TOUPPER ${_spell} _upspell)
 841   if (NOT ${_upspell}_FOUND)
 842     find_package(${_spell})
 843   endif()
 844   if (${_upspell}_FOUND)
 845     include_directories(${${_upspell}_INCLUDE_DIR})
 846     set(Spelling_FOUND ON)
 847     message(STATUS "Building with USE_${_upspell}")
 848     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 849   else()
 850     if(LYX_${_upspell})
 851       message(FATAL_ERROR "Required ${_spell} devel package not found")
 852     else()
 853       message(STATUS "${_upspell} not found, building without ${_spell} support")
 854     endif()
 855   endif()
 856 endforeach()
 857
 858 if(GNUWIN32_DIR)
 859         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 860 endif()
 861
 862 # Search for python default version first
 863 unset(PYTHON_EXECUTABLE CACHE)
 864 unset(LYX_PYTHON_EXECUTABLE CACHE)
 865 unset(PYTHON_VERSION_MAJOR)
 866 unset(PYTHON_VERSION_MINOR)
 867 unset(PYTHON_VERSION_STRING)
 868 if (CMAKE_VERSION VERSION_LESS "3.13")
 869   find_package(PythonInterp 3.5 QUIET)
 870   if(NOT PYTHONINTERP_FOUND)
 871     find_package(PythonInterp 2.0 REQUIRED)
 872     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 873       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 874     endif()
 875   endif()
 876   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 877 else()
 878   find_package(Python3 3.5 QUIET)
 879   if(NOT Python3_Interpreter_FOUND)
 880     unset(PYTHON_EXECUTABLE CACHE)
 881     find_package(Python2 2.0 REQUIRED)
 882     if(NOT Python2_VERSION VERSION_LESS 2.8)
 883       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 884     endif()
 885     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 886   else()
 887     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 888   endif()
 889 endif()
 890
 891 if(LYX_NLS)
 892         find_package(LyXGettext)
 893         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 894                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 895         else()
 896                 # Install only supplied .gmo-files
 897                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 898                 message(STATUS "Installing provided .gmo-files only")
 899                 foreach( _gmo ${_gmofiles})
 900                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 901                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 902                 endforeach()
 903         endif()
 904 endif()
 905
 906 if(LYX_EXTERNAL_ICONV)
 907   find_package(ICONV REQUIRED)
 908 else()
 909   add_subdirectory(3rdparty/libiconv)
 910   set(HAVE_ICONV_CONST 1)
 911 endif()
 912
 913 if(LYX_EXTERNAL_Z)
 914   find_package(ZLIB REQUIRED)
 915 else()
 916   add_subdirectory(3rdparty/zlib)
 917 endif()
 918
 919 if(NOT LYX_EXTERNAL_DTL)
 920   add_subdirectory(3rdparty/dtl)
 921 endif()
 922
 923 if(LYX_USE_STD_REGEX)
 924   # Set only include path.
 925   # Use internal boost, which is known to exist
 926   # we don't need any libraries
 927   set(Lyx_Boost_Libraries)
 928   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 929   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 930 else()
 931   # Using boost-regex
 932   if(LYX_EXTERNAL_BOOST)
 933     message(STATUS "Searching for external boost")
 934     find_package(Boost COMPONENTS regex)
 935     if(Boost_FOUND)
 936       message(STATUS "Boost found")
 937       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 938       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 939       if (LYX_STDLIB_DEBUG OR LYX_DEBUG_GLIBC OR LYX_DEBUG_GLIBC_PEDANTIC)
 940         # Comment from  Jean-Marc Lasgouttes:
 941         # In general, system boost libraries are incompatible with
 942         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 943         # details.
 944         message(FATAL_ERROR "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF -DLYX_DEBUG_GLIBC=OFF -DLYX_DEBUG_GLIBC_PEDANTIC=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 945       endif()
 946     else()
 947       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 948     endif()
 949   else()
 950     # Using included boost
 951     set(Lyx_Boost_Libraries boost_regex)
 952     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 953     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 954     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 955   endif()
 956 endif()
 957
 958 if(WIN32)
 959         if(LYX_CONSOLE)
 960                 set(LYX_QTMAIN_LIBRARY)
 961         else()
 962                 set(WIN32_CONSOLE WIN32)
 963         endif()
 964         if(MSVC)
 965                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 966                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 967                 # disable checked iterators for msvc release builds to get maximum speed
 968                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 969         else()
 970                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 971                 # does not use it and always declares the vista compatible API.
 972                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 973                 add_definitions(-DWINVER=0x0500)
 974         endif()
 975 endif()
 976
 977 # Compute qt-version from ${QTVERSION}
 978
 979 message(STATUS "")
 980 foreach(_v PACKAGE PACKAGE_VERSION
 981         PROGRAM_SUFFIX LYX_VERSION LYX_DIR_VER LYX_USERDIR_VER
 982         LYX_ABS_TOP_SRCDIR
 983         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 984         if(NOT DEFINED ${_v})
 985                 message(FATAL_ERROR "${_v} not defined")
 986         endif()
 987         string(SUBSTRING "${_v}                            " 0 28 _v1)
 988         message(STATUS "----- ${_v1}: ${${_v}}")
 989 endforeach(_v)
 990 message(STATUS "")
 991
 992
 993 if(LYX_PCH)
 994         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 995         # Not sure if it works for all non-msvc compilers
 996         include(PCHSupport_26)
 997         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 998         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 999         add_definitions(-DLYX_ENABLE_PCH)
1000
1001         if(MSVC)
1002                 macro(lyx_add_msvc_pch name_)
1003                         set_source_files_properties(${${name_}_sources} PROPERTIES
1004                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
1005                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
1006                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
1007                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
1008                                 ${TOP_BINARY_DIR}/pcheaders.h)
1009                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1010                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
1011                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
1012                 endmacro(lyx_add_msvc_pch)
1013                 macro(lyx_add_gcc_pch name_)
1014                 endmacro()
1015         else()
1016                 macro(lyx_add_msvc_pch name_)
1017                 endmacro()
1018                 macro(lyx_add_gcc_pch name_)
1019                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
1020                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
1021                 endmacro()
1022         endif()
1023 else()
1024         macro(lyx_add_msvc_pch)
1025         endmacro(lyx_add_msvc_pch)
1026         macro(lyx_add_gcc_pch name_)
1027         endmacro()
1028 endif()
1029
1030
1031 if(MSVC)
1032
1033         if(LYX_VLD)
1034                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
1035                 add_subdirectory(${vld_path}/cmake)
1036                 include(${vld_path}/cmake/vld.cmake) # forced include
1037                 set(vld_dll vld)
1038         endif()
1039
1040         if(LYX_WALL)
1041                 # Use the highest warning level
1042                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
1043
1044                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
1045                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
1046                 else()
1047                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
1048                 endif()
1049
1050                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
1051                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
1052                 else()
1053                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
1054                 endif()
1055
1056                 # add here warnings which should produce an error /weXXXX
1057                 set(MSVC_W_ERROR   "/we4101 /we4189")
1058                 # add here warnings which should be disabled /wdXXXX
1059                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
1060
1061                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1062                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1063                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1064
1065         else()
1066                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1067
1068                 # add here warnings which should produce an error /weXXXX
1069                 set(MSVC_W_ERROR   "/we4101 /we4189")
1070                 # add here warnings which should be disabled /wdXXXX
1071                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1072
1073                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1074                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1075                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1076
1077         endif()
1078
1079         if (NOT Qt5Core_FOUND)
1080                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1081                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1082                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1083         endif()
1084
1085         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1086         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1087         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1088         message(STATUS "")
1089 endif()
1090
1091
1092 # Xcode compiler
1093 if (CMAKE_GENERATOR MATCHES Xcode)
1094         if (XCODE_VERSION VERSION_LESS "5.0")
1095                 # Automatically select the Xcode compiler if not set
1096                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1097                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1098                         if (XCODE_VERSION VERSION_GREATER "3.1")
1099                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1100                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1101                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1102                 # Print the selected compiler version
1103         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1104         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1105 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1106
1107 if (WIN32 AND Qt5Core_FOUND)
1108         set(Z_PREFIX 1)
1109 endif()
1110
1111 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1112 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1113 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1114
1115 unset(opts)
1116 foreach(_option ${LYX_OPTIONS})
1117   if(${_option}_show_message)
1118     string(SUBSTRING "${_option}                            " 0 31 _var)
1119     get_property(_prop CACHE ${_option} PROPERTY STRINGS)
1120     list(FIND LYX_OPTION_STRINGS ${_option} _index)
1121     if (${_index} GREATER -1)
1122       set(_isset ${${_option}})
1123     elseif(${_option})
1124       set(_isset ON)
1125     else()
1126       set(_isset OFF)
1127     endif()
1128     string(SUBSTRING "${_isset}           " 0 10 _val)
1129     set(opts "${opts} ${_option}(${${_option}})")
1130   endif()
1131 endforeach()
1132 set(tmp_vi "CMake Build")
1133 list(APPEND tmp_vi "  Host name:               ${CMAKE_HOST_SYSTEM_NAME}")
1134 list(APPEND tmp_vi "  Host processor:          ${CMAKE_HOST_SYSTEM_PROCESSOR}")
1135 list(APPEND tmp_vi "  Build flags:             ${opts}")
1136 list(APPEND tmp_vi "  C++ Compiler:            ${CMAKE_CXX_COMPILER_ID} (${CMAKE_CXX_COMPILER_VERSION})")
1137 list(APPEND tmp_vi "  C++ Compiler flags:      ${CMAKE_CXX_FLAGS}")
1138 if (LYX_DEBUG)
1139 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_DEBUG}")
1140 else()
1141 list(APPEND tmp_vi "  C++ Compiler user flags: ${CMAKE_CXX_FLAGS_RELEASE}")
1142 endif()
1143 list(APPEND tmp_vi "  Qt version:              ${QTVERSION}")
1144 list(APPEND tmp_vi "  LyX binary dir:          ${CMAKE_INSTALL_PREFIX}/${LYX_UTILITIES_INSTALL_PATH}")
1145 get_data_destination(dest_data)
1146 list(APPEND tmp_vi "  LyX files dir:           ${CMAKE_INSTALL_PREFIX}/${dest_data}")
1147 string(REPLACE ";" "\\n" VERSION_INFO "${tmp_vi}")
1148
1149 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1150 unset(opts)
1151 unset(tmp_vi)
1152
1153 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1154         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1155 endif()
1156
1157 if (NOT HAVE_REGEX)
1158         set(LYX_USE_STD_REGEX 0)
1159 endif()
1160
1161
1162 set (cmd ${CMAKE_CTEST_COMMAND})
1163 if (MSVC)
1164         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1165 else ()
1166         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1167 endif ()
1168 add_custom_target (lyx_run_tests COMMAND ${cmd})
1169 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1170
1171 if(LYX_ASAN)
1172     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1173     message(STATUS)
1174     message(STATUS "Address sanitizer enabled. Usage:")
1175     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1176     message(STATUS "    chmod  +x ./asan_symbolize.py")
1177     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1178     message(STATUS)
1179 endif()
1180
1181 if(LYX_INSTALL)
1182         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1183                 message(STATUS "Python required to create doc!")
1184         else()
1185                 if(UNIX)
1186                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1187                 endif()
1188                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1189         endif()
1190 endif()
1191 include(../Install)
1192
1193 # By running the URL tests first, time can be saved when running the ctests in
1194 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1195 if(LYX_ENABLE_URLTESTS)
1196         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1197 endif()
1198 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1199 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1200 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1201 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1202 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1203 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1204 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1205
1206 message(STATUS)
1207 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1208 message(STATUS)
1209
1210 LYX_OPTION_LIST_ALL(used)
1211
1212
1213 if(LYX_NLS)
1214         message(STATUS)
1215         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1216         message(STATUS)
1217         message(STATUS "  * iconv")
1218         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1219         message(STATUS "     - library: ${ICONV_LIBRARY}")
1220         message(STATUS "  * zlib")
1221         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1222         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1223         message(STATUS)
1224 endif()
1225
1226 # Apple has builtin native spell checker,
1227 # no need to warn for missing Aspell, Hunspell or Enchant
1228 if(NOT Spelling_FOUND AND NOT APPLE)
1229   if(LYX_REQUIRE_SPELLCHECK)
1230     set(_mode "FATAL_ERROR")
1231   else()
1232     set(_mode "STATUS")
1233   endif()
1234   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1235 endif()
1236
1237 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1238
1239 if(ENABLE_DIST)
1240   # Use git to create the source package
1241   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1242   if(UNIX)
1243     set(DIST_FORMAT tgz)
1244   else()
1245     set(DIST_FORMAT zip)
1246   endif()
1247   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1248
1249   add_custom_command(
1250     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1251     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1252     WORKING_DIRECTORY ${TOP_SRC_DIR})
1253   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1254 endif()
1255
1256 # Last directory to be included so that the fixup code (OS X)
1257 # can be run last
1258 add_subdirectory(development/cmake/post_install)
1259
1260 message(STATUS)