CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6
   7 cmake_minimum_required(VERSION 2.6.4)
   8
   9 set(LYX_PROJECT LyX)
  10
  11 enable_testing()
  12
  13 get_filename_component(lyx_dir_readme ${CMAKE_SOURCE_DIR}/README ABSOLUTE)
  14 get_filename_component(TOP_SRC_DIR ${lyx_dir_readme} PATH)
  15
  16 set(LYX_CMAKE_DIR "development/cmake")
  17 set(TOP_CMAKE_PATH "${TOP_SRC_DIR}/${LYX_CMAKE_DIR}")
  18 set(TOP_MODULE_PATH "${TOP_CMAKE_PATH}/modules")
  19 set(TOP_SCRIPT_PATH "${TOP_CMAKE_PATH}/scripts")
  20
  21 set(CMAKE_MODULE_PATH "${TOP_MODULE_PATH}")
  22
  23 set(CMAKE_PROJECT_NAME ${LYX_PROJECT})
  24
  25 message(STATUS)
  26 if (${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
  27         message(STATUS "Building in-source")
  28         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}/build")
  29 else()
  30         message(STATUS "Building out-of-source")
  31         set(TOP_BINARY_DIR "${CMAKE_BINARY_DIR}")
  32 endif()
  33
  34
  35 if(COMMAND cmake_policy)
  36         cmake_policy(SET CMP0003 OLD)
  37         cmake_policy(SET CMP0005 OLD)
  38 endif()
  39
  40 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  41
  42 # Supress regeneration
  43 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  44
  45 if(NOT help AND NOT HELP)
  46         # 'project' triggers the searching for a compiler
  47         project(${LYX_PROJECT})
  48 endif()
  49
  50 if(UNIX)
  51         set(ARCH_TRIPLET )
  52         FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
  53         if(DPKG_ARCHITECTURE_EXECUTABLE)
  54                 EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  55                                 OUTPUT_VARIABLE ARCH_TRIPLET
  56                                 ERROR_VARIABLE ERROR_ARCH_TRIPLET
  57                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  58         endif()
  59 endif()
  60 if(ARCH_TRIPLET)
  61         set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
  62 else()
  63         set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
  64 endif()
  65
  66 include(LyXMacros)
  67
  68 # Usage LYX_OPTION
  69 # 1. parameter: option name without prefix 'LYX_'
  70 # 2. parameter: description
  71 # 3. parameter: default value, ON or OFF
  72 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  73
  74
  75 LYX_OPTION_INIT()
  76
  77 # Options for all compilers/systems
  78 LYX_OPTION(CPACK            "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  79 LYX_OPTION(LOCALVERSIONING  "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
  80 LYX_OPTION(INSTALL          "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  81 LYX_OPTION(NLS              "Enable Native Language Support (NLS)" ON ALL)
  82 LYX_OPTION(ASPELL           "Require aspell" OFF ALL)
  83 LYX_OPTION(ENCHANT          "Require Enchant" OFF ALL)
  84 LYX_OPTION(HUNSPELL         "Require Hunspell" OFF ALL)
  85 LYX_OPTION(DEVEL_VERSION    "Build developer version" OFF ALL)
  86 LYX_OPTION(RELEASE          "Build release version, build debug when disabled" OFF ALL)
  87 LYX_OPTION(DEBUG            "Enforce debug build"  OFF ALL)
  88 LYX_OPTION(NO_OPTIMIZE      "Don't use any optimization/debug flags"  OFF ALL)
  89 LYX_OPTION(PACKAGE_SUFFIX   "Use version suffix for packaging" ON ALL)
  90 LYX_OPTION(PCH              "Use precompiled headers" OFF ALL)
  91 LYX_OPTION(MERGE_FILES      "Merge source files into one compilation unit" OFF ALL)
  92 LYX_OPTION(MERGE_REBUILD    "Rebuild generated files from merged files build" OFF ALL)
  93 LYX_OPTION(QUIET            "Don't generate verbose makefiles" OFF ALL)
  94 LYX_OPTION(INSTALL_PREFIX   "Install path for LyX" OFF ALL)
  95 LYX_OPTION(BUNDLE           "Build bundle  (experimental) " OFF ALL)
  96
  97 # GCC specific
  98 LYX_OPTION(PROFILE              "Build profile version" OFF GCC)
  99 LYX_OPTION(EXTERNAL_BOOST       "Use external boost" OFF GCC)
 100 LYX_OPTION(PROGRAM_SUFFIX       "Append version suffix to binaries" ON GCC)
 101 LYX_OPTION(DEBUG_GLIBC          "Enable libstdc++ debug mode" OFF GCC)
 102 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
 103 LYX_OPTION(STDLIB_DEBUG         "Use debug stdlib" OFF GCC)
 104 LYX_OPTION(CONCEPT_CHECKS       "Enable concept-checks" OFF GCC)
 105 LYX_OPTION(PROFILE              "Build with options for gprof" OFF GCC)
 106 LYX_OPTION(ENABLE_CXX11         "Build with options for c++11-mode" OFF GCC)
 107
 108 # MSVC specific
 109 LYX_OPTION(CONSOLE               "Show console on Windows, enforce with =FORCE" ON MSVC)
 110 LYX_OPTION(VLD                   "Use VLD with MSVC" OFF MSVC)
 111 LYX_OPTION(WALL                  "Enable all warnings" OFF MSVC)
 112 LYX_OPTION(CONFIGURE_CHECKS      "Also run configure checks for MSVC" OFF MSVC)
 113 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
 114
 115 # APPLE specific
 116 LYX_OPTION(DMG                   "Build as Mac bundle, needed for .dmg  (experimental) " OFF MAC)
 117 LYX_OPTION(COCOA                 "Use Cocoa on Mac" OFF MAC)
 118
 119
 120 if(help OR HELP)
 121         message(STATUS)
 122         message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
 123         message(STATUS)
 124         LYX_OPTION_LIST_ALL(help)
 125         message(STATUS)
 126         RETURN()
 127 endif()
 128
 129 # Check option dependencies
 130
 131 if(LYX_DMG)
 132         set(LYX_BUNDLE ON)
 133         set(LYX_CPACK ON)
 134 endif()
 135
 136 if(LYX_CPACK)
 137         set(LYX_INSTALL ON)
 138 endif()
 139
 140 if(LYX_INSTALL)
 141         set(LYX_NLS ON)
 142         if (WIN32)
 143                 set(LYX_HUNSPELL ON)
 144         endif()
 145         if(LYX_CONSOLE MATCHES "FORCE")
 146                 set(LYX_CONSOLE ON)
 147         else()
 148                 set(LYX_CONSOLE OFF)
 149         endif()
 150         set(LYX_PACKAGE_SUFFIX ON)
 151         if(NOT LYX_DEBUG)
 152                 set(LYX_RELEASE ON)
 153         endif()
 154         set(LYX_PROFILE OFF)
 155 endif()
 156
 157
 158 if(LYX_MERGE_FILES)
 159         set(LYX_PCH OFF)
 160 else()
 161         set(LYX_MERGE_REBUILD OFF)
 162 endif()
 163
 164 if(LYX_DEPENDENCIES_DOWNLOAD)
 165         message(STATUS)
 166         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
 167         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
 168         set(deps_files lyx20-deps-msvc2010-x86.zip)
 169         set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
 170         foreach(it ${deps_files})
 171                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 172                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 173                 if(NOT already_downloaded)
 174                         message(STATUS "Downloading ${it} ...")
 175                         file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
 176                         list(GET status 0 status_code)
 177                         list(GET status 1 status_string)
 178                         if(NOT status_code EQUAL 0)
 179                                 file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
 180                                 message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
 181                         endif()
 182                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 183                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 184                 endif()
 185         endforeach()
 186         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 187 endif()
 188
 189
 190
 191 message(STATUS)
 192
 193 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 194 if(WIN32)
 195         set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 196 else()
 197         set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 198 endif()
 199
 200
 201 set(LYX_GCC11_MODE)
 202 if(UNIX OR MINGW)
 203         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 204         message(STATUS "Using GCC version ${GCC_VERSION}")
 205         if(NOT GCC_VERSION VERSION_LESS 4.4)
 206                 set(LYX_USE_TR1 1)
 207                 # GCC <= 4.5 does not support regex: there are linker errors
 208                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 209                 set(LYX_USE_TR1_REGEX 0)
 210         endif()
 211         if (LYX_ENABLE_CXX11)
 212                 if(GCC_VERSION VERSION_GREATER 4.7)
 213                         set(LYX_GCC11_MODE "-std=gnu++11")
 214                 elseif(GCC_VERSION VERSION_GREATER 4.2)
 215                         set(LYX_GCC11_MODE "-std=gnu++0x")
 216                 endif()
 217         endif()
 218 else()
 219         if(MSVC10)
 220                 set(LYX_USE_TR1 1)
 221                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 222         endif()
 223 endif()
 224
 225
 226 set(VERSION_INFO "CMake Build")
 227
 228 # Try to get some informations from configure.ac
 229
 230 include(LyXPaths)
 231 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 232
 233 if(WIN32)
 234         set(USE_WINDOWS_PACKAGING ON)
 235 elseif(APPLE)
 236         set(USE_MACOSX_PACKAGING ON)
 237 else()
 238         set(USE_POSIX_PACKAGING ON)
 239 endif()
 240
 241 macro(setstripped _varname)
 242         if(${ARGC} GREATER 1)
 243                 string(STRIP "${ARGV1}" _v)
 244                 if(USE_POSIX_PACKAGING)
 245                         string(TOLOWER ${_v} ${_varname})
 246                 else()
 247                         set(${_varname} ${_v})
 248                 endif()
 249         else()
 250                 set(${_varname})
 251         endif()
 252 endmacro(setstripped)
 253
 254 foreach(_c_l ${_config_lines} )
 255         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 256                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 257                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 258                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 259                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
 260                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 261                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 262                         set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
 263                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 264                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 265                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 266                 endif()
 267         endif()
 268         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 269                 set(LYX_DATE "${CMAKE_MATCH_1}")
 270         endif()
 271 endforeach(_c_l)
 272
 273 if (LYX_LOCALVERSIONING)
 274         # Find the revision number and for later use
 275         FIND_PROGRAM(LYX_GITVERSION git)
 276         #message(STATUS "gitversion = ${LYX_GITVERSION}")
 277         if(LYX_GITVERSION)
 278                 EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "describe" WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 279                 if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
 280                   # We will add offset of 40000 to get appropriate value to
 281                   # previous svn.
 282                   # We use this value than also to set the package-patch-value
 283                   MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
 284                   set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
 285                   set(ENABLE_DIST ON)
 286                 endif()
 287         else()
 288                 set(LYX_REVISION_VERSION git) #TODO use date
 289         endif()
 290 else()
 291         set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
 292 endif()
 293
 294 if(LYX_PROGRAM_SUFFIX)
 295         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 296 else()
 297         set(PROGRAM_SUFFIX "")
 298 endif()
 299
 300 add_custom_target(lyx_version ALL
 301   COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
 302   )
 303 set_target_properties(lyx_version PROPERTIES FOLDER "applications")
 304
 305 if(APPLE)
 306         set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 307         configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 308 endif()
 309
 310 if(LYX_BUNDLE)
 311         set(LYX_CPACK ON)
 312         message(STATUS)
 313         message(STATUS "Bundle creation is enabled (experimental):")
 314         message(STATUS "    make")
 315         message(STATUS "    make install/strip")
 316         message(STATUS "    make package")
 317         if(APPLE)
 318                 set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
 319                 set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
 320                 set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
 321                 set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
 322                 set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
 323                 if(NOT LYX_INSTALL_PREFIX)
 324                         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
 325                         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 326                 endif()
 327                 # Change the owner so that the install can work
 328                 install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
 329         elseif(UNIX)
 330                 message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
 331                 message(STATUS "  - fix PATH so a other qmake is found by cmake")
 332                 message(STATUS "  - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
 333         elseif(WIN32)
 334                 message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
 335         endif()
 336 endif()
 337
 338 if(LYX_INSTALL_PREFIX)
 339         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 340         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 341 endif()
 342 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 343
 344 if(LYX_PACKAGE_SUFFIX)
 345         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 346 else()
 347         set(PACKAGE ${PACKAGE_BASE})
 348 endif()
 349
 350
 351 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 352         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 353         if (UNIX)
 354                 # don't use the default "/usr/local"
 355                 # but respect the user-choice on the command-line
 356                 if(LYX_INSTALL_SUFFIX)
 357                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 358                 else()
 359                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 360                 endif()
 361         endif()
 362         if(WIN32)
 363                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 364         endif()
 365 endif()
 366 if(IS_ABSOLUTE)
 367         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
 368 else()
 369         set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
 370 endif()
 371
 372
 373
 374 if(NOT LYX_DATA_SUBDIR)
 375         if (WIN32)
 376                 set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 377         else()
 378                 set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 379         endif()
 380 endif()
 381
 382 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 383 set(LYX_LOCALEDIR "locale")
 384 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 385 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 386
 387
 388 if(LYX_INSTALL AND WIN32)
 389         message(STATUS "Configuring NSIS files")
 390         configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
 391         configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
 392         configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
 393         message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
 394 endif()
 395
 396 if(NOT GROUP_CODE)
 397         #set(GROUP_CODE "The Golden Code")
 398         set(GROUP_CODE flat)
 399 endif()
 400
 401 # lyx's source files
 402 set(LYX_CPP_FILES *.cpp)
 403 set(LYX_HPP_FILES *.h)
 404 set(LYX_MOC_FILES moc_*.cpp)
 405
 406 include(ProjectSourceGroup)
 407
 408
 409 if(LYX_PROFILE AND NOT MSVC)
 410         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 411         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg")
 412         set(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}  -pg")
 413 else()
 414         set(LYX_PROFILE OFF)
 415 endif()
 416
 417
 418 if(LYX_NO_OPTIMIZE)
 419         set(CMAKE_BUILD_TYPE None)
 420         set(LYX_DEBUG OFF)
 421         set(LYX_RELEASE OFF)
 422         set(LYX_PROFILE OFF)
 423 elseif(LYX_RELEASE)
 424         set(CMAKE_BUILD_TYPE Release)
 425         set(LYX_DEBUG OFF)
 426         set(LYX_PROFILE OFF)
 427 elseif(LYX_PROFILE)
 428         set(CMAKE_BUILD_TYPE Profile)
 429         set(LYX_DEBUG OFF)
 430 else()
 431         set(CMAKE_BUILD_TYPE Debug)
 432         set(LYX_DEBUG ON)
 433 endif()
 434
 435
 436 # When shared libs are supported enable this option
 437 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 438 if(LYX_SHARED_LIBRARIES)
 439         set(library_type SHARED)
 440 else()
 441         set(library_type STATIC)
 442 endif()
 443
 444 if(NOT MSVC)
 445         if(NOT LYX_QUIET)
 446                 set(CMAKE_VERBOSE_MAKEFILE ON)
 447         endif()
 448         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter ${LYX_GCC11_MODE}")
 449         if(LYX_STDLIB_DEBUG)
 450                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 451         endif()
 452         if(LYX_CONCEPT_CHECKS)
 453                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 454         endif()
 455         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 456         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g3 -D_DEBUG" CACHE TYPE STRING FORCE)
 457         if(MINGW)
 458                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 459         else()
 460                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 461         endif()
 462 endif()
 463
 464 find_package(Qt5Core QUIET)
 465 if (Qt5Core_FOUND)
 466         find_package(Qt5Widgets REQUIRED)
 467         set(QTVERSION ${Qt5Core_VERSION})
 468         macro (qt_use_modules)
 469                 qt5_use_modules(${ARGN})
 470         endmacro()
 471         macro (qt_add_resources)
 472                 qt5_add_resources(${ARGN})
 473         endmacro()
 474         macro (qt_wrap_uifiles)
 475                 qt5_wrap_ui(${ARGN})
 476         endmacro()
 477 else()
 478         find_package(Qt4 "4.5.0" REQUIRED)
 479         macro (qt_use_modules)
 480         endmacro()
 481         macro (qt_add_resources)
 482                 qt4_add_resources(${ARGN})
 483         endmacro()
 484         macro (qt_wrap_uifiles)
 485                 qt4_wrap_ui(${ARGN})
 486         endmacro()
 487 endif()
 488
 489 find_package(Magic)
 490 if(Magic_FOUND)
 491         set(HAVE_MAGIC_H 1)
 492 endif()
 493
 494 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 495
 496 if(LYX_ASPELL)
 497         find_package(ASPELL)
 498         include_directories(${ASPELL_INCLUDE_DIR})
 499 endif()
 500
 501 if(LYX_ENCHANT)
 502         find_package(Enchant REQUIRED)
 503         include_directories(${ENCHANT_INCLUDE_DIR})
 504 endif()
 505
 506 if(LYX_HUNSPELL)
 507         find_package(Hunspell REQUIRED)
 508         include_directories(${HUNSPELL_INCLUDE_DIR})
 509 endif()
 510
 511 if(LYX_NLS)
 512         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python2 python HINTS ${GNUWIN32_DIR}/python)
 513         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 514                 message(FATAL_ERROR "Python 2.6 needed!")
 515         endif()
 516         find_package(LyXGettext REQUIRED)
 517         add_subdirectory(po "${TOP_BINARY_DIR}/po")
 518 endif()
 519
 520 find_package(ICONV REQUIRED)
 521 find_package(ZLIB REQUIRED)
 522
 523 if(LYX_EXTERNAL_BOOST)
 524         message(STATUS "Searching for boost")
 525         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 526         if(Boost_FOUND)
 527                 message(STATUS "Boost found")
 528                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 529                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 530         else()
 531                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 532         endif()
 533 else()
 534         if(LYX_USE_TR1_REGEX)
 535                 set(Lyx_Boost_Libraries boost_signals)
 536         else()
 537                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 538         endif()
 539         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 540         include_directories(${TOP_SRC_DIR}/boost)
 541         add_subdirectory(boost "${TOP_BINARY_DIR}/boost")
 542 endif()
 543
 544
 545
 546
 547 if(WIN32)
 548         if(NOT LYX_CONSOLE)
 549                 set(WIN32_CONSOLE WIN32)
 550                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 551         endif()
 552         if(MSVC)
 553                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 554                 # disable checked iterators for msvc release builds to get maximum speed
 555                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 556         else()
 557                 add_definitions(-DWINVER=0x0500)
 558         endif()
 559 endif()
 560
 561 # Compute qt4-version from ${QTVERSION}
 562
 563 message(STATUS "")
 564 foreach(_v PACKAGE PACKAGE_VERSION
 565         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 566         LYX_ABS_TOP_SRCDIR
 567         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 568         if(NOT DEFINED ${_v})
 569                 message(FATAL_ERROR "${_v} not defined")
 570         endif()
 571         string(SUBSTRING "${_v}                            " 0 28 _v1)
 572         message(STATUS "----- ${_v1}: ${${_v}}")
 573 endforeach(_v)
 574 message(STATUS "")
 575
 576
 577 if(LYX_PCH)
 578         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 579         # Not sure if it works for all non-msvc compilers
 580         include(PCHSupport_26)
 581         configure_file(${TOP_CMAKE_PATH}/pcheaders.h      ${TOP_BINARY_DIR}/pcheaders.h)
 582         configure_file(${TOP_CMAKE_PATH}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 583         add_definitions(-DLYX_ENABLE_PCH)
 584
 585         if(MSVC)
 586                 macro(lyx_add_msvc_pch name_)
 587                         set_source_files_properties(${${name_}_sources} PROPERTIES
 588                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 589                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 590                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 591                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 592                                 ${TOP_BINARY_DIR}/pcheaders.h)
 593                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 594                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 595                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 596                 endmacro(lyx_add_msvc_pch)
 597                 macro(lyx_add_gcc_pch name_)
 598                 endmacro()
 599         else()
 600                 macro(lyx_add_msvc_pch name_)
 601                 endmacro()
 602                 macro(lyx_add_gcc_pch name_)
 603                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 604                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 605                 endmacro()
 606         endif()
 607 else()
 608         macro(lyx_add_msvc_pch)
 609         endmacro(lyx_add_msvc_pch)
 610         macro(lyx_add_gcc_pch name_)
 611         endmacro()
 612 endif()
 613
 614
 615 if(MSVC)
 616
 617         if(LYX_VLD)
 618                 set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/development/Win32/vld)
 619                 add_subdirectory(${vld_path}/cmake)
 620                 include(${vld_path}/cmake/vld.cmake) # forced include
 621                 set(vld_dll vld)
 622         endif()
 623
 624         if(LYX_WALL)
 625                 # Use the highest warning level
 626                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 627
 628                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 629                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 630                 else()
 631                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 632                 endif()
 633
 634                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 635                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 636                 else()
 637                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 638                 endif()
 639
 640                 # add here warnings which should produce an error /weXXXX
 641                 set(MSVC_W_ERROR   "/we4101 /we4189")
 642                 # add here warnings which should be disabled /wdXXXX
 643                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 644
 645                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 646                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 647                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 648
 649         else()
 650                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 651
 652                 # add here warnings which should produce an error /weXXXX
 653                 set(MSVC_W_ERROR   "/we4101 /we4189")
 654                 # add here warnings which should be disabled /wdXXXX
 655                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 656
 657                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 658                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 659                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 660
 661         endif()
 662
 663         if (NOT Qt5Core_FOUND)
 664                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 665                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 666                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 667         endif()
 668
 669         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 670         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 671         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 672         message(STATUS "")
 673 endif()
 674
 675
 676 if(LYX_DEBUG_GLIBC)
 677         set(_GLIBCXX_DEBUG ON)
 678 endif()
 679
 680 if(LYX_DEBUG_GLIBC_PEDANTIC)
 681         set(_GLIBCXX_DEBUG_PEDANTIC ON)
 682 endif()
 683
 684 # Xcode compiler
 685 if (CMAKE_GENERATOR MATCHES Xcode)
 686         # Automatically select the Xcode compiler if not set
 687         if (NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 688                 # XCode >= 3.1 has gcc 4.2 (up to actual Xcode)
 689                 if (XCODE_VERSION VERSION_GREATER "3.1")
 690                         SET(CMAKE_XCODE_ATTRIBUTE_GCC_VERSION "com.apple.compilers.llvmgcc42")
 691                 ENDIF(XCODE_VERSION VERSION_GREATER "3.1")
 692         ENDIF(NOT DEFINED CMAKE_XCODE_ATTRIBUTE_GCC_VERSION)
 693
 694         # Print the selected compiler version
 695     MESSAGE(STATUS "---- Using XCode compiler CMAKE_XCODE_ATTRIBUTE_GCC_VERSION=${CMAKE_XCODE_ATTRIBUTE_GCC_VERSION}")
 696 ENDIF(CMAKE_GENERATOR MATCHES Xcode)
 697
 698 if (WIN32 AND Qt5Core_FOUND)
 699         set(Z_PREFIX 1)
 700 endif()
 701
 702 # compiler tests, config.h generation
 703 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 704         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 705 else()
 706         include(${LYX_CMAKE_DIR}/ConfigureChecks.cmake)
 707         configure_file(${LYX_CMAKE_DIR}/configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 708 endif()
 709
 710 configure_file(${LYX_CMAKE_DIR}/config.h.cmake ${TOP_BINARY_DIR}/config.h)
 711
 712 if(QTVERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+).*")
 713         MATH(EXPR QT4_VERSION "(${CMAKE_MATCH_1}<<16)|(${CMAKE_MATCH_2}<<8)|${CMAKE_MATCH_3}")
 714 endif()
 715
 716 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
 717 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
 718
 719 set (cmd ${CMAKE_CTEST_COMMAND})
 720 if (MSVC)
 721         set (cmd ${cmd} -C ${CMAKE_CFG_INTDIR})
 722 else ()
 723         set (cmd ${cmd} -C ${CMAKE_BUILD_TYPE})
 724 endif ()
 725 add_custom_target (lyx_run_tests COMMAND ${cmd})
 726 set_target_properties(lyx_run_tests PROPERTIES FOLDER "tests")
 727
 728
 729 add_subdirectory(src "${TOP_BINARY_DIR}/src")
 730 add_subdirectory(lib/lyx2lyx "${TOP_BINARY_DIR}/lyx2lyx")
 731 add_subdirectory(lib/scripts "${TOP_BINARY_DIR}/scripts")
 732 add_subdirectory(lib/examples "${TOP_BINARY_DIR}/lib/examples")
 733
 734
 735 if(LYX_INSTALL)
 736         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 737                 message(STATUS "Python required to create doc!")
 738         else()
 739                 add_subdirectory(${LYX_CMAKE_DIR}/man "${TOP_BINARY_DIR}/man")
 740                 add_subdirectory(${LYX_CMAKE_DIR}/doc "${TOP_BINARY_DIR}/doc")
 741         endif()
 742         if(NOT(LYX_BUNDLE AND APPLE))
 743                 include(../Install)
 744         endif()
 745 endif()
 746
 747 add_subdirectory(sourcedoc "${TOP_BINARY_DIR}/sourcedoc")
 748 add_subdirectory(development/autotests "${TOP_BINARY_DIR}/autotests")
 749
 750 message(STATUS)
 751 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=ON or OFF:")
 752 message(STATUS)
 753 LYX_OPTION_LIST_ALL(used)
 754
 755
 756 if(LYX_NLS)
 757         message(STATUS)
 758         message(STATUS "Building Native Language Support (LYX_NLS is set), used libraries:")
 759         message(STATUS)
 760         message(STATUS "  * iconv")
 761         message(STATUS "     - header : ${ICONV_HEADER}")
 762         message(STATUS "     - library: ${ICONV_LIBRARY}")
 763         message(STATUS "  * zlib")
 764         message(STATUS "     - header : ${ZLIB_HEADER}")
 765         message(STATUS "     - library: ${ZLIB_LIBRARY}")
 766         message(STATUS)
 767 endif()
 768
 769 include("${TOP_CMAKE_PATH}/LyxPackaging.cmake")
 770
 771 if(ENABLE_DIST)
 772   # Use git to create the source package
 773   # git archive --format=tgz --output=/home/kornel/x.tar.gz master
 774   if(UNIX)
 775     set(DIST_FORMAT tgz)
 776   else()
 777     set(DIST_FORMAT zip)
 778   endif()
 779   set(DIST_NAME ${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}-${CMAKE_SYSTEM_NAME}.${DIST_FORMAT})
 780
 781   add_custom_command(
 782     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME}
 783     COMMAND  ${LYX_GITVERSION} archive --format=${DIST_FORMAT} --output=${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME} master
 784     WORKING_DIRECTORY ${TOP_SRC_DIR})
 785   add_custom_target(git-archive DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${DIST_NAME})
 786 endif()
 787
 788 message(STATUS)