CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 # Instruct cmake to not use gnu extensions,
  12 # this prevents the mix of '-std=c++*' and '-std=gnu++*' flags
  13 set(CMAKE_CXX_EXTENSIONS OFF)
  14
  15 enable_testing()
  16
  17 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README REALPATH) # Resolve symlinks
  18 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  19 message(STATUS "TOP_SRC_DIR = ${TOP_SRC_DIR}")
  20
  21 set(LYX_CMAKE_DIR "development/cmake")
  22 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  23 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  24 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  25
  26 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  27
  28 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  29
  30 message(STATUS)
  31 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  32         message(STATUS "Building in-source")
  33         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  34 else()
  35         message(STATUS "Building out-of-source")
  36         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  37 endif()
  38
  39 # This directory should be used if some test uses lyx-executable
  40 set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
  41 file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
  42
  43 if(COMMAND cmake_policy)
  44         # Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION
  45         cmake_policy(SET CMP0006 NEW)
  46         if(POLICY CMP0043)
  47                 # COMPILE_DEFINITIONS are not used yet. Enable new behavior.
  48                 cmake_policy(SET CMP0043 NEW)
  49         endif()
  50         cmake_policy(SET CMP0020 NEW)
  51 endif()
  52
  53 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  54
  55 # Supress regeneration
  56 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  57
  58 if(LYX_XMINGW)
  59     set(CMAKE_SYSTEM_NAME Windows)
  60     set(TOOLNAME ${LYX_XMINGW})
  61     set(TOOLCHAIN "${TOOLNAME}-")
  62     set(CMAKE_C_COMPILER   "${TOOLCHAIN}gcc"     CACHE PATH "Mingw C compiler" FORCE)
  63     set(CMAKE_CXX_COMPILER "${TOOLCHAIN}g++"     CACHE PATH "Mingw C++ compiler" FORCE)
  64     set(CMAKE_RC_COMPILER  "${TOOLCHAIN}windres" CACHE PATH "Mingw rc compiler" FORCE)
  65
  66     set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
  67     set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  68     set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  69 endif()
  70
  71 if(NOT help AND NOT HELP)
  72   # 'project' triggers the searching for a compiler
  73   project(${LYX_PROJECT})
  74   if (CMAKE_COMPILER_IS_GNUCXX)
  75     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
  76       message(STATUS "Gnu CXX compiler version = ${CMAKE_CXX_COMPILER_VERSION}")
  77       message(STATUS "is too old, should be >= 4.0")
  78       message(FATAL_ERROR "Exiting")
  79     endif()
  80   endif()
  81 endif()
  82
  83 if(UNIX)
  84         set(ARCH_TRIPLET )
  85         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  86         if(DPKG_ARCHITECTURE_EXECUTABLE)
  87                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  88                                 OUTPUT_VARIABLE ARCH_TRIPLET
  89                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  90                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  91         endif()
  92 endif()
  93 if(ARCH_TRIPLET)
  94         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  95 else()
  96         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  97 endif()
  98
  99 include(LyXMacros)
 100 include(LyXDestinations)
 101
 102 # Usage LYX_OPTION
 103 # 1. parameter: option name without prefix 'LYX_'
 104 # 2. parameter: description
 105 # 3. parameter: default value, ON or OFF
 106 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
 107
 108 # Usage LYX_COMBO
 109 # 1. parameter: name without prefix 'LYX_'
 110 # 2. parameter: description
 111 # 3. parameter: default value
 112 # 4-n parameter: possible other string values
 113
 114 LYX_OPTION_INIT()
 115
 116 # Options for all compilers/systems
 117 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
 118 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
 119 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
 120 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
 121 LYX_OPTION(REQUIRE_SPELLCHECK "Abort if no spellchecker available" OFF ALL)
 122 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
 123 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
 124 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
 125 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
 126 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
 127 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
 128 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
 129 LYX_STRING(SUFFIX_VALUE     "Use this string as suffix" "")
 130 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
 131 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
 132 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
 133 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
 134 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
 135 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
 136 LYX_OPTION(ENABLE_URLTESTS  "Enable for URL tests" OFF ALL)
 137 LYX_OPTION(ENABLE_EXPORT_TESTS "Enable for export tests" OFF ALL)
 138 LYX_OPTION(ENABLE_KEYTESTS  "Enable for keytests" OFF ALL)
 139 LYX_OPTION(ASAN             "Use address sanitizer" OFF ALL)
 140 LYX_COMBO(USE_FILEDIALOG    "Use native or QT file dialog" QT NATIVE)
 141 LYX_COMBO(USE_QT            "Use Qt version as frontend" AUTO QT4 QT5)
 142 #LYX_OPTION(3RDPARTY_BUILD   "Build 3rdparty libs" OFF ALL)
 143 LYX_OPTION(EXTERNAL_Z       "OFF := Build 3rdparty lib zlib" ON ALL)
 144 LYX_OPTION(EXTERNAL_ICONV   "OFF := Build 3rdparty lib iconvlib" ON ALL)
 145 LYX_OPTION(EXTERNAL_HUNSPELL "OFF := Build 3rdparty lib hunspelllib" ON ALL)
 146 LYX_COMBO(EXTERNAL_MYTHES   "OFF := Build 3rdparty lib mytheslib" AUTO OFF ON)
 147
 148 # GCC specific
 149 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
 150 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 151 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 152 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 153 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 154 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 155 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 156
 157 # MSVC specific
 158 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
 159 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 160 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 161 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 162
 163 # APPLE specific
 164 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 165 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 166
 167
 168 if(help OR HELP)
 169         message(STATUS)
 170         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 171         message(STATUS)
 172         LYX_OPTION_LIST_ALL(help)
 173         message(STATUS)
 174         RETURN()
 175 endif()
 176
 177 # Check option dependencies
 178
 179 if(LYX_DMG)
 180         set(LYX_BUNDLE ON)
 181         set(LYX_CPACK ON)
 182 endif()
 183
 184 if(LYX_CPACK)
 185         set(LYX_INSTALL ON)
 186 endif()
 187
 188 if(LYX_INSTALL)
 189         set(LYX_NLS ON)
 190         if(WIN32 AND NOT MINGW)
 191                 set(LYX_HUNSPELL ON)
 192         endif()
 193         set(LYX_PACKAGE_SUFFIX ON)
 194         if(NOT LYX_DEBUG)
 195                 set(LYX_RELEASE ON)
 196         endif()
 197         set(LYX_PROFILE OFF)
 198 endif()
 199
 200
 201 if(LYX_MERGE_FILES)
 202         set(LYX_PCH OFF)
 203 else()
 204         set(LYX_MERGE_REBUILD OFF)
 205 endif()
 206
 207 if(LYX_DEPENDENCIES_DOWNLOAD)
 208         message(STATUS)
 209         if(MSVC14)
 210                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2015-deps)
 211                 set(deps_files lyx-windows-deps-msvc2015.zip)
 212                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 213                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2015)
 214         elseif(MSVC10)
 215                 set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 216                 set(deps_files lyx-windows-deps-msvc2010.zip)
 217                 set(deps_server http://ftp.lyx.de/LyX-Windows-Deps)
 218                 set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/lyx-windows-deps-msvc2010)
 219         else()
 220                 message(FATAL_ERROR "error: no dependency package known for the selected MSVC version.")
 221         endif()
 222     message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 223         foreach(it ${deps_files})
 224                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 225                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 226                 if(NOT already_downloaded)
 227                         message(STATUS "Downloading ${it} ...")
 228                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 229                         list(GET status 0 status_code)
 230                         list(GET status 1 status_string)
 231                         if(NOT status_code EQUAL 0)
 232                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 233                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 234                         endif()
 235                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 236                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 237                 endif()
 238         endforeach()
 239 endif()
 240
 241
 242
 243 message(STATUS)
 244
 245 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 246 if(WIN32)
 247         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 248 else()
 249         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 250 endif()
 251
 252
 253 # Set to some meaningful default
 254 find_package(CXX11Compiler)
 255 if(NOT CXX11COMPILER_FOUND)
 256         message(FATAL_ERROR "A C++11 compatible compiler is required.")
 257 endif()
 258 set(LYX_GCC11_MODE)
 259 if(UNIX OR MINGW)
 260         if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
 261           # ignore the GCC_VERSION for clang
 262           # and use the resulting CXX11_STD_REGEX found in FindCXX11Compiler.cmake
 263           message(STATUS "Using clang")
 264           if(CXX11_STD_REGEX)
 265             set(LYX_USE_STD_REGEX 1)
 266           else()
 267             set(LYX_USE_STD_REGEX 0)
 268           endif()
 269         else()
 270           execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
 271           message(STATUS "Using GCC version ${GCC_VERSION}")
 272           if(GCC_VERSION VERSION_LESS 4.9)
 273                   if(GCC_VERSION VERSION_LESS 4.6)
 274                           message(FATAL_ERROR "gcc >= 4.6 is required.")
 275                   endif()
 276                   # <regex> in gcc is unusable in versions less than 4.9.0
 277                   # see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 278                   set(LYX_USE_STD_REGEX 0)
 279           else()
 280                   set(LYX_USE_STD_REGEX 1)
 281           endif()
 282         endif()
 283         set(LYX_GCC11_MODE "${CXX11_FLAG}")
 284 else()
 285         set(LYX_USE_STD_REGEX 0)
 286 #       if(MSVC10)
 287 #               set(LYX_USE_STD_REGEX 1) #TODO should we use it in ECMAScript mode?
 288 #       endif()
 289 endif()
 290
 291
 292 set(VERSION_INFO "CMake Build")
 293
 294 # Try to get some informations from configure.ac
 295
 296 include(LyXPaths)
 297 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 298
 299 if(WIN32)
 300         set(CMAKE_PREFIX_PATH Specify-path-to-Qt CACHE PATH "Used Qt version")
 301         if(MSVC)
 302                 set(LYX_3RDPARTY_BUILD ON CACHE BOOL "Build 3rdparty libraries" FORCE)
 303         endif()
 304         set(USE_WINDOWS_PACKAGING ON)
 305 elseif(APPLE)
 306         set(USE_MACOSX_PACKAGING ON)
 307 else()
 308         set(USE_POSIX_PACKAGING ON)
 309 endif()
 310
 311 if(LYX_3RDPARTY_BUILD)
 312   # LYX_3RDPARTY_BUILD is not cached anymore, but for compatibility reasons
 313   # this enables the build of all 3rd_party libs
 314   set(LYX_EXTERNAL_Z        OFF CACHE BOOL "Build 3rdparty lib zlib"    FORCE)
 315   set(LYX_EXTERNAL_ICONV    OFF CACHE BOOL "Build 3rdparty iconvlib"    FORCE)
 316   set(LYX_EXTERNAL_HUNSPELL OFF CACHE BOOL "Build 3rdparty hunspelllib" FORCE)
 317   set(LYX_EXTERNAL_MYTHES   OFF CACHE STRING "Build 3rdparty mytheslib" FORCE)
 318 endif()
 319
 320 macro(setstripped _varname)
 321         if(${ARGC} GREATER 1)
 322                 string(STRIP "${ARGV1}" _v)
 323                 if(USE_POSIX_PACKAGING)
 324                         string(TOLOWER ${_v} ${_varname})
 325                 else()
 326                         set(${_varname} ${_v})
 327                 endif()
 328         else()
 329                 set(${_varname})
 330         endif()
 331 endmacro(setstripped)
 332
 333 foreach(_c_l ${_config_lines} )
 334         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 335                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 336                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 337                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 338                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 339                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 340                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 341                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 342                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 343                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 344                         if ("${LYX_SUFFIX_VALUE}" MATCHES "")
 345                           set(LYX_INSTALL_SUFFIX "${LYX_MAJOR_VERSION}.${LYX_MINOR_VERSION}")
 346                         else()
 347                           set(LYX_INSTALL_SUFFIX "${LYX_SUFFIX_VALUE}")
 348                         endif()
 349                 endif()
 350         endif()
 351         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 352                 set(LYX_DATE "${CMAKE_MATCH_1}")
 353         endif()
 354 endforeach(_c_l)
 355
 356 FIND_PROGRAM(LYX_GITVERSION git)
 357 #message(STATUS "gitversion = ${LYX_GITVERSION}")
 358 set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 359 set(LYX_PACKAGE_RELEASE "1")
 360 if(LYX_GITVERSION)
 361   if (LYX_LOCALVERSIONING)
 362     # Find the revision number and for later use
 363     EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} describe --match 2.0.0 HEAD
 364       WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE tmp_LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 365     if (tmp_LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-\(.*\)$")
 366       set(LYX_PACKAGE_RELEASE ${CMAKE_MATCH_2})
 367       # We will add offset of 40000 to get appropriate value to
 368       # previous svn.
 369       # We use this value than also to set the package-patch-value
 370       MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 371       set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 372       set(ENABLE_DIST ON)
 373     endif()
 374   endif()
 375 endif()
 376
 377 # Set the programs (lyx, tex2lyx, etc.) suffix
 378 # When building an OS X bundle, we will append
 379 # the suffix only to the bundle, not to the programs
 380 set(PROGRAM_SUFFIX "")
 381 if(LYX_PROGRAM_SUFFIX AND NOT (APPLE AND LYX_BUNDLE))
 382         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 383 endif()
 384 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 385 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 386 set(_convert lyxconvert${PROGRAM_SUFFIX})
 387
 388 add_custom_target(lyx_version ALL
 389   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 390   )
 391 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 392
 393 # Default paths for installed utilities (tex2lyx, lyxclient, etc.)
 394 set(LYX_UTILITIES_INSTALL_PATH bin)
 395
 396 if(LYX_BUNDLE)
 397         set(LYX_CPACK ON)
 398
 399         message(STATUS)
 400         message(STATUS "Bundle creation is enabled (experimental):")
 401         message(STATUS "    make")
 402         message(STATUS "    make install/strip")
 403         message(STATUS "    make package")
 404         if(APPLE)
 405                 set(MACOSX_BUNDLE TRUE)
 406                 # This sets the bundle + executable names
 407                 set(_lyx "${PACKAGE_BASE}${LYX_INSTALL_SUFFIX}")
 408                 # This sets the Info.plist executable name
 409                 set(osx_bundle_program_name ${_lyx})
 410                 # Bundle name
 411                 set(LYX_BUNDLE_NAME ${_lyx})
 412
 413                 # This will contain the list of files that need to be included
 414                 # in the bundle and their location within the bundle
 415                 set(OSX_BUNDLE_FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.sdef;${TOP_SRC_DIR}/development/MacOSX/LyXapp.icns;${CMAKE_BINARY_DIR}/lyxrc.dist")
 416                 set(OSX_BUNDLE_DIRS "Resources;Resources;Resources")
 417
 418                 # Process Info.plist and lyxrc.dist
 419                 # See development/cmake/Install.cmake
 420                 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 421
 422                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 423                 set(LYX_DATA_SUBDIR ${LYX_BUNDLE_NAME}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 424
 425                 # Variables used by CPack
 426                 set(CPACK_BUNDLE_NAME ${LYX_BUNDLE_NAME})
 427                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 428                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${LYX_BUNDLE_NAME}.app)
 429
 430                 # Set the install paths
 431                 set(LYX_UTILITIES_INSTALL_PATH ${LYX_BUNDLE_NAME}.app/Contents/MacOS)
 432                 if(NOT LYX_INSTALL_PREFIX)
 433                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 434                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 435                 endif()
 436                 # Change the owner so that the install can work
 437                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)" COMPONENT Runtime)
 438         elseif(UNIX)
 439                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 440                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 441                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 442         elseif(WIN32)
 443                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 444         endif()
 445 endif()
 446
 447 if(LYX_INSTALL_PREFIX)
 448         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 449         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 450 endif()
 451 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 452
 453 if(UNIX)
 454   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}/share")
 455 elseif(CMAKE_INSTALL_PREFIX MATCHES "/lyx${LYX_INSTALL_SUFFIX}$")
 456   string(REGEX REPLACE "/lyx${LYX_INSTALL_SUFFIX}$" "/share" SYSTEM_DATADIR ${CMAKE_INSTALL_PREFIX})
 457 else()
 458   set(SYSTEM_DATADIR "${CMAKE_INSTALL_PREFIX}")
 459 endif()
 460
 461 if(CMAKE_COMPILER_IS_GNUCXX)
 462   message(STATUS "CMAKE_COMPILER_IS_GNUCXX = ${CMAKE_COMPILER_IS_GNUCXX}")
 463   set(suffixing ${LYX_PROGRAM_SUFFIX})
 464 else()
 465   # Not a GCC compiler, programs do not have a suffix
 466   set(suffixing ${LYX_PACKAGE_SUFFIX})
 467 endif()
 468
 469 # The define PACKAGE below allows lyx-executable to find its default configuration files
 470 # see routines
 471 #    Package::messages_file()
 472 #    get_default_user_support_dir()
 473 #    relative_system_support_dir()
 474 # in src/support/Package.cpp
 475 #
 476 if(suffixing)
 477         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 478 else()
 479         set(PACKAGE ${PACKAGE_BASE})
 480 endif()
 481
 482 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 483         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 484         if (UNIX)
 485                 # use the default "/usr/local"
 486                 # but respect the user-choice on the command-line
 487                 set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "LyX default install prefix" FORCE)
 488         endif()
 489 endif()
 490 if(WIN32)
 491         set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 492 endif()
 493 if(IS_ABSOLUTE)
 494         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 495 else()
 496         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 497 endif()
 498
 499
 500
 501 if(NOT LYX_DATA_SUBDIR)
 502         if (WIN32)
 503                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 504         else()
 505                 set(LYX_DATA_SUBDIR "share/${_lyx}/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 506         endif()
 507 endif()
 508
 509 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 510 get_locale_destination(LYX_LOCALEDIR)
 511 set(LYX_ABS_INSTALLED_LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${LYX_LOCALEDIR}")
 512 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 513
 514 if(LYX_BUNDLE AND APPLE)
 515         set(LYX_MAN_DIR "${LYX_DATA_SUBDIR}" CACHE STRING "Install location for man pages.")
 516 else()
 517         if(WIN32)
 518                 set(LYX_MAN_DIR "${CMAKE_BINARY_DIR}/usr/local/man" CACHE STRING "Install location for man pages.")
 519         elseif(UNIX)
 520                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE STRING "Install location for man pages.")
 521         else()
 522                 set(LYX_MAN_DIR "${CMAKE_INSTALL_PREFIX}/man" CACHE STRING "Install location for man pages.")
 523         endif()
 524 endif()
 525 mark_as_advanced(LYX_MAN_DIR)
 526
 527 # The Win installer cannot be built by CMake because one needs to install plugins for NSIS
 528 # see the Readme.txt of the installer
 529 #if(LYX_INSTALL AND WIN32)
 530 #       message(STATUS "Configuring NSIS files")
 531 #       configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 532 #       configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 533 #       configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 534 #       message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 535 #endif()
 536
 537 if(NOT GROUP_CODE)
 538         #set(GROUP_CODE "The Golden Code")
 539         set(GROUP_CODE flat)
 540 endif()
 541
 542 # lyx's source files
 543 set(LYX_CPP_FILES [a-zA-Z]*.cpp)
 544 set(LYX_HPP_FILES [a-zA-Z]*.h)
 545 set(LYX_MOC_FILES moc_*.cpp)
 546
 547 include(ProjectSourceGroup)
 548
 549
 550 if(LYX_PROFILE AND NOT MSVC)
 551         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 552         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 553         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 554 else()
 555         set(LYX_PROFILE OFF)
 556 endif()
 557
 558
 559 if(LYX_NO_OPTIMIZE)
 560         set(CMAKE_BUILD_TYPE None)
 561         set(LYX_DEBUG OFF)
 562         set(LYX_RELEASE OFF)
 563         set(LYX_PROFILE OFF)
 564 elseif(LYX_RELEASE)
 565         set(CMAKE_BUILD_TYPE Release)
 566         set(LYX_DEBUG OFF)
 567         set(LYX_PROFILE OFF)
 568 elseif(LYX_PROFILE)
 569         set(CMAKE_BUILD_TYPE Profile)
 570         set(LYX_DEBUG OFF)
 571 else()
 572         set(CMAKE_BUILD_TYPE Debug)
 573         set(LYX_DEBUG ON)
 574 endif()
 575
 576
 577 # When shared libs are supported enable this option
 578 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 579 if(LYX_SHARED_LIBRARIES)
 580         set(library_type SHARED)
 581 else()
 582         set(library_type STATIC)
 583 endif()
 584
 585 if(NOT MSVC)
 586         if(NOT LYX_QUIET)
 587                 set(CMAKE_VERBOSE_MAKEFILE ON)
 588         endif()
 589         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 590         if(LYX_CXX_FLAGS MATCHES "\\+\\+(14|11|98)")
 591           # Thanks to Brad King <brad.king@kitware.com>
 592           # for the pointer to https://cmake.org/cmake/help/v3.6/variable/CMAKE_CXX_STANDARD.html
 593           # This allows us to use QT5.7 with recent g++ (version >= 4.9) compilers
 594           # and still use our own c++ extension tests
 595           set(CMAKE_CXX_STANDARD ${CMAKE_MATCH_1})
 596           message(STATUS "CMAKE_CXX_STANDARD set to ${CMAKE_CXX_STANDARD}")
 597         endif()
 598         if(LYX_STDLIB_DEBUG)
 599                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 600         endif()
 601         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 602         set(CMAKE_CXX_FLAGS_DEBUG "-O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 603         if(MINGW)
 604                 set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 605         else()
 606                 set(CMAKE_CXX_FLAGS_RELEASE "-O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 607         endif()
 608 endif()
 609
 610 set(LYX_CXX_FLAGS_EXTRA "" CACHE STRING "Desired semicolon separated list of extra cxx compile flags, like '-Werror'")
 611 mark_as_advanced(LYX_CXX_FLAGS_EXTRA)
 612 if(LYX_CXX_FLAGS_EXTRA)
 613         foreach(_flag ${LYX_CXX_FLAGS_EXTRA})
 614                 add_definitions(${_flag})
 615         endforeach()
 616 endif()
 617
 618 if(LYX_XMINGW)
 619         list(APPEND CMAKE_FIND_ROOT_PATH ${GNUWIN32_DIR})
 620 endif()
 621
 622 set(min_qt5_version "5.6")
 623 if(LYX_USE_QT MATCHES "AUTO")
 624         # try qt5 first
 625         find_package(Qt5Core QUIET)
 626         if(Qt5Core_FOUND)
 627                 set(LYX_USE_QT "QT5" CACHE STRING "Valid qt version" FORCE)
 628                 message(STATUS "Qt5Core_VERSION = ${Qt5Core_VERSION}")
 629                 if(Qt5Core_VERSION VERSION_LESS ${min_qt5_version})
 630                         find_package(Qt4 "4.5.0" QUIET)
 631                         if(QT4_FOUND)
 632                                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 633                         endif()
 634                 endif()
 635         else()
 636                 set(LYX_USE_QT "QT4" CACHE STRING "Valid qt version" FORCE)
 637         endif()
 638 endif()
 639 if(LYX_USE_QT MATCHES "QT5")
 640         # set QPA_XCB if QT uses X11
 641         find_package(Qt5Core REQUIRED)
 642         if (Qt5Core_FOUND)
 643                 find_package(Qt5Widgets REQUIRED)
 644                 if(APPLE)
 645                         find_package(Qt5MacExtras REQUIRED)
 646                 endif()
 647                 find_package(Qt5X11Extras QUIET)
 648                 find_package(Qt5WinExtras QUIET)
 649                 set(QTVERSION ${Qt5Core_VERSION})
 650                 if (QTVERSION VERSION_LESS ${min_qt5_version})
 651                         message(STATUS "QTVERSION = \"${QTVERSION}\"")
 652                         message(STATUS "This version is not recommended, try either option -DLYX_USE_QT=QT4 or")
 653                         message(STATUS "install QT-Version >= \"${min_qt5_version}\"")
 654                         # see thread in lyx-devel list
 655                         # From: Jean-Pierre Chrétien <jeanpierre.chretien@free.fr>
 656                         # Date 11.03.2017
 657                         # Subject: cmake compilation error
 658                         #message(FATAL_ERROR "Wrong Qt-Version")
 659                 endif()
 660                 macro (qt_use_modules)
 661                         qt5_use_modules(${ARGN})
 662                 endmacro()
 663                 macro (qt_add_resources)
 664                         qt5_add_resources(${ARGN})
 665                 endmacro()
 666                 macro (qt_wrap_uifiles)
 667                         qt5_wrap_ui(${ARGN})
 668                 endmacro()
 669                 message(STATUS "Found Qt-Version ${QTVERSION}")
 670                 if(WIN32)
 671                         set(LYX_QTMAIN_LIBRARY ${Qt5Core_QTMAIN_LIBRARIES})
 672                 endif()
 673         endif()
 674 elseif(LYX_USE_QT MATCHES "QT4")
 675         if(LYX_XMINGW)
 676                 set(QT_MINGW_DIR ${LYX_QT4} CACHE PATH "Qt for Mingw" FORCE)
 677                 list(APPEND CMAKE_FIND_ROOT_PATH ${QT_MINGW_DIR} ${GNUWIN32_DIR})
 678         endif()
 679         find_package(Qt4 "4.5.0" REQUIRED)
 680         macro (qt_use_modules)
 681         endmacro()
 682         macro (qt_add_resources)
 683                 qt4_add_resources(${ARGN})
 684         endmacro()
 685         macro (qt_wrap_uifiles)
 686                 qt4_wrap_ui(${ARGN})
 687         endmacro()
 688         set(LYX_QTMAIN_LIBRARY ${QT_QTSVG_LIBRARY})
 689         if(WIN32)
 690                 list(APPEND LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARIES})
 691         endif()
 692 else()
 693   message(FATAL_ERROR "Unhandled value for LYX_USE_QT (${LYX_USE_QT})")
 694 endif()
 695
 696 find_package(Magic)
 697 if(Magic_FOUND)
 698   set(HAVE_MAGIC_H 1)
 699   include_directories(${Magic_INCLUDE_DIR})
 700 endif()
 701
 702 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 703
 704 set(Spelling_FOUND OFF)
 705 set(Include_used_spellchecker)   # String will be inserted into config.h
 706
 707 if (LYX_EXTERNAL_MYTHES MATCHES "AUTO")
 708   # try system library first
 709   find_package(MyThesLIB)
 710   if (MYTHESLIB_FOUND)
 711     set(LYX_EXTERNAL_MYTHES ON CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 712   else()
 713     set(LYX_EXTERNAL_MYTHES OFF CACHE STRING "OFF:= Build 3rdparty mytheslib" FORCE)
 714   endif()
 715 endif()
 716 if (LYX_EXTERNAL_MYTHES MATCHES "ON")
 717   find_package(MyThesLIB REQUIRED)
 718 else()
 719   add_subdirectory(3rdparty/mythes)
 720 endif()
 721 set(MYTHES_DIR ${MYTHESLIB_INCLUDE_DIR})
 722
 723 if(NOT LYX_EXTERNAL_HUNSPELL)
 724     add_subdirectory(3rdparty/hunspell)
 725     add_definitions(-DHUNSPELL_STATIC)
 726     set(HUNSPELL_FOUND ON)
 727     message(STATUS "  * Hunspell:")
 728     message(STATUS "     - include: ${HUNSPELL_INCLUDE_DIR}")
 729     message(STATUS "     - library: ${HUNSPELL_LIBRARY}")
 730 endif()
 731
 732 foreach(_spell "ASPELL" "Enchant" "Hunspell")
 733   string(TOUPPER ${_spell} _upspell)
 734   if (NOT ${_upspell}_FOUND)
 735     find_package(${_spell})
 736   endif()
 737   if (${_upspell}_FOUND)
 738     include_directories(${${_upspell}_INCLUDE_DIR})
 739     set(Spelling_FOUND ON)
 740     message(STATUS "Building with USE_${_upspell}")
 741     set(Include_used_spellchecker "${Include_used_spellchecker}#define USE_${_upspell} 1\n")
 742   else()
 743     if(LYX_${_upspell})
 744       message(FATAL_ERROR "Required ${_spell} devel package not found")
 745     else()
 746       message(STATUS "${_upspell} not found, building without ${_spell} support")
 747     endif()
 748   endif()
 749 endforeach()
 750
 751 if(GNUWIN32_DIR)
 752         list(APPEND CMAKE_PROGRAM_PATH "${GNUWIN32_DIR}/Python" )
 753 endif()
 754
 755 # Search for python default version first
 756 unset(PYTHON_EXECUTABLE CACHE)
 757 unset(LYX_PYTHON_EXECUTABLE CACHE)
 758 unset(PYTHON_VERSION_MAJOR)
 759 unset(PYTHON_VERSION_MINOR)
 760 unset(PYTHON_VERSION_STRING)
 761 find_package(PythonInterp 3.3 QUIET)
 762 if(NOT PYTHONINTERP_FOUND)
 763   unset(PYTHON_EXECUTABLE CACHE)
 764   find_package(PythonInterp 2.0 REQUIRED)
 765   if(NOT PYTHON_VERSION_STRING VERSION_LESS 2.8)
 766     message(FATAL_ERROR "Python interpreter found, but is not suitable")
 767   endif()
 768 endif()
 769
 770 set(LYX_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "Python to be used by LyX")
 771
 772 if(LYX_NLS)
 773         find_package(LyXGettext)
 774         if(LYX_PYTHON_EXECUTABLE AND GETTEXT_FOUND)
 775                 add_subdirectory(po "${TOP_BINARY_DIR}/po")
 776         else()
 777                 # Install only supplied .gmo-files
 778                 file(GLOB _gmofiles RELATIVE "${TOP_SRC_DIR}/po" "${TOP_SRC_DIR}/po/*.gmo")
 779                 message(STATUS "Installing provided .gmo-files only")
 780                 foreach( _gmo ${_gmofiles})
 781                         string(REGEX REPLACE "\\.gmo$" "" _lang ${_gmo})
 782                         install(FILES "${TOP_SRC_DIR}/po/${_gmo}" DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${PACKAGE}.mo)
 783                 endforeach()
 784         endif()
 785 endif()
 786
 787 if(LYX_EXTERNAL_ICONV)
 788   find_package(ICONV REQUIRED)
 789 else()
 790   add_subdirectory(3rdparty/libiconv)
 791   set(HAVE_ICONV_CONST 1)
 792 endif()
 793
 794 if(LYX_EXTERNAL_Z)
 795   find_package(ZLIB REQUIRED)
 796 else()
 797   add_subdirectory(3rdparty/zlib)
 798 endif()
 799
 800 if(LYX_USE_STD_REGEX)
 801   # Set only include path.
 802   # Use internal boost, which is known to exist
 803   # we don't need any libraries
 804   set(Lyx_Boost_Libraries)
 805   add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 806   include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 807 else()
 808   # Using boost-regex
 809   if(LYX_EXTERNAL_BOOST)
 810     message(STATUS "Searching for external boost")
 811     find_package(Boost COMPONENTS regex)
 812     if(Boost_FOUND)
 813       message(STATUS "Boost found")
 814       message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 815       set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 816       if (LYX_STDLIB_DEBUG)
 817         # Comment from  Jean-Marc Lasgouttes:
 818         # In general, system boost libraries are incompatible with
 819         # the use of stdlib-debug in libstdc++. See ticket #9736 for
 820         # details.
 821         message(WARNING "Compiling LyX with stdlib-debug and system boost libraries may lead to crashes. Consider using '-DLYX_STDLIB_DEBUG=OFF' or using '-DLYX_EXTERNAL_BOOST=OFF'")
 822       endif()
 823     else()
 824       message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 825     endif()
 826   else()
 827     # Using included boost
 828     set(Lyx_Boost_Libraries boost_regex)
 829     add_definitions(-DBOOST_USER_CONFIG=<config.h>)
 830     include_directories(${TOP_SRC_DIR}/3rdparty/boost)
 831     add_subdirectory(3rdparty/boost "${TOP_BINARY_DIR}/3rdparty/boost")
 832   endif()
 833 endif()
 834
 835 if(WIN32)
 836         if(LYX_CONSOLE)
 837                 set(LYX_QTMAIN_LIBRARY)
 838         else()
 839                 set(WIN32_CONSOLE WIN32)
 840         endif()
 841         if(MSVC)
 842                 # -DPSAPI_VERSION=1 is needed to run on vista (bug 10186)
 843                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX -DPSAPI_VERSION=1)
 844                 # disable checked iterators for msvc release builds to get maximum speed
 845                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 846         else()
 847                 # -DPSAPI_VERSION=1 is not needed for mingw, since the mingw psapi.h
 848                 # does not use it and always declares the vista compatible API.
 849                 # If this ever changes then -DPSAPI_VERSION might be needed here as well.
 850                 add_definitions(-DWINVER=0x0500)
 851         endif()
 852 endif()
 853
 854 # Compute qt-version from ${QTVERSION}
 855
 856 message(STATUS "")
 857 foreach(_v PACKAGE PACKAGE_VERSION
 858         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 859         LYX_ABS_TOP_SRCDIR
 860         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 861         if(NOT DEFINED ${_v})
 862                 message(FATAL_ERROR "${_v} not defined")
 863         endif()
 864         string(SUBSTRING "${_v}                            " 0 28 _v1)
 865         message(STATUS "----- ${_v1}: ${${_v}}")
 866 endforeach(_v)
 867 message(STATUS "")
 868
 869
 870 if(LYX_PCH)
 871         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 872         # Not sure if it works for all non-msvc compilers
 873         include(PCHSupport_26)
 874         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 875         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 876         add_definitions(-DLYX_ENABLE_PCH)
 877
 878         if(MSVC)
 879                 macro(lyx_add_msvc_pch name_)
 880                         set_source_files_properties(${${name_}_sources} PROPERTIES
 881                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 882                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 883                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 884                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 885                                 ${TOP_BINARY_DIR}/pcheaders.h)
 886                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 887                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT")
 888                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 889                 endmacro(lyx_add_msvc_pch)
 890                 macro(lyx_add_gcc_pch name_)
 891                 endmacro()
 892         else()
 893                 macro(lyx_add_msvc_pch name_)
 894                 endmacro()
 895                 macro(lyx_add_gcc_pch name_)
 896                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT)
 897                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 898                 endmacro()
 899         endif()
 900 else()
 901         macro(lyx_add_msvc_pch)
 902         endmacro(lyx_add_msvc_pch)
 903         macro(lyx_add_gcc_pch name_)
 904         endmacro()
 905 endif()
 906
 907
 908 if(MSVC)
 909
 910         if(LYX_VLD)
 911                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 912                 add_subdirectory(${vld_path}/cmake)
 913                 include(${vld_path}/cmake/vld.cmake) # forced include
 914                 set(vld_dll vld)
 915         endif()
 916
 917         if(LYX_WALL)
 918                 # Use the highest warning level
 919                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 920
 921                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 922                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 923                 else()
 924                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 925                 endif()
 926
 927                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 928                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 929                 else()
 930                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 931                 endif()
 932
 933                 # add here warnings which should produce an error /weXXXX
 934                 set(MSVC_W_ERROR   "/we4101 /we4189")
 935                 # add here warnings which should be disabled /wdXXXX
 936                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 937
 938                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 939                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 940                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 941
 942         else()
 943                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 944
 945                 # add here warnings which should produce an error /weXXXX
 946                 set(MSVC_W_ERROR   "/we4101 /we4189")
 947                 # add here warnings which should be disabled /wdXXXX
 948                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 949
 950                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 951                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 952                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 953
 954         endif()
 955
 956         if (NOT Qt5Core_FOUND)
 957                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 958                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 959                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 960         endif()
 961
 962         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 963         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 964         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 965         message(STATUS "")
 966 endif()
 967
 968
 969 if(LYX_DEBUG_GLIBC)
 970         set(_GLIBCXX_DEBUG ON)
 971 endif()
 972
 973 if(LYX_DEBUG_GLIBC_PEDANTIC)
 974         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 975 endif()
 976
 977 # Xcode compiler
 978 if (CMAKE_GENERATOR MATCHES Xcode)
 979         if (XCODE_VERSION VERSION_LESS "5.0")
 980                 # Automatically select the Xcode compiler if not set
 981                 if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 982                         # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 983                         if (XCODE_VERSION VERSION_GREATER "3.1")
 984                                 SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 985                         ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 986                 ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 987                 # Print the selected compiler version
 988         MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 989         ENDIF(XCODE_VERSION VERSION_LESS "5.0")
 990 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 991
 992 if (WIN32 AND Qt5Core_FOUND)
 993         set(Z_PREFIX 1)
 994 endif()
 995
 996 # compiler tests, config.h generation LYX_CONFIGURE_CHECKS
 997 include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 998 configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 999
1000 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
1001
1002 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
1003         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
1004 endif()
1005
1006 if (NOT HAVE_REGEX)
1007         set(LYX_USE_STD_REGEX 0)
1008 endif()
1009
1010
1011 set (cmd ${CMAKE_CTEST_COMMAND})
1012 if (MSVC)
1013         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
1014 else ()
1015         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
1016 endif ()
1017 add_custom_target (lyx_run_tests COMMAND ${cmd})
1018 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
1019
1020 if(LYX_ASAN)
1021     set(LYX_CXX_FLAGS "-fsanitize=address -fno-omit-frame-pointer -g")
1022     message(STATUS)
1023     message(STATUS "Address sanitizer enabled. Usage:")
1024     message(STATUS "    wget https://llvm.org/svn/llvm-project/compiler-rt/trunk/lib/asan/scripts/asan_symbolize.py")
1025     message(STATUS "    chmod  +x ./asan_symbolize.py")
1026     message(STATUS "    ./bin/lyx2.2 2>&1 | ./asan_symbolize.py  | c++filt ")
1027     message(STATUS)
1028 endif()
1029
1030 if(LYX_INSTALL)
1031         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
1032                 message(STATUS "Python required to create doc!")
1033         else()
1034                 if(UNIX)
1035                         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
1036                 endif()
1037                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
1038         endif()
1039 endif()
1040 include(../Install)
1041
1042 # By running the URL tests first, time can be saved when running the ctests in
1043 # parallel since the URL tests take a long time to run (e.g. 10 minutes).
1044 if(LYX_ENABLE_URLTESTS)
1045         add_subdirectory(development/checkurls "${TOP_BINARY_DIR}/checkurls")
1046 endif()
1047 add_subdirectory(src "${TOP_BINARY_DIR}/src")
1048 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
1049 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
1050 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
1051 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
1052 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
1053 add_subdirectory(development/batchtests "${TOP_BINARY_DIR}/batchtests")
1054
1055 message(STATUS)
1056 message(STATUS "Build params, switch LYX_* options by -DLYX_*=ON or OFF, LYX_* combos by -DLYX_*=value:")
1057 message(STATUS)
1058
1059 LYX_OPTION_LIST_ALL(used)
1060
1061
1062 if(LYX_NLS)
1063         message(STATUS)
1064         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
1065         message(STATUS)
1066         message(STATUS "  * iconv")
1067         message(STATUS "     - include: ${ICONV_INCLUDE_DIR}")
1068         message(STATUS "     - library: ${ICONV_LIBRARY}")
1069         message(STATUS "  * zlib")
1070         message(STATUS "     - include: ${ZLIB_INCLUDE_DIR}")
1071         message(STATUS "     - library: ${ZLIB_LIBRARY}")
1072         message(STATUS)
1073 endif()
1074
1075 # Apple has builtin native spell checker,
1076 # no need to warn for missing Aspell, Hunspell or Enchant
1077 if(NOT Spelling_FOUND AND NOT APPLE)
1078   if(LYX_REQUIRE_SPELLCHECK)
1079     set(_mode "FATAL_ERROR")
1080   else()
1081     set(_mode "STATUS")
1082   endif()
1083   message(${_mode} "No spellcheck libraries found. LyX will be unable use spellchecking")
1084 endif()
1085
1086 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
1087
1088 if(ENABLE_DIST)
1089   # Use git to create the source package
1090   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
1091   if(UNIX)
1092     set(DIST_FORMAT tgz)
1093   else()
1094     set(DIST_FORMAT zip)
1095   endif()
1096   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
1097
1098   add_custom_command(
1099     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
1100     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
1101     WORKING_DIRECTORY ${TOP_SRC_DIR})
1102   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
1103 endif()
1104
1105 # Last directory to be included so that the fixup code (OS X)
1106 # can be run last
1107 add_subdirectory(development/cmake/post_install)
1108
1109 message(STATUS)