CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT lyx)
  10
  11 set(LYX_CMAKE_DIR "development/cmake")
  12 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/${LYX_CMAKE_DIR}/modules")
  13
  14 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  15 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  16
  17 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  18
  19 message(STATUS)
  20 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  21         message(STATUS "Building in-source")
  22         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  23 else()
  24         message(STATUS "Building out-of-source")
  25         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  26 endif()
  27
  28
  29 if(COMMAND cmake_policy)
  30         cmake_policy(SET CMP0003 OLD)
  31         cmake_policy(SET CMP0005 OLD)
  32 endif()
  33
  34 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  35
  36 # Supress regeneration
  37 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  38
  39
  40 include(LyXMacros)
  41
  42 # Usage LYX_OPTION
  43 # 1. parameter: option name without prefix 'LYX_'
  44 # 2. parameter: description
  45 # 3. parameter: default value, ON or OFF
  46 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  47
  48
  49 LYX_OPTION_INIT()
  50
  51 # Options for all compilers/systems
  52 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  53 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  54 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  55 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  56 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  57 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  58 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  59 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  60 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  61 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  62 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  63 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  64 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  65 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  66 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  67
  68 # GCC specific
  69 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  70 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
  71 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
  72 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
  73 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  74 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
  75 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
  76
  77 # MSVC specific
  78 LYX_OPTION(CONSOLE               "Show console on Windows" ON MSVC)
  79 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
  80 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
  81 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
  82 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  83
  84
  85 if(help OR HELP)
  86         message(STATUS)
  87         message(STATUS "Available options: (dis/enable with -D=0/1)")
  88         message(STATUS)
  89         LYX_OPTION_LIST_ALL(help)
  90         message(STATUS)
  91 else()
  92
  93 # 'project' triggers the searching for a compiler
  94 project(${LYX_PROJECT})
  95
  96
  97 # Check option dependencies
  98
  99 if(LYX_CPACK)
 100         set(LYX_INSTALL ON)
 101 endif()
 102
 103 if(LYX_INSTALL)
 104         set(LYX_NLS ON)
 105         if (WIN32)
 106                 set(LYX_HUNSPELL ON)
 107         endif()
 108         set(LYX_CONSOLE OFF)
 109         set(LYX_PACKAGE_SUFFIX ON)
 110         set(LYX_RELEASE ON)
 111         set(LYX_PROFILE OFF)
 112 endif()
 113
 114 if(LYX_MERGE_FILES)
 115         set(LYX_PCH OFF)
 116 else()
 117         set(LYX_MERGE_REBUILD OFF)
 118 endif()
 119
 120 if(LYX_DEPENDENCIES_DOWNLOAD)
 121         message(STATUS)
 122         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 123         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 124         set(deps_files lyx20-deps-msvc2010-x86.zip)
 125         foreach(it ${deps_files})
 126                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 127                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 128                 if(NOT already_downloaded)
 129                         message(STATUS "Downloading ${it} ...")
 130                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 131                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 132                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 133                 endif()
 134         endforeach()
 135         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 136 endif()
 137
 138
 139 message(STATUS)
 140
 141 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 142 set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 143
 144
 145
 146 if(UNIX OR MINGW)
 147         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 148         message(STATUS "Using GCC version ${GCC_VERSION}")
 149         if(NOT GCC_VERSION VERSION_LESS 4.4)
 150                 set(LYX_USE_TR1 1)
 151                 # GCC <= 4.5 does not support regex: there are linker errors
 152                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 153                 set(LYX_USE_TR1_REGEX 0)
 154         endif()
 155 else()
 156         if(MSVC10)
 157                 set(LYX_USE_TR1 1)
 158                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 159         endif()
 160 endif()
 161
 162
 163 set(VERSION_INFO "CMake Build")
 164
 165 # Try to get some informations from configure.ac
 166
 167 include(LyXPaths)
 168 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 169
 170 if(WIN32)
 171         set(USE_WINDOWS_PACKAGING 1)
 172 elseif(APPLE)
 173         set(USE_MACOSX_PACKAGING 1)
 174 else()
 175         set(USE_POSIX_PACKAGING 1)
 176 endif()
 177
 178 macro(setstripped _varname _value)
 179         string(STRIP ${_value} _v)
 180         if(USE_POSIX_PACKAGING)
 181                 string(TOLOWER ${_v} ${_varname})
 182         else()
 183                 set(${_varname} ${_v})
 184         endif()
 185 endmacro(setstripped)
 186
 187 foreach(_c_l ${_config_lines} )
 188         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 189                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 190                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 191                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 192                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 193                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 194                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 195                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 196                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 197                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 198                 endif()
 199         endif()
 200         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 201                 set(LYX_DATE "${CMAKE_MATCH_1}")
 202         endif()
 203 endforeach(_c_l)
 204
 205
 206 if (LYX_INSTALL_PREFIX)
 207         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 208         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 209 endif()
 210 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 211
 212 if(LYX_PACKAGE_SUFFIX)
 213         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 214 else()
 215         set(PACKAGE ${PACKAGE_BASE})
 216 endif()
 217
 218 if(LYX_PROGRAM_SUFFIX)
 219         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 220 else()
 221         set(PROGRAM_SUFFIX "")
 222 endif()
 223
 224
 225 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 226         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 227         if (UNIX)
 228                 # don't use the default "/usr/local"
 229                 # but respect the user-choice on the command-line
 230                 if(LYX_INSTALL_SUFFIX)
 231                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 232                 else()
 233                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 234                 endif()
 235         endif()
 236         if(WIN32)
 237                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 238         endif()
 239 endif()
 240
 241 if (WIN32)
 242         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 243 else()
 244         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 245 endif()
 246
 247 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 248 set(LYX_LOCALEDIR "locale")
 249 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 250 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 251
 252
 253 if(NOT GROUP_CODE)
 254         #set(GROUP_CODE "The Golden Code")
 255         set(GROUP_CODE flat)
 256 endif()
 257
 258 # lyx's source files
 259 set(LYX_CPP_FILES *.cpp)
 260 set(LYX_HPP_FILES *.h)
 261 set(LYX_MOC_FILES moc_*.cpp)
 262
 263
 264 include(ProjectSourceGroup)
 265
 266
 267 if(LYX_PROFILE)
 268         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 269         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 270 endif()
 271
 272 if(LYX_RELEASE)
 273         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build release version" FORCE)
 274 else()
 275         set(CMAKE_BUILD_TYPE Debug CACHE STRING "Build debug version" FORCE)
 276 endif()
 277
 278 # When shared libs are supported enable this option
 279 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 280 if(LYX_SHARED_LIBRARIES)
 281         set(library_type SHARED)
 282 else()
 283         set(library_type STATIC)
 284 endif()
 285
 286 if(NOT MSVC)
 287         if(NOT LYX_QUIET)
 288                 set(CMAKE_VERBOSE_MAKEFILE ON)
 289         endif()
 290         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 291         if(LYX_STDLIB_DEBUG)
 292                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 293         endif()
 294         if(LYX_CONCEPT_CHECKS)
 295                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 296         endif()
 297         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 298         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 299         if(MINGW)
 300                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 301         else()
 302                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 303         endif()
 304         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 305 endif()
 306
 307
 308 find_package(Qt4 REQUIRED)
 309
 310
 311 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 312
 313 if(LYX_ASPELL)
 314         find_package(ASPELL)
 315         include_directories(${ASPELL_INCLUDE_DIR})
 316 endif()
 317
 318 if(LYX_ENCHANT)
 319         find_package(Enchant REQUIRED)
 320         include_directories(${ENCHANT_INCLUDE_DIR})
 321 endif()
 322
 323 if(LYX_HUNSPELL)
 324         find_package(Hunspell REQUIRED)
 325         include_directories(${HUNSPELL_INCLUDE_DIR})
 326 endif()
 327
 328 if(LYX_NLS)
 329         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 330         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 331                 message(FATAL_ERROR "Python 2.6 needed!")
 332         endif()
 333         find_package(LyXGettext REQUIRED)
 334         include_directories(${TOP_SRC_DIR}/po)
 335         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 336 endif()
 337
 338 if(LYX_NLS)
 339         if(LYX_EXTERNAL_LIBINTL)
 340                 find_package(Libintl REQUIRED)
 341                 if(DEFINED LIBINTL_LIBRARIES)
 342                         # find getext when configuring
 343                         list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBINTL_LIBRARIES})
 344                         # on mac use iconv also form ports
 345                         get_filename_component(ICONV_RELATIVE_TO_LIBINTL ${LIBINTL_LIBRARIES} PATH)
 346                 endif()
 347         else()
 348                 add_subdirectory(intl "${TOP_BINARY_DIR}/intl")
 349         endif()
 350 endif()
 351
 352 find_package(ICONV REQUIRED)
 353 find_package(ZLIB REQUIRED)
 354
 355 if(LYX_EXTERNAL_BOOST)
 356         message(STATUS "Searching for boost")
 357         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 358         if(Boost_FOUND)
 359                 message(STATUS "Boost found")
 360                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 361                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 362         else()
 363                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 364         endif()
 365 else()
 366         if(LYX_USE_TR1_REGEX)
 367                 set(Lyx_Boost_Libraries boost_signals)
 368         else()
 369                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 370         endif()
 371         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 372         include_directories(${TOP_SRC_DIR}/boost)
 373         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 374 endif()
 375
 376
 377
 378
 379 if(WIN32)
 380         if(NOT LYX_CONSOLE)
 381                 set(WIN32_CONSOLE WIN32)
 382                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 383         endif()
 384         if(MSVC)
 385                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 386                 # disable checked iterators for msvc release builds to get maximum speed
 387                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 388         else()
 389                 add_definitions(-DWINVER=0x0500)
 390         endif()
 391 endif()
 392
 393 message(STATUS "")
 394 foreach(_v PACKAGE PACKAGE_VERSION
 395         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 396         LYX_ABS_TOP_SRCDIR
 397         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 398         if(NOT DEFINED ${_v})
 399                 message(FATAL_ERROR "${_v} not defined")
 400         endif()
 401         string(SUBSTRING "${_v}                            " 0 28 _v1)
 402         message(STATUS "----- ${_v1}: ${${_v}}")
 403 endforeach(_v)
 404 message(STATUS "")
 405
 406
 407 if(LYX_PCH)
 408         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 409         # Not sure if it works for all non-msvc compilers
 410         include(PCHSupport_26)
 411         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 412         configure_file(${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 413         add_definitions(-DLYX_ENABLE_PCH)
 414
 415         if(MSVC)
 416                 macro(lyx_add_msvc_pch name_)
 417                         set_source_files_properties(${${name_}_sources} PROPERTIES
 418                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 419                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 420                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 421                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 422                                 ${TOP_BINARY_DIR}/pcheaders.h)
 423                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 424                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 425                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 426                 endmacro(lyx_add_msvc_pch)
 427                 macro(lyx_add_gcc_pch name_)
 428                 endmacro()
 429         else()
 430                 macro(lyx_add_msvc_pch name_)
 431                 endmacro()
 432                 macro(lyx_add_gcc_pch name_)
 433                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 434                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 435                 endmacro()
 436         endif()
 437 else()
 438         macro(lyx_add_msvc_pch)
 439         endmacro(lyx_add_msvc_pch)
 440         macro(lyx_add_gcc_pch name_)
 441         endmacro()
 442 endif()
 443
 444 if(MSVC)
 445         if(LYX_VLD)
 446                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 447                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 448                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 449                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 450         endif()
 451
 452         if(LYX_WALL)
 453                 # Use the highest warning level
 454                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 455
 456                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 457                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 458                 else()
 459                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 460                 endif()
 461
 462                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 463                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 464                 else()
 465                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 466                 endif()
 467
 468                 # add here warnings which should produce an error /weXXXX
 469                 set(MSVC_W_ERROR   "/we4101 /we4189")
 470                 # add here warnings which should be disabled /wdXXXX
 471                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 472
 473                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 474                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 475                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 476
 477         else()
 478                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 479
 480                 # add here warnings which should produce an error /weXXXX
 481                 set(MSVC_W_ERROR   "/we4101 /we4189")
 482                 # add here warnings which should be disabled /wdXXXX
 483                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 484
 485                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 486                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 487                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 488
 489         endif()
 490         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 491         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 492         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 493
 494         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 495         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 496         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 497         message(STATUS "")
 498 endif()
 499
 500
 501 if(LYX_DEBUG_GLIBC)
 502         set(_GLIBCXX_DEBUG 1)
 503 endif()
 504
 505 if(LYX_DEBUG_GLIBC_PEDANTIC)
 506         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 507 endif()
 508
 509 # compiler tests, config.h generation
 510 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 511         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 512 else()
 513         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 514         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 515 endif()
 516
 517 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 518
 519
 520 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 521 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 522 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 523
 524
 525 if(LYX_INSTALL)
 526         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 527         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 528                 message(FATAL_ERROR "Perl required!")
 529         endif()
 530         add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 531         add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 532         include(../Install)
 533 endif()
 534
 535
 536 message(STATUS)
 537 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 538 message(STATUS)
 539 LYX_OPTION_LIST_ALL(used)
 540
 541
 542 if(LYX_NLS)
 543         message(STATUS)
 544         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 545         message(STATUS)
 546         message(STATUS "  * intl")
 547         message(STATUS "     - header : ${LIBINTL_HEADER}")
 548         message(STATUS "     - library: ${LIBINTL_LIBRARIES}")
 549         message(STATUS "  * iconv")
 550         message(STATUS "     - header : ${ICONV_HEADER}")
 551         message(STATUS "     - library: ${ICONV_LIBRARY}")
 552         message(STATUS "  * zlib")
 553         message(STATUS "     - header : ${ZLIB_HEADER}")
 554         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 555         message(STATUS)
 556 endif()
 557
 558 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 559 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 560 FILE(STRINGS "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 561
 562 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 563 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 564
 565 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 566
 567 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 568 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 569 #
 570 # needed by rpm
 571 set(CPACK_SET_DESTDIR "ON")
 572 FILE(READ "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 573 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 574 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 575 #
 576 # the next ones are needed by deb
 577 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 578 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 579
 580 # This is experimental, valid on _my_ system (Kornel)
 581 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 582 if(ASPELL_FOUND)
 583         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 584 endif()
 585 if(ENCHANT_FOUND)
 586         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 587 endif()
 588 if(LYX_EXTERNAL_BOOST)
 589         if(Boost_FOUND)
 590                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 591         endif()
 592 endif()
 593 #
 594 # for the next ones, cpack insists on data with values in some file
 595 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_description.txt")
 596 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}/LyX_license.txt")
 597
 598 # Find the revision number and use it as the release in rpm-package-build.
 599 # This way we may omit the otherwise needed "--force" parameter when
 600 # installing from that rpm package.
 601 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 602 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 603 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 604         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 605         # We use this value also to set the package-patch-value
 606         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 607                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 608         endif()
 609 endif()
 610
 611 # we do not have a readme or welcome data,
 612 # so we do not provide infofiles for
 613 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 614
 615 if(LYX_CPACK)
 616         include(CPack)
 617 endif()
 618
 619 #Now it is possible to create some packages
 620 # cd <BuildDir>
 621 # make package
 622 #############################################################################################
 623 # So, e.g. for variables
 624 #    CMAKE_PROJECT_NAME                     : lyx
 625 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 626 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 627 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 628 #    CMAKE_SYSTEM_NAME                      : Linux
 629 #    CPACK_BINARY_DEB:BOOL                  : ON
 630 #
 631 # the package name builds as "lyx-2.0.1-Linux.deb"
 632 #
 633 ############################## rpm ################################### deb ##################
 634 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 635 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 636 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 637 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 638 #
 639 message(STATUS)
 640
 641 endif() #help
 642