CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9
  10 set(LYX_PROJECT lyx)
  11
  12 set(LYX_CMAKE_DIR "development/cmake")
  13 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  14
  15 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  16 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  17
  18 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  19
  20 message(STATUS)
  21 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  22         message(STATUS "Building in-source")
  23         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  24 else()
  25         message(STATUS "Building out-of-source")
  26         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  27 endif()
  28
  29
  30 if(COMMAND cmake_policy)
  31         cmake_policy(SET CMP0003 OLD)
  32         cmake_policy(SET CMP0005 OLD)
  33 endif()
  34
  35 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  36
  37 # Supress regeneration
  38 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  39
  40 if(NOT help AND NOT HELP)
  41         # 'project' triggers the searching for a compiler
  42         project(${LYX_PROJECT})
  43 endif()
  44
  45 if(UNIX)
  46         set(ARCH_TRIPLET )
  47         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  48         if(DPKG_ARCHITECTURE_EXECUTABLE)
  49                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  50                                 OUTPUT_VARIABLE ARCH_TRIPLET
  51                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  52                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  53         endif()
  54 endif()
  55 if(ARCH_TRIPLET)
  56         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  57 else()
  58         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  59 endif()
  60
  61 include(LyXMacros)
  62
  63 # Usage LYX_OPTION
  64 # 1. parameter: option name without prefix 'LYX_'
  65 # 2. parameter: description
  66 # 3. parameter: default value, ON or OFF
  67 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  68
  69
  70 LYX_OPTION_INIT()
  71
  72 # Options for all compilers/systems
  73 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  74 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  75 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  76 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  77 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  78 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  79 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  80 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  81 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  82 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  83 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  84 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  85 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  86 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  87 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  88 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  89 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  90 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  91
  92 # GCC specific
  93 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  94 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  95 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  96 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  97 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  98 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  99 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 100
 101 # MSVC specific
 102 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 103 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 104 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 105 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 106 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 107
 108 # APPLE specific
 109 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 110 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 111
 112
 113 if(help OR HELP)
 114         message(STATUS)
 115         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 116         message(STATUS)
 117         LYX_OPTION_LIST_ALL(help)
 118         message(STATUS)
 119         RETURN()
 120 endif()
 121
 122 # Check option dependencies
 123
 124 if(LYX_CPACK)
 125         set(LYX_INSTALL ON)
 126 endif()
 127
 128 if(LYX_DMG)
 129         set(LYX_BUNDLE ON)
 130         set(LYX_CPACK ON)
 131 endif()
 132
 133 if(LYX_INSTALL)
 134         set(LYX_NLS ON)
 135         if (WIN32)
 136                 set(LYX_HUNSPELL ON)
 137         endif()
 138         set(LYX_CONSOLE OFF)
 139         set(LYX_PACKAGE_SUFFIX ON)
 140         set(LYX_RELEASE ON)
 141         set(LYX_PROFILE OFF)
 142 endif()
 143
 144
 145 if(LYX_MERGE_FILES)
 146         set(LYX_PCH OFF)
 147 else()
 148         set(LYX_MERGE_REBUILD OFF)
 149 endif()
 150
 151 if(LYX_DEPENDENCIES_DOWNLOAD)
 152         message(STATUS)
 153         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 154         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 155         set(deps_files lyx20-deps-msvc2010-x86.zip)
 156         foreach(it ${deps_files})
 157                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 158                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 159                 if(NOT already_downloaded)
 160                         message(STATUS "Downloading ${it} ...")
 161                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 162                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 163                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 164                 endif()
 165         endforeach()
 166         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 167 endif()
 168
 169
 170
 171 message(STATUS)
 172
 173 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 174 if(WIN32)
 175         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 176 else()
 177         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 178 endif()
 179
 180
 181 if(UNIX OR MINGW)
 182         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 183         message(STATUS "Using GCC version ${GCC_VERSION}")
 184         if(NOT GCC_VERSION VERSION_LESS 4.4)
 185                 set(LYX_USE_TR1 1)
 186                 # GCC <= 4.5 does not support regex: there are linker errors
 187                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 188                 set(LYX_USE_TR1_REGEX 0)
 189         endif()
 190 else()
 191         if(MSVC10)
 192                 set(LYX_USE_TR1 1)
 193                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 194         endif()
 195 endif()
 196
 197
 198 set(VERSION_INFO "CMake Build")
 199
 200 # Try to get some informations from configure.ac
 201
 202 include(LyXPaths)
 203 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 204
 205 if(WIN32)
 206         set(USE_WINDOWS_PACKAGING ON)
 207 elseif(APPLE)
 208         set(USE_MACOSX_PACKAGING ON)
 209 else()
 210         set(USE_POSIX_PACKAGING ON)
 211 endif()
 212
 213 macro(setstripped _varname _value)
 214         string(STRIP ${_value} _v)
 215         if(USE_POSIX_PACKAGING)
 216                 string(TOLOWER ${_v} ${_varname})
 217         else()
 218                 set(${_varname} ${_v})
 219         endif()
 220 endmacro(setstripped)
 221
 222 foreach(_c_l ${_config_lines} )
 223         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 224                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 225                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 226                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 227                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 228                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 229                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 230                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 231                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 232                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 233                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 234                 endif()
 235         endif()
 236         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 237                 set(LYX_DATE "${CMAKE_MATCH_1}")
 238         endif()
 239 endforeach(_c_l)
 240
 241 # Find the revision number and for later use
 242 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 243 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 244 if(LYX_SVNVERSION)
 245         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 246         # We use this value also to set the package-patch-value
 247         if(LYX_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 248                 set(LYX_REVISION_VERSION ${CMAKE_MATCH_1})
 249         endif()
 250 else()
 251         set(LYX_REVISION_VERSION svn) #TODO use date
 252 endif()
 253
 254
 255 if(LYX_PROGRAM_SUFFIX)
 256         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 257 else()
 258         set(PROGRAM_SUFFIX "")
 259 endif()
 260
 261
 262 if(LYX_BUNDLE)
 263         set(LYX_CPACK ON)
 264         message(STATUS)
 265         message(STATUS "Bundle creation is enabled (experimental):")
 266         message(STATUS "    make")
 267         message(STATUS "    make install/strip")
 268         message(STATUS "    make package")
 269         if(APPLE)
 270                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 271                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 272                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 273                 if(NOT LYX_INSTALL_PREFIX)
 274                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 275                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 276                 endif()
 277         elseif(UNIX)
 278                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 279                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 280                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 281         elseif(WIN32)
 282                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 283         endif()
 284 endif()
 285
 286 if(LYX_INSTALL_PREFIX)
 287         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 288         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 289 endif()
 290 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 291
 292 if(LYX_PACKAGE_SUFFIX)
 293         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 294 else()
 295         set(PACKAGE ${PACKAGE_BASE})
 296 endif()
 297
 298
 299 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 300         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 301         if (UNIX)
 302                 # don't use the default "/usr/local"
 303                 # but respect the user-choice on the command-line
 304                 if(LYX_INSTALL_SUFFIX)
 305                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 306                 else()
 307                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 308                 endif()
 309         endif()
 310         if(WIN32)
 311                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 312         endif()
 313 endif()
 314 if(IS_ABSOLUTE)
 315         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 316 else()
 317         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 318 endif()
 319
 320
 321
 322 if(NOT LYX_DATA_SUBDIR)
 323         if (WIN32)
 324                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 325         else()
 326                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 327         endif()
 328 endif()
 329
 330 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 331 set(LYX_LOCALEDIR "locale")
 332 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 333 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 334
 335
 336 if(LYX_INSTALL AND WIN32)
 337         message(STATUS "Configuring NSIS files")
 338         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 339         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 340         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 341         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 342 endif()
 343
 344 if(NOT GROUP_CODE)
 345         #set(GROUP_CODE "The Golden Code")
 346         set(GROUP_CODE flat)
 347 endif()
 348
 349 # lyx's source files
 350 set(LYX_CPP_FILES *.cpp)
 351 set(LYX_HPP_FILES *.h)
 352 set(LYX_MOC_FILES moc_*.cpp)
 353
 354 include(ProjectSourceGroup)
 355
 356
 357 if(LYX_PROFILE)
 358         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 359         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 360 endif()
 361
 362
 363 if(LYX_NO_OPTIMIZE)
 364         set(CMAKE_BUILD_TYPE None)
 365         set(LYX_DEBUG OFF)
 366         set(LYX_RELEASE OFF)
 367 elseif(LYX_RELEASE)
 368         set(CMAKE_BUILD_TYPE Release)
 369         set(LYX_DEBUG OFF)
 370 else()
 371         set(CMAKE_BUILD_TYPE Debug)
 372 endif()
 373
 374
 375 # When shared libs are supported enable this option
 376 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 377 if(LYX_SHARED_LIBRARIES)
 378         set(library_type SHARED)
 379 else()
 380         set(library_type STATIC)
 381 endif()
 382
 383 if(NOT MSVC)
 384         if(NOT LYX_QUIET)
 385                 set(CMAKE_VERBOSE_MAKEFILE ON)
 386         endif()
 387         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 388         if(LYX_STDLIB_DEBUG)
 389                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 390         endif()
 391         if(LYX_CONCEPT_CHECKS)
 392                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 393         endif()
 394         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 395         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 396         if(MINGW)
 397                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 398         else()
 399                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 400         endif()
 401         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 402 endif()
 403
 404
 405 find_package(Qt4 REQUIRED)
 406
 407
 408 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 409
 410 if(LYX_ASPELL)
 411         find_package(ASPELL)
 412         include_directories(${ASPELL_INCLUDE_DIR})
 413 endif()
 414
 415 if(LYX_ENCHANT)
 416         find_package(Enchant REQUIRED)
 417         include_directories(${ENCHANT_INCLUDE_DIR})
 418 endif()
 419
 420 if(LYX_HUNSPELL)
 421         find_package(Hunspell REQUIRED)
 422         include_directories(${HUNSPELL_INCLUDE_DIR})
 423 endif()
 424
 425 if(LYX_NLS)
 426         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 427         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 428                 message(FATAL_ERROR "Python 2.6 needed!")
 429         endif()
 430         find_package(LyXGettext REQUIRED)
 431         include_directories(${TOP_SRC_DIR}/po)
 432         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 433 endif()
 434
 435 if(LYX_NLS)
 436         if(LYX_EXTERNAL_LIBINTL)
 437                 find_package(Libintl REQUIRED)
 438                 if(DEFINED LIBINTL_LIBRARIES)
 439                         # find getext when configuring
 440                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 441                         # on mac use iconv also form ports
 442                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 443                 endif()
 444         else()
 445                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 446         endif()
 447 endif()
 448
 449 find_package(ICONV REQUIRED)
 450 find_package(ZLIB REQUIRED)
 451
 452 if(LYX_EXTERNAL_BOOST)
 453         message(STATUS "Searching for boost")
 454         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 455         if(Boost_FOUND)
 456                 message(STATUS "Boost found")
 457                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 458                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 459         else()
 460                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 461         endif()
 462 else()
 463         if(LYX_USE_TR1_REGEX)
 464                 set(Lyx_Boost_Libraries boost_signals)
 465         else()
 466                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 467         endif()
 468         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 469         include_directories(${TOP_SRC_DIR}/boost)
 470         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 471 endif()
 472
 473
 474
 475
 476 if(WIN32)
 477         if(NOT LYX_CONSOLE)
 478                 set(WIN32_CONSOLE WIN32)
 479                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 480         endif()
 481         if(MSVC)
 482                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 483                 # disable checked iterators for msvc release builds to get maximum speed
 484                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 485         else()
 486                 add_definitions(-DWINVER=0x0500)
 487         endif()
 488 endif()
 489
 490 message(STATUS "")
 491 foreach(_v PACKAGE PACKAGE_VERSION
 492         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 493         LYX_ABS_TOP_SRCDIR
 494         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 495         if(NOT DEFINED ${_v})
 496                 message(FATAL_ERROR "${_v} not defined")
 497         endif()
 498         string(SUBSTRING "${_v}                            " 0 28 _v1)
 499         message(STATUS "----- ${_v1}: ${${_v}}")
 500 endforeach(_v)
 501 message(STATUS "")
 502
 503
 504 if(LYX_PCH)
 505         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 506         # Not sure if it works for all non-msvc compilers
 507         include(PCHSupport_26)
 508         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 509         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 510         add_definitions(-DLYX_ENABLE_PCH)
 511
 512         if(MSVC)
 513                 macro(lyx_add_msvc_pch name_)
 514                         set_source_files_properties(${${name_}_sources} PROPERTIES
 515                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 516                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 517                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 518                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 519                                 ${TOP_BINARY_DIR}/pcheaders.h)
 520                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 521                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 522                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 523                 endmacro(lyx_add_msvc_pch)
 524                 macro(lyx_add_gcc_pch name_)
 525                 endmacro()
 526         else()
 527                 macro(lyx_add_msvc_pch name_)
 528                 endmacro()
 529                 macro(lyx_add_gcc_pch name_)
 530                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 531                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 532                 endmacro()
 533         endif()
 534 else()
 535         macro(lyx_add_msvc_pch)
 536         endmacro(lyx_add_msvc_pch)
 537         macro(lyx_add_gcc_pch name_)
 538         endmacro()
 539 endif()
 540
 541
 542 if(MSVC)
 543
 544         if(LYX_VLD)
 545                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 546                 add_subdirectory(${vld_path}/cmake)
 547                 include(${vld_path}/cmake/vld.cmake) # forced include
 548                 set(vld_dll vld)
 549         endif()
 550
 551         if(LYX_WALL)
 552                 # Use the highest warning level
 553                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 554
 555                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 556                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 557                 else()
 558                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 559                 endif()
 560
 561                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 562                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 563                 else()
 564                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 565                 endif()
 566
 567                 # add here warnings which should produce an error /weXXXX
 568                 set(MSVC_W_ERROR   "/we4101 /we4189")
 569                 # add here warnings which should be disabled /wdXXXX
 570                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 571
 572                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 573                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 574                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 575
 576         else()
 577                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 578
 579                 # add here warnings which should produce an error /weXXXX
 580                 set(MSVC_W_ERROR   "/we4101 /we4189")
 581                 # add here warnings which should be disabled /wdXXXX
 582                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 583
 584                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 585                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 586                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 587
 588         endif()
 589         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 590         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 591         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 592
 593         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 594         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 595         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 596         message(STATUS "")
 597 endif()
 598
 599
 600 if(LYX_DEBUG_GLIBC)
 601         set(_GLIBCXX_DEBUG ON)
 602 endif()
 603
 604 if(LYX_DEBUG_GLIBC_PEDANTIC)
 605         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 606 endif()
 607
 608 # compiler tests, config.h generation
 609 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 610         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 611 else()
 612         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 613         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 614 endif()
 615
 616 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 617
 618
 619 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 620 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 621 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 622
 623
 624 if(LYX_INSTALL)
 625         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 626                 message(STATUS "Python required to create doc!")
 627         else()
 628                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 629                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 630         endif()
 631         include(../Install)
 632 endif()
 633
 634 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 635
 636 message(STATUS)
 637 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 638 message(STATUS)
 639 LYX_OPTION_LIST_ALL(used)
 640
 641
 642 if(LYX_NLS)
 643         message(STATUS)
 644         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 645         message(STATUS)
 646         message(STATUS "  * intl")
 647         message(STATUS "     - header : ${LIBINTL_HEADER}")
 648         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 649         message(STATUS "  * iconv")
 650         message(STATUS "     - header : ${ICONV_HEADER}")
 651         message(STATUS "     - library: ${ICONV_LIBRARY}")
 652         message(STATUS "  * zlib")
 653         message(STATUS "     - header : ${ZLIB_HEADER}")
 654         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 655         message(STATUS)
 656 endif()
 657
 658 include("${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyxPackaging.cmake")
 659
 660 message(STATUS)