CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  16
  17 set(LYX_CMAKE_DIR "development/cmake")
  18 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  19 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  20 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  21
  22 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  23
  24 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  25
  26 message(STATUS)
  27 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  28         message(STATUS "Building in-source")
  29         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  30 else()
  31         message(STATUS "Building out-of-source")
  32         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  33 endif()
  34
  35 # This directory should be used if some test uses lyx-executable
  36 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  37 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  38
  39 if(COMMAND cmake_policy)
  40         cmake_policy(SET CMP0003 OLD)
  41         cmake_policy(SET CMP0005 OLD)
  42         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  43         cmake_policy(SET CMP0006 NEW)
  44         if(POLICY CMP0020)
  45                 cmake_policy(SET CMP0020 OLD)
  46         endif()
  47         if(POLICY CMP0028)
  48                 cmake_policy(SET CMP0028 OLD)
  49         endif()
  50         if(POLICY CMP0043)
  51                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  52                 cmake_policy(SET CMP0043 NEW)
  53         endif()
  54 endif()
  55
  56 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  57
  58 # Supress regeneration
  59 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  60
  61 if(LYX_XMINGW)
  62     set(CMAKE_SYSTEM_NAME Windows)
  63     set(TOOLNAME ${LYX_XMINGW})
  64     set(TOOLCHAIN "${TOOLNAME}-")
  65     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  66     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  67     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  68
  69     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  70     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  71     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  72 endif()
  73
  74 if(NOT help AND NOT HELP)
  75   # 'project' triggers the searching for a compiler
  76   project(${LYX_PROJECT})
  77   if (CMAKE_COMPILER_IS_GNUCXX)
  78     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  79       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  80       message(STATUS "is too old, should be >= 4.0")
  81       message(FATAL_ERROR "Exiting")
  82     endif()
  83   endif()
  84 endif()
  85
  86 if(UNIX)
  87         set(ARCH_TRIPLET )
  88         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  89         if(DPKG_ARCHITECTURE_EXECUTABLE)
  90                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  91                                 OUTPUT_VARIABLE ARCH_TRIPLET
  92                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  93                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  94         endif()
  95 endif()
  96 if(ARCH_TRIPLET)
  97         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  98 else()
  99         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
 100 endif()
 101
 102 include(LyXMacros)
 103 include(LyXDestinations)
 104
 105 # Usage LYX_OPTION
 106 # 1. parameter: option name without prefix 'LYX_'
 107 # 2. parameter: description
 108 # 3. parameter: default value, ON or OFF
 109 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 110
 111 # Usage LYX_COMBO
 112 # 1. parameter: name without prefix 'LYX_'
 113 # 2. parameter: description
 114 # 3. parameter: default value
 115 # 4-n parameter: possible other string values
 116
 117 LYX_OPTION_INIT()
 118
 119 # Options for all compilers/systems
 120 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 121 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 122 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 123 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 124 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 125 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 126 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 127 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 128 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
 129 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 130 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 131 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 132 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 133 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 134 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 135 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 136 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 137 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 138 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 139 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 140 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 141 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 142 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 143 LYX_COMBO(USE_QT            "Use Qt version as frontend" QT4 QT5)
 144 LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 145
 146 # GCC specific
 147 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 148 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 149 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 150 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 151 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 152 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 153 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 154
 155 # MSVC specific
 156 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 157 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 158 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 159 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 160 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 161
 162 # APPLE specific
 163 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 164 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 165
 166
 167 if(help OR HELP)
 168         message(STATUS)
 169         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 170         message(STATUS)
 171         LYX_OPTION_LIST_ALL(help)
 172         message(STATUS)
 173         RETURN()
 174 endif()
 175
 176 # Check option dependencies
 177
 178 if(LYX_DMG)
 179         set(LYX_BUNDLE ON)
 180         set(LYX_CPACK ON)
 181 endif()
 182
 183 if(LYX_CPACK)
 184         set(LYX_INSTALL ON)
 185 endif()
 186
 187 if(LYX_INSTALL)
 188         set(LYX_NLS ON)
 189         if(WIN32 AND NOT MINGW)
 190                 set(LYX_HUNSPELL ON)
 191         endif()
 192         if(LYX_CONSOLE MATCHES "FORCE")
 193                 set(LYX_CONSOLE ON)
 194         else()
 195                 set(LYX_CONSOLE OFF)
 196         endif()
 197         set(LYX_PACKAGE_SUFFIX ON)
 198         if(NOT LYX_DEBUG)
 199                 set(LYX_RELEASE ON)
 200         endif()
 201         set(LYX_PROFILE OFF)
 202 endif()
 203
 204
 205 if(LYX_MERGE_FILES)
 206         set(LYX_PCH OFF)
 207 else()
 208         set(LYX_MERGE_REBUILD OFF)
 209 endif()
 210
 211
 212 if(LYX_DEPENDENCIES_DOWNLOAD)
 213         message(STATUS)
 214     if(MSVC12)
 215         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2013-deps)
 216         set(deps_files lyx-windows-deps-msvc2013.zip)
 217         set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 218         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2013)
 219     else()
 220         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 221             set(deps_files lyx20-deps-msvc2010-x86.zip)
 222             set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 223         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 224     endif()
 225     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 226         foreach(it ${deps_files})
 227                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 228                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 229                 if(NOT already_downloaded)
 230                         message(STATUS "Downloading ${it} ...")
 231                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 232                         list(GET status 0 status_code)
 233                         list(GET status 1 status_string)
 234                         if(NOT status_code EQUAL 0)
 235                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 236                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 237                         endif()
 238                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 239                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 240                 endif()
 241         endforeach()
 242 endif()
 243
 244
 245
 246 message(STATUS)
 247
 248 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 249 if(WIN32)
 250         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 251 else()
 252         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 253 endif()
 254
 255
 256 # Set to some meaningful default
 257 find_package(CXX11Compiler)
 258 if(NOT CXX11COMPILER_FOUND)
 259         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 260 endif()
 261 set(LYX_GCC11_MODE)
 262 if(UNIX OR MINGW)
 263         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 264         message(STATUS "Using GCC version ${GCC_VERSION}")
 265         if(GCC_VERSION VERSION_LESS 4.9)
 266                 if(GCC_VERSION VERSION_LESS 4.3)
 267                         message(FATAL_ERROR "gcc >= 4.3 is required.")
 268                 endif()
 269                 # <regex> in gcc is unusable in versions less than 4.9.0
 270                 # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 271                 set(LYX_USE_STD_REGEX 0)
 272         else()
 273                 set(LYX_USE_STD_REGEX 1)
 274         endif()
 275         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 276 else()
 277         set(LYX_USE_STD_REGEX 0)
 278 #       if(MSVC10)
 279 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 280 #       endif()
 281 endif()
 282
 283
 284 set(VERSION_INFO "CMake Build")
 285
 286 # Try to get some informations from configure.ac
 287
 288 include(LyXPaths)
 289 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 290
 291 if(WIN32)
 292         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 293         if(MSVC)
 294                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 295         endif()
 296         set(USE_WINDOWS_PACKAGING ON)
 297 elseif(APPLE)
 298         set(USE_MACOSX_PACKAGING ON)
 299 else()
 300         set(USE_POSIX_PACKAGING ON)
 301 endif()
 302
 303 macro(setstripped _varname)
 304         if(${ARGC} GREATER 1)
 305                 string(STRIP "${ARGV1}" _v)
 306                 if(USE_POSIX_PACKAGING)
 307                         string(TOLOWER ${_v} ${_varname})
 308                 else()
 309                         set(${_varname} ${_v})
 310                 endif()
 311         else()
 312                 set(${_varname})
 313         endif()
 314 endmacro(setstripped)
 315
 316 foreach(_c_l ${_config_lines} )
 317         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 318                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 319                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 320                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 321                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 322                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 323                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 324                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 325                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 326                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 327                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 328                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 329                         else()
 330                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 331                         endif()
 332                 endif()
 333         endif()
 334         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 335                 set(LYX_DATE "${CMAKE_MATCH_1}")
 336         endif()
 337 endforeach(_c_l)
 338
 339 FIND_PROGRAM(LYX_GITVERSION git)
 340 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 341 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 342 if(LYX_GITVERSION)
 343   if (LYX_LOCALVERSIONING)
 344     # Find the revision number and for later use
 345     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 346       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 347     if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 348       # We will add offset of 40000 to get appropriate value to
 349       # previous svn.
 350       # We use this value than also to set the package-patch-value
 351       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 352       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 353       set(ENABLE_DIST ON)
 354     endif()
 355   endif()
 356 endif()
 357
 358 # Set the programs (lyx, tex2lyx, etc.) suffix
 359 # When building an OS X bundle, we will append
 360 # the suffix only to the bundle, not to the programs
 361 set(PROGRAM_SUFFIX "")
 362 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 363         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 364 endif()
 365 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 366 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 367
 368 add_custom_target(lyx_version ALL
 369   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 370   )
 371 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 372
 373 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 374 set(LYX_UTILITIES_INSTALL_PATH bin)
 375
 376 if(LYX_BUNDLE)
 377         set(LYX_CPACK ON)
 378
 379         message(STATUS)
 380         message(STATUS "Bundle creation is enabled (experimental):")
 381         message(STATUS "    make")
 382         message(STATUS "    make install/strip")
 383         message(STATUS "    make package")
 384         if(APPLE)
 385                 set(MACOSX_BUNDLE TRUE)
 386                 # This sets the bundle + executable names
 387                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 388                 # This sets the Info.plist executable name
 389                 set(osx_bundle_program_name ${_lyx})
 390                 # Bundle name
 391                 set(LYX_BUNDLE_NAME ${_lyx})
 392
 393                 # This will contain the list of files that need to be included
 394                 # in the bundle and their location within the bundle
 395                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 396                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 397
 398                 # Process Info.plist and lyxrc.dist
 399                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 400                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/lyxrc.dist.in" "${CMAKE_CURRENT_BINARY_DIR}/lyxrc.dist")
 401
 402                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 403                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 404
 405                 # Variables used by CPack
 406                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 407                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 408                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 409
 410                 # Set the install paths
 411                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 412                 if(NOT LYX_INSTALL_PREFIX)
 413                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 414                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 415                 endif()
 416                 # Change the owner so that the install can work
 417                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 418         elseif(UNIX)
 419                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 420                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 421                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 422         elseif(WIN32)
 423                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 424         endif()
 425 endif()
 426
 427 if(LYX_INSTALL_PREFIX)
 428         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 429         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 430 endif()
 431 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 432
 433 string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 434
 435 if(LYX_PACKAGE_SUFFIX)
 436         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 437 else()
 438         set(PACKAGE ${PACKAGE_BASE})
 439 endif()
 440
 441 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 442         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 443         if (UNIX)
 444                 # use the default "/usr/local"
 445                 # but respect the user-choice on the command-line
 446                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 447         endif()
 448 endif()
 449 if(WIN32)
 450         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 451 endif()
 452 if(IS_ABSOLUTE)
 453         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 454 else()
 455         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 456 endif()
 457
 458
 459
 460 if(NOT LYX_DATA_SUBDIR)
 461         if (WIN32)
 462                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 463         else()
 464                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 465         endif()
 466 endif()
 467
 468 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 469 get_locale_destination(LYX_LOCALEDIR)
 470 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 471 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 472
 473 if(LYX_BUNDLE AND APPLE)
 474         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 475 else()
 476         if(WIN32)
 477                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 478         elseif(UNIX)
 479                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 480         else()
 481                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 482         endif()
 483 endif()
 484 mark_as_advanced(LYX_MAN_DIR)
 485
 486 if(LYX_INSTALL AND WIN32)
 487         message(STATUS "Configuring NSIS files")
 488         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 489         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 490         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 491         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 492 endif()
 493
 494 if(NOT GROUP_CODE)
 495         #set(GROUP_CODE "The Golden Code")
 496         set(GROUP_CODE flat)
 497 endif()
 498
 499 # lyx's source files
 500 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 501 set(LYX_HPP_FILES [a-zA-Z]*.h)
 502 set(LYX_MOC_FILES moc_*.cpp)
 503
 504 include(ProjectSourceGroup)
 505
 506
 507 if(LYX_PROFILE AND NOT MSVC)
 508         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 509         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 510         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 511 else()
 512         set(LYX_PROFILE OFF)
 513 endif()
 514
 515
 516 if(LYX_NO_OPTIMIZE)
 517         set(CMAKE_BUILD_TYPE None)
 518         set(LYX_DEBUG OFF)
 519         set(LYX_RELEASE OFF)
 520         set(LYX_PROFILE OFF)
 521 elseif(LYX_RELEASE)
 522         set(CMAKE_BUILD_TYPE Release)
 523         set(LYX_DEBUG OFF)
 524         set(LYX_PROFILE OFF)
 525 elseif(LYX_PROFILE)
 526         set(CMAKE_BUILD_TYPE Profile)
 527         set(LYX_DEBUG OFF)
 528 else()
 529         set(CMAKE_BUILD_TYPE Debug)
 530         set(LYX_DEBUG ON)
 531 endif()
 532
 533
 534 # When shared libs are supported enable this option
 535 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 536 if(LYX_SHARED_LIBRARIES)
 537         set(library_type SHARED)
 538 else()
 539         set(library_type STATIC)
 540 endif()
 541
 542 if(NOT MSVC)
 543         if(NOT LYX_QUIET)
 544                 set(CMAKE_VERBOSE_MAKEFILE ON)
 545         endif()
 546     set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 547         if(LYX_STDLIB_DEBUG)
 548                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 549         endif()
 550         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 551         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 552         if(MINGW)
 553                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 554         else()
 555                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 556         endif()
 557 endif()
 558
 559 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 560 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 561 if(LYX_CXX_FLAGS_EXTRA)
 562         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 563                 add_definitions(${_flag})
 564         endforeach()
 565 endif()
 566
 567 if(LYX_XMINGW)
 568         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 569 endif()
 570
 571 set(QPA_XCB)
 572 if(LYX_USE_QT MATCHES "QT5")
 573         # set QPA_XCB if QT uses X11
 574         find_package(Qt5Core REQUIRED)
 575         if (Qt5Core_FOUND)
 576                 find_package(Qt5Widgets REQUIRED)
 577                 if(APPLE)
 578                         find_package(Qt5MacExtras REQUIRED)
 579                 endif()
 580                 find_package(Qt5X11Extras QUIET)
 581                 if(Qt5X11Extras_FOUND)
 582                   set(QPA_XCB 1)
 583                 endif()
 584                 find_package(Qt5WinExtras QUIET)
 585                 set(QTVERSION ${Qt5Core_VERSION})
 586                 macro (qt_use_modules)
 587                         qt5_use_modules(${ARGN})
 588                 endmacro()
 589                 macro (qt_add_resources)
 590                         qt5_add_resources(${ARGN})
 591                 endmacro()
 592                 macro (qt_wrap_uifiles)
 593                         qt5_wrap_ui(${ARGN})
 594                 endmacro()
 595                 message(STATUS "Found Qt-Version ${QTVERSION}")
 596                 if(WIN32)
 597                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 598                 endif()
 599         endif()
 600 elseif(LYX_USE_QT MATCHES "QT4")
 601         if(LYX_XMINGW)
 602                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 603                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 604         endif()
 605         find_package(Qt4 "4.5.0" REQUIRED)
 606         macro (qt_use_modules)
 607         endmacro()
 608         macro (qt_add_resources)
 609                 qt4_add_resources(${ARGN})
 610         endmacro()
 611         macro (qt_wrap_uifiles)
 612                 qt4_wrap_ui(${ARGN})
 613         endmacro()
 614         if(WIN32)
 615                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 616         endif()
 617 else()
 618   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 619 endif()
 620
 621 find_package(Magic)
 622 if(Magic_FOUND)
 623         set(HAVE_MAGIC_H 1)
 624 endif()
 625
 626 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 627
 628 set(Spelling_FOUND OFF)
 629 set(Include_used_spellchecker)   # String will be inserted into config.h
 630
 631 if(LYX_3RDPARTY_BUILD)
 632     add_subdirectory(3rdparty/hunspell)
 633     add_definitions(-DHUNSPELL_STATIC)
 634     set(HUNSPELL_FOUND ON)
 635     message(STATUS "  * Hunspell:")
 636     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 637     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 638 endif()
 639
 640 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 641   string(TOUPPER ${_spell} _upspell)
 642   if (NOT ${_upspell}_FOUND)
 643     find_package(${_spell})
 644   endif()
 645   if (${_upspell}_FOUND)
 646     include_directories(${${_upspell}_INCLUDE_DIR})
 647     set(Spelling_FOUND ON)
 648     message(STATUS "Building with USE_${_upspell}")
 649     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 650   else()
 651     if(LYX_${_upspell})
 652       message(FATAL_ERROR "Required ${_spell} devel package not found")
 653     else()
 654       message(STATUS "${_upspell} not found, building without ${_spell} support")
 655     endif()
 656   endif()
 657 endforeach()
 658
 659 if(GNUWIN32_DIR)
 660         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 661 endif()
 662
 663 find_package(PythonInterp 2.7 QUIET)
 664 if(PYTHONINTERP_FOUND)
 665         if(PYTHON_VERSION_STRING VERSION_GREATER 2.8)
 666         unset(PYTHONINTERP_FOUND)
 667         endif()
 668 endif()
 669
 670 if(NOT PYTHONINTERP_FOUND)
 671   unset(PYTHON_EXECUTABLE CACHE)
 672   unset(PYTHON_VERSION_MAJOR)
 673   unset(PYTHON_VERSION_MINOR)
 674   unset(PYTHON_VERSION_STRING)
 675   find_package(PythonInterp 3.3 REQUIRED)
 676 endif()
 677
 678 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 679
 680 if(LYX_NLS)
 681         find_package(LyXGettext)
 682         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 683                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 684         else()
 685                 # Install only supplied .gmo-files
 686                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 687                 message(STATUS "Installing provided .gmo-files only")
 688                 foreach( _gmo ${_gmofiles})
 689                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 690                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 691                 endforeach()
 692         endif()
 693 endif()
 694
 695 if(UNIX)
 696     find_package(ICONV REQUIRED)
 697     find_package(ZLIB REQUIRED)
 698 else()
 699     if(LYX_3RDPARTY_BUILD)
 700         add_subdirectory(3rdparty/libiconv)
 701         set(HAVE_ICONV_CONST 1)
 702         add_subdirectory(3rdparty/zlib)
 703     endif()
 704 endif()
 705
 706 if(LYX_EXTERNAL_BOOST)
 707         message(STATUS "Searching for boost")
 708         if(LYX_USE_STD_REGEX)
 709                 find_package(Boost COMPONENTS signals)
 710         else()
 711                 find_package(Boost COMPONENTS signals regex)
 712         endif()
 713         if(Boost_FOUND)
 714                 message(STATUS "Boost found")
 715                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 716                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 717                 if (LYX_STDLIB_DEBUG)
 718                         # Comment from  Jean-Marc Lasgouttes:
 719                         # In general, system boost libraries are incompatible with
 720                         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 721                         # details.
 722                         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 723                 endif()
 724         else()
 725                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 726         endif()
 727 else()
 728         if(LYX_USE_STD_REGEX)
 729                 set(Lyx_Boost_Libraries boost_signals)
 730         else()
 731                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 732         endif()
 733         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 734         add_definitions(-DBOOST_SIGNALS_NO_DEPRECATION_WARNING=1)
 735         include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 736         add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 737 endif()
 738
 739
 740
 741
 742 if(WIN32)
 743         if(LYX_CONSOLE)
 744                 set(LYX_QTMAIN_LIBRARY)
 745         else()
 746                 set(WIN32_CONSOLE WIN32)
 747         endif()
 748         if(MSVC)
 749                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 750                 # disable checked iterators for msvc release builds to get maximum speed
 751                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 752         else()
 753                 add_definitions(-DWINVER=0x0500)
 754         endif()
 755 endif()
 756
 757 # Compute qt4-version from ${QTVERSION}
 758
 759 message(STATUS "")
 760 foreach(_v PACKAGE PACKAGE_VERSION
 761         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 762         LYX_ABS_TOP_SRCDIR
 763         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 764         if(NOT DEFINED ${_v})
 765                 message(FATAL_ERROR "${_v} not defined")
 766         endif()
 767         string(SUBSTRING "${_v}                            " 0 28 _v1)
 768         message(STATUS "----- ${_v1}: ${${_v}}")
 769 endforeach(_v)
 770 message(STATUS "")
 771
 772
 773 if(LYX_PCH)
 774         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 775         # Not sure if it works for all non-msvc compilers
 776         include(PCHSupport_26)
 777         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 778         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 779         add_definitions(-DLYX_ENABLE_PCH)
 780
 781         if(MSVC)
 782                 macro(lyx_add_msvc_pch name_)
 783                         set_source_files_properties(${${name_}_sources} PROPERTIES
 784                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 785                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 786                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 787                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 788                                 ${TOP_BINARY_DIR}/pcheaders.h)
 789                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 790                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 791                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 792                 endmacro(lyx_add_msvc_pch)
 793                 macro(lyx_add_gcc_pch name_)
 794                 endmacro()
 795         else()
 796                 macro(lyx_add_msvc_pch name_)
 797                 endmacro()
 798                 macro(lyx_add_gcc_pch name_)
 799                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 800                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 801                 endmacro()
 802         endif()
 803 else()
 804         macro(lyx_add_msvc_pch)
 805         endmacro(lyx_add_msvc_pch)
 806         macro(lyx_add_gcc_pch name_)
 807         endmacro()
 808 endif()
 809
 810
 811 if(MSVC)
 812
 813         if(LYX_VLD)
 814                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 815                 add_subdirectory(${vld_path}/cmake)
 816                 include(${vld_path}/cmake/vld.cmake) # forced include
 817                 set(vld_dll vld)
 818         endif()
 819
 820         if(LYX_WALL)
 821                 # Use the highest warning level
 822                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 823
 824                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 825                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 826                 else()
 827                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 828                 endif()
 829
 830                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 831                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 832                 else()
 833                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 834                 endif()
 835
 836                 # add here warnings which should produce an error /weXXXX
 837                 set(MSVC_W_ERROR   "/we4101 /we4189")
 838                 # add here warnings which should be disabled /wdXXXX
 839                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 840
 841                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 842                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 843                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 844
 845         else()
 846                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 847
 848                 # add here warnings which should produce an error /weXXXX
 849                 set(MSVC_W_ERROR   "/we4101 /we4189")
 850                 # add here warnings which should be disabled /wdXXXX
 851                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 852
 853                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 854                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 855                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 856
 857         endif()
 858
 859         if (NOT Qt5Core_FOUND)
 860                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 861                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 862                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 863         endif()
 864
 865         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 866         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 867         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 868         message(STATUS "")
 869 endif()
 870
 871
 872 if(LYX_DEBUG_GLIBC)
 873         set(_GLIBCXX_DEBUG ON)
 874 endif()
 875
 876 if(LYX_DEBUG_GLIBC_PEDANTIC)
 877         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 878 endif()
 879
 880 # Xcode compiler
 881 if (CMAKE_GENERATOR MATCHES Xcode)
 882         if (XCODE_VERSION VERSION_LESS "5.0")
 883                 # Automatically select the Xcode compiler if not set
 884                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 885                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 886                         if (XCODE_VERSION VERSION_GREATER "3.1")
 887                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 888                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 889                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 890                 # Print the selected compiler version
 891         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 892         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 893 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 894
 895 if (WIN32 AND Qt5Core_FOUND)
 896         set(Z_PREFIX 1)
 897 endif()
 898
 899 # compiler tests, config.h generation
 900 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 901         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 902 else()
 903         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 904         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 905 endif()
 906
 907 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 908
 909 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 910         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 911 endif()
 912
 913 if (NOT HAVE_REGEX)
 914         set(LYX_USE_STD_REGEX 0)
 915 endif()
 916
 917
 918 set (cmd ${CMAKE_CTEST_COMMAND})
 919 if (MSVC)
 920         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 921 else ()
 922         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 923 endif ()
 924 add_custom_target (lyx_run_tests COMMAND ${cmd})
 925 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 926
 927 if(LYX_ASAN)
 928     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
 929     message(STATUS)
 930     message(STATUS "Address sanitizer enabled. Usage:")
 931     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
 932     message(STATUS "    chmod  +x ./asan_symbolize.py")
 933     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
 934     message(STATUS)
 935 endif()
 936
 937 if(LYX_INSTALL)
 938         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 939                 message(STATUS "Python required to create doc!")
 940         else()
 941                 if(UNIX)
 942                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 943                 endif()
 944                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 945         endif()
 946         include(../Install)
 947 endif()
 948
 949 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 950 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 951 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 952 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 953 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 954 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 955 if(LYX_ENABLE_URLTESTS)
 956         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
 957 endif()
 958
 959 message(STATUS)
 960 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
 961 message(STATUS)
 962
 963 LYX_OPTION_LIST_ALL(used)
 964
 965
 966 if(LYX_NLS)
 967         message(STATUS)
 968         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 969         message(STATUS)
 970         message(STATUS "  * iconv")
 971         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
 972         message(STATUS "     - library: ${ICONV_LIBRARY}")
 973         message(STATUS "  * zlib")
 974         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
 975         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 976         message(STATUS)
 977 endif()
 978
 979 # Apple has builtin native spell checker,
 980 # no need to warn for missing Aspell, Hunspell or Enchant
 981 if(NOT Spelling_FOUND AND NOT APPLE)
 982   if(LYX_REQUIRE_SPELLCHECK)
 983     set(_mode "FATAL_ERROR")
 984   else()
 985     set(_mode "STATUS")
 986   endif()
 987   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
 988 endif()
 989
 990 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 991
 992 if(ENABLE_DIST)
 993   # Use git to create the source package
 994   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 995   if(UNIX)
 996     set(DIST_FORMAT tgz)
 997   else()
 998     set(DIST_FORMAT zip)
 999   endif()
1000   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1001
1002   add_custom_command(
1003     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1004     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1005     WORKING_DIRECTORY ${TOP_SRC_DIR})
1006   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1007 endif()
1008
1009 # Last directory to be included so that the fixup code (OS X)
1010 # can be run last
1011 add_subdirectory(development/cmake/post_install)
1012
1013 message(STATUS)