CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 3.1.0)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51         if(POLICY CMP0075)
  52                 cmake_policy(SET CMP0075 OLD)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 129 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 130 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 131 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 132 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 133 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 134 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 135 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 136 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 137 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 138 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 139 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 140 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 141 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 144 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 145 LYX_COMBO(USE_IPO           "Interprocedural optimization" OFF AUTO ON)
 146 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 147 LYX_OPTION(DISABLE_CALLSTACK_PRINTING "do not print a callstack when crashing" OFF ALL)
 148 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 149 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 150 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 151 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 152
 153 # GCC specific
 154 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 155 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 156 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 157 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 158 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 159 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 160
 161 # MSVC specific
 162 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 163 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 164 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 165 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 166
 167 # APPLE specific
 168 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 169 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 170
 171
 172 if(help OR HELP)
 173         message(STATUS)
 174         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 175         message(STATUS)
 176         LYX_OPTION_LIST_ALL(help)
 177         message(STATUS)
 178         RETURN()
 179 endif()
 180
 181 # Check option dependencies
 182
 183 if(LYX_DMG)
 184         set(LYX_BUNDLE ON)
 185         set(LYX_CPACK ON)
 186 endif()
 187
 188 if(LYX_CPACK)
 189         set(LYX_INSTALL ON)
 190 endif()
 191
 192 if(LYX_INSTALL)
 193         set(LYX_NLS ON)
 194         if(WIN32 AND NOT MINGW)
 195                 set(LYX_HUNSPELL ON)
 196         endif()
 197         set(LYX_PACKAGE_SUFFIX ON)
 198         if(NOT LYX_DEBUG)
 199                 set(LYX_RELEASE ON)
 200         endif()
 201         set(LYX_PROFILE OFF)
 202 endif()
 203
 204
 205 if(LYX_MERGE_FILES)
 206         set(LYX_PCH OFF)
 207 else()
 208         set(LYX_MERGE_REBUILD OFF)
 209 endif()
 210
 211 if(LYX_DEPENDENCIES_DOWNLOAD)
 212         message(STATUS)
 213         if(MSVC14)
 214                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 215                 set(deps_files lyx-windows-deps-msvc2015.zip)
 216                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 217                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 218         elseif(MSVC10)
 219                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 220                 set(deps_files lyx-windows-deps-msvc2010.zip)
 221                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 222                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 223         else()
 224                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 225         endif()
 226     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 227         foreach(it ${deps_files})
 228                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 229                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 230                 if(NOT already_downloaded)
 231                         message(STATUS "Downloading ${it} ...")
 232                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 233                         list(GET status 0 status_code)
 234                         list(GET status 1 status_string)
 235                         if(NOT status_code EQUAL 0)
 236                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 237                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 238                         endif()
 239                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 240                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 241                 endif()
 242         endforeach()
 243 endif()
 244
 245 message(STATUS)
 246
 247 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 248 if(WIN32)
 249         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 250 else()
 251         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 252 endif()
 253
 254 set(LYX_IPO_SUPPORTED OFF)
 255 if (POLICY CMP0069)
 256   cmake_policy(SET CMP0069 NEW)
 257   if(LYX_USE_IPO MATCHES "AUTO")
 258     # Enable LTO if supported and not debugging
 259     if (NOT LYX_DEBUG)
 260       include(CheckIPOSupported)
 261       check_ipo_supported(RESULT LYX_IPO_SUPPORTED)
 262     endif()
 263   else()
 264     set(LYX_IPO_SUPPORTED ${LYX_USE_IPO})
 265   endif()
 266 endif()
 267 if (LYX_IPO_SUPPORTED)
 268   set(LYX_USE_IPO "ON" CACHE STRING "Use interprocedural optimization" FORCE)
 269 else()
 270   set(LYX_USE_IPO "OFF" CACHE STRING "Use interprocedural optimization" FORCE)
 271 endif()
 272
 273 # Set to some meaningful default
 274 find_package(CXX11Compiler)
 275 if(NOT CXX11COMPILER_FOUND)
 276         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 277 endif()
 278 set(LYX_GCC11_MODE)
 279 if(UNIX OR MINGW)
 280         if (CMAKE_CXX_COMPILER_ID MATCHES "^([cC]lang|AppleClang)$")
 281           # ignore the GCC_VERSION for clang
 282           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 283           message(STATUS "Using clang")
 284           if(CXX11_STD_REGEX)
 285             set(LYX_USE_STD_REGEX 1)
 286           else()
 287             set(LYX_USE_STD_REGEX 0)
 288           endif()
 289         else()
 290           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpfullversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 291           #message(STATUS "dumpfullversion: error = ${_error}, result = ${_err}")
 292           if (_err)
 293             # previous check failed, try again with _old_ parameter
 294             execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION ERROR_VARIABLE _error RESULT_VARIABLE _err OUTPUT_STRIP_TRAILING_WHITESPACE)
 295             #message(STATUS "dumpversion: error = ${_error}, result = ${_err}")
 296           endif()
 297           message(STATUS "Using GCC version ${GCC_VERSION}")
 298           if(GCC_VERSION VERSION_LESS 4.6)
 299                 message(FATAL_ERROR "gcc >= 4.6 is required.")
 300           elseif(GCC_VERSION VERSION_LESS 4.9)
 301                 # <regex> in gcc is unusable in versions less than 4.9.0
 302                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 303                 set(LYX_USE_STD_REGEX 0)
 304           else()
 305                 set(LYX_USE_STD_REGEX 1)
 306           endif()
 307         endif()
 308         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 309 else()
 310         if(MSVC_VERSION LESS 1900)
 311                 # Drop support for msvc versions prior to 1900 (Visual Studio 2015)
 312                 message(FATAL_ERROR "Visual Studio >= 2015 is required.")
 313                 set(LYX_USE_STD_REGEX 0)
 314         else()
 315                 set(LYX_USE_STD_REGEX 1)
 316         endif()
 317 endif()
 318
 319
 320 set(VERSION_INFO "CMake Build")
 321
 322 # Try to get some informations from configure.ac
 323
 324 include(LyXPaths)
 325 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 326
 327 if(WIN32)
 328         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 329         if(MSVC)
 330                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 331         endif()
 332         set(USE_WINDOWS_PACKAGING ON)
 333 elseif(APPLE)
 334         set(USE_MACOSX_PACKAGING ON)
 335 else()
 336         set(USE_POSIX_PACKAGING ON)
 337 endif()
 338
 339 if(LYX_3RDPARTY_BUILD)
 340   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 341   # this enables the build of all 3rd_party libs
 342   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 343   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 344   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 345   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 346 endif()
 347
 348 macro(setstripped _varname)
 349         if(${ARGC} GREATER 1)
 350                 string(STRIP "${ARGV1}" _v)
 351                 if (_v MATCHES "^\\[\(.+\)\\]$")
 352                   set(_v ${CMAKE_MATCH_1})
 353                 endif()
 354                 if(USE_POSIX_PACKAGING)
 355                         string(TOLOWER ${_v} ${_varname})
 356                 else()
 357                         set(${_varname} ${_v})
 358                 endif()
 359         else()
 360                 set(${_varname})
 361         endif()
 362 endmacro(setstripped)
 363
 364 foreach(_c_l ${_config_lines} )
 365         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 366                 # Not using CMAKE_MATCH_ directly is needed, because
 367                 # its value is now changed inside macro setstripped
 368                 set(_PB ${CMAKE_MATCH_1})
 369                 set(_PV ${CMAKE_MATCH_2})
 370                 set(_PBU ${CMAKE_MATCH_3})
 371                 setstripped(PACKAGE_BASE ${_PB})
 372                 setstripped(PACKAGE_VERSION ${_PV})
 373                 setstripped(PACKAGE_BUGREPORT ${_PBU})
 374                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\(\\.\([0-9]+\)\)?\)?.*$")
 375                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 376                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 377                         set(LYX_RELEASE_LEVEL ${CMAKE_MATCH_4})
 378                         set(LYX_RELEASE_PATCH ${CMAKE_MATCH_6})
 379                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 380                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 381                         if (NOT LYX_RELEASE_LEVEL)
 382                                 set(LYX_RELEASE_LEVEL 0)
 383                         endif()
 384                         if (NOT LYX_RELEASE_PATCH)
 385                                 set(LYX_RELEASE_PATCH 0)
 386                         endif()
 387                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 388                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 389                         else()
 390                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 391                         endif()
 392                 endif()
 393         endif()
 394         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 395                 set(LYX_DATE "${CMAKE_MATCH_1}")
 396         endif()
 397 endforeach(_c_l)
 398
 399 FIND_PROGRAM(LYX_GITVERSION git)
 400 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 401 set(LYX_REVISION_VERSION ${LYX_RELEASE_LEVEL})
 402 set(LYX_PACKAGE_RELEASE "1")
 403 if(LYX_GITVERSION)
 404   if (LYX_LOCALVERSIONING)
 405     # Find the revision number and for later use
 406     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 407       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 408     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 409       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 410       # We will add offset of 40000 to get appropriate value to
 411       # previous svn.
 412       # We use this value than also to set the package-patch-value
 413       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 414       set(LYX_REVISION_VERSION "${LYX_RELEASE_LEVEL}-${tmp_REVISION_VERSION}git")
 415       set(ENABLE_DIST ON)
 416     endif()
 417   endif()
 418 endif()
 419 message(STATUS "LYX_REVISION_VERSION = ${LYX_REVISION_VERSION}")
 420
 421 # Set the programs (lyx, tex2lyx, etc.) suffix
 422 # When building an OS X bundle, we will append
 423 # the suffix only to the bundle, not to the programs
 424 set(PROGRAM_SUFFIX "")
 425 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 426         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 427 endif()
 428 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 429 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 430 set(_convert lyxconvert${PROGRAM_SUFFIX})
 431
 432 add_custom_target(lyx_version ALL
 433   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 434   )
 435 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 436
 437 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 438 set(LYX_UTILITIES_INSTALL_PATH bin)
 439
 440 if(LYX_BUNDLE)
 441         set(LYX_CPACK ON)
 442
 443         message(STATUS)
 444         message(STATUS "Bundle creation is enabled (experimental):")
 445         message(STATUS "    make")
 446         message(STATUS "    make install/strip")
 447         message(STATUS "    make package")
 448         if(APPLE)
 449                 set(MACOSX_BUNDLE TRUE)
 450                 # This sets the bundle + executable names
 451                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 452                 # This sets the Info.plist executable name
 453                 set(osx_bundle_program_name ${_lyx})
 454                 # Bundle name
 455                 set(LYX_BUNDLE_NAME ${_lyx})
 456
 457                 # This will contain the list of files that need to be included
 458                 # in the bundle and their location within the bundle
 459                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 460                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 461
 462                 # Process Info.plist and lyxrc.dist
 463                 # See development/cmake/Install.cmake
 464                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 465
 466                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 467                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 468
 469                 # Variables used by CPack
 470                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 471                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 472                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 473
 474                 # Set the install paths
 475                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 476                 if(NOT LYX_INSTALL_PREFIX)
 477                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 478                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 479                 endif()
 480                 # Change the owner so that the install can work
 481                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 482         elseif(UNIX)
 483                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 484                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 485                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 486         elseif(WIN32)
 487                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 488         endif()
 489 endif()
 490
 491 if(LYX_INSTALL_PREFIX)
 492         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 493         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 494 endif()
 495 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 496
 497 if(UNIX)
 498   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 499 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 500   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 501 else()
 502   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 503 endif()
 504
 505 if(NOT CMAKE_COMPILER_IS_GNUCXX)
 506   # Not a GCC compiler, programs do not have a suffix
 507   set(suffixing ${LYX_PACKAGE_SUFFIX})
 508 elseif(WIN32 AND MINGW)
 509   # We want to use a suffix for the package in this case,
 510   # even if not for the program
 511   set(suffixing ${LYX_PACKAGE_SUFFIX})
 512 else()
 513   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 514   set(suffixing ${LYX_PROGRAM_SUFFIX})
 515 endif()
 516
 517 # The define PACKAGE below allows lyx-executable to find its default configuration files
 518 # see routines
 519 #    Package::messages_file()
 520 #    get_default_user_support_dir()
 521 #    relative_system_support_dir()
 522 # in src/support/Package.cpp
 523 if(suffixing)
 524         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 525 else()
 526         set(PACKAGE ${PACKAGE_BASE})
 527 endif()
 528
 529 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 530         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 531         if (UNIX)
 532                 # use the default "/usr/local"
 533                 # but respect the user-choice on the command-line
 534                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 535         endif()
 536 endif()
 537 if(WIN32)
 538         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 539 endif()
 540 if(IS_ABSOLUTE)
 541         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 542 else()
 543         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 544 endif()
 545
 546
 547
 548 if(NOT LYX_DATA_SUBDIR)
 549         if (WIN32)
 550                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 551         else()
 552                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 553         endif()
 554 endif()
 555
 556 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 557 get_locale_destination(LYX_LOCALEDIR)
 558 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 559 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 560
 561 if(LYX_BUNDLE AND APPLE)
 562         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 563 else()
 564         if(WIN32)
 565                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 566         elseif(UNIX)
 567                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 568         else()
 569                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 570         endif()
 571 endif()
 572 mark_as_advanced(LYX_MAN_DIR)
 573
 574 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 575 # see the Readme.txt of the installer
 576 #if(LYX_INSTALL AND WIN32)
 577 #       message(STATUS "Configuring NSIS files")
 578 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 579 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 580 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 581 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 582 #endif()
 583
 584 if(NOT GROUP_CODE)
 585         #set(GROUP_CODE "The Golden Code")
 586         set(GROUP_CODE flat)
 587 endif()
 588
 589 # lyx's source files
 590 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 591 set(LYX_HPP_FILES [a-zA-Z]*.h)
 592 set(LYX_MOC_FILES moc_*.cpp)
 593
 594 include(ProjectSourceGroup)
 595
 596
 597 if(LYX_PROFILE AND NOT MSVC)
 598         set(CMAKE_BUILD_TYPE Profile CACHE STRING "Profile build type" FORCE)
 599         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 600         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 601 else()
 602         set(LYX_PROFILE OFF)
 603 endif()
 604
 605
 606 if(LYX_NO_OPTIMIZE)
 607         set(CMAKE_BUILD_TYPE None)
 608         set(LYX_DEBUG OFF)
 609         set(LYX_RELEASE OFF)
 610         set(LYX_PROFILE OFF)
 611 elseif(LYX_RELEASE)
 612         set(CMAKE_BUILD_TYPE Release)
 613         set(LYX_DEBUG OFF)
 614         set(LYX_PROFILE OFF)
 615 elseif(LYX_PROFILE)
 616         set(CMAKE_BUILD_TYPE Profile)
 617         set(LYX_DEBUG OFF)
 618 else()
 619         set(CMAKE_BUILD_TYPE Debug)
 620         set(LYX_DEBUG ON)
 621 endif()
 622
 623
 624 # When shared libs are supported enable this option
 625 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 626 if(LYX_SHARED_LIBRARIES)
 627         set(library_type SHARED)
 628 else()
 629         set(library_type STATIC)
 630 endif()
 631
 632 if(NOT MSVC)
 633         if(NOT LYX_QUIET)
 634                 set(CMAKE_VERBOSE_MAKEFILE ON)
 635         endif()
 636         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 637         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 638           # Thanks to Brad King <brad.king@kitware.com>
 639           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 640           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 641           # and still use our own c++ extension tests
 642           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 643           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 644         endif()
 645         if(LYX_STDLIB_DEBUG)
 646                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 647         endif()
 648         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE STRING "Set CXX flags" FORCE)
 649         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE STRING "Set debug flags" FORCE)
 650         if(MINGW)
 651                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE STRING "Set release flags for Mingw" FORCE)
 652         else()
 653                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE STRING "Set release flags" FORCE)
 654         endif()
 655 endif()
 656
 657 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 658 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 659 if(LYX_CXX_FLAGS_EXTRA)
 660         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 661                 add_definitions(${_flag})
 662         endforeach()
 663 endif()
 664
 665 if(LYX_XMINGW)
 666         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 667 endif()
 668
 669 set(min_qt5_version "5.6")
 670 if(LYX_USE_QT MATCHES "AUTO")
 671         # try qt5 first
 672         find_package(Qt5Core CONFIG QUIET)
 673         if(Qt5Core_FOUND)
 674                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 675                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 676                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 677                         find_package(Qt4 "4.5.0" QUIET)
 678                         if(QT4_FOUND)
 679                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 680                         endif()
 681                 endif()
 682         else()
 683                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 684         endif()
 685 endif()
 686 if(LYX_USE_QT MATCHES "QT5")
 687         # set QPA_XCB if QT uses X11
 688         find_package(Qt5Core CONFIG REQUIRED)
 689         if (Qt5Core_FOUND)
 690                 find_package(Qt5Widgets CONFIG REQUIRED)
 691                 if(APPLE)
 692                         find_package(Qt5MacExtras CONFIG REQUIRED)
 693                 endif()
 694                 find_package(Qt5X11Extras CONFIG QUIET)
 695                 find_package(Qt5WinExtras CONFIG QUIET)
 696                 set(QTVERSION ${Qt5Core_VERSION})
 697                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 698                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 699                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 700                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 701                         # see thread in lyx-devel list
 702                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 703                         # Date 11.03.2017
 704                         # Subject: cmake compilation error
 705                         #message(FATAL_ERROR "Wrong Qt-Version")
 706                 endif()
 707                 macro (qt_use_modules lyxtarget)
 708                         foreach (_tg ${ARGN})
 709                                 find_package(Qt5${_tg} CONFIG REQUIRED)
 710                                 target_link_libraries(${lyxtarget} Qt5::${_tg})
 711                         endforeach()
 712                 endmacro()
 713                 macro (qt_add_resources)
 714                         qt5_add_resources(${ARGN})
 715                 endmacro()
 716                 macro (qt_wrap_uifiles)
 717                         qt5_wrap_ui(${ARGN})
 718                 endmacro()
 719                 message(STATUS "Found Qt-Version ${QTVERSION}")
 720                 if(WIN32)
 721                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 722                 endif()
 723         endif()
 724 elseif(LYX_USE_QT MATCHES "QT4")
 725         if(LYX_XMINGW)
 726                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 727                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 728         endif()
 729         find_package(Qt4 "4.5.0" REQUIRED)
 730         macro (qt_use_modules)
 731         endmacro()
 732         macro (qt_add_resources)
 733                 qt4_add_resources(${ARGN})
 734         endmacro()
 735         macro (qt_wrap_uifiles)
 736                 qt4_wrap_ui(${ARGN})
 737         endmacro()
 738         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 739         if(WIN32)
 740                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 741         endif()
 742 else()
 743   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 744 endif()
 745
 746 find_package(Magic)
 747 if(Magic_FOUND)
 748   set(HAVE_MAGIC_H 1)
 749   include_directories(${Magic_INCLUDE_DIR})
 750 endif()
 751
 752 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 753
 754 set(Spelling_FOUND OFF)
 755 set(Include_used_spellchecker)   # String will be inserted into config.h
 756
 757 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 758   # try system library first
 759   find_package(MyThesLIB)
 760   if (MYTHESLIB_FOUND)
 761     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 762   else()
 763     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 764   endif()
 765 endif()
 766 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 767   find_package(MyThesLIB REQUIRED)
 768 else()
 769   add_subdirectory(3rdparty/mythes)
 770 endif()
 771 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 772
 773 if(NOT LYX_EXTERNAL_HUNSPELL)
 774     add_subdirectory(3rdparty/hunspell)
 775     add_definitions(-DHUNSPELL_STATIC)
 776     set(HUNSPELL_FOUND ON)
 777     message(STATUS "  * Hunspell:")
 778     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 779     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 780 endif()
 781
 782 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 783   string(TOUPPER ${_spell} _upspell)
 784   if (NOT ${_upspell}_FOUND)
 785     find_package(${_spell})
 786   endif()
 787   if (${_upspell}_FOUND)
 788     include_directories(${${_upspell}_INCLUDE_DIR})
 789     set(Spelling_FOUND ON)
 790     message(STATUS "Building with USE_${_upspell}")
 791     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 792   else()
 793     if(LYX_${_upspell})
 794       message(FATAL_ERROR "Required ${_spell} devel package not found")
 795     else()
 796       message(STATUS "${_upspell} not found, building without ${_spell} support")
 797     endif()
 798   endif()
 799 endforeach()
 800
 801 if(GNUWIN32_DIR)
 802         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 803 endif()
 804
 805 # Search for python default version first
 806 unset(PYTHON_EXECUTABLE CACHE)
 807 unset(LYX_PYTHON_EXECUTABLE CACHE)
 808 unset(PYTHON_VERSION_MAJOR)
 809 unset(PYTHON_VERSION_MINOR)
 810 unset(PYTHON_VERSION_STRING)
 811 if (CMAKE_VERSION VERSION_LESS "3.13")
 812   find_package(PythonInterp 3.5 QUIET)
 813   if(NOT PYTHONINTERP_FOUND)
 814     find_package(PythonInterp 2.0 REQUIRED)
 815     if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 816       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 817     endif()
 818   endif()
 819   set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 820 else()
 821   find_package(Python3 3.5 QUIET)
 822   if(NOT Python3_Interpreter_FOUND)
 823     unset(PYTHON_EXECUTABLE CACHE)
 824     find_package(Python2 2.0 REQUIRED)
 825     if(NOT Python2_VERSION VERSION_LESS 2.8)
 826       message(FATAL_ERROR "Python interpreter found, but is not suitable")
 827     endif()
 828     set(LYX_PYTHON_EXECUTABLE ${Python2_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 829   else()
 830     set(LYX_PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 831   endif()
 832 endif()
 833
 834 if(LYX_NLS)
 835         find_package(LyXGettext)
 836         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 837                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 838         else()
 839                 # Install only supplied .gmo-files
 840                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 841                 message(STATUS "Installing provided .gmo-files only")
 842                 foreach( _gmo ${_gmofiles})
 843                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 844                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 845                 endforeach()
 846         endif()
 847 endif()
 848
 849 if(LYX_EXTERNAL_ICONV)
 850   find_package(ICONV REQUIRED)
 851 else()
 852   add_subdirectory(3rdparty/libiconv)
 853   set(HAVE_ICONV_CONST 1)
 854 endif()
 855
 856 if(LYX_EXTERNAL_Z)
 857   find_package(ZLIB REQUIRED)
 858 else()
 859   add_subdirectory(3rdparty/zlib)
 860 endif()
 861
 862 if(LYX_USE_STD_REGEX)
 863   # Set only include path.
 864   # Use internal boost, which is known to exist
 865   # we don't need any libraries
 866   set(Lyx_Boost_Libraries)
 867   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 868   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 869 else()
 870   # Using boost-regex
 871   if(LYX_EXTERNAL_BOOST)
 872     message(STATUS "Searching for external boost")
 873     find_package(Boost COMPONENTS regex)
 874     if(Boost_FOUND)
 875       message(STATUS "Boost found")
 876       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 877       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 878       if (LYX_STDLIB_DEBUG)
 879         # Comment from  Jean-Marc Lasgouttes:
 880         # In general, system boost libraries are incompatible with
 881         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 882         # details.
 883         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 884       endif()
 885     else()
 886       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 887     endif()
 888   else()
 889     # Using included boost
 890     set(Lyx_Boost_Libraries boost_regex)
 891     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 892     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 893     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 894   endif()
 895 endif()
 896
 897 if(WIN32)
 898         if(LYX_CONSOLE)
 899                 set(LYX_QTMAIN_LIBRARY)
 900         else()
 901                 set(WIN32_CONSOLE WIN32)
 902         endif()
 903         if(MSVC)
 904                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 905                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 906                 # disable checked iterators for msvc release builds to get maximum speed
 907                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 908         else()
 909                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 910                 # does not use it and always declares the vista compatible API.
 911                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 912                 add_definitions(-DWINVER=0x0500)
 913         endif()
 914 endif()
 915
 916 # Compute qt-version from ${QTVERSION}
 917
 918 message(STATUS "")
 919 foreach(_v PACKAGE PACKAGE_VERSION
 920         PROGRAM_SUFFIX LYX_DIR_VER LYX_USERDIR_VER
 921         LYX_ABS_TOP_SRCDIR
 922         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 923         if(NOT DEFINED ${_v})
 924                 message(FATAL_ERROR "${_v} not defined")
 925         endif()
 926         string(SUBSTRING "${_v}                            " 0 28 _v1)
 927         message(STATUS "----- ${_v1}: ${${_v}}")
 928 endforeach(_v)
 929 message(STATUS "")
 930
 931
 932 if(LYX_PCH)
 933         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 934         # Not sure if it works for all non-msvc compilers
 935         include(PCHSupport_26)
 936         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 937         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 938         add_definitions(-DLYX_ENABLE_PCH)
 939
 940         if(MSVC)
 941                 macro(lyx_add_msvc_pch name_)
 942                         set_source_files_properties(${${name_}_sources} PROPERTIES
 943                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 944                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 945                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 946                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 947                                 ${TOP_BINARY_DIR}/pcheaders.h)
 948                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 949                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 950                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 951                 endmacro(lyx_add_msvc_pch)
 952                 macro(lyx_add_gcc_pch name_)
 953                 endmacro()
 954         else()
 955                 macro(lyx_add_msvc_pch name_)
 956                 endmacro()
 957                 macro(lyx_add_gcc_pch name_)
 958                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 959                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 960                 endmacro()
 961         endif()
 962 else()
 963         macro(lyx_add_msvc_pch)
 964         endmacro(lyx_add_msvc_pch)
 965         macro(lyx_add_gcc_pch name_)
 966         endmacro()
 967 endif()
 968
 969
 970 if(MSVC)
 971
 972         if(LYX_VLD)
 973                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 974                 add_subdirectory(${vld_path}/cmake)
 975                 include(${vld_path}/cmake/vld.cmake) # forced include
 976                 set(vld_dll vld)
 977         endif()
 978
 979         if(LYX_WALL)
 980                 # Use the highest warning level
 981                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "Warning level" FORCE)
 982
 983                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 984                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 985                 else()
 986                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 987                 endif()
 988
 989                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 990                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 991                 else()
 992                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 993                 endif()
 994
 995                 # add here warnings which should produce an error /weXXXX
 996                 set(MSVC_W_ERROR   "/we4101 /we4189")
 997                 # add here warnings which should be disabled /wdXXXX
 998                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 999
1000                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1001                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1002                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1003
1004         else()
1005                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "Warning level" FORCE)
1006
1007                 # add here warnings which should produce an error /weXXXX
1008                 set(MSVC_W_ERROR   "/we4101 /we4189")
1009                 # add here warnings which should be disabled /wdXXXX
1010                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
1011
1012                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1013                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1014                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
1015
1016         endif()
1017
1018         if (NOT Qt5Core_FOUND)
1019                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
1020                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
1021                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
1022         endif()
1023
1024         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
1025         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
1026         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
1027         message(STATUS "")
1028 endif()
1029
1030
1031 if(LYX_DEBUG_GLIBC)
1032         set(_GLIBCXX_DEBUG ON)
1033 endif()
1034
1035 if(LYX_DEBUG_GLIBC_PEDANTIC)
1036         set(_GLIBCXX_DEBUG_PEDANTIC ON)
1037 endif()
1038
1039 # Xcode compiler
1040 if (CMAKE_GENERATOR MATCHES Xcode)
1041         if (XCODE_VERSION VERSION_LESS "5.0")
1042                 # Automatically select the Xcode compiler if not set
1043                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1044                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
1045                         if (XCODE_VERSION VERSION_GREATER "3.1")
1046                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
1047                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
1048                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
1049                 # Print the selected compiler version
1050         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
1051         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
1052 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
1053
1054 if (WIN32 AND Qt5Core_FOUND)
1055         set(Z_PREFIX 1)
1056 endif()
1057
1058 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
1059 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
1060 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
1061
1062 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1063
1064 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1065         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1066 endif()
1067
1068 if (NOT HAVE_REGEX)
1069         set(LYX_USE_STD_REGEX 0)
1070 endif()
1071
1072
1073 set (cmd ${CMAKE_CTEST_COMMAND})
1074 if (MSVC)
1075         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1076 else ()
1077         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1078 endif ()
1079 add_custom_target (lyx_run_tests COMMAND ${cmd})
1080 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1081
1082 if(LYX_ASAN)
1083     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1084     message(STATUS)
1085     message(STATUS "Address sanitizer enabled. Usage:")
1086     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1087     message(STATUS "    chmod  +x ./asan_symbolize.py")
1088     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1089     message(STATUS)
1090 endif()
1091
1092 if(LYX_INSTALL)
1093         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1094                 message(STATUS "Python required to create doc!")
1095         else()
1096                 if(UNIX)
1097                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1098                 endif()
1099                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1100         endif()
1101 endif()
1102 include(../Install)
1103
1104 # By running the URL tests first, time can be saved when running the ctests in
1105 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1106 if(LYX_ENABLE_URLTESTS)
1107         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1108 endif()
1109 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1110 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1111 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1112 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1113 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1114 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1115 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1116
1117 message(STATUS)
1118 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1119 message(STATUS)
1120
1121 LYX_OPTION_LIST_ALL(used)
1122
1123
1124 if(LYX_NLS)
1125         message(STATUS)
1126         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1127         message(STATUS)
1128         message(STATUS "  * iconv")
1129         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1130         message(STATUS "     - library: ${ICONV_LIBRARY}")
1131         message(STATUS "  * zlib")
1132         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1133         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1134         message(STATUS)
1135 endif()
1136
1137 # Apple has builtin native spell checker,
1138 # no need to warn for missing Aspell, Hunspell or Enchant
1139 if(NOT Spelling_FOUND AND NOT APPLE)
1140   if(LYX_REQUIRE_SPELLCHECK)
1141     set(_mode "FATAL_ERROR")
1142   else()
1143     set(_mode "STATUS")
1144   endif()
1145   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1146 endif()
1147
1148 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1149
1150 if(ENABLE_DIST)
1151   # Use git to create the source package
1152   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1153   if(UNIX)
1154     set(DIST_FORMAT tgz)
1155   else()
1156     set(DIST_FORMAT zip)
1157   endif()
1158   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1159
1160   add_custom_command(
1161     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1162     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1163     WORKING_DIRECTORY ${TOP_SRC_DIR})
1164   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1165 endif()
1166
1167 # Last directory to be included so that the fixup code (OS X)
1168 # can be run last
1169 add_subdirectory(development/cmake/post_install)
1170
1171 message(STATUS)